qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '-3 -3 -3', '3 3 3');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .entity lgbeam, exteriorlgbeam;
 188 void lgbeam_think()
 189 {
 190         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.BUTTON_ATCK == 0)
 191         {
 192                 remove(self);
 193                 return;
 194         }
 195
 196         self.nextthink = time;
 197
 198         makevectors(self.owner.v_angle);
 199         vector angle;
 200         angle = v_forward;
 201
 202         vector force;
 203         force = angle * cvar("g_balance_electro_primary_force");
 204
 205         traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 206
 207         self.scale = vlen(self.owner.origin - trace_endpos) / 256 * (0.75 + 0.75 * random());
 208 }
 209
 210 void exteriorlgbeam_think()
 211 {
 212         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.exteriorlgbeam || self.owner.BUTTON_ATCK == 0)
 213         {
 214                 sound (self, CHAN_PROJECTILE, "sound/misc/null.wav", VOL_BASE, ATTN_NORM);
 215                 remove(self);
 216                 return;
 217         }
 218
 219         if (time - self.shot_spread + random() * 0.2 > 0)
 220         {
 221                 self.shot_spread = time + 2;
 222                 sound (self, CHAN_PROJECTILE, "turrets/phaser.wav", VOL_BASE, ATTN_NORM);
 223         }
 224
 225         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 226                 self.ammo_cells = max(0, self.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 227
 228         self.nextthink = time;
 229
 230         makevectors(self.owner.v_angle);
 231         vector angle;
 232         angle = v_forward;
 233
 234         traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 235
 236         // apply the damage
 237         if(trace_fraction < 1)
 238         {
 239                 vector force;
 240                 force = angle * cvar("g_balance_electro_primary_force") + trace_ent.velocity * cvar("g_balance_electro_primary_velocityfactor") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 241                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
 242                 W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
 243         }
 244
 245         self.angles = '0 0 0';
 246         self.scale = vlen(gettaginfo(self, 0) - trace_endpos) / 256 * (0.75 + 0.75 * random());
 247
 248         // v_forward, v_right, v_up now are the ACTUAL directions
 249         // express self.angles in terms of them to aim at target!
 250         self.angles = vectoangles('1 0 0' * (angle * v_forward) + '0 -1 0' * (angle * v_right) + '0 0 1' * (angle * v_up));
 251 }
 252
 253 // experimental lightning gun
 254 void W_Electro_Attack3 (void)
 255 {
 256         entity beam, oldself;
 257
 258         self.lgbeam = beam = spawn();
 259         setmodel(beam,"models/turrets/phaser_beam.md3");
 260         beam.effects = EF_LOWPRECISION;
 261         beam.solid = SOLID_NOT;
 262         beam.think = lgbeam_think;
 263         beam.owner = self;
 264         beam.movetype = MOVETYPE_NONE;
 265         if(gettagindex(self.weaponentity, "shot"))
 266                 setattachment(beam, self.weaponentity, "shot");
 267         else
 268                 setattachment(beam, self.weaponentity, "tag_shot");
 269
 270         oldself = self;
 271         self = beam;
 272         self.think();
 273         self = oldself;
 274
 275         self.exteriorlgbeam = beam = spawn();
 276         setmodel(beam,"models/turrets/phaser_beam.md3");
 277         beam.effects = EF_LOWPRECISION;
 278         beam.solid = SOLID_NOT;
 279         beam.think = exteriorlgbeam_think;
 280         beam.owner = self;
 281         beam.movetype = MOVETYPE_NONE;
 282         //beam.viewmodelforclient = self;
 283         if(self.weaponentity.oldorigin_x > 0)
 284         {
 285                 setattachment(beam, self.exteriorweaponentity, "");
 286                 setorigin(beam, self.weaponentity.oldorigin);
 287         }
 288         else
 289         {
 290                 if(gettagindex(self.exteriorweaponentity, "shot"))
 291                         setattachment(beam, self.exteriorweaponentity, "shot");
 292                 else
 293                         setattachment(beam, self.exteriorweaponentity, "tag_shot");
 294         }
 295
 296         beam.shot_spread = 0;
 297         beam.bot_dodge = TRUE;
 298         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 299
 300         oldself = self;
 301         self = beam;
 302         self.think();
 303         self = oldself;
 304 }
 305
 306 void spawnfunc_weapon_electro (void)
 307 {
 308         weapon_defaultspawnfunc(WEP_ELECTRO);
 309 }
 310
 311 void w_electro_checkattack()
 312 {
 313         if(self.electro_count > 1)
 314         if(self.BUTTON_ATCK2)
 315         if(weapon_prepareattack(1, -1))
 316         {
 317                 W_Electro_Attack2();
 318                 self.electro_count -= 1;
 319                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 320                 return;
 321         }
 322
 323         w_ready();
 324 }
 325
 326 .float bot_secondary_electromooth;
 327 .float BUTTON_ATCK_prev;
 328 float w_electro(float req)
 329 {
 330         if (req == WR_AIM)
 331         {
 332                 self.BUTTON_ATCK=FALSE;
 333                 self.BUTTON_ATCK2=FALSE;
 334                 if(vlen(self.origin-self.enemy.origin) > 1000)
 335                         self.bot_secondary_electromooth = 0;
 336                 if(self.bot_secondary_electromooth == 0)
 337                 {
 338                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 339                         {
 340                                 self.BUTTON_ATCK = TRUE;
 341                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 342                         }
 343                 }
 344                 else
 345                 {
 346                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 347                         {
 348                                 self.BUTTON_ATCK2 = TRUE;
 349                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 350                         }
 351                 }
 352         }
 353         else if (req == WR_THINK)
 354         {
 355                 if (self.BUTTON_ATCK)
 356                 {
 357                         if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 358                         {
 359                                 if(cvar("g_balance_electro_lightning"))
 360                                 {
 361                                         if (self.BUTTON_ATCK_prev == 0)
 362                                         {
 363                                                 W_Electro_Attack3();
 364                                         }
 365                                         self.BUTTON_ATCK_prev = 1;
 366                                 }
 367                                 else
 368                                 {
 369                                         W_Electro_Attack();
 370                                 }
 371                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 372                         }
 373                 } else {
 374                         self.BUTTON_ATCK_prev = 0;
 375                 }
 376
 377                 if (self.BUTTON_ATCK2)
 378                 if (time >= self.electro_secondarytime)
 379                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 380                 {
 381                         W_Electro_Attack2();
 382                         self.electro_count = cvar("g_balance_electro_secondary_count");
 383                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 384                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 385                 }
 386         }
 387         else if (req == WR_PRECACHE)
 388         {
 389                 precache_model ("models/weapons/g_electro.md3");
 390                 precache_model ("models/weapons/v_electro.md3");
 391                 precache_model ("models/weapons/h_electro.iqm");
 392                 precache_sound ("weapons/electro_bounce.wav");
 393                 precache_sound ("weapons/electro_fire.wav");
 394                 precache_sound ("weapons/electro_fire2.wav");
 395                 precache_sound ("weapons/electro_impact.wav");
 396                 precache_sound ("weapons/electro_impact_combo.wav");
 397                 if(cvar("g_balance_electro_lightning"))
 398                         precache_sound ("weapons/crylink_fire2.wav");
 399         }
 400         else if (req == WR_SETUP)
 401                 weapon_setup(WEP_ELECTRO);
 402         else if (req == WR_CHECKAMMO1)
 403                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 404         else if (req == WR_CHECKAMMO2)
 405                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 406         else if (req == WR_RESETPLAYER)
 407         {
 408                 self.electro_secondarytime = time;
 409         }
 410         return TRUE;
 411 };
 412 #endif
 413 #ifdef CSQC
 414 float w_electro(float req)
 415 {
 416         if(req == WR_IMPACTEFFECT)
 417         {
 418                 vector org2;
 419                 org2 = w_org + w_backoff * 6;
 420                 if(w_deathtype & HITTYPE_SECONDARY)
 421                 {
 422                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 423                         if(!w_issilent)
 424                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 425                 }
 426                 else
 427                 {
 428                         if(w_deathtype & HITTYPE_BOUNCE)
 429                         {
 430                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 431                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 432                                 if(!w_issilent)
 433                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 434                         }
 435                         else
 436                         {
 437                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 438                                 if(!w_issilent)
 439                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 440                         }
 441                 }
 442         }
 443         else if(req == WR_PRECACHE)
 444         {
 445                 precache_sound("weapons/electro_impact.wav");
 446                 precache_sound("weapons/electro_impact_combo.wav");
 447         }
 448         else if (req == WR_SUICIDEMESSAGE)
 449         {
 450                 if(w_deathtype & HITTYPE_SECONDARY)
 451                         w_deathtypestring = "could not remember where they put plasma";
 452                 else
 453                         w_deathtypestring = "played with plasma";
 454         }
 455         else if (req == WR_KILLMESSAGE)
 456         {
 457                 if(w_deathtype & HITTYPE_SECONDARY)
 458                 {
 459                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 460                                 w_deathtypestring = "just noticed #'s blue ball";
 461                         else // unchecked: BOUNCE
 462                                 w_deathtypestring = "got in touch with #'s blue ball";
 463                 }
 464                 else
 465                 {
 466                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 467                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 468                         else if(w_deathtype & HITTYPE_SPLASH)
 469                                 w_deathtypestring = "got too close to #'s blue beam";
 470                         else
 471                                 w_deathtypestring = "was blasted by #'s blue beam";
 472                 }
 473         }
 474         return TRUE;
 475 }
 476 #endif
 477 #endif