qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", _("Mortar"))
   3 #else
   4 #ifdef SVQC
   5 .float gl_detonate_later;
   6 .float gl_bouncecnt;
   7
   8 .float grenadelauncher_load;
   9
  10 void W_GrenadeLauncher_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.grenadelauncher_load;
  18                 self.clip_size = autocvar_g_balance_grenadelauncher_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_GrenadeLauncher_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_grenadelauncher_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_rockets -= 1;
  32         }
  33         self.grenadelauncher_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_grenadelauncher_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_GrenadeLauncher_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_rockets))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_grenadelauncher_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_grenadelauncher_reload_time, W_GrenadeLauncher_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Grenade_Explode (void)
  63 {
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(other.classname == "player")
  66                         if(IsDifferentTeam(self.owner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 AnnounceTo(self.owner, "airshot");
  70
  71         self.event_damage = SUB_Null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         if(self.movetype == MOVETYPE_NONE)
  75                 self.velocity = self.oldvelocity;
  76
  77         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_primary_damage, autocvar_g_balance_grenadelauncher_primary_edgedamage, autocvar_g_balance_grenadelauncher_primary_radius, world, autocvar_g_balance_grenadelauncher_primary_force, self.projectiledeathtype, other);
  78
  79         remove (self);
  80 }
  81
  82 void W_Grenade_Explode2 (void)
  83 {
  84         if(other.takedamage == DAMAGE_AIM)
  85                 if(other.classname == "player")
  86                         if(IsDifferentTeam(self.owner, other))
  87                                 if(IsFlying(other))
  88                                         AnnounceTo(self.owner, "airshot");
  89
  90         self.event_damage = SUB_Null;
  91         self.takedamage = DAMAGE_NO;
  92
  93         if(self.movetype == MOVETYPE_NONE)
  94                 self.velocity = self.oldvelocity;
  95
  96         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_secondary_damage, autocvar_g_balance_grenadelauncher_secondary_edgedamage, autocvar_g_balance_grenadelauncher_secondary_radius, world, autocvar_g_balance_grenadelauncher_secondary_force, self.projectiledeathtype, other);
  97
  98         remove (self);
  99 }
 100
 101 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 102 {
 103         if (self.health <= 0)
 104                 return;
 105         self.health = self.health - damage;
 106         if (self.health <= 0)
 107         {
 108                 W_PrepareExplosionByDamage(attacker, self.think);
 109         }
 110 }
 111
 112 void W_Grenade_Think1 (void)
 113 {
 114         self.nextthink = time;
 115         if (time > self.cnt)
 116         {
 117                 other = world;
 118                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 119                 W_Grenade_Explode ();
 120                 return;
 121         }
 122         if(self.gl_detonate_later && self.gl_bouncecnt >= autocvar_g_balance_grenadelauncher_primary_remote_minbouncecnt)
 123                 W_Grenade_Explode();
 124 }
 125
 126 void W_Grenade_Touch1 (void)
 127 {
 128         PROJECTILE_TOUCH;
 129         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_primary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 130         {
 131                 self.use ();
 132         }
 133         else if (autocvar_g_balance_grenadelauncher_primary_type == 1) // bounce
 134         {
 135                 float r;
 136                 r = random() * 6;
 137                 if(r < 1)
 138                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 139                 else if(r < 2)
 140                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 141                 else if(r < 3)
 142                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 143                 else if(r < 4)
 144                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 145                 else if(r < 5)
 146                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 147                 else
 148                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 149                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 150                 self.gl_bouncecnt += 1;
 151         }
 152         else if(autocvar_g_balance_grenadelauncher_primary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 153         {
 154                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 155
 156                 // let it stick whereever it is
 157                 self.oldvelocity = self.velocity;
 158                 self.velocity = '0 0 0';
 159                 self.movetype = MOVETYPE_NONE; // also disables gravity
 160                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 161                 UpdateCSQCProjectile(self);
 162
 163                 // do not respond to any more touches
 164                 self.solid = SOLID_NOT;
 165
 166                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_primary_lifetime2);
 167         }
 168 }
 169
 170 void W_Grenade_Touch2 (void)
 171 {
 172         PROJECTILE_TOUCH;
 173         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_secondary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 174         {
 175                 self.use ();
 176         }
 177         else if (autocvar_g_balance_grenadelauncher_secondary_type == 1) // bounce
 178         {
 179                 float r;
 180                 r = random() * 6;
 181                 if(r < 1)
 182                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 183                 else if(r < 2)
 184                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 185                 else if(r < 3)
 186                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 187                 else if(r < 4)
 188                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 189                 else if(r < 5)
 190                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 191                 else
 192                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 193                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 194                 self.gl_bouncecnt += 1;
 195         }
 196         else if(autocvar_g_balance_grenadelauncher_secondary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 197         {
 198                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 199
 200                 // let it stick whereever it is
 201                 self.oldvelocity = self.velocity;
 202                 self.velocity = '0 0 0';
 203                 self.movetype = MOVETYPE_NONE; // also disables gravity
 204                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 205                 UpdateCSQCProjectile(self);
 206
 207                 // do not respond to any more touches
 208                 self.solid = SOLID_NOT;
 209
 210                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_secondary_lifetime2);
 211         }
 212 }
 213
 214 void W_Grenade_Attack (void)
 215 {
 216         if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load <= 0)
 217                 return; // reloading, so we are done
 218
 219         local entity gren;
 220
 221         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_primary_damage);
 222         w_shotdir = v_forward; // no TrueAim for grenades please
 223
 224         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 225
 226         gren = spawn ();
 227         gren.owner = self;
 228         gren.classname = "grenade";
 229         gren.bot_dodge = TRUE;
 230         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_primary_damage;
 231         gren.movetype = MOVETYPE_BOUNCE;
 232         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 233         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 234         PROJECTILE_MAKETRIGGER(gren);
 235         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 236         setorigin(gren, w_shotorg);
 237         setsize(gren, '-3 -3 -3', '3 3 3');
 238
 239         gren.cnt = time + autocvar_g_balance_grenadelauncher_primary_lifetime;
 240         gren.nextthink = time;
 241         gren.think = W_Grenade_Think1;
 242         gren.use = W_Grenade_Explode;
 243         gren.touch = W_Grenade_Touch1;
 244
 245         gren.takedamage = DAMAGE_YES;
 246         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 247         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 248         gren.event_damage = W_Grenade_Damage;
 249         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 250
 251         gren.angles = vectoangles (gren.velocity);
 252         gren.flags = FL_PROJECTILE;
 253
 254         if(autocvar_g_balance_grenadelauncher_primary_type == 0 || autocvar_g_balance_grenadelauncher_primary_type == 2)
 255                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 256         else
 257                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 258
 259         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 260
 261         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 262         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 263         {
 264                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 265                 {
 266                         self.clip_load -= autocvar_g_balance_grenadelauncher_primary_ammo;
 267                         self.grenadelauncher_load = self.clip_load;
 268                 }
 269                 else
 270                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_primary_ammo;
 271         }
 272 }
 273
 274 void W_Grenade_Attack2 (void)
 275 {
 276         local entity gren;
 277
 278         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_secondary_damage);
 279         w_shotdir = v_forward; // no TrueAim for grenades please
 280
 281         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 282
 283         gren = spawn ();
 284         gren.owner = self;
 285         gren.classname = "grenade";
 286         gren.bot_dodge = TRUE;
 287         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_secondary_damage;
 288         gren.movetype = MOVETYPE_BOUNCE;
 289         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 290         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 291         PROJECTILE_MAKETRIGGER(gren);
 292         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 293         setorigin(gren, w_shotorg);
 294         setsize(gren, '-3 -3 -3', '3 3 3');
 295
 296         gren.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime;
 297         gren.think = adaptor_think2use_hittype_splash;
 298         gren.use = W_Grenade_Explode2;
 299         gren.touch = W_Grenade_Touch2;
 300
 301         gren.takedamage = DAMAGE_YES;
 302         gren.health = autocvar_g_balance_grenadelauncher_secondary_health;
 303         gren.damageforcescale = autocvar_g_balance_grenadelauncher_secondary_damageforcescale;
 304         gren.event_damage = W_Grenade_Damage;
 305         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 306
 307         gren.angles = vectoangles (gren.velocity);
 308         gren.flags = FL_PROJECTILE;
 309
 310         if(autocvar_g_balance_grenadelauncher_secondary_type == 0 || autocvar_g_balance_grenadelauncher_secondary_type == 2)
 311                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 312         else
 313                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 314
 315         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 316
 317         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 318         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 319         {
 320                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 321                 {
 322                         self.clip_load -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 323                         self.grenadelauncher_load = self.clip_load;
 324                 }
 325                 else
 326                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 327         }
 328 }
 329
 330 void spawnfunc_weapon_grenadelauncher (void)
 331 {
 332         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 333 }
 334
 335 .float bot_secondary_grenademooth;
 336 float w_glauncher(float req)
 337 {
 338         entity nade;
 339         float nadefound;
 340
 341         if (req == WR_AIM)
 342         {
 343                 self.BUTTON_ATCK = FALSE;
 344                 self.BUTTON_ATCK2 = FALSE;
 345                 if (self.bot_secondary_grenademooth == 0)
 346                 {
 347                         if(bot_aim(autocvar_g_balance_grenadelauncher_primary_speed, autocvar_g_balance_grenadelauncher_primary_speed_up, autocvar_g_balance_grenadelauncher_primary_lifetime, TRUE))
 348                         {
 349                                 self.BUTTON_ATCK = TRUE;
 350                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 351                         }
 352                 }
 353                 else
 354                 {
 355                         if(bot_aim(autocvar_g_balance_grenadelauncher_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_grenadelauncher_secondary_lifetime, TRUE))
 356                         {
 357                                 self.BUTTON_ATCK2 = TRUE;
 358                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 359                         }
 360                 }
 361         }
 362         else if (req == WR_THINK)
 363         {
 364                 if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)) // forced reload
 365                         W_GrenadeLauncher_Reload();
 366                 else if (self.BUTTON_ATCK)
 367                 {
 368                         if (weapon_prepareattack(0, autocvar_g_balance_grenadelauncher_primary_refire))
 369                         {
 370                                 W_Grenade_Attack();
 371                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_grenadelauncher_primary_animtime, w_ready);
 372                         }
 373                 }
 374                 else if (self.BUTTON_ATCK2)
 375                 {
 376                         if (cvar("g_balance_grenadelauncher_secondary_remote_detonateprimary"))
 377                         {
 378                                 nadefound = 0;
 379                                 for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.owner == self)
 380                                 {
 381                                         if(!nade.gl_detonate_later)
 382                                         {
 383                                                 nade.gl_detonate_later = TRUE;
 384                                                 nadefound = 1;
 385                                         }
 386                                 }
 387                                 if(nadefound)
 388                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 389                         }
 390                         else if (weapon_prepareattack(1, autocvar_g_balance_grenadelauncher_secondary_refire))
 391                         {
 392                                 W_Grenade_Attack2();
 393                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_grenadelauncher_secondary_animtime, w_ready);
 394                         }
 395                 }
 396         if(self.wish_reload)
 397         {
 398             if(self.switchweapon == self.weapon)
 399             {
 400                 if(self.weaponentity.state == WS_READY)
 401                 {
 402                     self.wish_reload = 0;
 403                     W_GrenadeLauncher_Reload();
 404                 }
 405             }
 406         }
 407         }
 408         else if (req == WR_PRECACHE)
 409         {
 410                 precache_model ("models/weapons/g_gl.md3");
 411                 precache_model ("models/weapons/v_gl.md3");
 412                 precache_model ("models/weapons/h_gl.iqm");
 413                 precache_sound ("weapons/grenade_bounce1.wav");
 414                 precache_sound ("weapons/grenade_bounce2.wav");
 415                 precache_sound ("weapons/grenade_bounce3.wav");
 416                 precache_sound ("weapons/grenade_bounce4.wav");
 417                 precache_sound ("weapons/grenade_bounce5.wav");
 418                 precache_sound ("weapons/grenade_bounce6.wav");
 419                 precache_sound ("weapons/grenade_stick.wav");
 420                 precache_sound ("weapons/grenade_fire.wav");
 421         }
 422         else if (req == WR_SETUP)
 423         {
 424                 weapon_setup(WEP_GRENADE_LAUNCHER);
 425                 W_GrenadeLauncher_SetAmmoCounter();
 426         }
 427         else if (req == WR_CHECKAMMO1)
 428         {
 429                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 430                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_primary_ammo;
 431                 else
 432                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_primary_ammo;
 433         }
 434         else if (req == WR_CHECKAMMO2)
 435         {
 436                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 437                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 438                 else
 439                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 440         }
 441         return TRUE;
 442 };
 443 #endif
 444 #ifdef CSQC
 445 float w_glauncher(float req)
 446 {
 447         if(req == WR_IMPACTEFFECT)
 448         {
 449                 vector org2;
 450                 org2 = w_org + w_backoff * 12;
 451                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 452                 if(!w_issilent)
 453                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 454         }
 455         else if(req == WR_PRECACHE)
 456         {
 457                 precache_sound("weapons/grenade_impact.wav");
 458         }
 459         else if (req == WR_SUICIDEMESSAGE)
 460         {
 461                 if(w_deathtype & HITTYPE_SECONDARY)
 462                         w_deathtypestring = "%s tried out his own grenade";
 463                 else
 464                         w_deathtypestring = "%s detonated";
 465         }
 466         else if (req == WR_KILLMESSAGE)
 467         {
 468                 if(w_deathtype & HITTYPE_SPLASH)
 469                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 470                                 w_deathtypestring = "%s didn't see %s's grenade";
 471                         else // unchecked: SECONDARY
 472                                 w_deathtypestring = "%s almost dodged %s's grenade";
 473                 else // unchecked: SECONDARY, BOUNCE
 474                         w_deathtypestring = "%s ate %s's grenade";
 475         }
 476         else if (req == WR_RELOAD)
 477         {
 478                 W_GrenadeLauncher_Reload();
 479         }
 480         return TRUE;
 481 }
 482 #endif
 483 #endif