qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadtime, hagar_loadreset;
 116 void W_Hagar_Attack2_Load (void)
 117 {
 118         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 119         {
 120                 W_SwitchToOtherWeapon(self);
 121                 return;
 122         }
 123
 124         local entity missile;
 125         local float counter, shots, loaded;
 126         local float used_ammo, enough_ammo;
 127         local vector s;
 128         vector forward, right, up;
 129
 130         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 131
 132         // check if we have enough ammo for another rocket
 133         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 134         if(autocvar_g_balance_hagar_reload_ammo)
 135                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 136         else
 137                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 138
 139         if(self.BUTTON_ATCK)
 140         {
 141                 if(self.hagar_load)
 142                 {
 143                         // if we press the primary fire button while loading rockets, unload them and abort the loading
 144                         self.hagar_load = 0;
 145                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 146                 }
 147                 // require letting go of both firing buttons before we can load again
 148                 self.hagar_loadreset = TRUE;
 149         }
 150         else if(self.BUTTON_ATCK2)
 151         {
 152                 // check if we can attempt to load another rocket
 153                 if(!self.hagar_loadreset && !loaded && enough_ammo)
 154                 if(self.hagar_loadtime < time)
 155                 {
 156                         self.hagar_load += 1;
 157                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 158
 159                         self.hagar_loadtime = time + autocvar_g_balance_hagar_secondary_load_speed;
 160                 }
 161         }
 162         else if(self.hagar_loadreset)
 163         {
 164                 self.hagar_loadreset = FALSE;
 165         }
 166
 167         if(self.hagar_load)
 168         if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadtime < time && !autocvar_g_balance_hagar_secondary_load_hold))
 169         if(weapon_prepareattack(0, autocvar_g_balance_hagar_secondary_refire))
 170         {
 171                 // time to release the rockets we've loaded
 172
 173                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 174
 175                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 176                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 177
 178                 forward = v_forward;
 179                 right = v_right;
 180                 up = v_up;
 181
 182                 shots = self.hagar_load;
 183                 missile = world;
 184                 while (counter < shots)
 185                 {
 186                         missile = spawn ();
 187                         missile.owner = missile.realowner = self;
 188                         missile.classname = "missile";
 189                         missile.bot_dodge = TRUE;
 190                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 191
 192                         missile.touch = W_Hagar_Touch; // not bouncy
 193                         missile.use = W_Hagar_Explode2;
 194                         missile.think = adaptor_think2use_hittype_splash;
 195                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 196                         PROJECTILE_MAKETRIGGER(missile);
 197                         missile.projectiledeathtype = WEP_HAGAR;
 198                         setorigin (missile, w_shotorg);
 199                         setsize(missile, '0 0 0', '0 0 0');
 200                         missile.movetype = MOVETYPE_FLY;
 201
 202                         s = '0 0 0';
 203                         if (counter == 0)
 204                                 s = '0 0 0';
 205                         else
 206                         {
 207                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 208                                 s_y = v_forward_x;
 209                                 s_z = v_forward_y;
 210                         }
 211                         s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 212                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 213
 214                         missile.angles = vectoangles (missile.velocity);
 215                         missile.flags = FL_PROJECTILE;
 216
 217                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 218
 219                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 220
 221                         counter = counter + 1;
 222                 }
 223
 224                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 225                 self.hagar_loadtime = time + autocvar_g_balance_hagar_secondary_refire;
 226                 self.hagar_load = 0;
 227         }
 228 }
 229
 230 void spawnfunc_weapon_hagar (void)
 231 {
 232         weapon_defaultspawnfunc(WEP_HAGAR);
 233 }
 234
 235 float w_hagar(float req)
 236 {
 237         float ammo_amount;
 238         if (req == WR_AIM)
 239                 if (random()>0.15)
 240                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 241                 else
 242                 {
 243                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 244                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 245                 }
 246         else if (req == WR_THINK)
 247         {
 248                 local float loadable_secondary;
 249                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 250
 251                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 252                         weapon_action(self.weapon, WR_RELOAD);
 253                 else if (self.BUTTON_ATCK && (!self.BUTTON_ATCK2 && loadable_secondary) && !self.hagar_load) // not while loading the secondary fire
 254                 {
 255                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 256                         {
 257                                 W_Hagar_Attack();
 258                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 259                         }
 260                 }
 261                 else if(loadable_secondary)
 262                         W_Hagar_Attack2_Load(); // must run each frame
 263                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 264                 {
 265                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 266                         {
 267                                 W_Hagar_Attack2();
 268                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 269                         }
 270                 }
 271         }
 272         else if (req == WR_PRECACHE)
 273         {
 274                 precache_model ("models/weapons/g_hagar.md3");
 275                 precache_model ("models/weapons/v_hagar.md3");
 276                 precache_model ("models/weapons/h_hagar.iqm");
 277                 precache_sound ("weapons/hagar_fire.wav");
 278                 precache_sound ("weapons/hagar_load.wav");
 279                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 280         }
 281         else if (req == WR_SETUP)
 282         {
 283                 weapon_setup(WEP_HAGAR);
 284                 self.current_ammo = ammo_rockets;
 285                 self.hagar_load = 0;
 286         }
 287         else if (req == WR_CHECKAMMO1)
 288         {
 289                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 290                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 291                 return ammo_amount;
 292         }
 293         else if (req == WR_CHECKAMMO2)
 294         {
 295                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 296                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 297                 return ammo_amount;
 298         }
 299         else if (req == WR_RELOAD)
 300         {
 301                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 302         }
 303         return TRUE;
 304 };
 305 #endif
 306 #ifdef CSQC
 307 float w_hagar(float req)
 308 {
 309         if(req == WR_IMPACTEFFECT)
 310         {
 311                 vector org2;
 312                 org2 = w_org + w_backoff * 6;
 313                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 314                 if(!w_issilent)
 315                 {
 316                         if (w_random<0.15)
 317                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 318                         else if (w_random<0.7)
 319                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 320                         else
 321                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 322                 }
 323         }
 324         else if(req == WR_PRECACHE)
 325         {
 326                 precache_sound("weapons/hagexp1.wav");
 327                 precache_sound("weapons/hagexp2.wav");
 328                 precache_sound("weapons/hagexp3.wav");
 329         }
 330         else if (req == WR_SUICIDEMESSAGE)
 331                 w_deathtypestring = _("%s played with tiny rockets");
 332         else if (req == WR_KILLMESSAGE)
 333         {
 334                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 335                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 336                 else // unchecked: SPLASH, SECONDARY
 337                         w_deathtypestring = _("%s was pummeled by %s");
 338         }
 339         return TRUE;
 340 }
 341 #endif
 342 #endif