qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 .entity queuenext;
   8 .entity queueprev;
   9
  10 void W_Hagar_Explode (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Explode2 (void)
  19 {
  20         self.event_damage = SUB_Null;
  21         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  22
  23         remove (self);
  24 }
  25
  26 void W_Hagar_Touch (void)
  27 {
  28         PROJECTILE_TOUCH;
  29         self.use ();
  30 }
  31
  32 void W_Hagar_Touch2 (void)
  33 {
  34         PROJECTILE_TOUCH;
  35
  36         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  37                 self.use();
  38         } else {
  39                 self.cnt++;
  40                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  41                 self.angles = vectoangles (self.velocity);
  42                 self.owner = world;
  43                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  44         }
  45 }
  46
  47 void W_Hagar_Attack (void)
  48 {
  49         local entity missile;
  50
  51         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  52
  53         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  54
  55         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  56
  57         missile = spawn ();
  58         missile.owner = missile.realowner = self;
  59         missile.classname = "missile";
  60         missile.bot_dodge = TRUE;
  61         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  62         missile.touch = W_Hagar_Touch;
  63         missile.use = W_Hagar_Explode;
  64         missile.think = adaptor_think2use_hittype_splash;
  65         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  66         PROJECTILE_MAKETRIGGER(missile);
  67         missile.projectiledeathtype = WEP_HAGAR;
  68         setorigin (missile, w_shotorg);
  69         setsize(missile, '0 0 0', '0 0 0');
  70
  71         missile.movetype = MOVETYPE_FLY;
  72         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  73
  74         missile.angles = vectoangles (missile.velocity);
  75         missile.flags = FL_PROJECTILE;
  76
  77         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  78
  79         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  80 }
  81
  82 void W_Hagar_Attack2 (void)
  83 {
  84         local entity missile;
  85
  86         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  87
  88         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  89
  90         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  91
  92         missile = spawn ();
  93         missile.owner = missile.realowner = self;
  94         missile.classname = "missile";
  95         missile.bot_dodge = TRUE;
  96         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  97         missile.touch = W_Hagar_Touch2;
  98         missile.cnt = 0;
  99         missile.use = W_Hagar_Explode2;
 100         missile.think = adaptor_think2use_hittype_splash;
 101         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 102         PROJECTILE_MAKETRIGGER(missile);
 103         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 108         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 109
 110         missile.angles = vectoangles (missile.velocity);
 111         missile.flags = FL_PROJECTILE;
 112
 113         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 114
 115         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 116 }
 117
 118 .float hagarload_refire;
 119
 120 void W_Hagar_Attack2_Load (void)
 121 {
 122         if not(autocvar_g_balance_hagar_secondary)
 123                 return;
 124
 125         local entity missile, prevmissile, firstmissile;
 126         local float counter, shots, loaded;
 127         local float used_ammo, enough_ammo;
 128         local vector s;
 129         vector forward, right, up;
 130
 131         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_maxload;
 132
 133         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 134         if(autocvar_g_balance_hagar_reload_ammo)
 135                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 136         else
 137                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 138
 139         if(self.BUTTON_ATCK2 && !loaded && enough_ammo)
 140         {
 141                 if(self.hagarload_refire < time)
 142                 {
 143                         self.hagar_load += 1;
 144                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 145
 146                         self.hagarload_refire = time + autocvar_g_balance_hagar_secondary_refire;
 147                 }
 148         }
 149         else if(self.hagar_load && (!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && !autocvar_g_balance_hagar_secondary_load_canhold)))
 150         {
 151                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 152                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 153
 154                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 155
 156                 forward = v_forward;
 157                 right = v_right;
 158                 up = v_up;
 159
 160                 shots = self.hagar_load;
 161                 missile = world;
 162                 while (counter < shots)
 163                 {
 164
 165                         missile = spawn ();
 166                         missile.owner = missile.realowner = self;
 167                         missile.classname = "missile";
 168                         missile.bot_dodge = TRUE;
 169                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 170                         if(shots == 1) {
 171                                 missile.queuenext = missile;
 172                                 missile.queueprev = missile;
 173                         }
 174                         else if(counter == 0) { // first projectile, store in firstmissile for now
 175                                 firstmissile = missile;
 176                         }
 177                         else if(counter == shots - 1) { // last projectile, link up with first projectile
 178                                 prevmissile.queuenext = missile;
 179                                 firstmissile.queueprev = missile;
 180                                 missile.queuenext = firstmissile;
 181                                 missile.queueprev = prevmissile;
 182                         }
 183                         else { // else link up with previous projectile
 184                                 prevmissile.queuenext = missile;
 185                                 missile.queueprev = prevmissile;
 186                         }
 187
 188                         prevmissile = missile;
 189
 190                         missile.touch = W_Hagar_Touch;
 191                         missile.use = W_Hagar_Explode;
 192                         missile.think = adaptor_think2use_hittype_splash;
 193                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 194                         PROJECTILE_MAKETRIGGER(missile);
 195                         missile.projectiledeathtype = WEP_HAGAR;
 196                         setorigin (missile, w_shotorg);
 197                         setsize(missile, '0 0 0', '0 0 0');
 198
 199                         missile.movetype = MOVETYPE_FLY;
 200
 201                         s = '0 0 0';
 202                         if (counter == 0)
 203                                 s = '0 0 0';
 204                         else
 205                         {
 206                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 207                                 s_y = v_forward_x;
 208                                 s_z = v_forward_y;
 209                         }
 210                         s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 211                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 212
 213                         missile.angles = vectoangles (missile.velocity);
 214                         missile.flags = FL_PROJECTILE;
 215
 216                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 217
 218                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 219
 220                         counter = counter + 1;
 221                 }
 222
 223                 self.hagar_load = 0;
 224         }
 225 }
 226
 227 void spawnfunc_weapon_hagar (void)
 228 {
 229         weapon_defaultspawnfunc(WEP_HAGAR);
 230 }
 231
 232 float w_hagar(float req)
 233 {
 234         float ammo_amount;
 235         if (req == WR_AIM)
 236                 if (random()>0.15)
 237                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 238                 else
 239                 {
 240                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 241                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 242                 }
 243         else if (req == WR_THINK)
 244         {
 245                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 246                         weapon_action(self.weapon, WR_RELOAD);
 247                 else if (self.BUTTON_ATCK && !self.hagar_load) // not while loading secondary fire
 248                 {
 249                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 250                         {
 251                                 W_Hagar_Attack();
 252                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 253                         }
 254                 }
 255                 else if(autocvar_g_balance_hagar_secondary_load)
 256                         W_Hagar_Attack2_Load(); // must run each frame
 257                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 258                 {
 259                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 260                         {
 261                                 W_Hagar_Attack2();
 262                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 263                         }
 264                 }
 265         }
 266         else if (req == WR_PRECACHE)
 267         {
 268                 precache_model ("models/weapons/g_hagar.md3");
 269                 precache_model ("models/weapons/v_hagar.md3");
 270                 precache_model ("models/weapons/h_hagar.iqm");
 271                 precache_sound ("weapons/hagar_fire.wav");
 272                 precache_sound ("weapons/hagar_load.wav");
 273                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 274         }
 275         else if (req == WR_SETUP)
 276         {
 277                 weapon_setup(WEP_HAGAR);
 278                 self.current_ammo = ammo_rockets;
 279
 280                 self.hagar_load = 0;
 281         }
 282         else if (req == WR_CHECKAMMO1)
 283         {
 284                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 285                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 286                 return ammo_amount;
 287         }
 288         else if (req == WR_CHECKAMMO2)
 289         {
 290                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 291                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 292                 return ammo_amount;
 293         }
 294         else if (req == WR_RELOAD)
 295         {
 296                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 297         }
 298         return TRUE;
 299 };
 300 #endif
 301 #ifdef CSQC
 302 float w_hagar(float req)
 303 {
 304         if(req == WR_IMPACTEFFECT)
 305         {
 306                 vector org2;
 307                 org2 = w_org + w_backoff * 6;
 308                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 309                 if(!w_issilent)
 310                 {
 311                         if (w_random<0.15)
 312                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 313                         else if (w_random<0.7)
 314                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 315                         else
 316                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 317                 }
 318         }
 319         else if(req == WR_PRECACHE)
 320         {
 321                 precache_sound("weapons/hagexp1.wav");
 322                 precache_sound("weapons/hagexp2.wav");
 323                 precache_sound("weapons/hagexp3.wav");
 324         }
 325         else if (req == WR_SUICIDEMESSAGE)
 326                 w_deathtypestring = _("%s played with tiny rockets");
 327         else if (req == WR_KILLMESSAGE)
 328         {
 329                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 330                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 331                 else // unchecked: SPLASH, SECONDARY
 332                         w_deathtypestring = _("%s was pummeled by %s");
 333         }
 334         return TRUE;
 335 }
 336 #endif
 337 #endif