qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  24 {
  25         if (self.health <= 0)
  26                 return;
  27
  28         float is_linkexplode = ((inflictor.realowner == self.realowner)
  29                 && ((inflictor.projectiledeathtype & HITTYPE_SECONDARY) && (self.projectiledeathtype & HITTYPE_SECONDARY))
  30                 && autocvar_g_balance_hagar_secondary_load_linkexplode);
  31
  32         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, is_linkexplode))
  33                 return; // g_projectiles_damage says to halt
  34
  35         self.health = self.health - damage;
  36         self.angles = vectoangles(self.velocity);
  37
  38         if (self.health <= 0)
  39                 W_PrepareExplosionByDamage(attacker, self.think);
  40 }
  41
  42 void W_Hagar_Touch (void)
  43 {
  44         PROJECTILE_TOUCH;
  45         self.use ();
  46 }
  47
  48 void W_Hagar_Touch2 (void)
  49 {
  50         PROJECTILE_TOUCH;
  51
  52         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  53                 self.use();
  54         } else {
  55                 self.cnt++;
  56                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  57                 self.angles = vectoangles (self.velocity);
  58                 self.owner = world;
  59                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  60         }
  61 }
  62
  63 void W_Hagar_Attack (void)
  64 {
  65         local entity missile;
  66
  67         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  68
  69         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_primary_damage);
  70
  71         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  72
  73         missile = spawn ();
  74         missile.owner = missile.realowner = self;
  75         missile.classname = "missile";
  76         missile.bot_dodge = TRUE;
  77         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  78
  79         missile.takedamage = DAMAGE_YES;
  80         missile.health = autocvar_g_balance_hagar_primary_health;
  81         missile.damageforcescale = autocvar_g_balance_hagar_primary_damageforcescale;
  82         missile.event_damage = W_Hagar_Damage;
  83         missile.damagedbycontents = TRUE;
  84
  85         missile.touch = W_Hagar_Touch;
  86         missile.use = W_Hagar_Explode;
  87         missile.think = adaptor_think2use_hittype_splash;
  88         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  89         PROJECTILE_MAKETRIGGER(missile);
  90         missile.projectiledeathtype = WEP_HAGAR;
  91         setorigin (missile, w_shotorg);
  92         setsize(missile, '0 0 0', '0 0 0');
  93
  94         missile.movetype = MOVETYPE_FLY;
  95         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  96
  97         missile.angles = vectoangles (missile.velocity);
  98         missile.flags = FL_PROJECTILE;
  99
 100         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 101
 102         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 103 }
 104
 105 void W_Hagar_Attack2 (void)
 106 {
 107         local entity missile;
 108
 109         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 110
 111         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 112
 113         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 114
 115         missile = spawn ();
 116         missile.owner = missile.realowner = self;
 117         missile.classname = "missile";
 118         missile.bot_dodge = TRUE;
 119         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 120
 121         missile.takedamage = DAMAGE_YES;
 122         missile.health = autocvar_g_balance_hagar_secondary_health;
 123         missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 124         missile.event_damage = W_Hagar_Damage;
 125         missile.damagedbycontents = TRUE;
 126
 127         missile.touch = W_Hagar_Touch2;
 128         missile.cnt = 0;
 129         missile.use = W_Hagar_Explode2;
 130         missile.think = adaptor_think2use_hittype_splash;
 131         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 132         PROJECTILE_MAKETRIGGER(missile);
 133         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 134         setorigin (missile, w_shotorg);
 135         setsize(missile, '0 0 0', '0 0 0');
 136
 137         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 138         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 139
 140         missile.angles = vectoangles (missile.velocity);
 141         missile.flags = FL_PROJECTILE;
 142
 143         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 144
 145         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 146 }
 147
 148 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep, hagar_warning;
 149 void W_Hagar_Attack2_Load_Release (void)
 150 {
 151         // time to release the rockets we've loaded
 152
 153         local entity missile;
 154         local float counter, shots, spread_pershot;
 155         local vector s;
 156         vector forward, right, up;
 157
 158         if(!self.hagar_load)
 159                 return;
 160
 161         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
 162
 163         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 164         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 165
 166         forward = v_forward;
 167         right = v_right;
 168         up = v_up;
 169
 170         shots = self.hagar_load;
 171         missile = world;
 172         while (counter < shots)
 173         {
 174                 missile = spawn ();
 175                 missile.owner = missile.realowner = self;
 176                 missile.classname = "missile";
 177                 missile.bot_dodge = TRUE;
 178                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 179
 180                 missile.takedamage = DAMAGE_YES;
 181                 missile.health = autocvar_g_balance_hagar_secondary_health;
 182                 missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 183                 missile.event_damage = W_Hagar_Damage;
 184                 missile.damagedbycontents = TRUE;
 185
 186                 missile.touch = W_Hagar_Touch; // not bouncy
 187                 missile.use = W_Hagar_Explode2;
 188                 missile.think = adaptor_think2use_hittype_splash;
 189                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 190                 PROJECTILE_MAKETRIGGER(missile);
 191                 missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 192                 setorigin (missile, w_shotorg);
 193                 setsize(missile, '0 0 0', '0 0 0');
 194                 missile.movetype = MOVETYPE_FLY;
 195
 196                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
 197                 spread_pershot = ((shots - 1) / (autocvar_g_balance_hagar_secondary_load_max - 1));
 198                 spread_pershot = (1 - (spread_pershot * autocvar_g_balance_hagar_secondary_load_spread_bias));
 199                 spread_pershot = (autocvar_g_balance_hagar_secondary_spread * spread_pershot * g_weaponspreadfactor);
 200
 201                 // pattern spread calculation
 202                 s = '0 0 0';
 203                 if (counter == 0)
 204                         s = '0 0 0';
 205                 else
 206                 {
 207                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 208                         s_y = v_forward_x;
 209                         s_z = v_forward_y;
 210                 }
 211                 s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 212
 213                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, autocvar_g_balance_hagar_secondary_speed, 0, 0, spread_pershot, FALSE);
 214
 215                 missile.angles = vectoangles (missile.velocity);
 216                 missile.flags = FL_PROJECTILE;
 217
 218                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 219
 220                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 221
 222                 counter = counter + 1;
 223         }
 224
 225         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_load_animtime, w_ready);
 226         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire * W_WeaponRateFactor();
 227         self.hagar_load = 0;
 228 }
 229
 230 void W_Hagar_Attack2_Load (void)
 231 {
 232         // loadable hagar secondary attack, must always run each frame
 233
 234         local float loaded, enough_ammo;
 235         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 236
 237         // this is different than WR_CHECKAMMO when it comes to reloading
 238         if(autocvar_g_balance_hagar_reload_ammo)
 239                 enough_ammo = self.(weapon_load[WEP_HAGAR]) >= autocvar_g_balance_hagar_secondary_ammo;
 240         else
 241                 enough_ammo = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 242
 243         if(self.BUTTON_ATCK2)
 244         {
 245                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 246                 {
 247                         if(self.hagar_load)
 248                         {
 249                                 // if we pressed primary fire while loading, unload all rockets and abort
 250                                 self.weaponentity.state = WS_READY;
 251                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
 252                                 self.hagar_load = 0;
 253                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 254
 255                                 // pause until we can load rockets again, once we re-press the alt fire button
 256                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 257
 258                                 // require letting go of the alt fire button before we can load again
 259                                 self.hagar_loadblock = TRUE;
 260                         }
 261                 }
 262                 else
 263                 {
 264                         // check if we can attempt to load another rocket
 265                         if(!loaded && enough_ammo)
 266                         {
 267                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
 268                                 {
 269                                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 270                                         self.weaponentity.state = WS_INUSE;
 271                                         self.hagar_load += 1;
 272                                         sound(self, CH_WEAPON_B, "weapons/hagar_load.wav", VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
 273
 274                                         if (self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 275                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_hold * W_WeaponRateFactor();
 276                                         else
 277                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 278                                 }
 279                         }
 280                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
 281                         {
 282                                 // if this is the last rocket we can load, play a beep sound to notify the player
 283                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 284                                 self.hagar_loadbeep = TRUE;
 285                         }
 286                 }
 287         }
 288         else if(self.hagar_loadblock)
 289         {
 290                 // the alt fire button has been released, so re-enable loading if blocked
 291                 self.hagar_loadblock = FALSE;
 292         }
 293
 294         if(self.hagar_load)
 295         {
 296                 // play warning sound if we're about to release
 297                 if((loaded || !enough_ammo) && self.hagar_loadstep - 0.5 < time && autocvar_g_balance_hagar_secondary_load_hold >= 0)
 298                 {
 299                         if(!self.hagar_warning && self.hagar_load) // prevents the beep from playing each frame
 300                         {
 301                                 // we're about to automatically release after holding time, play a beep sound to notify the player
 302                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 303                                 self.hagar_warning = TRUE;
 304                         }
 305                 }
 306
 307                 // release if player let go of button or if they've held it in too long
 308                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && autocvar_g_balance_hagar_secondary_load_hold >= 0))
 309                 {
 310                         self.weaponentity.state = WS_READY;
 311                         W_Hagar_Attack2_Load_Release();
 312                 }
 313         }
 314         else
 315         {
 316                 self.hagar_loadbeep = FALSE;
 317                 self.hagar_warning = FALSE;
 318         }
 319
 320         // we aren't checking ammo during an attack, so we must do it here
 321         if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
 322         {
 323                 // note: this doesn't force the switch
 324                 W_SwitchToOtherWeapon(self);
 325                 return;
 326         }
 327 }
 328
 329 void spawnfunc_weapon_hagar (void)
 330 {
 331         weapon_defaultspawnfunc(WEP_HAGAR);
 332 }
 333
 334 float w_hagar(float req)
 335 {
 336         float ammo_amount;
 337         if (req == WR_AIM)
 338                 if (random()>0.15)
 339                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 340                 else
 341                 {
 342                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 343                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 344                 }
 345         else if (req == WR_THINK)
 346         {
 347                 local float loadable_secondary;
 348                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 349
 350                 if (loadable_secondary)
 351                         W_Hagar_Attack2_Load(); // must always run each frame
 352                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 353                         weapon_action(self.weapon, WR_RELOAD);
 354                 else if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 355                 {
 356                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 357                         {
 358                                 W_Hagar_Attack();
 359                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 360                         }
 361                 }
 362                 else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 363                 {
 364                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 365                         {
 366                                 W_Hagar_Attack2();
 367                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 368                         }
 369                 }
 370         }
 371         else if (req == WR_GONETHINK)
 372         {
 373                 // we lost the weapon and want to prepare switching away
 374                 if(self.hagar_load)
 375                 {
 376                         self.weaponentity.state = WS_READY;
 377                         W_Hagar_Attack2_Load_Release();
 378                 }
 379         }
 380         else if (req == WR_PRECACHE)
 381         {
 382                 precache_model ("models/weapons/g_hagar.md3");
 383                 precache_model ("models/weapons/v_hagar.md3");
 384                 precache_model ("models/weapons/h_hagar.iqm");
 385                 precache_sound ("weapons/hagar_fire.wav");
 386                 precache_sound ("weapons/hagar_load.wav");
 387                 precache_sound ("weapons/hagar_beep.wav");
 388                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 389         }
 390         else if (req == WR_SETUP)
 391         {
 392                 weapon_setup(WEP_HAGAR);
 393                 self.current_ammo = ammo_rockets;
 394                 self.hagar_loadblock = FALSE;
 395
 396                 if(self.hagar_load)
 397                 {
 398                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
 399                         self.hagar_load = 0;
 400                 }
 401         }
 402         else if (req == WR_CHECKAMMO1)
 403         {
 404                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 405                 ammo_amount += self.(weapon_load[WEP_HAGAR]) >= autocvar_g_balance_hagar_primary_ammo;
 406                 return ammo_amount;
 407         }
 408         else if (req == WR_CHECKAMMO2)
 409         {
 410                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 411                 ammo_amount += self.(weapon_load[WEP_HAGAR]) >= autocvar_g_balance_hagar_secondary_ammo;
 412                 return ammo_amount;
 413         }
 414         else if (req == WR_RESETPLAYER)
 415         {
 416                 self.hagar_load = 0;
 417         }
 418         else if (req == WR_PLAYERDEATH)
 419         {
 420                 // if we have any rockets loaded when we die, release them
 421                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 422                         W_Hagar_Attack2_Load_Release();
 423         }
 424         else if (req == WR_RELOAD)
 425         {
 426                 if not(self.hagar_load) // require releasing loaded rockets first
 427                         W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 428         }
 429         return TRUE;
 430 };
 431 #endif
 432 #ifdef CSQC
 433 float w_hagar(float req)
 434 {
 435         if(req == WR_IMPACTEFFECT)
 436         {
 437                 vector org2;
 438                 org2 = w_org + w_backoff * 6;
 439                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 440                 if(!w_issilent)
 441                 {
 442                         if (w_random<0.15)
 443                                 sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 444                         else if (w_random<0.7)
 445                                 sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 446                         else
 447                                 sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 448                 }
 449         }
 450         else if(req == WR_PRECACHE)
 451         {
 452                 precache_sound("weapons/hagexp1.wav");
 453                 precache_sound("weapons/hagexp2.wav");
 454                 precache_sound("weapons/hagexp3.wav");
 455         }
 456         else if (req == WR_SUICIDEMESSAGE)
 457                 w_deathtypestring = _("%s played with tiny rockets");
 458         else if (req == WR_KILLMESSAGE)
 459         {
 460                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 461                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 462                 else // unchecked: SPLASH, SECONDARY
 463                         w_deathtypestring = _("%s was pummeled by %s");
 464         }
 465         return TRUE;
 466 }
 467 #endif
 468 #endif