qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", _("Electro"));
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 .float electro_load;
   9
  10 void W_Electro_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_electro_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.electro_load;
  18                 self.clip_size = autocvar_g_balance_electro_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_Electro_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_electro_reload_ammo && self.ammo_cells) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_cells -= 1;
  32         }
  33         self.electro_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_electro_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_Electro_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_electro_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_cells, min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo)))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_electro_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_electro_reload_time, W_Electro_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Plasma_Explode_Combo (void);
  63
  64 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  65 {
  66         local entity e;
  67         e = WarpZone_FindRadius(org, rad, TRUE);
  68         while (e)
  69         {
  70                 if (e.classname == "plasma")
  71                 {
  72                         // change owner to whoever caused the combo explosion
  73                         e.owner = own;
  74                         e.takedamage = DAMAGE_NO;
  75                         e.classname = "plasma_chain";
  76                         e.think = W_Plasma_Explode_Combo;
  77                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  78                 }
  79                 e = e.chain;
  80         }
  81 }
  82
  83 void W_Plasma_Explode (void)
  84 {
  85         if(other.takedamage == DAMAGE_AIM)
  86                 if(other.classname == "player")
  87                         if(IsDifferentTeam(self.owner, other))
  88                                 if(other.deadflag == DEAD_NO)
  89                                         if(IsFlying(other))
  90                                                 AnnounceTo(self.owner, "electrobitch");
  91
  92         self.event_damage = SUB_Null;
  93         self.takedamage = DAMAGE_NO;
  94         if (self.movetype == MOVETYPE_BOUNCE)
  95         {
  96                 RadiusDamage (self, self.owner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  97         }
  98         else
  99         {
 100                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.owner);
 101                 RadiusDamage (self, self.owner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
 102         }
 103
 104         remove (self);
 105 }
 106
 107 void W_Plasma_Explode_Combo (void)
 108 {
 109         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.owner);
 110
 111         self.event_damage = SUB_Null;
 112         RadiusDamage (self, self.owner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
 113         remove (self);
 114 }
 115
 116 void W_Plasma_Touch (void)
 117 {
 118         //self.velocity = self.velocity  * 0.1;
 119
 120         PROJECTILE_TOUCH;
 121         if (other.takedamage == DAMAGE_AIM) {
 122                 W_Plasma_Explode ();
 123         } else {
 124                 //UpdateCSQCProjectile(self);
 125                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
 126                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 127         }
 128 }
 129
 130 void W_Plasma_TouchExplode (void)
 131 {
 132         PROJECTILE_TOUCH;
 133         W_Plasma_Explode ();
 134 }
 135
 136 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 137 {
 138         if(self.health <= 0)
 139                 return;
 140         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 141         self.health = self.health - damage;
 142         if (self.health <= 0)
 143         {
 144                 self.takedamage = DAMAGE_NO;
 145                 self.nextthink = time;
 146                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
 147                 {
 148                         // change owner to whoever caused the combo explosion
 149                         self.owner = inflictor.owner;
 150                         self.classname = "plasma_chain";
 151                         self.think = W_Plasma_Explode_Combo;
 152                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
 153                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 154                 }
 155                 else
 156                 {
 157                         self.use = W_Plasma_Explode;
 158                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 159                 }
 160         }
 161 }
 162
 163 void W_Electro_Attack()
 164 {
 165         local entity proj;
 166
 167         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 168         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 169         {
 170                 if(autocvar_g_balance_electro_reload_ammo)
 171                 {
 172                         self.clip_load -= autocvar_g_balance_electro_primary_ammo;
 173                         self.electro_load = self.clip_load;
 174                 }
 175                 else
 176                         self.ammo_cells -= autocvar_g_balance_electro_primary_ammo;
 177         }
 178
 179         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CHAN_WEAPON, autocvar_g_balance_electro_primary_damage);
 180
 181         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 182
 183         proj = spawn ();
 184         proj.classname = "plasma_prim";
 185         proj.owner = self;
 186         proj.bot_dodge = TRUE;
 187         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 188         proj.use = W_Plasma_Explode;
 189         proj.think = adaptor_think2use_hittype_splash;
 190         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 191         PROJECTILE_MAKETRIGGER(proj);
 192         proj.projectiledeathtype = WEP_ELECTRO;
 193         setorigin(proj, w_shotorg);
 194
 195         proj.movetype = MOVETYPE_FLY;
 196         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 197         proj.angles = vectoangles(proj.velocity);
 198         proj.touch = W_Plasma_TouchExplode;
 199         setsize(proj, '0 0 -3', '0 0 -3');
 200         proj.flags = FL_PROJECTILE;
 201
 202         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 203         //sounds bad
 204
 205         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 206
 207         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 208 }
 209
 210 void W_Electro_Attack2()
 211 {
 212         local entity proj;
 213
 214         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 215         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 216         {
 217                 if(autocvar_g_balance_electro_reload_ammo)
 218                 {
 219                         self.clip_load -= autocvar_g_balance_electro_secondary_ammo;
 220                         self.electro_load = self.clip_load;
 221                 }
 222                 else
 223                         self.ammo_cells -= autocvar_g_balance_electro_secondary_ammo;
 224         }
 225
 226         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CHAN_WEAPON, autocvar_g_balance_electro_secondary_damage);
 227
 228         w_shotdir = v_forward; // no TrueAim for grenades please
 229
 230         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 231
 232         proj = spawn ();
 233         proj.classname = "plasma";
 234         proj.owner = self;
 235         proj.use = W_Plasma_Explode;
 236         proj.think = adaptor_think2use_hittype_splash;
 237         proj.bot_dodge = TRUE;
 238         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 239         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 240         PROJECTILE_MAKETRIGGER(proj);
 241         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 242         setorigin(proj, w_shotorg);
 243
 244         //proj.glow_size = 50;
 245         //proj.glow_color = 45;
 246         proj.movetype = MOVETYPE_BOUNCE;
 247         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 248         proj.touch = W_Plasma_Touch;
 249         setsize(proj, '0 0 -4', '0 0 -4');
 250         proj.takedamage = DAMAGE_YES;
 251         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 252         proj.health = autocvar_g_balance_electro_secondary_health;
 253         proj.event_damage = W_Plasma_Damage;
 254         proj.flags = FL_PROJECTILE;
 255
 256         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 257         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 258
 259 #if 0
 260         entity p2;
 261         p2 = spawn();
 262         copyentity(proj, p2);
 263         setmodel(p2, "models/ebomb.mdl");
 264         setsize(p2, proj.mins, proj.maxs);
 265 #endif
 266
 267         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 268
 269         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 270 }
 271
 272 .vector hook_start, hook_end;
 273 float lgbeam_send(entity to, float sf)
 274 {
 275         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 276         sf = sf & 0x7F;
 277         if(sound_allowed(MSG_BROADCAST, self.owner))
 278                 sf |= 0x80;
 279         WriteByte(MSG_ENTITY, sf);
 280         if(sf & 1)
 281         {
 282                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 283                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 284         }
 285         if(sf & 2)
 286         {
 287                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 288                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 289                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 290         }
 291         if(sf & 4)
 292         {
 293                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 294                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 295                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 296         }
 297         return TRUE;
 298 }
 299 .entity lgbeam;
 300 .float prevlgfire;
 301 float lgbeam_checkammo()
 302 {
 303         if(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 304                 return TRUE;
 305         else if(autocvar_g_balance_electro_reload_ammo)
 306                 return self.owner.clip_load > 0;
 307         else
 308                 return self.owner.ammo_cells > 0;
 309 }
 310
 311 void lgbeam_think()
 312 {
 313         self.owner.prevlgfire = time;
 314         if (self != self.owner.lgbeam)
 315         {
 316                 remove(self);
 317                 return;
 318         }
 319
 320         if (self.owner.weaponentity.state != WS_INUSE || !lgbeam_checkammo() || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK || self.owner.freezetag_frozen)
 321         {
 322                 if(self == self.owner.lgbeam)
 323                         self.owner.lgbeam = world;
 324                 remove(self);
 325                 return;
 326         }
 327
 328         self.nextthink = time;
 329
 330         makevectors(self.owner.v_angle);
 331
 332         float dt, f;
 333         dt = frametime;
 334         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 335         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 336         {
 337                 if(autocvar_g_balance_electro_primary_ammo)
 338                 {
 339                         if(autocvar_g_balance_electro_reload_ammo)
 340                         {
 341                                 dt = min(dt, self.owner.clip_load / autocvar_g_balance_electro_primary_ammo);
 342                                 self.owner.clip_load = max(0, self.owner.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 343                                 self.owner.electro_load = self.owner.clip_load;
 344                         }
 345                         else
 346                         {
 347                                 dt = min(dt, self.owner.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 348                                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 349                         }
 350                 }
 351         }
 352
 353         W_SetupShot_Range(self.owner, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 354         WarpZone_traceline_antilag(self.owner, w_shotorg, w_shotend, MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
 355
 356         // apply the damage
 357         if(trace_ent)
 358         {
 359                 vector force;
 360                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 361
 362                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 363
 364                 if(accuracy_isgooddamage(self.owner, trace_ent))
 365                         accuracy_add(self.owner, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 366                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 367         }
 368         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, self.owner);
 369
 370         // draw effect
 371         if(w_shotorg != self.hook_start)
 372         {
 373                 self.SendFlags |= 2;
 374                 self.hook_start = w_shotorg;
 375         }
 376         if(w_shotend != self.hook_end)
 377         {
 378                 self.SendFlags |= 4;
 379                 self.hook_end = w_shotend;
 380         }
 381 }
 382
 383 // experimental lightning gun
 384 void W_Electro_Attack3 (void)
 385 {
 386         // only play fire sound if 0.5 sec has passed since player let go the fire button
 387         if(time - self.prevlgfire > 0.5)
 388                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 389
 390         entity beam, oldself;
 391
 392         self.lgbeam = beam = spawn();
 393         beam.classname = "lgbeam";
 394         beam.solid = SOLID_NOT;
 395         beam.think = lgbeam_think;
 396         beam.owner = self;
 397         beam.movetype = MOVETYPE_NONE;
 398         beam.shot_spread = 0;
 399         beam.bot_dodge = TRUE;
 400         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 401         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 402
 403         oldself = self;
 404         self = beam;
 405         self.think();
 406         self = oldself;
 407 }
 408
 409 void ElectroInit()
 410 {
 411         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 412         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 413         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 414         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 415         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 416 }
 417
 418 void spawnfunc_weapon_electro (void)
 419 {
 420         weapon_defaultspawnfunc(WEP_ELECTRO);
 421 }
 422
 423 void w_electro_checkattack()
 424 {
 425         if(self.electro_count > 1)
 426         if(self.BUTTON_ATCK2)
 427         if(weapon_prepareattack(1, -1))
 428         {
 429                 W_Electro_Attack2();
 430                 self.electro_count -= 1;
 431                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 432                 return;
 433         }
 434
 435         w_ready();
 436 }
 437
 438 .float bot_secondary_electromooth;
 439 .float BUTTON_ATCK_prev;
 440 float w_electro(float req)
 441 {
 442         if (req == WR_AIM)
 443         {
 444                 self.BUTTON_ATCK=FALSE;
 445                 self.BUTTON_ATCK2=FALSE;
 446                 if(vlen(self.origin-self.enemy.origin) > 1000)
 447                         self.bot_secondary_electromooth = 0;
 448                 if(self.bot_secondary_electromooth == 0)
 449                 {
 450                         float shoot;
 451
 452                         if(autocvar_g_balance_electro_primary_speed)
 453                                 shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 454                         else
 455                                 shoot = bot_aim(1000000, 0, 0.001, FALSE);
 456
 457                         if(shoot)
 458                         {
 459                                 self.BUTTON_ATCK = TRUE;
 460                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 461                         }
 462                 }
 463                 else
 464                 {
 465                         if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE))
 466                         {
 467                                 self.BUTTON_ATCK2 = TRUE;
 468                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 469                         }
 470                 }
 471         }
 472         else if (req == WR_THINK)
 473         {
 474                 if(autocvar_g_balance_electro_reload_ammo && self.clip_load < min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo)) // forced reload
 475                         W_Electro_Reload();
 476                 else if (self.BUTTON_ATCK)
 477                 {
 478                         if(autocvar_g_balance_electro_lightning)
 479                                 if(self.BUTTON_ATCK_prev)
 480                                 {
 481                                         // prolong the animtime while the gun is being fired
 482                                         if(self.animstate_startframe == self.anim_shoot_x && self.animstate_numframes == self.anim_shoot_y)
 483                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_electro_primary_animtime, w_ready);
 484                                         else
 485                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 486                                 }
 487                         if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 488                         {
 489                                 if(autocvar_g_balance_electro_lightning)
 490                                 {
 491                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 492                                         {
 493                                                 W_Electro_Attack3();
 494                                         }
 495                                         if(!self.BUTTON_ATCK_prev)
 496                                         {
 497                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 498                                                 self.BUTTON_ATCK_prev = 1;
 499                                         }
 500                                 }
 501                                 else
 502                                 {
 503                                         W_Electro_Attack();
 504                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 505                                 }
 506                         }
 507                 } else {
 508                         if(autocvar_g_balance_electro_lightning)
 509                         {
 510                                 if (self.BUTTON_ATCK_prev != 0)
 511                                 {
 512                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 513                                         ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 514                                 }
 515                                 self.BUTTON_ATCK_prev = 0;
 516                         }
 517
 518                         if (self.BUTTON_ATCK2)
 519                         {
 520                                 if (time >= self.electro_secondarytime)
 521                                 if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 522                                 {
 523                                         W_Electro_Attack2();
 524                                         self.electro_count = autocvar_g_balance_electro_secondary_count;
 525                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 526                                         self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 527                                 }
 528                         }
 529                 }
 530
 531         if(self.wish_reload)
 532         {
 533             if(self.switchweapon == self.weapon)
 534             {
 535                 if(self.weaponentity.state == WS_READY)
 536                 {
 537                     self.wish_reload = 0;
 538                     W_Electro_Reload();
 539                 }
 540             }
 541         }
 542         }
 543         else if (req == WR_PRECACHE)
 544         {
 545                 precache_model ("models/weapons/g_electro.md3");
 546                 precache_model ("models/weapons/v_electro.md3");
 547                 precache_model ("models/weapons/h_electro.iqm");
 548                 precache_sound ("weapons/electro_bounce.wav");
 549                 precache_sound ("weapons/electro_fire.wav");
 550                 precache_sound ("weapons/electro_fire2.wav");
 551                 precache_sound ("weapons/electro_impact.wav");
 552                 precache_sound ("weapons/electro_impact_combo.wav");
 553                 if(autocvar_g_balance_electro_lightning)
 554                 {
 555                         precache_sound ("weapons/lgbeam_fire.wav");
 556                 }
 557         }
 558         else if (req == WR_SETUP)
 559         {
 560                 weapon_setup(WEP_ELECTRO);
 561                 W_Electro_SetAmmoCounter();
 562         }
 563         else if (req == WR_CHECKAMMO1)
 564         {
 565                 if(autocvar_g_balance_electro_reload_ammo)
 566                 {
 567                         if(autocvar_g_balance_electro_lightning)
 568                                 return !autocvar_g_balance_electro_primary_ammo || (self.electro_load > 0);
 569                         else
 570                                 return self.electro_load >= autocvar_g_balance_electro_primary_ammo;
 571                 }
 572                 else
 573                 {
 574                         if(autocvar_g_balance_electro_lightning)
 575                                 return !autocvar_g_balance_electro_primary_ammo || (self.ammo_cells > 0);
 576                         else
 577                                 return self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 578                 }
 579         }
 580         else if (req == WR_CHECKAMMO2)
 581         {
 582                 if(autocvar_g_balance_electro_reload_ammo)
 583                         return self.electro_load >= autocvar_g_balance_electro_secondary_ammo;
 584                 else
 585                         return self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 586         }
 587         else if (req == WR_RESETPLAYER)
 588         {
 589                 self.electro_secondarytime = time;
 590         }
 591         else if (req == WR_RELOAD)
 592         {
 593                 W_Shotgun_Reload();
 594         }
 595         return TRUE;
 596 };
 597 #endif
 598 #ifdef CSQC
 599 float w_electro(float req)
 600 {
 601         if(req == WR_IMPACTEFFECT)
 602         {
 603                 vector org2;
 604                 org2 = w_org + w_backoff * 6;
 605                 if(w_deathtype & HITTYPE_SECONDARY)
 606                 {
 607                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 608                         if(!w_issilent)
 609                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 610                 }
 611                 else
 612                 {
 613                         if(w_deathtype & HITTYPE_BOUNCE)
 614                         {
 615                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 616                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 617                                 if(!w_issilent)
 618                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 619                         }
 620                         else
 621                         {
 622                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 623                                 if(!w_issilent)
 624                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 625                         }
 626                 }
 627         }
 628         else if(req == WR_PRECACHE)
 629         {
 630                 precache_sound("weapons/electro_impact.wav");
 631                 precache_sound("weapons/electro_impact_combo.wav");
 632         }
 633         else if (req == WR_SUICIDEMESSAGE)
 634         {
 635                 if(w_deathtype & HITTYPE_SECONDARY)
 636                         w_deathtypestring = "%s could not remember where they put plasma";
 637                 else
 638                         w_deathtypestring = "%s played with plasma";
 639         }
 640         else if (req == WR_KILLMESSAGE)
 641         {
 642                 if(w_deathtype & HITTYPE_SECONDARY)
 643                 {
 644                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 645                                 w_deathtypestring = "%s just noticed %s's blue ball";
 646                         else // unchecked: BOUNCE
 647                                 w_deathtypestring = "%s got in touch with %s's blue ball";
 648                 }
 649                 else
 650                 {
 651                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 652                                 w_deathtypestring = "%s felt the electrifying air of %s's combo";
 653                         else if(w_deathtype & HITTYPE_SPLASH)
 654                                 w_deathtypestring = "%s got too close to %s's blue beam";
 655                         else
 656                                 w_deathtypestring = "%s was blasted by %s's blue beam";
 657                 }
 658         }
 659         return TRUE;
 660 }
 661 #endif
 662 #endif