qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   8 void vehicles_return();
   9 void vehicles_enter();
  10 void vehicles_touch();
  11 void vehicles_reset_colors();
  12 void vehicles_clearrturn();
  13 void vehicles_setreturn();
  14
  15
  16 /** AuxiliaryXhair*
  17     Send additional points of interest to be drawn, to vehicle owner
  18 **/
  19 float MAX_AXH = 4;
  20 .entity AuxiliaryXhair[MAX_AXH];
  21
  22 float SendAuxiliaryXhair(entity to, float sf)
  23 {
  24
  25         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  26
  27         WriteByte(MSG_ENTITY, self.cnt);
  28
  29         WriteCoord(MSG_ENTITY, self.origin_x);
  30         WriteCoord(MSG_ENTITY, self.origin_y);
  31         WriteCoord(MSG_ENTITY, self.origin_z);
  32
  33     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  35     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  36
  37     return TRUE;
  38 }
  39
  40 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  41 {
  42     entity axh;
  43
  44     axh_id = bound(0, axh_id, MAX_AXH);
  45     axh = own.AuxiliaryXhair[axh_id];
  46
  47     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  48     {
  49         axh                     = spawn();
  50         axh.cnt                 = axh_id;
  51         axh.drawonlytoclient    = own;
  52         axh.owner               = own;
  53         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  54     }
  55
  56     setorigin(axh, loc);
  57     axh.colormod            = clr;
  58     axh.SendFlags           = 0x01;
  59     own.AuxiliaryXhair[axh_id] = axh;
  60 }
  61
  62 /*
  63 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  64 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  65 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  66 {
  67         msg_entity = own;
  68
  69         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  70         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  71
  72         WriteByte(MSG_ONE, axh_id);
  73
  74         WriteCoord(MSG_ONE, loc_x);
  75         WriteCoord(MSG_ONE, loc_y);
  76         WriteCoord(MSG_ONE, loc_z);
  77
  78     WriteByte(MSG_ONE, rint(clr_x * 255));
  79     WriteByte(MSG_ONE, rint(clr_y * 255));
  80     WriteByte(MSG_ONE, rint(clr_z * 255));
  81
  82 }
  83 */
  84 // End AuxiliaryXhair
  85
  86 /**
  87     Notifies the client that he enterd a vehicle, and sends
  88     realavent data.
  89
  90     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  91 **/
  92 void CSQCVehicleSetup(entity own, float vehicle_id)
  93 {
  94         msg_entity = own;
  95
  96         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  97         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  98         WriteByte(MSG_ONE, vehicle_id);
  99 }
 100
 101 /** vehicles_locktarget
 102
 103     Generic target locking.
 104
 105     Figure out if what target is "locked" (if any), for missile tracking as such.
 106
 107     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 108     you have a locked in target.
 109
 110     Exspects a crosshair_trace() or equivalent to be
 111     dont before calling.
 112
 113 **/
 114 .entity lock_target;
 115 .float  lock_strength;
 116 .float  lock_time;
 117 .float  lock_soundtime;
 118 void vehicles_locktarget(float incr, float decr, float _lock_time)
 119 {
 120     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 121     {
 122         self.lock_target    = world;
 123         self.lock_strength  = 0;
 124         self.lock_time      = 0;
 125     }
 126
 127     if(self.lock_time > time)
 128     {
 129         if(self.lock_target)
 130         if(self.lock_soundtime < time)
 131         {
 132             self.lock_soundtime = time + 0.5;
 133             play2(self.owner, "vehicles/locked.wav");
 134         }
 135
 136         return;
 137     }
 138
 139     if(trace_ent != world)
 140     {
 141         if(teamplay && trace_ent.team == self.team)
 142             trace_ent = world;
 143
 144         if(trace_ent.deadflag != DEAD_NO)
 145             trace_ent = world;
 146
 147         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 148             trace_ent = world;
 149     }
 150
 151     if(self.lock_target == world && trace_ent != world)
 152         self.lock_target = trace_ent;
 153
 154     if(self.lock_target && trace_ent == self.lock_target)
 155     {
 156         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 157         {
 158             play2(self.owner, "vehicles/lock.wav");
 159             self.lock_soundtime = time + 0.8;
 160         }
 161         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 162         {
 163             play2(self.owner, "vehicles/locking.wav");
 164             self.lock_soundtime = time + 0.3;
 165         }
 166
 167     }
 168
 169     // Have a locking target
 170     // Trace hit current target
 171     if(trace_ent == self.lock_target && trace_ent != world)
 172     {
 173         self.lock_strength = min(self.lock_strength + incr, 1);
 174         if(self.lock_strength == 1)
 175             self.lock_time = time + _lock_time;
 176     }
 177     else
 178     {
 179         if(trace_ent)
 180             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 181         else
 182             self.lock_strength = max(self.lock_strength - decr, 0);
 183
 184         if(self.lock_strength == 0)
 185             self.lock_target = world;
 186     }
 187 }
 188
 189 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 190 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 191
 192 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 193 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 194 if(trace_fraction != 1) \
 195     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 196
 197 // Hover movement support
 198 float  force_fromtag_power;
 199 float  force_fromtag_normpower;
 200 vector force_fromtag_origin;
 201 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 202 {
 203     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 204     v_forward  = normalize(v_forward) * -1;
 205     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 206
 207     force_fromtag_power = (1 - trace_fraction) * max_power;
 208     force_fromtag_normpower = force_fromtag_power / max_power;
 209
 210     return v_forward  * force_fromtag_power;
 211 }
 212
 213 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 214 // Can possibly be use to move abt any surface (inclusing walls/celings)
 215 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 216 {
 217
 218     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 219     v_forward  = normalize(v_forward) * -1;
 220     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 221
 222     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 223     if(trace_fraction == 1.0)
 224     {
 225         force_fromtag_normpower = -0.25;
 226         return '0 0 -200';
 227     }
 228
 229     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 230     force_fromtag_normpower = force_fromtag_power / max_power;
 231
 232     return v_forward  * force_fromtag_power;
 233 }
 234
 235 // Generic vehile projectile system
 236 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 237 {
 238     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 239     if(inflictor.owner == self.owner)
 240         return;
 241
 242     self.health -= damage;
 243     self.velocity += force;
 244     if(self.health < 1)
 245     {
 246         self.takedamage = DAMAGE_NO;
 247         self.event_damage = SUB_Null;
 248         self.think = self.use;
 249         self.nextthink = time;
 250     }
 251
 252 }
 253
 254 void vehicles_projectile_explode()
 255 {
 256     if(self.owner && other != world)
 257     {
 258         if(other == self.owner.vehicle)
 259             return;
 260
 261         if(other == self.owner.vehicle.tur_head)
 262             return;
 263     }
 264
 265         PROJECTILE_TOUCH;
 266
 267         self.event_damage = SUB_Null;
 268     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 269
 270     remove (self);
 271 }
 272
 273 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 274                            vector _org, vector _vel,
 275                            float _dmg, float _radi, float _force,  float _size,
 276                            float _deahtype, float _projtype, float _health,
 277                            float _cull, float _clianim)
 278 {
 279     entity proj;
 280
 281     proj = spawn();
 282
 283     PROJECTILE_MAKETRIGGER(proj);
 284     setorigin(proj, _org);
 285
 286     proj.shot_dmg         = _dmg;
 287     proj.shot_radius      = _radi;
 288     proj.shot_force       = _force;
 289     proj.totalfrags       = _deahtype;
 290     proj.solid            = SOLID_BBOX;
 291     proj.movetype         = MOVETYPE_FLYMISSILE;
 292     proj.flags            = FL_PROJECTILE;
 293     proj.bot_dodge        = TRUE;
 294     proj.bot_dodgerating  = _dmg;
 295     proj.velocity         = _vel;
 296     proj.touch            = vehicles_projectile_explode;
 297     proj.use              = vehicles_projectile_explode;
 298     proj.owner            = self;
 299     proj.realowner        = self.owner;
 300     proj.think            = SUB_Remove;
 301     proj.nextthink        = time + 30;
 302
 303     if(_health)
 304     {
 305         proj.takedamage       = DAMAGE_AIM;
 306         proj.event_damage     = vehicles_projectile_damage;
 307         proj.health           = _health;
 308     }
 309     else
 310         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 311
 312     if(_mzlsound)
 313         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 314
 315     if(_mzlfx)
 316         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 317
 318
 319     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 320
 321     CSQCProjectile(proj, _clianim, _projtype, _cull);
 322
 323     return proj;
 324 }
 325 // End generic vehile projectile system
 326
 327 /** vehicles_spawn
 328     Exetuted for all vehicles on (re)spawn.
 329     Sets defaults for newly spawned units.
 330 **/
 331 void vehicles_spawn()
 332 {
 333     dprint("Spawning vehicle: ", self.netname, "\n");
 334
 335     // De-own & reset
 336     self.vehicle_hudmodel.viewmodelforclient = self;
 337
 338     self.owner              = world;
 339     self.touch              = vehicles_touch;
 340     self.event_damage       = vehicles_damage;
 341     self.iscreature         = TRUE;
 342     self.movetype           = MOVETYPE_WALK;
 343     self.solid              = SOLID_SLIDEBOX;
 344     self.takedamage         = DAMAGE_AIM;
 345         self.deadflag           = DEAD_NO;
 346     self.bot_attack         = TRUE;
 347     self.flags              = FL_NOTARGET;
 348     self.avelocity          = '0 0 0';
 349     self.velocity           = '0 0 0';
 350
 351     // Reset locking
 352     self.lock_strength      = 0;
 353     self.lock_target        = world;
 354     self.misc_bulletcounter = 0;
 355
 356     // Return to spawn
 357     self.angles             = self.pos2;
 358     setorigin(self, self.pos1 + '0 0 128');
 359     // Show it
 360     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 361
 362     vehicles_reset_colors();
 363     self.vehicle_spawn();
 364 }
 365
 366 // Better way of determening whats crushable needed! (fl_crushable?)
 367 float vehicles_crushable(entity e)
 368 {
 369     if(e.classname == "player")
 370         return TRUE;
 371
 372     if(e.classname == "monster_zombie")
 373         return TRUE;
 374
 375     return FALSE;
 376 }
 377
 378 void vehicles_touch()
 379 {
 380     // Vehicle currently in use
 381     if(self.owner)
 382     {
 383         // Colided with world?
 384         if(other == world)
 385         {
 386         }
 387         else
 388         {
 389             if(other.vehicle_flags & VHF_ISVEHICLE)
 390             {
 391                 //other.velocity += self.velocity * (self.mass / other.mass);
 392             }
 393             else if(vehicles_crushable(other))
 394             {
 395                 if(vlen(self.velocity) != 0)
 396                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 397             }
 398         }
 399         return;
 400     }
 401
 402     if(other.classname != "player")
 403         return;
 404
 405     if(other.deadflag != DEAD_NO)
 406         return;
 407
 408     if(other.vehicle != world)
 409         return;
 410
 411     // Remove this when bots know how to use vehicles.
 412     if (clienttype(other) != CLIENTTYPE_REAL)
 413         return;
 414
 415     vehicles_enter();
 416 }
 417
 418 void vehicles_enter()
 419 {
 420    // Remove this when bots know how to use vehicles
 421     if (clienttype(other) != CLIENTTYPE_REAL)
 422         return;
 423
 424     if(self.phase > time)
 425         return;
 426
 427     if(teamplay)
 428     if(self.team)
 429     if(self.team != other.team)
 430         return;
 431
 432     self.vehicle_ammo1   = 0;
 433     self.vehicle_ammo2   = 0;
 434     self.vehicle_reload1 = 0;
 435     self.vehicle_reload2 = 0;
 436     self.vehicle_energy  = 0;
 437
 438     self.owner          = other;
 439     self.switchweapon   = other.switchweapon;
 440
 441     // .viewmodelforclient works better.
 442     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 443
 444     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 445
 446     self.event_damage         = vehicles_damage;
 447     self.nextthink            = 0;
 448     self.owner.angles         = self.angles;
 449     self.owner.takedamage     = DAMAGE_NO;
 450     self.owner.solid          = SOLID_NOT;
 451     self.owner.movetype       = MOVETYPE_NOCLIP;
 452     self.owner.alpha          = -1;
 453     self.owner.vehicle        = self;
 454     self.owner.event_damage   = SUB_Null;
 455     self.owner.view_ofs       = '0 0 0';
 456     self.colormap             = self.owner.colormap;
 457     if(self.tur_head)
 458         self.tur_head.colormap    = self.owner.colormap;
 459
 460     self.owner.hud            = self.hud;
 461     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 462
 463     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 464     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 465     self.owner.vehicle_reload1  = self.vehicle_reload1;
 466     self.owner.vehicle_reload2  = self.vehicle_reload2;
 467
 468     // Cant do this, hides attached objects too.
 469     //self.exteriormodeltoclient = self.owner;
 470     //self.tur_head.exteriormodeltoclient = self.owner;
 471
 472     other.flags &~= FL_ONGROUND;
 473     self.flags  &~= FL_ONGROUND;
 474
 475     self.team                 = self.owner.team;
 476     self.flags               -= FL_NOTARGET;
 477
 478     msg_entity = other;
 479     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 480     WriteEntity(MSG_ONE, self.vehicle_viewport);
 481
 482     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 483     if(self.tur_head)
 484     {
 485         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 486         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 487         WriteAngle(MSG_ONE, 0);                                      // roll
 488     }
 489     else
 490     {
 491         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 492         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 493         WriteAngle(MSG_ONE,  0);                  // roll
 494     }
 495
 496     vehicles_clearrturn();
 497
 498     CSQCVehicleSetup(self.owner, self.hud);
 499
 500     if(other.flagcarried)
 501     {
 502         if(!autocvar_g_vehicles_allow_flagcarry)
 503             DropFlag(other.flagcarried, world, world);
 504         else
 505         {
 506             other.flagcarried.scale = 1;
 507             setattachment(other.flagcarried, self, "");
 508             setorigin(other, '0 0 96');
 509         }
 510     }
 511
 512     self.vehicle_enter();
 513 }
 514
 515 /** vehicles_findgoodexit
 516     Locates a valid location for the player to exit the vehicle.
 517     Will first try prefer_spot, then up 100 random spots arround the vehicle
 518     wich are in direct line of sight and empty enougth to hold a players bbox
 519 **/
 520 vector vehicles_findgoodexit(vector prefer_spot)
 521 {
 522     //vector exitspot;
 523     float mysize;
 524
 525     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 526     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 527         return prefer_spot;
 528
 529     mysize = vlen(self.maxs - self.mins);
 530     float i;
 531     vector v, v2;
 532     v2 = 0.5 * (self.absmin + self.absmax);
 533     for(i = 0; i < 100; ++i)
 534     {
 535         v = randomvec();
 536         v_z = 0;
 537         v = v2 + normalize(v) * mysize;
 538         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 539         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 540             return v;
 541     }
 542
 543     /*
 544     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 545     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 546     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 547         return exitspot;
 548
 549     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 550     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 551     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 552         return exitspot;
 553
 554     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 555     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 556     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 557         return exitspot;
 558
 559     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 560     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 561     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 562         return exitspot;
 563     */
 564
 565     return self.origin;
 566 }
 567
 568 /** vehicles_exit
 569     Standarrd vehicle release fucntion.
 570     custom code goes in self.vehicle_exit
 571 **/
 572 void vehicles_exit(float eject)
 573 {
 574     entity oldself;
 575     if(self.flags & FL_CLIENT)
 576     {
 577         oldself = self;
 578         self = self.vehicle;
 579     }
 580
 581         self.flags |= FL_NOTARGET;
 582
 583     if (self.owner)
 584     {
 585         msg_entity = self.owner;
 586         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 587         WriteEntity( MSG_ONE, self.owner);
 588
 589         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 590         WriteAngle(MSG_ONE, 0);                 // pich
 591         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 592         WriteAngle(MSG_ONE, 0);                 // roll
 593
 594         setsize(self.owner, PL_MIN,PL_MAX);
 595
 596         self.owner.takedamage     = DAMAGE_AIM;
 597         self.owner.solid          = SOLID_SLIDEBOX;
 598         self.owner.movetype       = MOVETYPE_WALK;
 599         self.owner.effects        &~= EF_NODRAW;
 600         self.owner.alpha          = 1;
 601         self.owner.PlayerPhysplug = SUB_Null;
 602         self.owner.vehicle        = world;
 603         self.owner.view_ofs       = PL_VIEW_OFS;
 604         self.owner.event_damage   = PlayerDamage;
 605         self.owner.hud            = HUD_NORMAL;
 606         self.owner.switchweapon   = self.switchweapon;
 607         //self.owner.BUTTON_USE     = 0;
 608     }
 609
 610     if(self.deadflag == DEAD_NO)
 611         self.avelocity          = '0 0 0';
 612
 613     self.vehicle_hudmodel.viewmodelforclient = self;
 614         self.tur_head.nodrawtoclient             = world;
 615     vehicles_setreturn();
 616
 617     self.phase = time + 1;
 618
 619     if(!teamplay)
 620         self.team = 0;
 621     else
 622         self.team = self.tur_head.team;
 623
 624     if(self.owner.flagcarried)
 625     {
 626         self.owner.flagcarried.scale = 0.6;
 627         setattachment(self.owner.flagcarried, self.owner, "");
 628         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 629     }
 630
 631     sound (self, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 632     self.vehicle_exit(eject);
 633     self.owner = world;
 634     vehicles_reset_colors();
 635
 636     if(oldself)
 637         self = oldself;
 638 }
 639
 640
 641 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 642 {
 643     if(self.regen_field < field_max)
 644     if(self.timer + rpause < time)
 645     {
 646         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 647
 648         if(self.owner)
 649             self.owner.regen_field = (self.regen_field / field_max) * 100;
 650     }
 651 }
 652
 653 void shieldhit_think()
 654 {
 655     self.alpha -= 0.1;
 656     if (self.alpha <= 0)
 657     {
 658         //setmodel(self, "");
 659         self.alpha = -1;
 660     }
 661     else
 662     {
 663         self.nextthink = time + 0.1;
 664     }
 665 }
 666
 667 void vehicles_painframe()
 668 {
 669 //.float        pain_finished;                  //Added by Supajoe
 670
 671     if(self.owner.vehicle_health <= 50)
 672     if(self.pain_frame < time)
 673     {
 674         float _ftmp;
 675         _ftmp = self.owner.vehicle_health / 50;
 676         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 677         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 678
 679         if(self.vehicle_flags & VHF_DMGSHAKE)
 680             self.velocity += randomvec() * 30;
 681
 682         if(self.vehicle_flags & VHF_DMGROLL)
 683             if(self.vehicle_flags & VHF_DMGHEADROLL)
 684                 self.tur_head.angles += randomvec();
 685             else
 686                 self.angles += randomvec();
 687
 688     }
 689 }
 690
 691 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 692 {
 693     self.dmg_time = time;
 694
 695     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 696     {
 697         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 698         {
 699             self.vehicle_shieldent = spawn();
 700             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 701
 702             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 703             setattachment(self.vehicle_shieldent, self, "");
 704             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 705             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 706             self.vehicle_shieldent.think       = shieldhit_think;
 707         }
 708
 709         self.vehicle_shieldent.colormod    = '1 1 1';
 710         self.vehicle_shieldent.alpha       = 0.45;
 711         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 712         self.vehicle_shieldent.nextthink   = time;
 713
 714         self.vehicle_shield -= damage;
 715
 716         if(self.vehicle_shield < 0)
 717         {
 718             self.vehicle_health            -= fabs(self.vehicle_shield);
 719             self.vehicle_shieldent.colormod = '2 0 0';
 720             self.vehicle_shield             = 0;
 721             self.vehicle_shieldent.alpha    = 0.75;
 722
 723                 if(sound_allowed(MSG_BROADCAST, attacker))
 724                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 725         }
 726         else
 727                 if(sound_allowed(MSG_BROADCAST, attacker))
 728                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 729
 730     }
 731     else
 732     {
 733         self.vehicle_health -= damage;
 734
 735         if(sound_allowed(MSG_BROADCAST, attacker))
 736             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 737     }
 738
 739     self.velocity += force; // * (vlen(force) / self.mass);
 740
 741     if(self.vehicle_health <= 0)
 742     {
 743         if(self.owner)
 744             if(self.vehicle_flags & VHF_DEATHEJECT)
 745                 vehicles_exit(VHEF_EJECT);
 746             else
 747                 vehicles_exit(VHEF_RELESE);
 748
 749         self.vehicle_die();
 750         vehicles_setreturn();
 751     }
 752 }
 753
 754 void vehicles_clearrturn()
 755 {
 756     entity ret;
 757     // Remove "return helper", if any.
 758     ret = findchain(classname, "vehicle_return");
 759     while(ret)
 760     {
 761         if(ret.enemy == self)
 762         {
 763             ret.classname   = "";
 764             ret.think       = SUB_Remove;
 765             ret.nextthink   = time + 0.1;
 766
 767             if(ret.waypointsprite_attached)
 768                 WaypointSprite_Kill(ret.waypointsprite_attached);
 769
 770             return;
 771         }
 772         ret = ret.chain;
 773     }
 774 }
 775
 776 void vehicles_return()
 777 {
 778     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 779
 780     self.enemy.think     = vehicles_spawn;
 781     self.enemy.nextthink = time;
 782
 783     if(self.waypointsprite_attached)
 784         WaypointSprite_Kill(self.waypointsprite_attached);
 785
 786     remove(self);
 787 }
 788
 789 void vehicles_showwp_goaway()
 790 {
 791     if(self.waypointsprite_attached)
 792         WaypointSprite_Kill(self.waypointsprite_attached);
 793
 794     remove(self);
 795
 796 }
 797
 798 void vehicles_showwp()
 799 {
 800     entity oldself;
 801     vector rgb;
 802
 803     if(self.cnt)
 804     {
 805         self.think      = vehicles_return;
 806         self.nextthink  = self.cnt;
 807     }
 808     else
 809     {
 810         self.think      = vehicles_return;
 811         self.nextthink  = time +1;
 812
 813         oldself = self;
 814         self = spawn();
 815         setmodel(self, "null");
 816         self.team = oldself.enemy.team;
 817         self.enemy = oldself.enemy;
 818         setorigin(self, oldself.enemy.pos1);
 819
 820         self.nextthink = time + 5;
 821         self.think = vehicles_showwp_goaway;
 822     }
 823
 824     if(teamplay && self.team)
 825             rgb = TeamColor(self.team);
 826     else
 827             rgb = '1 1 1';
 828     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 829     if(self.waypointsprite_attached)
 830     {
 831         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 832         if(oldself == world)
 833             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 834         WaypointSprite_Ping(self.waypointsprite_attached);
 835     }
 836
 837     if(oldself != world)
 838         self = oldself;
 839 }
 840
 841 void vehicles_setreturn()
 842 {
 843     entity ret;
 844
 845     vehicles_clearrturn();
 846
 847     ret = spawn();
 848     ret.classname   = "vehicle_return";
 849     ret.enemy       = self;
 850     ret.team        = self.team;
 851     ret.think       = vehicles_showwp;
 852
 853     if(self.deadflag != DEAD_NO)
 854     {
 855         ret.cnt         = time + self.vehicle_respawntime;
 856         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 857     }
 858     else
 859     {
 860         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 861     }
 862
 863     setmodel(ret, "null");
 864     setorigin(ret, self.pos1 + '0 0 96');
 865
 866 }
 867
 868 void vehicles_configcheck(string  configname, float check_cvar)
 869 {
 870     if(check_cvar == 0)
 871         localcmd(strcat("exec ", configname, "\n"));
 872 }
 873
 874 void vehicles_reset_colors()
 875 {
 876     entity e;
 877     float _effects, _colormap;
 878     vector _glowmod, _colormod;
 879
 880     if(autocvar_g_nodepthtestplayers)
 881         _effects = EF_NODEPTHTEST;
 882
 883     if(autocvar_g_fullbrightplayers)
 884         _effects |= EF_FULLBRIGHT;
 885
 886     if(self.team)
 887         _colormap = 1024 + (self.team - 1) * 17;
 888     else
 889         _colormap = 1024;
 890
 891     _glowmod  = '0 0 0';
 892     _colormod = '0 0 0';
 893
 894     // Find all ents attacked to main model and setup effects, colormod etc.
 895     e = findchainentity(tag_entity, self);
 896     while(e)
 897     {
 898         if(e != self.vehicle_shieldent)
 899         {
 900             e.effects   = _effects; //  | EF_LOWPRECISION;
 901             e.colormod  = _colormod;
 902             e.colormap  = _colormap;
 903             e.alpha     = 1;
 904         }
 905         e = e.chain;
 906     }
 907
 908     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
 909     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 910     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 911     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 912
 913     self.alpha     = 1;
 914     self.avelocity = '0 0 0';
 915     self.velocity  = '0 0 0';
 916     self.effects   = _effects;
 917 }
 918
 919 float vehicle_initialize(string  net_name,
 920                          string  bodymodel,
 921                          string  topmodel,
 922                          string  hudmodel,
 923                          string  toptag,
 924                          string  hudtag,
 925                          string  viewtag,
 926                          float   vhud,
 927                          vector  min_s,
 928                          vector  max_s,
 929                          float   nodrop,
 930                          void()  spawnproc,
 931                          float   _respawntime,
 932                          float() physproc,
 933                          void()  enterproc,
 934                          void(float extflag) exitfunc,
 935                          void() dieproc,
 936                          void() thinkproc,
 937                          float  use_csqc)
 938 {
 939     addstat(STAT_HUD, AS_INT,  hud);
 940         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 941         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 942         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 943
 944         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 945         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 946
 947         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 948         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 949
 950     if(bodymodel == "")
 951         error("vehicles: missing bodymodel!");
 952
 953     if(hudmodel == "")
 954         error("vehicles: missing hudmodel!");
 955
 956     if(net_name == "")
 957         self.netname = self.classname;
 958     else
 959         self.netname = net_name;
 960
 961     if(self.team && !teamplay)
 962         self.team = 0;
 963
 964     self.vehicle_flags |= VHF_ISVEHICLE;
 965
 966     setmodel(self, bodymodel);
 967
 968     self.vehicle_viewport   = spawn();
 969     self.vehicle_hudmodel   = spawn();
 970     self.tur_head           = spawn();
 971     self.tur_head.owner     = self;
 972     self.takedamage         = DAMAGE_AIM;
 973     self.bot_attack         = TRUE;
 974     self.iscreature         = TRUE;
 975     self.hud                = vhud;
 976
 977     self.vehicle_die         = dieproc;
 978     self.vehicle_exit        = exitfunc;
 979     self.vehicle_enter       = enterproc;
 980     self.PlayerPhysplug      = physproc;
 981     self.event_damage        = vehicles_damage;
 982     self.touch               = vehicles_touch;
 983     self.think               = vehicles_spawn;
 984     self.nextthink           = time;
 985     self.vehicle_respawntime = _respawntime;
 986     self.vehicle_spawn       = spawnproc;
 987
 988     if(autocvar_g_nodepthtestplayers)
 989         self.effects = self.effects | EF_NODEPTHTEST;
 990
 991     if(autocvar_g_fullbrightplayers)
 992         self.effects = self.effects | EF_FULLBRIGHT;
 993
 994     setmodel(self.vehicle_hudmodel, hudmodel);
 995     setmodel(self.vehicle_viewport, "null");
 996
 997
 998     if(topmodel != "")
 999     {
1000         setmodel(self.tur_head, topmodel);
1001         setattachment(self.tur_head, self, toptag);
1002         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1003         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1004     }
1005     else
1006     {
1007         setattachment(self.tur_head, self, "");
1008         setattachment(self.vehicle_hudmodel, self, hudtag);
1009         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1010     }
1011
1012     setsize(self, min_s, max_s);
1013     if not (nodrop)
1014     {
1015         setorigin(self, self.origin);
1016         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1017         setorigin(self, trace_endpos);
1018     }
1019
1020     self.pos1 = self.origin;
1021     self.pos2 = self.angles;
1022     self.tur_head.team = self.team;
1023
1024     return TRUE;
1025 }
1026
1027 void bugmenot()
1028 {
1029     self.vehicle_exit       = self.vehicle_exit;
1030     self.vehicle_enter      = self.vehicle_exit;
1031     self.vehicle_die        = self.vehicle_exit;
1032     self.vehicle_spawn      = self.vehicle_exit;
1033     self.AuxiliaryXhair     = self.AuxiliaryXhair;
1034 }