qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 float autocvar_g_vehicle_spiderbot_respawntime;
   5
   6 //float autocvar_g_vehicle_spiderbot_crush_dmg;
   7 //float autocvar_g_vehicle_spiderbot_crush_force;
   8
   9 float autocvar_g_vehicle_spiderbot_speed_stop;
  10 float autocvar_g_vehicle_spiderbot_speed_strafe;
  11 float autocvar_g_vehicle_spiderbot_speed_walk;
  12 float autocvar_g_vehicle_spiderbot_turnspeed;
  13 float autocvar_g_vehicle_spiderbot_movement_inertia;
  14
  15 float autocvar_g_vehicle_spiderbot_springlength;
  16 float autocvar_g_vehicle_spiderbot_springup;
  17 float autocvar_g_vehicle_spiderbot_springblend;
  18
  19 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  20 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  21 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  22 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  23 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  24
  25 //float autocvar_g_vehicle_spiderbot_energy;
  26 //float autocvar_g_vehicle_spiderbot_energy_regen;
  27 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  28
  29 float autocvar_g_vehicle_spiderbot_health;
  30 float autocvar_g_vehicle_spiderbot_health_regen;
  31 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  32
  33 float autocvar_g_vehicle_spiderbot_shield;
  34 float autocvar_g_vehicle_spiderbot_shield_regen;
  35 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  36
  37 float autocvar_g_vehicle_spiderbot_minigun_damage;
  38 float autocvar_g_vehicle_spiderbot_minigun_refire;
  39 float autocvar_g_vehicle_spiderbot_minigun_spread;
  40 float autocvar_g_vehicle_spiderbot_minigun_cooldown;
  41 float autocvar_g_vehicle_spiderbot_minigun_heat;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_edgedamage;
  45 float autocvar_g_vehicle_spiderbot_rocket_force;
  46 float autocvar_g_vehicle_spiderbot_rocket_health;
  47 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  48 float autocvar_g_vehicle_spiderbot_rocket_noise;
  49 float autocvar_g_vehicle_spiderbot_rocket_radius;
  50 float autocvar_g_vehicle_spiderbot_rocket_refire;
  51 float autocvar_g_vehicle_spiderbot_rocket_reload;
  52 float autocvar_g_vehicle_spiderbot_rocket_speed;
  53 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  54
  55
  56 void spiderbot_exit(float eject);
  57 void spiderbot_enter();
  58 void spiderbot_spawn();
  59
  60 void spiderbot_rocket_unguided()
  61 {
  62     vector newdir, olddir;
  63
  64     self.nextthink  = time;
  65
  66     olddir = normalize(self.velocity);
  67     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  68     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  69
  70     UpdateCSQCProjectile(self);
  71
  72     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  73         self.use();
  74 }
  75
  76 void spiderbot_rocket_guided()
  77 {
  78     vector newdir, olddir;
  79
  80     self.nextthink  = time;
  81
  82     if not (self.realowner.vehicle)
  83         self.think = spiderbot_rocket_unguided;
  84
  85     crosshair_trace(self.realowner);
  86     olddir = normalize(self.velocity);
  87     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  88     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  89
  90     UpdateCSQCProjectile(self);
  91
  92     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  93         self.use();
  94 }
  95
  96 void spiderbot_guide_release()
  97 {
  98     entity rkt;
  99     rkt = findchainentity(realowner, self.owner);
 100     if not (rkt)
 101         return;
 102
 103     crosshair_trace(self.owner);
 104     while(rkt)
 105     {
 106         if(rkt.think == spiderbot_rocket_guided)
 107         {
 108             rkt.pos1 = trace_endpos;
 109             rkt.think = spiderbot_rocket_unguided;
 110         }
 111         rkt = rkt.chain;
 112     }
 113 }
 114
 115 void spiderbot_rocket_do()
 116 {
 117
 118     vector v;
 119     entity rocket;
 120
 121     if (self.owner.BUTTON_ATCK2)
 122     {
 123         if (self.wait == 1)
 124         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 125         {
 126             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 127                 self.tur_head.frame = 1;
 128
 129             return;
 130         }
 131         self.wait = 1;
 132     }
 133     else
 134     {
 135         if(self.wait)
 136             spiderbot_guide_release();
 137
 138         self.wait = 0;
 139     }
 140
 141     if(self.gun2.cnt > time)
 142         return;
 143
 144     if (self.tur_head.frame >= 9)
 145         self.tur_head.frame = 1;
 146
 147     if not (self.owner.BUTTON_ATCK2)
 148         return;
 149
 150     crosshair_trace(self.owner);
 151 //normalize(v_forward + (v_up * 0.5) + randomvec() * 0.25) * autocvar_g_vehicle_spiderbot_rocket_speed,
 152     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 153     rocket = vehicles_projectile("spiderbot_rocket_explode", "weapons/rocket_impact.wav", "spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 154                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 155                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 156                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health);
 157
 158     rocket.cnt        = time + 15;
 159     rocket.classname  = "spiderbot_rocket";
 160     rocket.pos1       = trace_endpos;
 161     rocket.think      = spiderbot_rocket_guided;
 162     rocket.nextthink  = time;
 163     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 164
 165
 166     self.tur_head.frame += 1;
 167     if (self.tur_head.frame == 9)
 168         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 169     else
 170         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 171
 172     self.gun2.cnt = time + self.attack_finished_single;
 173 }
 174
 175 void spiderbot_minigun_fire(entity gun, float trail)
 176 {
 177     vector v;
 178
 179     v = gettaginfo(gun, gettagindex(gun,"barrels"));
 180     v_forward = normalize(v_forward);
 181     v += v_forward * 50;
 182
 183     fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 184         autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 185
 186     if(trail)
 187     {
 188         sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 189         trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 190         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 191         pointparticles(particleeffectnum("spiderbot_minigun_impact"), trace_endpos, trace_plane_normal * 2500,1);
 192     }
 193 }
 194
 195 void spiderbot_miniguns_do()
 196 {
 197     float ftmp;
 198
 199     if((self.vehicle_reload1 == 1) || (!self.owner.BUTTON_ATCK))
 200     {
 201         ftmp = 1 / autocvar_g_vehicle_spiderbot_minigun_cooldown * sys_frametime;
 202         self.owner.vehicle_reload1 = max(self.owner.vehicle_reload1 - ftmp, 0);
 203         if(self.owner.vehicle_reload1 <= 0)
 204             self.vehicle_reload1 = 0;
 205
 206         return;
 207     }
 208
 209     if (self.owner.BUTTON_ATCK)
 210     {
 211
 212         // Animate miniguns
 213         self.gun1.angles_z += (1440 * sys_frametime);
 214         self.gun2.angles_z -= (1440 * sys_frametime);
 215         if(self.gun1.angles_z >= 360)
 216         {
 217             self.gun1.angles_z = 0;
 218             self.gun2.angles_z = 360;
 219         }
 220
 221         if (self.tur_head.attack_finished_single < time)
 222         {
 223             // Fire bullets, alternating trails left<->right
 224             self = self.owner;
 225             if(self.misc_bulletcounter == 1)
 226             {
 227                 spiderbot_minigun_fire(self.vehicle.gun1, 0);
 228                 spiderbot_minigun_fire(self.vehicle.gun2, 1);
 229                 self.misc_bulletcounter = 0;
 230             }
 231             else
 232             {
 233                 spiderbot_minigun_fire(self.vehicle.gun1, 1);
 234                 spiderbot_minigun_fire(self.vehicle.gun2, 0);
 235                 self.misc_bulletcounter += 1;
 236             }
 237             self = self.vehicle;
 238
 239             ftmp = autocvar_g_vehicle_spiderbot_minigun_refire / autocvar_g_vehicle_spiderbot_minigun_heat;
 240             self.owner.vehicle_reload1 +=  ftmp;
 241
 242             if(self.owner.vehicle_reload1 >= 1)
 243             {
 244                 self.vehicle_reload1 = 1;
 245                 self.owner.vehicle_reload1 = 1;
 246                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_cooldown + time;
 247             }
 248             else
 249                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_refire + time;
 250         }
 251         return;
 252     }
 253 }
 254
 255 float spiderbot_frame()
 256 {
 257     vector ad;
 258     entity player, spider;
 259     float ftmp;
 260
 261     player = self;
 262     spider = self.vehicle;
 263
 264     player.BUTTON_ZOOM      = 0;
 265     player.BUTTON_CROUCH    = 0;
 266     player.switchweapon     = 0;
 267
 268     if(player.BUTTON_USE)
 269     {
 270         self = spider;
 271         vehicles_exit(VHEF_NORMAL);
 272         self = player;
 273         return 0;
 274     }
 275
 276     self = spider;
 277
 278     //vector v;
 279     //v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 280     //te_lightning1(world, v, v + normalize(v_forward + (v_up * 0.5) + randomvec() * 0.25) * autocvar_g_vehicle_spiderbot_rocket_speed);
 281     crosshair_trace(player);
 282     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 283
 284 #if VEHICLES_VIEWROTATE_CROSSHAIR
 285     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 286     if(ad_x > 180) ad_x -= 360;
 287     if(ad_x < -180) ad_x += 360;
 288     if(ad_y > 180) ad_y -= 360;
 289     if(ad_y < -180) ad_y += 360;
 290
 291     // Rotate head
 292     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 293     ad_y = bound(-ftmp, ad_y, ftmp);
 294     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 295
 296     // Pitch head
 297     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 298     //ad_x = bound(-ftmp, ad_x, ftmp);
 299     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 300
 301     // Turn Body
 302     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 303     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 304 #else
 305
 306     player.v_angle_x *= -1;
 307     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 308     player.v_angle_x *= -1;
 309     if(ad_x > 180)  ad_x -= 360;
 310     if(ad_x < -180) ad_x += 360;
 311     if(ad_y > 180)  ad_y -= 360;
 312     if(ad_y < -180) ad_y += 360;
 313
 314     // Rotate head
 315     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 316     ad_y = bound(-ftmp, ad_y, ftmp);
 317     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 318
 319
 320     // Pitch head
 321     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 322     if(ad_x > 180) ad_x -= 360;
 323     if(ad_x < -180) ad_x += 360;
 324
 325
 326     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 327     ad_x = bound(ftmp * -1, ad_x, ftmp);
 328     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 329
 330
 331
 332     // Turn Body
 333     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 334     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 335
 336
 337 #endif
 338     makevectors(spider.angles + '-1 0 0' * spider.angles_x);
 339
 340     /*
 341     vector ofs;
 342     ofs = self.origin + v_up * 128;
 343     te_lightning1(world, ofs, ofs + v_up * 32);
 344     te_lightning1(world, ofs, ofs + v_right * 128);
 345     te_lightning1(world, ofs, ofs + v_forward * 256);
 346     */
 347
 348     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 349
 350     if(spider.flags & FL_ONGROUND)
 351     {
 352         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 353         {
 354             self.tur_head.wait = time + 2;
 355             player.BUTTON_JUMP = 0;
 356             spider.velocity   = v_forward * 700 + v_up * 600;
 357             spider.frame = 4;
 358         }
 359         else
 360         {
 361             if(vlen(player.movement) == 0)
 362             {
 363                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 364                 spider.frame = 5;
 365             }
 366             else
 367             {
 368                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 369                 spider.tur_head.angles_y -= ftmp;
 370
 371                 if(player.movement_x != 0)
 372                 {
 373                     if(player.movement_x > 0)
 374                     {
 375                         player.movement_x = 1;
 376                         spider.frame = 0;
 377                     }
 378                     else if(player.movement_x < 0)
 379                     {
 380                         player.movement_x = -1;
 381                         spider.frame = 1;
 382                     }
 383                     player.movement_y = 0;
 384                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 385                 }
 386                 else if(player.movement_y != 0)
 387                 {
 388                     if(player.movement_y < 0)
 389                     {
 390                         player.movement_y = -1;
 391                         spider.frame = 2;
 392                     }
 393                     else if(player.movement_y > 0)
 394                     {
 395                         player.movement_y = 1;
 396                         spider.frame = 3;
 397                     }
 398                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 399                 }
 400             }
 401         }
 402     }
 403
 404     self.angles_x = bound(-45, self.angles_x, 45);
 405     self.angles_z = bound(-45, self.angles_z, 45);
 406
 407     spiderbot_miniguns_do();
 408     spiderbot_rocket_do();
 409
 410     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 411         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 412
 413     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 414         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 415
 416     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 417     player.vehicle_ammo2 = spider.tur_head.frame;
 418
 419     if(spider.gun2.cnt <= time)
 420         player.vehicle_reload2 = 1;
 421     else
 422         player.vehicle_reload2 = 1 - ((spider.gun2.cnt - time) / spider.attack_finished_single);
 423
 424     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 425     player.velocity = spider.velocity;
 426
 427     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 428
 429     if(self.vehicle_flags & VHF_HASSHIELD)
 430         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 431
 432 #if 1 // 0 to enable per-gun impact aux crosshairs
 433     // Avarage gun impact point's -> aux cross
 434     vector vf;
 435     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 436     vf = v_forward;
 437     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 438     vf += v_forward;
 439     ad = ad * 0.5;
 440     v_forward = vf * 0.5;
 441     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 442     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 443
 444 #else
 445     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 446     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 447     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 448
 449     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 450     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 451     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 452 #endif
 453
 454     self = player;
 455     return 1;
 456 }
 457
 458 void spiderbot_think()
 459 {
 460     if(self.flags & FL_ONGROUND)
 461         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 462
 463     self.nextthink = time;
 464 }
 465
 466 void spiderbot_enter()
 467 {
 468     self.movetype   = MOVETYPE_WALK;
 469     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 470     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 471 }
 472
 473 void spiderbot_exit(float eject)
 474 {
 475     entity e;
 476
 477     e = findchain(classname,"spiderbot_rocket");
 478     while(e)
 479     {
 480         if(e.owner == self.owner)
 481         {
 482             e.realowner = self.owner;
 483             e.owner = world;
 484         }
 485         e = e.chain;
 486     }
 487
 488     self.velocity   = '0 0 0';
 489     self.think      = spiderbot_think;
 490     self.nextthink  = time;
 491     self.frame      = 5;
 492     self.movetype   = MOVETYPE_WALK;
 493
 494     if not (self.owner)
 495         return;
 496
 497         makevectors(self.angles);
 498         if(eject)
 499         {
 500             setorigin(self.owner ,self.origin + v_forward * 100 + '0 0 64');
 501             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 502         }
 503         else
 504         setorigin(self.owner, self.origin - v_forward * 200 + '0 0 64');
 505
 506     self.owner = world;
 507 }
 508
 509 // Better way of determening whats crushable needed! (fl_crushable?)
 510 float spiderbot_crushable(entity e)
 511 {
 512     if(e.classname == "corpse")
 513         return 1;
 514
 515     if(e.classname == "player")
 516         return 1;
 517
 518     if(e.classname == "monster_zombie")
 519         return 1;
 520
 521     return 0;
 522 }
 523
 524 /*void spiderbot_touch(
 525 {
 526     //vehicles_touch();
 527     if(self.owner)
 528     {
 529         if(vlen(self.velocity) == 0)
 530             return;
 531
 532         if not (spiderbot_crushable(other))
 533             return;
 534
 535         //todo: add check for velocity/angle here (so we dont cush players runing into us from behind)
 536
 537         Damage(other, self, self.owner,autocvar_g_vehicle_spiderbot_crush_dmg,DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicle_spiderbot_crush_force);
 538         return;
 539     }
 540
 541     if(other.classname != "player")
 542         return;
 543
 544     if(other.deadflag != DEAD_NO)
 545         return;
 546
 547     if(other.vehicle != world)
 548         return;
 549
 550     vehicles_enter();
 551 }*/
 552
 553
 554 void spiderbot_spawn()
 555 {
 556     self.frame              = 5;
 557     self.tur_head.frame     = 1;
 558     self.think              = spiderbot_think;
 559     self.nextthink          = time;
 560     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 561     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 562     self.movetype           = MOVETYPE_WALK;
 563     self.solid              = SOLID_SLIDEBOX;
 564     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 565     self.tur_head.angles    = '0 0 0';
 566
 567     setorigin(self, self.pos1 + '0 0 128');
 568     self.angles = self.pos2;
 569 }
 570
 571 void spiderbot_headfade()
 572 {
 573         self.think = spiderbot_headfade;
 574         self.nextthink = self.fade_time;
 575         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 576
 577     if(self.cnt < time || self.alpha < 0.1)
 578     {
 579         if(self.alpha > 0.1)
 580         {
 581             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 582             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 583         }
 584         remove(self);
 585     }
 586 }
 587
 588 void spiderbot_blowup()
 589 {
 590     float i;
 591     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 592
 593     for(i = 0; i < 5; ++i)
 594         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 100) + '0 0 100', '0 0 0', 1);
 595
 596     entity h, g1, g2, b;
 597     b = spawn();
 598     h = spawn();
 599     g1 = spawn();
 600     g2 = spawn();
 601
 602     setmodel(b,  "models/vehicles/spiderbot.dpm");
 603     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 604     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 605     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 606
 607     setorigin(b, self.origin);
 608     b.frame         = 11;
 609     b.angles        = self.angles;
 610     setsize(b, self.mins, self.maxs);
 611
 612     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 613     h.movetype      = MOVETYPE_BOUNCE;
 614     h.solid         = SOLID_BBOX;
 615     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 616     h.modelflags    = MF_ROCKET;
 617     h.effects       = EF_FLAME | EF_LOWPRECISION;
 618     h.avelocity     = randomvec() * 360;
 619
 620     h.alpha         = 1;
 621     h.cnt           = time + (3.5 * random());
 622     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 623     h.fade_time     = time;
 624     h.think         = spiderbot_headfade;
 625     h.nextthink     = time;
 626
 627     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 628     g1.movetype     = MOVETYPE_TOSS;
 629     g1.solid        = SOLID_CORPSE;
 630     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 631     g1.avelocity    = randomvec() * 180;
 632
 633     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 634     g2.movetype     = MOVETYPE_TOSS;
 635     g2.solid        = SOLID_CORPSE;
 636     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 637     g2.avelocity    = randomvec() * 180;
 638
 639     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 640
 641     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 642     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 643     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 644     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 645
 646     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 647
 648     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 649     self.movetype   = MOVETYPE_NONE;
 650     self.deadflag   = DEAD_DEAD;
 651     self.solid      = SOLID_NOT;
 652     self.tur_head.effects  &~=  EF_FLAME;
 653         self.vehicle_hudmodel.viewmodelforclient = self;
 654
 655     //self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 656     //self.think      = spiderbot_spawn;
 657
 658     //setorigin(self, self.tur_aimpos);
 659 }
 660
 661 void spiderbot_die()
 662 {
 663     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 664     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 665
 666     self.health         = 0;
 667     self.event_damage   = SUB_Null;
 668     self.takedamage     = DAMAGE_NO;
 669     self.touch          = SUB_Null;
 670     self.nextthink      = 3.4 + time + random() * 2;
 671     self.think          = spiderbot_blowup;
 672     self.deadflag       = DEAD_DYING;
 673         self.frame          = 5;
 674         self.tur_head.effects        |= EF_FLAME;
 675         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 676         self.frame = 10;
 677         self.movetype = MOVETYPE_TOSS;
 678
 679 }
 680
 681 void vewhicle_spiderbot_dinit()
 682 {
 683     if not (vehicle_initialize(
 684              "Spiderbot",
 685              "models/vehicles/spiderbot.dpm",
 686              "models/vehicles/spiderbot_top.dpm",
 687              "models/vehicles/spiderbot_cockpit.dpm",
 688              "tag_head", "tag_hud", "",
 689              HUD_SPIDERBOT,
 690              SPIDERBOT_MIN, SPIDERBOT_MAX,
 691              FALSE,
 692              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 693              spiderbot_frame,
 694              spiderbot_enter, spiderbot_exit,
 695              spiderbot_die,   spiderbot_think))
 696     {
 697         remove(self);
 698         return;
 699     }
 700
 701     self.gun1               = spawn();
 702     self.gun2               = spawn();
 703
 704     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 705     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 706
 707     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 708     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 709
 710     self.gravity            = 2;
 711     self.mass               = 5000;
 712 }
 713
 714 void spawnfunc_vehicle_spiderbot()
 715 {
 716     precache_model ( "models/vhshield.md3");
 717     precache_model ( "models/vehicles/spiderbot.dpm");
 718     precache_model ( "models/vehicles/spiderbot_top.dpm");
 719     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 720     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 721     precache_model ( "models/uziflash.md3");
 722
 723     precache_sound ( "weapons/rocket_impact.wav" );
 724     precache_sound ( "weapons/uzi_fire.wav" );
 725     precache_sound ( "weapons/rocket_impact.wav" );
 726
 727     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 728     if(autocvar_g_vehicle_spiderbot_shield)
 729         self.vehicle_flags |= VHF_HASSHIELD;
 730
 731     if(autocvar_g_vehicle_spiderbot_shield_regen)
 732         self.vehicle_flags |= VHF_SHIELDREGEN;
 733
 734     if(autocvar_g_vehicle_spiderbot_health_regen)
 735         self.vehicle_flags |= VHF_HEALTHREGEN;
 736
 737     self.think = vewhicle_spiderbot_dinit;
 738     self.nextthink = time + 0.5;
 739 }