qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadstep, hagar_loadblock;
 116 void W_Hagar_Attack2_Load_Release (void)
 117 {
 118         // time to release the rockets we've loaded
 119
 120         local entity missile;
 121         local float counter, shots;
 122         local vector s;
 123         vector forward, right, up;
 124
 125         if(!self.hagar_load)
 126                 return;
 127
 128         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
 129
 130         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 131         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 132
 133         forward = v_forward;
 134         right = v_right;
 135         up = v_up;
 136
 137         shots = self.hagar_load;
 138         missile = world;
 139         while (counter < shots)
 140         {
 141                 missile = spawn ();
 142                 missile.owner = missile.realowner = self;
 143                 missile.classname = "missile";
 144                 missile.bot_dodge = TRUE;
 145                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 146
 147                 missile.touch = W_Hagar_Touch; // not bouncy
 148                 missile.use = W_Hagar_Explode2;
 149                 missile.think = adaptor_think2use_hittype_splash;
 150                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 151                 PROJECTILE_MAKETRIGGER(missile);
 152                 missile.projectiledeathtype = WEP_HAGAR;
 153                 setorigin (missile, w_shotorg);
 154                 setsize(missile, '0 0 0', '0 0 0');
 155                 missile.movetype = MOVETYPE_FLY;
 156
 157                 s = '0 0 0';
 158                 if (counter == 0)
 159                         s = '0 0 0';
 160                 else
 161                 {
 162                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 163                         s_y = v_forward_x;
 164                         s_z = v_forward_y;
 165                 }
 166                 s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 167                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 168
 169                 missile.angles = vectoangles (missile.velocity);
 170                 missile.flags = FL_PROJECTILE;
 171
 172                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 173
 174                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 175
 176                 counter = counter + 1;
 177         }
 178
 179         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 180         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire;
 181         self.hagar_load = 0;
 182 }
 183
 184 void W_Hagar_Attack2_Load (void)
 185 {
 186         // loadable hagar secondary attack, must always run each frame
 187
 188         local float loaded;
 189         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 190
 191         if(self.BUTTON_ATCK2)
 192         {
 193                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 194                 {
 195                         if(self.hagar_load)
 196                         {
 197                                 // if we pressed primary fire while loading, unload all rockets and abort
 198                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
 199                                 self.hagar_load = 0;
 200                                 sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 201
 202                                 // pause until we can load rockets again, once we re-press the alt fire button
 203                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 204
 205                                 // require letting go of the alt fire button before we can load again
 206                                 self.hagar_loadblock = TRUE;
 207                         }
 208                 }
 209                 else
 210                 {
 211                         // check if we can attempt to load another rocket
 212                         if(!self.hagar_loadblock && !loaded && weapon_action(self.weapon, WR_CHECKAMMO2))
 213                         if(self.hagar_loadstep < time)
 214                         {
 215                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 216                                 self.hagar_load += 1;
 217                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 218
 219                                 // if this is the last rocket we can load, play the beep sound to notify the player of that
 220                                 if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 221                                         sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 222
 223                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 224                         }
 225                 }
 226         }
 227         else if(self.hagar_loadblock)
 228         {
 229                 // the alt fire button was released, so re-enable loading if blocked
 230                 self.hagar_loadblock = FALSE;
 231         }
 232
 233         if(self.hagar_load)
 234         {
 235                 self.weapon_forbidchange = TRUE;
 236
 237                 if(!self.BUTTON_ATCK2 || ((loaded || !weapon_action(self.weapon, WR_CHECKAMMO2)) && self.hagar_loadstep < time && !autocvar_g_balance_hagar_secondary_load_hold))
 238                         W_Hagar_Attack2_Load_Release();
 239         }
 240         else
 241                 self.weapon_forbidchange = FALSE;
 242
 243         // we aren't checking ammo during an attack, so we must do it here
 244         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 245         {
 246                 W_SwitchToOtherWeapon(self);
 247                 return;
 248         }
 249 }
 250
 251 void spawnfunc_weapon_hagar (void)
 252 {
 253         weapon_defaultspawnfunc(WEP_HAGAR);
 254 }
 255
 256 float w_hagar(float req)
 257 {
 258         float ammo_amount;
 259         if (req == WR_AIM)
 260                 if (random()>0.15)
 261                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 262                 else
 263                 {
 264                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 265                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 266                 }
 267         else if (req == WR_THINK)
 268         {
 269                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 270                         weapon_action(self.weapon, WR_RELOAD);
 271                 else
 272                 {
 273                         local float loadable_secondary;
 274                         loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 275
 276                         if (loadable_secondary)
 277                                 W_Hagar_Attack2_Load(); // must run each frame, even when no firing buttons are pressed
 278                         if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 279                         {
 280                                 if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 281                                 {
 282                                         W_Hagar_Attack();
 283                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 284                                 }
 285                         }
 286                         else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 287                         {
 288                                 if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 289                                 {
 290                                         W_Hagar_Attack2();
 291                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 292                                 }
 293                         }
 294                 }
 295         }
 296         else if (req == WR_PRECACHE)
 297         {
 298                 precache_model ("models/weapons/g_hagar.md3");
 299                 precache_model ("models/weapons/v_hagar.md3");
 300                 precache_model ("models/weapons/h_hagar.iqm");
 301                 precache_sound ("weapons/hagar_fire.wav");
 302                 precache_sound ("weapons/hagar_load.wav");
 303                 precache_sound ("weapons/hagar_beep.wav");
 304                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 305         }
 306         else if (req == WR_SETUP)
 307         {
 308                 weapon_setup(WEP_HAGAR);
 309                 self.current_ammo = ammo_rockets;
 310
 311                 if(self.hagar_load)
 312                 {
 313                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
 314                         self.hagar_load = 0;
 315                 }
 316         }
 317         else if (req == WR_CHECKAMMO1)
 318         {
 319                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 320                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 321                 return ammo_amount;
 322         }
 323         else if (req == WR_CHECKAMMO2)
 324         {
 325                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 326                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 327                 return ammo_amount;
 328         }
 329         else if (req == WR_RESETPLAYER)
 330         {
 331                 self.hagar_load = 0;
 332         }
 333         else if (req == WR_PLAYERDEATH)
 334         {
 335                 // if we have any rockets loaded when we die, release them
 336                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 337                         W_Hagar_Attack2_Load_Release();
 338         }
 339         else if (req == WR_RELOAD)
 340         {
 341                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 342         }
 343         return TRUE;
 344 };
 345 #endif
 346 #ifdef CSQC
 347 float w_hagar(float req)
 348 {
 349         if(req == WR_IMPACTEFFECT)
 350         {
 351                 vector org2;
 352                 org2 = w_org + w_backoff * 6;
 353                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 354                 if(!w_issilent)
 355                 {
 356                         if (w_random<0.15)
 357                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 358                         else if (w_random<0.7)
 359                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 360                         else
 361                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 362                 }
 363         }
 364         else if(req == WR_PRECACHE)
 365         {
 366                 precache_sound("weapons/hagexp1.wav");
 367                 precache_sound("weapons/hagexp2.wav");
 368                 precache_sound("weapons/hagexp3.wav");
 369         }
 370         else if (req == WR_SUICIDEMESSAGE)
 371                 w_deathtypestring = _("%s played with tiny rockets");
 372         else if (req == WR_KILLMESSAGE)
 373         {
 374                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 375                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 376                 else // unchecked: SPLASH, SECONDARY
 377                         w_deathtypestring = _("%s was pummeled by %s");
 378         }
 379         return TRUE;
 380 }
 381 #endif
 382 #endif