qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadstep, hagar_loadblock;
 116 void W_Hagar_Attack2_Load (void)
 117 {
 118         // loadable hagar secondary attack, must always run each frame
 119
 120         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 121         {
 122                 W_SwitchToOtherWeapon(self);
 123                 return;
 124         }
 125
 126         local entity missile;
 127         local float counter, shots, loaded;
 128         local float used_ammo, enough_ammo;
 129         local vector s;
 130         vector forward, right, up;
 131
 132         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 133
 134         // check if we have enough ammo for another rocket
 135         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 136         if(autocvar_g_balance_hagar_reload_ammo)
 137                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 138         else
 139                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 140
 141         if(self.BUTTON_ATCK2)
 142         {
 143                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 144                 {
 145                         if(self.hagar_load)
 146                         {
 147                                 // if we pressed primary fire while loading, unload all rockets and abort
 148                                 self.hagar_load = 0;
 149                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 150
 151                                 // pause until we can load rockets again, once we re-press the alt fire button
 152                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 153
 154                                 // require letting go of the alt fire button before we can load again
 155                                 self.hagar_loadblock = TRUE;
 156                         }
 157                 }
 158                 else
 159                 {
 160                         // check if we can attempt to load another rocket
 161                         if(!self.hagar_loadblock && !loaded && enough_ammo)
 162                         if(self.hagar_loadstep < time)
 163                         {
 164                                 self.hagar_load += 1;
 165                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 166
 167                                 // if this is the last rocket we can load, play a beep sound to notify the player of that
 168                                 if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 169                                         sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 170
 171                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 172                         }
 173                 }
 174         }
 175         else if(self.hagar_loadblock)
 176         {
 177                 // the alt fire button was released, so re-enable loading if blocked
 178                 self.hagar_loadblock = FALSE;
 179         }
 180
 181         if(self.hagar_load)
 182         if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && !autocvar_g_balance_hagar_secondary_load_hold))
 183         if(weapon_prepareattack(0, autocvar_g_balance_hagar_secondary_refire))
 184         {
 185                 // time to release the rockets we've loaded
 186
 187                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 188
 189                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 190                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 191
 192                 forward = v_forward;
 193                 right = v_right;
 194                 up = v_up;
 195
 196                 shots = self.hagar_load;
 197                 missile = world;
 198                 while (counter < shots)
 199                 {
 200                         missile = spawn ();
 201                         missile.owner = missile.realowner = self;
 202                         missile.classname = "missile";
 203                         missile.bot_dodge = TRUE;
 204                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 205
 206                         missile.touch = W_Hagar_Touch; // not bouncy
 207                         missile.use = W_Hagar_Explode2;
 208                         missile.think = adaptor_think2use_hittype_splash;
 209                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 210                         PROJECTILE_MAKETRIGGER(missile);
 211                         missile.projectiledeathtype = WEP_HAGAR;
 212                         setorigin (missile, w_shotorg);
 213                         setsize(missile, '0 0 0', '0 0 0');
 214                         missile.movetype = MOVETYPE_FLY;
 215
 216                         s = '0 0 0';
 217                         if (counter == 0)
 218                                 s = '0 0 0';
 219                         else
 220                         {
 221                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 222                                 s_y = v_forward_x;
 223                                 s_z = v_forward_y;
 224                         }
 225                         s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 226                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 227
 228                         missile.angles = vectoangles (missile.velocity);
 229                         missile.flags = FL_PROJECTILE;
 230
 231                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 232
 233                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 234
 235                         counter = counter + 1;
 236                 }
 237
 238                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 239                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire;
 240                 self.hagar_load = 0;
 241         }
 242 }
 243
 244 void spawnfunc_weapon_hagar (void)
 245 {
 246         weapon_defaultspawnfunc(WEP_HAGAR);
 247 }
 248
 249 float w_hagar(float req)
 250 {
 251         float ammo_amount;
 252         if (req == WR_AIM)
 253                 if (random()>0.15)
 254                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 255                 else
 256                 {
 257                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 258                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 259                 }
 260         else if (req == WR_THINK)
 261         {
 262                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 263                         weapon_action(self.weapon, WR_RELOAD);
 264                 else
 265                 {
 266                         local float loadable_secondary;
 267                         loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 268
 269                         if (loadable_secondary)
 270                                 W_Hagar_Attack2_Load(); // must run each frame, even when no firing buttons are pressed
 271                         if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 272                         {
 273                                 if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 274                                 {
 275                                         W_Hagar_Attack();
 276                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 277                                 }
 278                         }
 279                         else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 280                         {
 281                                 if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 282                                 {
 283                                         W_Hagar_Attack2();
 284                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 285                                 }
 286                         }
 287                 }
 288         }
 289         else if (req == WR_PRECACHE)
 290         {
 291                 precache_model ("models/weapons/g_hagar.md3");
 292                 precache_model ("models/weapons/v_hagar.md3");
 293                 precache_model ("models/weapons/h_hagar.iqm");
 294                 precache_sound ("weapons/hagar_fire.wav");
 295                 precache_sound ("weapons/hagar_load.wav");
 296                 precache_sound ("weapons/hagar_beep.wav");
 297                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 298         }
 299         else if (req == WR_SETUP)
 300         {
 301                 weapon_setup(WEP_HAGAR);
 302                 self.current_ammo = ammo_rockets;
 303                 self.hagar_load = 0;
 304         }
 305         else if (req == WR_CHECKAMMO1)
 306         {
 307                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 308                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 309                 return ammo_amount;
 310         }
 311         else if (req == WR_CHECKAMMO2)
 312         {
 313                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 314                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 315                 return ammo_amount;
 316         }
 317         else if (req == WR_RELOAD)
 318         {
 319                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 320         }
 321         return TRUE;
 322 };
 323 #endif
 324 #ifdef CSQC
 325 float w_hagar(float req)
 326 {
 327         if(req == WR_IMPACTEFFECT)
 328         {
 329                 vector org2;
 330                 org2 = w_org + w_backoff * 6;
 331                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 332                 if(!w_issilent)
 333                 {
 334                         if (w_random<0.15)
 335                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 336                         else if (w_random<0.7)
 337                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 338                         else
 339                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 340                 }
 341         }
 342         else if(req == WR_PRECACHE)
 343         {
 344                 precache_sound("weapons/hagexp1.wav");
 345                 precache_sound("weapons/hagexp2.wav");
 346                 precache_sound("weapons/hagexp3.wav");
 347         }
 348         else if (req == WR_SUICIDEMESSAGE)
 349                 w_deathtypestring = _("%s played with tiny rockets");
 350         else if (req == WR_KILLMESSAGE)
 351         {
 352                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 353                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 354                 else // unchecked: SPLASH, SECONDARY
 355                         w_deathtypestring = _("%s was pummeled by %s");
 356         }
 357         return TRUE;
 358 }
 359 #endif
 360 #endif