qcsrc/server/vehicles/vehicle.qc

   1 #include "vehicle.qh"
   2
   3 #include "../_all.qh"
   4 #include "../cl_player.qh"
   5 #include "../../common/constants.qh"
   6 #include "../waypointsprites.qh"
   7
   8 #include "../bot/waypoints.qh"
   9
  10 float autocvar_g_vehicles_crush_dmg;
  11 float autocvar_g_vehicles_crush_force;
  12 float autocvar_g_vehicles_delayspawn;
  13 float autocvar_g_vehicles_delayspawn_jitter;
  14
  15 float autocvar_g_vehicles_vortex_damagerate = 0.5;
  16 float autocvar_g_vehicles_machinegun_damagerate = 0.5;
  17 float autocvar_g_vehicles_rifle_damagerate = 0.75;
  18 float autocvar_g_vehicles_vaporizer_damagerate = 0.001;
  19 float autocvar_g_vehicles_tag_damagerate = 5;
  20
  21 float autocvar_g_vehicles;
  22
  23 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  24 void vehicles_return();
  25 void vehicles_enter();
  26 void vehicles_reset_colors();
  27 void vehicles_clearreturn();
  28 void vehicles_setreturn();
  29
  30
  31 /** AuxiliaryXhair*
  32     Send additional points of interest to be drawn, to vehicle owner
  33 **/
  34 const float MAX_AXH = 4;
  35 .entity AuxiliaryXhairs[MAX_AXH];
  36
  37 float SendAuxiliaryXhair(entity to, int sf)
  38 {
  39
  40         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  41
  42         WriteByte(MSG_ENTITY, self.cnt);
  43
  44         WriteCoord(MSG_ENTITY, self.origin.x);
  45         WriteCoord(MSG_ENTITY, self.origin.y);
  46         WriteCoord(MSG_ENTITY, self.origin.z);
  47
  48     WriteByte(MSG_ENTITY, rint(self.colormod.x * 255));
  49     WriteByte(MSG_ENTITY, rint(self.colormod.y * 255));
  50     WriteByte(MSG_ENTITY, rint(self.colormod.z * 255));
  51
  52     return true;
  53 }
  54
  55 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  56 {
  57     if (!IS_REAL_CLIENT(own))
  58         return;
  59
  60     entity axh;
  61
  62     axh_id = bound(0, axh_id, MAX_AXH);
  63     axh = own.(AuxiliaryXhairs[axh_id]);
  64
  65     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  66     {
  67         axh                     = spawn();
  68         axh.cnt                 = axh_id;
  69         axh.drawonlytoclient    = own;
  70         axh.owner               = own;
  71         Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  72     }
  73
  74     setorigin(axh, loc);
  75     axh.colormod            = clr;
  76     axh.SendFlags           = 0x01;
  77     own.(AuxiliaryXhairs[axh_id]) = axh;
  78 }
  79
  80 /*
  81 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  82 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  83 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  84 {
  85         msgexntity = own;
  86
  87         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  88         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  89
  90         WriteByte(MSG_ONE, axh_id);
  91
  92         WriteCoord(MSG_ONE, loc_x);
  93         WriteCoord(MSG_ONE, loc_y);
  94         WriteCoord(MSG_ONE, loc_z);
  95
  96     WriteByte(MSG_ONE, rint(clr_x * 255));
  97     WriteByte(MSG_ONE, rint(clr_y * 255));
  98     WriteByte(MSG_ONE, rint(clr_z * 255));
  99
 100 }
 101 */
 102 // End AuxiliaryXhair
 103
 104 /**
 105     Notifies the client that he enterd a vehicle, and sends
 106     realavent data.
 107
 108     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 109 **/
 110 void CSQCVehicleSetup(entity own, float vehicle_id)
 111 {
 112     if (!IS_REAL_CLIENT(own))
 113         return;
 114
 115         msg_entity = own;
 116
 117         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 118         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 119         if(vehicle_id != 0)
 120             WriteByte(MSG_ONE, vehicle_id);
 121         else
 122         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 123 }
 124
 125
 126 const float     DAMAGE_TARGETDRONE = 10;
 127
 128 vector targetdrone_getnewspot()
 129 {
 130
 131         vector spot;
 132         float i;
 133         for(i = 0; i < 100; ++i)
 134         {
 135                 spot = self.origin + randomvec() * 1024;
 136                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 137                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 138                         return spot;
 139         }
 140         return self.origin;
 141 }
 142
 143 #if 0
 144 void targetdrone_think();
 145 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
 146 void targetdrone_renwe()
 147 {
 148         self.think = targetdrone_think;
 149         self.nextthink = time + 0.1;
 150         setorigin(self, targetdrone_getnewspot());
 151         self.health = 200;
 152         self.takedamage = DAMAGE_TARGETDRONE;
 153         self.event_damage = targetdrone_damage;
 154         self.solid = SOLID_BBOX;
 155         setmodel(self, "models/runematch/rune.mdl");
 156         self.effects = EF_LOWPRECISION;
 157         self.scale = 10;
 158         self.movetype = MOVETYPE_BOUNCEMISSILE;
 159         setsize(self, '-100 -100 -100', '100 100 100');
 160
 161 }
 162 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 163 {
 164         self.health -= damage;
 165         if(self.health <= 0)
 166         {
 167                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 168
 169                 if(!self.cnt)
 170                         remove(self);
 171                 else
 172                 {
 173                         self.think = targetdrone_renwe;
 174                         self.nextthink = time + 1 + random() * 2;
 175                         self.solid = SOLID_NOT;
 176                         setmodel(self, "");
 177                 }
 178         }
 179 }
 180 entity targetdrone_getfear()
 181 {
 182         entity fear;
 183         float i;
 184
 185         for(i = 64; i <= 1024; i += 64)
 186         {
 187                 fear = findradius(self.origin, i);
 188                 while(fear)
 189                 {
 190                         if(fear.bot_dodge)
 191                                 return fear;
 192
 193                         fear = fear.chain;
 194                 }
 195         }
 196
 197         return world;
 198 }
 199 void targetdrone_think()
 200 {
 201         self.nextthink = time + 0.1;
 202
 203         if(self.wp00)
 204         if(self.wp00.deadflag != DEAD_NO)
 205                 self.wp00 = targetdrone_getfear();
 206
 207         if(!self.wp00)
 208                 self.wp00 = targetdrone_getfear();
 209
 210         vector newdir;
 211
 212         if(self.wp00)
 213                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 214         else
 215                 newdir = randomvec() * 0.75;
 216
 217         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 218
 219         if(self.wp00)
 220                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 221         else
 222                 self.velocity = normalize(newdir) * 750;
 223
 224         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 225         if(trace_fraction != 1.0)
 226                 self.velocity = self.velocity * -1;
 227
 228         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 229 }
 230
 231 void targetdrone_spawn(vector _where, float _autorenew)
 232 {
 233         entity drone = spawn();
 234         setorigin(drone, _where);
 235         drone.think = targetdrone_renwe;
 236         drone.nextthink = time + 0.1;
 237         drone.cnt = _autorenew;
 238 }
 239 #endif
 240
 241 void vehicles_locktarget(float incr, float decr, float _lock_time)
 242 {
 243     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 244     {
 245         self.lock_target    = world;
 246         self.lock_strength  = 0;
 247         self.lock_time      = 0;
 248     }
 249
 250     if(self.lock_time > time)
 251     {
 252         if(self.lock_target)
 253         if(self.lock_soundtime < time)
 254         {
 255             self.lock_soundtime = time + 0.5;
 256             play2(self.owner, "vehicles/locked.wav");
 257         }
 258
 259         return;
 260     }
 261
 262     if(trace_ent != world)
 263     {
 264         if(teamplay && trace_ent.team == self.team)
 265             trace_ent = world;
 266
 267         if(trace_ent.deadflag != DEAD_NO)
 268             trace_ent = world;
 269         if(!(
 270             (trace_ent.vehicle_flags & VHF_ISVEHICLE) ||
 271             (trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET) ||
 272             (trace_ent.takedamage == DAMAGE_TARGETDRONE)
 273             )) { trace_ent = world; }
 274     }
 275
 276     if(self.lock_target == world && trace_ent != world)
 277         self.lock_target = trace_ent;
 278
 279     if(self.lock_target && trace_ent == self.lock_target)
 280     {
 281         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 282         {
 283             play2(self.owner, "vehicles/lock.wav");
 284             self.lock_soundtime = time + 0.8;
 285         }
 286         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 287         {
 288             play2(self.owner, "vehicles/locking.wav");
 289             self.lock_soundtime = time + 0.3;
 290         }
 291
 292     }
 293
 294     // Have a locking target
 295     // Trace hit current target
 296     if(trace_ent == self.lock_target && trace_ent != world)
 297     {
 298         self.lock_strength = min(self.lock_strength + incr, 1);
 299         if(self.lock_strength == 1)
 300             self.lock_time = time + _lock_time;
 301     }
 302     else
 303     {
 304         if(trace_ent)
 305             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 306         else
 307             self.lock_strength = max(self.lock_strength - decr, 0);
 308
 309         if(self.lock_strength == 0)
 310             self.lock_target = world;
 311     }
 312 }
 313
 314
 315 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 316 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 317 if(trace_fraction != 1) \
 318     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 319
 320 // Hover movement support
 321 float  force_fromtag_power;
 322 vector force_fromtag_origin;
 323 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 324 {
 325     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 326     v_forward  = normalize(v_forward) * -1;
 327     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 328
 329     force_fromtag_power = (1 - trace_fraction) * max_power;
 330     force_fromtag_normpower = force_fromtag_power / max_power;
 331
 332     return v_forward  * force_fromtag_power;
 333 }
 334
 335 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 336 // Can possibly be use to move abt any surface (inclusing walls/celings)
 337 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 338 {
 339
 340     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 341     v_forward  = normalize(v_forward) * -1;
 342     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 343
 344     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 345     if(trace_fraction == 1.0)
 346     {
 347         force_fromtag_normpower = -0.25;
 348         return '0 0 -200';
 349     }
 350
 351     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 352     force_fromtag_normpower = force_fromtag_power / max_power;
 353
 354     return v_forward  * force_fromtag_power;
 355 }
 356
 357 // Generic vehile projectile system
 358 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 359 {
 360     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 361     if(inflictor.owner == self.owner)
 362         return;
 363
 364     self.health -= damage;
 365     self.velocity += force;
 366     if(self.health < 1)
 367     {
 368         self.takedamage = DAMAGE_NO;
 369         self.event_damage = func_null;
 370         self.think = self.use;
 371         self.nextthink = time;
 372     }
 373 }
 374
 375 void vehicles_projectile_explode()
 376 {
 377     if(self.owner && other != world)
 378     {
 379         if(other == self.owner.vehicle)
 380             return;
 381
 382         if(other == self.owner.vehicle.tur_head)
 383             return;
 384     }
 385
 386         PROJECTILE_TOUCH;
 387
 388         self.event_damage = func_null;
 389     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 390
 391     remove (self);
 392 }
 393
 394 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 395                            vector _org, vector _vel,
 396                            float _dmg, float _radi, float _force,  float _size,
 397                            float _deahtype, float _projtype, float _health,
 398                            float _cull, float _clianim, entity _owner)
 399 {
 400     entity proj;
 401
 402     proj = spawn();
 403
 404     PROJECTILE_MAKETRIGGER(proj);
 405     setorigin(proj, _org);
 406
 407     proj.shot_dmg         = _dmg;
 408     proj.shot_radius      = _radi;
 409     proj.shot_force       = _force;
 410     proj.totalfrags       = _deahtype;
 411     proj.solid            = SOLID_BBOX;
 412     proj.movetype         = MOVETYPE_FLYMISSILE;
 413     proj.flags            = FL_PROJECTILE;
 414     proj.bot_dodge        = true;
 415     proj.bot_dodgerating  = _dmg;
 416     proj.velocity         = _vel;
 417     proj.touch            = vehicles_projectile_explode;
 418     proj.use              = vehicles_projectile_explode;
 419     proj.owner            = self;
 420     proj.realowner        = _owner;
 421     proj.think            = SUB_Remove;
 422     proj.nextthink        = time + 30;
 423
 424     if(_health)
 425     {
 426         proj.takedamage       = DAMAGE_AIM;
 427         proj.event_damage     = vehicles_projectile_damage;
 428         proj.health           = _health;
 429     }
 430     else
 431         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 432
 433     if(_mzlsound)
 434         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 435
 436     if(_mzlfx)
 437         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 438
 439
 440     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 441
 442     CSQCProjectile(proj, _clianim, _projtype, _cull);
 443
 444     return proj;
 445 }
 446 // End generic vehile projectile system
 447
 448 void vehicles_reset()
 449 {
 450         if(self.owner)
 451         {
 452                 entity oldself = self;
 453                 self = self.owner;
 454                 vehicles_exit(VHEF_RELESE);
 455                 self = oldself;
 456         }
 457         self.alpha      = -1;
 458         self.movetype   = MOVETYPE_NONE;
 459         self.effects    = EF_NODRAW;
 460         self.colormod  = '0 0 0';
 461         self.avelocity = '0 0 0';
 462         self.velocity  = '0 0 0';
 463         self.event_damage = func_null;
 464         self.solid = SOLID_NOT;
 465         self.deadflag = DEAD_NO;
 466
 467         self.touch = func_null;
 468         self.nextthink = 0;
 469         vehicles_setreturn();
 470 }
 471
 472 /** vehicles_spawn
 473     Exetuted for all vehicles on (re)spawn.
 474     Sets defaults for newly spawned units.
 475 **/
 476 void vehicles_spawn()
 477 {
 478     dprint("Spawning vehicle: ", self.netname, "\n");
 479
 480     // De-own & reset
 481     self.vehicle_hudmodel.viewmodelforclient = self;
 482
 483     self.owner              = world;
 484     self.touch              = vehicles_touch;
 485     self.event_damage       = vehicles_damage;
 486     self.reset              = vehicles_reset;
 487     self.iscreature         = true;
 488     self.teleportable       = false; // no teleporting for vehicles, too buggy
 489     self.damagedbycontents      = true;
 490     self.movetype           = MOVETYPE_WALK;
 491     self.solid              = SOLID_SLIDEBOX;
 492     self.takedamage         = DAMAGE_AIM;
 493         self.deadflag           = DEAD_NO;
 494     self.bot_attack         = true;
 495     self.flags              = FL_NOTARGET;
 496     self.avelocity          = '0 0 0';
 497     self.velocity           = '0 0 0';
 498
 499     // Reset locking
 500     self.lock_strength      = 0;
 501     self.lock_target        = world;
 502     self.misc_bulletcounter = 0;
 503
 504     // Return to spawn
 505     self.angles             = self.pos2;
 506     setorigin(self, self.pos1 + '0 0 0');
 507     // Show it
 508     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 509
 510     if(self.vehicle_controller)
 511         self.team = self.vehicle_controller.team;
 512
 513     vehicles_reset_colors();
 514     self.vehicle_spawn(VHSF_NORMAL);
 515 }
 516
 517 // Better way of determening whats crushable needed! (fl_crushable?)
 518 float vehicles_crushable(entity e)
 519 {
 520     if(IS_PLAYER(e))
 521         return true;
 522
 523     if(e.flags & FL_MONSTER)
 524         return true;
 525
 526     return false;
 527 }
 528
 529 void vehicles_impact(float _minspeed, float _speedfac, float _maxpain)
 530 {
 531     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 532         return;
 533
 534     if(self.play_time < time)
 535     {
 536         float wc = vlen(self.velocity - self.oldvelocity);
 537         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 538         //dprint("vel: ", vtos(self.velocity), "\n");
 539         if(_minspeed < wc)
 540         {
 541             float take = min(_speedfac * wc, _maxpain);
 542             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 543             self.play_time = time + 0.25;
 544
 545             //dprint("wc: ", ftos(wc), "\n");
 546             //dprint("take: ", ftos(take), "\n");
 547         }
 548     }
 549 }
 550
 551 void vehicles_touch()
 552 {
 553         if(MUTATOR_CALLHOOK(VehicleTouch))
 554                 return;
 555
 556     // Vehicle currently in use
 557     if(self.owner)
 558     {
 559         if(other != world)
 560         if(vehicles_crushable(other))
 561         {
 562             if(vlen(self.velocity) != 0)
 563                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 564
 565             return; // Dont do selfdamage when hitting "soft targets".
 566         }
 567
 568         if(self.play_time < time)
 569         if(self.vehicle_impact)
 570             self.vehicle_impact();
 571
 572         return;
 573     }
 574
 575     if (!IS_PLAYER(other))
 576         return;
 577
 578     if(other.deadflag != DEAD_NO)
 579         return;
 580
 581     if(other.vehicle != world)
 582         return;
 583
 584     vehicles_enter();
 585 }
 586 .float monster_attack;
 587 void vehicles_enter()
 588 {
 589    // Remove this when bots know how to use vehicles
 590
 591     if (IS_BOT_CLIENT(other))
 592         if (autocvar_g_vehicles_allow_bots)
 593             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 594         else
 595             return;
 596
 597     if(self.phase > time)
 598         return;
 599     if(other.frozen)
 600         return;
 601     if(other.vehicle)
 602         return;
 603     if(other.deadflag != DEAD_NO)
 604         return;
 605
 606     if(teamplay)
 607     if(self.team)
 608     if(self.team != other.team)
 609         return;
 610
 611     RemoveGrapplingHook(other);
 612
 613     self.vehicle_ammo1   = 0;
 614     self.vehicle_ammo2   = 0;
 615     self.vehicle_reload1 = 0;
 616     self.vehicle_reload2 = 0;
 617     self.vehicle_energy  = 0;
 618
 619     self.owner          = other;
 620     self.switchweapon   = other.switchweapon;
 621
 622     // .viewmodelforclient works better.
 623     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 624
 625     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 626
 627     self.event_damage         = vehicles_damage;
 628     self.nextthink            = 0;
 629     self.owner.angles         = self.angles;
 630     self.owner.takedamage     = DAMAGE_NO;
 631     self.owner.solid          = SOLID_NOT;
 632     self.owner.movetype       = MOVETYPE_NOCLIP;
 633     self.owner.alpha          = -1;
 634     self.owner.vehicle        = self;
 635     self.owner.event_damage   = func_null;
 636     self.owner.view_ofs       = '0 0 0';
 637     self.colormap             = self.owner.colormap;
 638     if(self.tur_head)
 639         self.tur_head.colormap    = self.owner.colormap;
 640
 641     self.owner.hud            = self.hud;
 642     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 643
 644     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 645     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 646     self.owner.vehicle_reload1  = self.vehicle_reload1;
 647     self.owner.vehicle_reload2  = self.vehicle_reload2;
 648     self.owner.vehicle_energy   = self.vehicle_energy;
 649
 650     // Cant do this, hides attached objects too.
 651     //self.exteriormodeltoclient = self.owner;
 652     //self.tur_head.exteriormodeltoclient = self.owner;
 653
 654     other.flags &= ~FL_ONGROUND;
 655     self.flags  &= ~FL_ONGROUND;
 656
 657     self.team                 = self.owner.team;
 658     self.flags               -= FL_NOTARGET;
 659     self.monster_attack       = true;
 660
 661     if (IS_REAL_CLIENT(other))
 662     {
 663         msg_entity = other;
 664         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 665         WriteEntity(MSG_ONE, self.vehicle_viewport);
 666
 667         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 668         if(self.tur_head)
 669         {
 670             WriteAngle(MSG_ONE, self.tur_head.angles.x + self.angles.x); // tilt
 671             WriteAngle(MSG_ONE, self.tur_head.angles.y + self.angles.y); // yaw
 672             WriteAngle(MSG_ONE, 0);                                      // roll
 673         }
 674         else
 675         {
 676             WriteAngle(MSG_ONE,  self.angles.x * -1); // tilt
 677             WriteAngle(MSG_ONE,  self.angles.y);      // yaw
 678             WriteAngle(MSG_ONE,  0);                  // roll
 679         }
 680     }
 681
 682     vehicles_clearreturn();
 683
 684     CSQCVehicleSetup(self.owner, self.hud);
 685
 686     vh_player = other;
 687     vh_vehicle = self;
 688     MUTATOR_CALLHOOK(VehicleEnter);
 689     other = vh_player;
 690     self = vh_vehicle;
 691
 692     self.vehicle_enter();
 693     antilag_clear(other);
 694 }
 695
 696 /** vehicles_findgoodexit
 697     Locates a valid location for the player to exit the vehicle.
 698     Will first try prefer_spot, then up 100 random spots arround the vehicle
 699     wich are in direct line of sight and empty enougth to hold a players bbox
 700 **/
 701 vector vehicles_findgoodexit(vector prefer_spot)
 702 {
 703     //vector exitspot;
 704     float mysize;
 705
 706     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 707     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 708         return prefer_spot;
 709
 710     mysize = 1.5 * vlen(self.maxs - self.mins);
 711     float i;
 712     vector v, v2;
 713     v2 = 0.5 * (self.absmin + self.absmax);
 714     for(i = 0; i < 100; ++i)
 715     {
 716         v = randomvec();
 717         v.z = 0;
 718         v = v2 + normalize(v) * mysize;
 719         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 720         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 721             return v;
 722     }
 723
 724     /*
 725     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 726     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 727     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 728         return exitspot;
 729
 730     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 731     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 732     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 733         return exitspot;
 734
 735     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 736     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 737     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 738         return exitspot;
 739
 740     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 741     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 742     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 743         return exitspot;
 744     */
 745
 746     return self.origin;
 747 }
 748
 749 /** vehicles_exit
 750     Standarrd vehicle release fucntion.
 751     custom code goes in self.vehicle_exit
 752 **/
 753 float vehicles_exit_running;
 754 void vehicles_exit(float eject)
 755 {
 756     entity _vehicle;
 757     entity _player;
 758     entity _oldself = self;
 759
 760     if(vehicles_exit_running)
 761     {
 762         dprint("^1vehicles_exit allready running! this is not good..\n");
 763         return;
 764     }
 765
 766     vehicles_exit_running = true;
 767     if(IS_CLIENT(self))
 768     {
 769         _vehicle = self.vehicle;
 770
 771         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 772         {
 773             _vehicle.vehicle_exit(eject);
 774             self = _oldself;
 775             vehicles_exit_running = false;
 776             return;
 777         }
 778     }
 779     else
 780         _vehicle = self;
 781
 782     _player = _vehicle.owner;
 783
 784     self = _vehicle;
 785
 786     if (_player)
 787     {
 788         if (IS_REAL_CLIENT(_player))
 789         {
 790             msg_entity = _player;
 791             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 792             WriteEntity( MSG_ONE, _player);
 793
 794             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 795             WriteAngle(MSG_ONE, 0);
 796             WriteAngle(MSG_ONE, _vehicle.angles.y);
 797             WriteAngle(MSG_ONE, 0);
 798         }
 799
 800         setsize(_player, PL_MIN,PL_MAX);
 801
 802         _player.takedamage     = DAMAGE_AIM;
 803         _player.solid          = SOLID_SLIDEBOX;
 804         _player.movetype       = MOVETYPE_WALK;
 805         _player.effects        &= ~EF_NODRAW;
 806         _player.alpha          = 1;
 807         _player.PlayerPhysplug = func_null;
 808         _player.vehicle        = world;
 809         _player.view_ofs       = PL_VIEW_OFS;
 810         _player.event_damage   = PlayerDamage;
 811         _player.hud            = HUD_NORMAL;
 812         _player.switchweapon   = _vehicle.switchweapon;
 813
 814         CSQCVehicleSetup(_player, HUD_NORMAL);
 815     }
 816     _vehicle.flags |= FL_NOTARGET;
 817
 818     if(_vehicle.deadflag == DEAD_NO)
 819         _vehicle.avelocity          = '0 0 0';
 820
 821     _vehicle.tur_head.nodrawtoclient             = world;
 822
 823     if(!teamplay)
 824         _vehicle.team = 0;
 825
 826     vh_player = _player;
 827     vh_vehicle = _vehicle;
 828     MUTATOR_CALLHOOK(VehicleExit);
 829     _player = vh_player;
 830     _vehicle = vh_vehicle;
 831
 832     _vehicle.team = _vehicle.tur_head.team;
 833
 834     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTEN_NORM);
 835     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 836     _vehicle.phase = time + 1;
 837     _vehicle.monster_attack = false;
 838
 839     _vehicle.vehicle_exit(eject);
 840
 841     vehicles_setreturn();
 842     vehicles_reset_colors();
 843     _vehicle.owner = world;
 844     self = _oldself;
 845
 846     vehicles_exit_running = false;
 847 }
 848
 849
 850 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 851 {
 852     if (self.(regen_field) < field_max)
 853     if (timer + rpause < time)
 854     {
 855         if (_healthscale)
 856             regen = regen * (self.vehicle_health / self.tur_health);
 857
 858         self.(regen_field) = min(self.(regen_field) + regen * delta_time, field_max);
 859
 860         if (self.owner)
 861             self.owner.(regen_field) = (self.(regen_field) / field_max) * 100;
 862     }
 863 }
 864
 865 void shieldhit_think()
 866 {
 867     self.alpha -= 0.1;
 868     if (self.alpha <= 0)
 869     {
 870         //setmodel(self, "");
 871         self.alpha = -1;
 872         self.effects |= EF_NODRAW;
 873     }
 874     else
 875     {
 876         self.nextthink = time + 0.1;
 877     }
 878 }
 879
 880 void vehicles_painframe()
 881 {
 882     if(self.owner.vehicle_health <= 50)
 883     if(self.pain_frame < time)
 884     {
 885         float _ftmp;
 886         _ftmp = self.owner.vehicle_health / 50;
 887         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 888         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 889
 890         if(self.vehicle_flags & VHF_DMGSHAKE)
 891             self.velocity += randomvec() * 30;
 892
 893         if(self.vehicle_flags & VHF_DMGROLL)
 894             if(self.vehicle_flags & VHF_DMGHEADROLL)
 895                 self.tur_head.angles += randomvec();
 896             else
 897                 self.angles += randomvec();
 898
 899     }
 900 }
 901
 902 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 903 {
 904     self.dmg_time = time;
 905
 906         // WEAPONTODO
 907     if(DEATH_ISWEAPON(deathtype, WEP_VORTEX.m_id))
 908         damage *= autocvar_g_vehicles_vortex_damagerate;
 909
 910     if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN.m_id))
 911         damage *= autocvar_g_vehicles_machinegun_damagerate;
 912
 913     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE.m_id))
 914         damage *= autocvar_g_vehicles_rifle_damagerate;
 915
 916     if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id))
 917         damage *= autocvar_g_vehicles_vaporizer_damagerate;
 918
 919     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER.m_id))
 920         damage *= autocvar_g_vehicles_tag_damagerate;
 921
 922     self.enemy = attacker;
 923
 924     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 925     {
 926         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 927         {
 928             self.vehicle_shieldent = spawn();
 929             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 930
 931             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 932             setattachment(self.vehicle_shieldent, self, "");
 933             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 934             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 935             self.vehicle_shieldent.think       = shieldhit_think;
 936         }
 937
 938         self.vehicle_shieldent.colormod    = '1 1 1';
 939         self.vehicle_shieldent.alpha       = 0.45;
 940         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 941         self.vehicle_shieldent.nextthink   = time;
 942         self.vehicle_shieldent.effects &= ~EF_NODRAW;
 943
 944         self.vehicle_shield -= damage;
 945
 946         if(self.vehicle_shield < 0)
 947         {
 948             self.vehicle_health            -= fabs(self.vehicle_shield);
 949             self.vehicle_shieldent.colormod = '2 0 0';
 950             self.vehicle_shield             = 0;
 951             self.vehicle_shieldent.alpha    = 0.75;
 952
 953                 if(sound_allowed(MSG_BROADCAST, attacker))
 954                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 955         }
 956         else
 957                 if(sound_allowed(MSG_BROADCAST, attacker))
 958                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 959
 960     }
 961     else
 962     {
 963         self.vehicle_health -= damage;
 964
 965         if(sound_allowed(MSG_BROADCAST, attacker))
 966             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 967     }
 968
 969         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 970                 self.velocity += force * self.damageforcescale;
 971         else
 972                 self.velocity += force;
 973
 974     if(self.vehicle_health <= 0)
 975     {
 976         if(self.owner)
 977             if(self.vehicle_flags & VHF_DEATHEJECT)
 978                 vehicles_exit(VHEF_EJECT);
 979             else
 980                 vehicles_exit(VHEF_RELESE);
 981
 982
 983         antilag_clear(self);
 984
 985         self.vehicle_die();
 986         vehicles_setreturn();
 987     }
 988 }
 989
 990 void vehicles_clearreturn()
 991 {
 992     entity ret;
 993     // Remove "return helper", if any.
 994     ret = findchain(classname, "vehicle_return");
 995     while(ret)
 996     {
 997         if(ret.wp00 == self)
 998         {
 999             ret.classname   = "";
1000             ret.think       = SUB_Remove;
1001             ret.nextthink   = time + 0.1;
1002
1003             if(ret.waypointsprite_attached)
1004                 WaypointSprite_Kill(ret.waypointsprite_attached);
1005
1006             return;
1007         }
1008         ret = ret.chain;
1009     }
1010 }
1011
1012 void vehicles_return()
1013 {
1014     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
1015
1016     self.wp00.think     = vehicles_spawn;
1017     self.wp00.nextthink = time;
1018
1019     if(self.waypointsprite_attached)
1020         WaypointSprite_Kill(self.waypointsprite_attached);
1021
1022     remove(self);
1023 }
1024
1025 void vehicles_showwp_goaway()
1026 {
1027     if(self.waypointsprite_attached)
1028         WaypointSprite_Kill(self.waypointsprite_attached);
1029
1030     remove(self);
1031
1032 }
1033
1034 void vehicles_showwp()
1035 {
1036     entity oldself = world;
1037     vector rgb;
1038
1039     if(self.cnt)
1040     {
1041         self.think      = vehicles_return;
1042         self.nextthink  = self.cnt;
1043     }
1044     else
1045     {
1046         self.think      = vehicles_return;
1047         self.nextthink  = time +1;
1048
1049         oldself = self;
1050         self = spawn();
1051         setmodel(self, "null");
1052         self.team = oldself.wp00.team;
1053         self.wp00 = oldself.wp00;
1054         setorigin(self, oldself.wp00.pos1);
1055
1056         self.nextthink = time + 5;
1057         self.think = vehicles_showwp_goaway;
1058     }
1059
1060     if(teamplay && self.team)
1061             rgb = Team_ColorRGB(self.team);
1062     else
1063             rgb = '1 1 1';
1064     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
1065     if(self.waypointsprite_attached)
1066     {
1067         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1068         if(oldself == world)
1069             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1070         WaypointSprite_Ping(self.waypointsprite_attached);
1071     }
1072
1073     if(oldself != world)
1074         self = oldself;
1075 }
1076
1077 void vehicles_setreturn()
1078 {
1079     entity ret;
1080
1081     vehicles_clearreturn();
1082
1083     ret = spawn();
1084     ret.classname   = "vehicle_return";
1085     ret.wp00       = self;
1086     ret.team        = self.team;
1087     ret.think       = vehicles_showwp;
1088
1089         if(self.deadflag != DEAD_NO)
1090         {
1091                 ret.cnt = max(game_starttime, time) + self.vehicle_respawntime;
1092                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 5);
1093         }
1094         else
1095                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 1);
1096
1097     setmodel(ret, "null");
1098     setorigin(ret, self.pos1 + '0 0 96');
1099 }
1100
1101 void vehicles_reset_colors()
1102 {
1103     entity e;
1104     float _effects = 0, _colormap;
1105     vector _glowmod, _colormod;
1106
1107     if(autocvar_g_nodepthtestplayers)
1108         _effects |= EF_NODEPTHTEST;
1109
1110     if(autocvar_g_fullbrightplayers)
1111         _effects |= EF_FULLBRIGHT;
1112
1113     if(self.team)
1114         _colormap = 1024 + (self.team - 1) * 17;
1115     else
1116         _colormap = 1024;
1117
1118     _glowmod  = '0 0 0';
1119     _colormod = '0 0 0';
1120
1121     // Find all ents attacked to main model and setup effects, colormod etc.
1122     e = findchainentity(tag_entity, self);
1123     while(e)
1124     {
1125         if(e != self.vehicle_shieldent)
1126         {
1127             e.effects   = _effects; //  | EF_LOWPRECISION;
1128             e.colormod  = _colormod;
1129             e.colormap  = _colormap;
1130             e.alpha     = 1;
1131         }
1132         e = e.chain;
1133     }
1134
1135     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1136     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1137     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1138     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1139
1140     self.alpha     = 1;
1141     self.avelocity = '0 0 0';
1142     self.velocity  = '0 0 0';
1143     self.effects   = _effects;
1144 }
1145
1146 void vehicle_use()
1147 {
1148     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1149
1150     self.tur_head.team = activator.team;
1151
1152     if(self.tur_head.team == 0)
1153         self.active = ACTIVE_NOT;
1154     else
1155         self.active = ACTIVE_ACTIVE;
1156
1157     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1158     {
1159         dprint("^3Eat shit yall!\n");
1160         vehicles_setreturn();
1161         vehicles_reset_colors();
1162     }
1163     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1164     {
1165
1166     }
1167 }
1168
1169 float vehicle_addplayerslot(    entity _owner,
1170                                 entity _slot,
1171                                 float _hud,
1172                                 string _hud_model,
1173                                 float() _framefunc,
1174                                 void(float) _exitfunc)
1175 {
1176     if (!(_owner.vehicle_flags & VHF_MULTISLOT))
1177         _owner.vehicle_flags |= VHF_MULTISLOT;
1178
1179     _slot.PlayerPhysplug = _framefunc;
1180     _slot.vehicle_exit = _exitfunc;
1181     _slot.hud = _hud;
1182     _slot.vehicle_flags = VHF_PLAYERSLOT;
1183     _slot.vehicle_viewport = spawn();
1184     _slot.vehicle_hudmodel = spawn();
1185     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1186     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1187
1188     setmodel(_slot.vehicle_hudmodel, _hud_model);
1189     setmodel(_slot.vehicle_viewport, "null");
1190
1191     setattachment(_slot.vehicle_hudmodel, _slot, "");
1192     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1193
1194     return true;
1195 }
1196
1197 float vehicle_initialize(string  net_name,
1198                          string  bodymodel,
1199                          string  topmodel,
1200                          string  hudmodel,
1201                          string  toptag,
1202                          string  hudtag,
1203                          string  viewtag,
1204                          float   vhud,
1205                          vector  min_s,
1206                          vector  max_s,
1207                          float   nodrop,
1208                          void(float _spawnflag)  spawnproc,
1209                          float   _respawntime,
1210                          float() physproc,
1211                          void()  enterproc,
1212                          void(float extflag) exitfunc,
1213                          void() dieproc,
1214                          void() thinkproc,
1215                          float  use_csqc,
1216                          float _max_health,
1217                          float _max_shield)
1218 {
1219         if(!autocvar_g_vehicles)
1220                 return false;
1221
1222     if(self.targetname)
1223     {
1224         self.vehicle_controller = find(world, target, self.targetname);
1225         if(!self.vehicle_controller)
1226         {
1227             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1228         }
1229         else
1230         {
1231             self.team = self.vehicle_controller.team;
1232             self.use = vehicle_use;
1233
1234             if(teamplay)
1235             {
1236                 if(self.vehicle_controller.team == 0)
1237                     self.active = ACTIVE_NOT;
1238                 else
1239                     self.active = ACTIVE_ACTIVE;
1240             }
1241         }
1242     }
1243
1244     precache_sound("onslaught/ons_hit2.wav");
1245     precache_sound("onslaught/electricity_explode.wav");
1246
1247
1248     addstat(STAT_HUD, AS_INT,  hud);
1249         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1250         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1251         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1252
1253         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1254         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1255
1256         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1257         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1258
1259     if(bodymodel == "")
1260         error("vehicles: missing bodymodel!");
1261
1262     if(hudmodel == "")
1263         error("vehicles: missing hudmodel!");
1264
1265     if(net_name == "")
1266         self.netname = self.classname;
1267     else
1268         self.netname = net_name;
1269
1270     if(self.team && !teamplay)
1271         self.team = 0;
1272
1273     self.vehicle_flags |= VHF_ISVEHICLE;
1274
1275     setmodel(self, bodymodel);
1276
1277     self.vehicle_viewport   = spawn();
1278     self.vehicle_hudmodel   = spawn();
1279     self.tur_head           = spawn();
1280     self.tur_head.owner     = self;
1281     self.takedamage         = DAMAGE_AIM;
1282     self.bot_attack         = true;
1283     self.iscreature         = true;
1284     self.teleportable       = false; // no teleporting for vehicles, too buggy
1285     self.damagedbycontents      = true;
1286     self.hud                = vhud;
1287     self.tur_health          = _max_health;
1288     self.tur_head.tur_health = _max_shield;
1289     self.vehicle_die         = dieproc;
1290     self.vehicle_exit        = exitfunc;
1291     self.vehicle_enter       = enterproc;
1292     self.PlayerPhysplug      = physproc;
1293     self.event_damage        = func_null;
1294     self.touch               = vehicles_touch;
1295     self.think               = vehicles_spawn;
1296     self.vehicle_spawn       = spawnproc;
1297         self.vehicle_respawntime = max(0, _respawntime);
1298     self.effects             = EF_NODRAW;
1299         self.dphitcontentsmask   = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1300         if(!autocvar_g_vehicles_delayspawn || !self.vehicle_respawntime)
1301                 self.nextthink = time;
1302         else
1303                 self.nextthink = max(time, game_starttime) + max(0, self.vehicle_respawntime + ((random() * 2 - 1) * autocvar_g_vehicles_delayspawn_jitter));
1304
1305         if(autocvar_g_playerclip_collisions)
1306                 self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1307
1308     if(autocvar_g_nodepthtestplayers)
1309         self.effects = self.effects | EF_NODEPTHTEST;
1310
1311     if(autocvar_g_fullbrightplayers)
1312         self.effects = self.effects | EF_FULLBRIGHT;
1313
1314     setmodel(self.vehicle_hudmodel, hudmodel);
1315     setmodel(self.vehicle_viewport, "null");
1316
1317     if(topmodel != "")
1318     {
1319         setmodel(self.tur_head, topmodel);
1320         setattachment(self.tur_head, self, toptag);
1321         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1322         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1323     }
1324     else
1325     {
1326         setattachment(self.tur_head, self, "");
1327         setattachment(self.vehicle_hudmodel, self, hudtag);
1328         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1329     }
1330
1331     setsize(self, min_s, max_s);
1332     if (!nodrop)
1333     {
1334         setorigin(self, self.origin);
1335         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1336         setorigin(self, trace_endpos);
1337     }
1338
1339     self.pos1 = self.origin;
1340     self.pos2 = self.angles;
1341     self.tur_head.team = self.team;
1342
1343         if(MUTATOR_CALLHOOK(VehicleSpawn))
1344                 return false;
1345
1346     return true;
1347 }
1348
1349 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1350                          float _pichlimit_min, float _pichlimit_max,
1351                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1352 {
1353     vector vtmp, vtag;
1354     float ftmp;
1355     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1356     vtmp = vectoangles(normalize(_target - vtag));
1357     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1358     vtmp = AnglesTransform_Normalize(vtmp, true);
1359     ftmp = _aimspeed * frametime;
1360     vtmp.y = bound(-ftmp, vtmp.y, ftmp);
1361     vtmp.x = bound(-ftmp, vtmp.x, ftmp);
1362     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles.y + vtmp.y, _rotlimit_max);
1363     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles.x + vtmp.x, _pichlimit_max);
1364     return vtag;
1365 }
1366
1367 void vehicles_gib_explode()
1368 {
1369         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
1370         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1371         remove(self);
1372 }
1373
1374 void vehicles_gib_think()
1375 {
1376         self.alpha -= 0.1;
1377         if(self.cnt >= time)
1378                 remove(self);
1379         else
1380                 self.nextthink = time + 0.1;
1381 }
1382
1383 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1384 {
1385         entity _gib = spawn();
1386         setmodel(_gib, _template.model);
1387         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1388         _gib.velocity = _vel;
1389         _gib.movetype = MOVETYPE_TOSS;
1390         _gib.solid = SOLID_CORPSE;
1391         _gib.colormod = '-0.5 -0.5 -0.5';
1392         _gib.effects = EF_LOWPRECISION;
1393         _gib.avelocity = _rot;
1394
1395         if(_burn)
1396                 _gib.effects |= EF_FLAME;
1397
1398         if(_explode)
1399         {
1400                 _gib.think = vehicles_gib_explode;
1401                 _gib.nextthink = time + random() * _explode;
1402                 _gib.touch = vehicles_gib_explode;
1403         }
1404         else
1405         {
1406                 _gib.cnt = time + _maxtime;
1407                 _gib.think = vehicles_gib_think;
1408                 _gib.nextthink = time + _maxtime - 1;
1409                 _gib.alpha = 1;
1410         }
1411         return _gib;
1412 }
1413
1414 /*
1415 vector predict_target(entity _targ, vector _from, float _shot_speed)
1416 {
1417     float i;                // loop
1418     float _distance;        // How far to target
1419     float _impact_time;     // How long untill projectile impacts
1420     vector _predict_pos;    // Predicted enemy location
1421     vector _original_origin;// Where target is before predicted
1422
1423      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1424
1425     _predict_pos = _original_origin;
1426     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1427     {
1428         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1429         _impact_time = _distance / _shot_speed; // Calculate impact time
1430         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1431     }
1432
1433     return _predict_pos;
1434 }
1435 */