qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 .entity queuenext;
   8 .entity queueprev;
   9
  10 void W_Hagar_Explode (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Explode2 (void)
  19 {
  20         self.event_damage = SUB_Null;
  21         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  22
  23         remove (self);
  24 }
  25
  26 void W_Hagar_Touch (void)
  27 {
  28         PROJECTILE_TOUCH;
  29         self.use ();
  30 }
  31
  32 void W_Hagar_Touch2 (void)
  33 {
  34         PROJECTILE_TOUCH;
  35
  36         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  37                 self.use();
  38         } else {
  39                 self.cnt++;
  40                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  41                 self.angles = vectoangles (self.velocity);
  42                 self.owner = world;
  43                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  44         }
  45 }
  46
  47 void W_Hagar_Attack (void)
  48 {
  49         local entity missile;
  50
  51         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  52
  53         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  54
  55         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  56
  57         missile = spawn ();
  58         missile.owner = missile.realowner = self;
  59         missile.classname = "missile";
  60         missile.bot_dodge = TRUE;
  61         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  62         missile.touch = W_Hagar_Touch;
  63         missile.use = W_Hagar_Explode;
  64         missile.think = adaptor_think2use_hittype_splash;
  65         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  66         PROJECTILE_MAKETRIGGER(missile);
  67         missile.projectiledeathtype = WEP_HAGAR;
  68         setorigin (missile, w_shotorg);
  69         setsize(missile, '0 0 0', '0 0 0');
  70
  71         missile.movetype = MOVETYPE_FLY;
  72         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  73
  74         missile.angles = vectoangles (missile.velocity);
  75         missile.flags = FL_PROJECTILE;
  76
  77         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  78
  79         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  80 }
  81
  82 void W_Hagar_Attack2 (void)
  83 {
  84         local entity missile;
  85
  86         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  87
  88         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  89
  90         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  91
  92         missile = spawn ();
  93         missile.owner = missile.realowner = self;
  94         missile.classname = "missile";
  95         missile.bot_dodge = TRUE;
  96         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  97         missile.touch = W_Hagar_Touch2;
  98         missile.cnt = 0;
  99         missile.use = W_Hagar_Explode2;
 100         missile.think = adaptor_think2use_hittype_splash;
 101         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 102         PROJECTILE_MAKETRIGGER(missile);
 103         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 108         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 109
 110         missile.angles = vectoangles (missile.velocity);
 111         missile.flags = FL_PROJECTILE;
 112
 113         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 114
 115         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 116 }
 117
 118 .float hagarload_refire, hagarload_loaded;
 119
 120 void W_Hagar_Attack2_Load (void)
 121 {
 122         if not(autocvar_g_balance_hagar_secondary)
 123                 return;
 124
 125         local entity missile, prevmissile, firstmissile;
 126         local float counter, shots;
 127         local vector s;
 128         vector forward, right, up;
 129
 130         if(self.BUTTON_ATCK2 && !self.hagarload_loaded)
 131         {
 132                 if(self.hagarload_refire < time)
 133                 {
 134                         self.hagar_load += 1;
 135                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 136
 137                         if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_maxload)
 138                                 self.hagarload_loaded = TRUE;
 139
 140                         self.hagarload_refire = time + autocvar_g_balance_hagar_secondary_refire;
 141                 }
 142         }
 143
 144         if(self.hagar_load && (!self.BUTTON_ATCK2 || (self.hagarload_loaded && !autocvar_g_balance_hagar_secondary_load_canhold)))
 145         {
 146                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 147                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 148
 149                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 150
 151                 forward = v_forward;
 152                 right = v_right;
 153                 up = v_up;
 154
 155                 shots = self.hagar_load;
 156                 missile = world;
 157                 while (counter < shots)
 158                 {
 159
 160                         missile = spawn ();
 161                         missile.owner = missile.realowner = self;
 162                         missile.classname = "missile";
 163                         missile.bot_dodge = TRUE;
 164                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 165                         if(shots == 1) {
 166                                 missile.queuenext = missile;
 167                                 missile.queueprev = missile;
 168                         }
 169                         else if(counter == 0) { // first projectile, store in firstmissile for now
 170                                 firstmissile = missile;
 171                         }
 172                         else if(counter == shots - 1) { // last projectile, link up with first projectile
 173                                 prevmissile.queuenext = missile;
 174                                 firstmissile.queueprev = missile;
 175                                 missile.queuenext = firstmissile;
 176                                 missile.queueprev = prevmissile;
 177                         }
 178                         else { // else link up with previous projectile
 179                                 prevmissile.queuenext = missile;
 180                                 missile.queueprev = prevmissile;
 181                         }
 182
 183                         prevmissile = missile;
 184
 185                         missile.touch = W_Hagar_Touch;
 186                         missile.use = W_Hagar_Explode;
 187                         missile.think = adaptor_think2use_hittype_splash;
 188                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 189                         PROJECTILE_MAKETRIGGER(missile);
 190                         missile.projectiledeathtype = WEP_HAGAR;
 191                         setorigin (missile, w_shotorg);
 192                         setsize(missile, '0 0 0', '0 0 0');
 193
 194                         missile.movetype = MOVETYPE_FLY;
 195
 196                         s = '0 0 0';
 197                         if (counter == 0)
 198                                 s = '0 0 0';
 199                         else
 200                         {
 201                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 202                                 s_y = v_forward_x;
 203                                 s_z = v_forward_y;
 204                         }
 205                         s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 206                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 207
 208                         missile.angles = vectoangles (missile.velocity);
 209                         missile.flags = FL_PROJECTILE;
 210
 211                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 212
 213                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 214
 215                         counter = counter + 1;
 216                 }
 217
 218                 self.hagar_load = 0;
 219                 self.hagarload_loaded = FALSE;
 220         }
 221 }
 222
 223 void spawnfunc_weapon_hagar (void)
 224 {
 225         weapon_defaultspawnfunc(WEP_HAGAR);
 226 }
 227
 228 float w_hagar(float req)
 229 {
 230         float ammo_amount;
 231         if (req == WR_AIM)
 232                 if (random()>0.15)
 233                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 234                 else
 235                 {
 236                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 237                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 238                 }
 239         else if (req == WR_THINK)
 240         {
 241                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 242                         weapon_action(self.weapon, WR_RELOAD);
 243                 else if (self.BUTTON_ATCK && !self.hagar_load) // not while loading secondary fire
 244                 {
 245                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 246                         {
 247                                 W_Hagar_Attack();
 248                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 249                         }
 250                 }
 251                 else if(autocvar_g_balance_hagar_secondary_load)
 252                         W_Hagar_Attack2_Load(); // must run each frame
 253                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 254                 {
 255                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 256                         {
 257                                 W_Hagar_Attack2();
 258                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 259                         }
 260                 }
 261         }
 262         else if (req == WR_PRECACHE)
 263         {
 264                 precache_model ("models/weapons/g_hagar.md3");
 265                 precache_model ("models/weapons/v_hagar.md3");
 266                 precache_model ("models/weapons/h_hagar.iqm");
 267                 precache_sound ("weapons/hagar_fire.wav");
 268                 precache_sound ("weapons/hagar_load.wav");
 269                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 270         }
 271         else if (req == WR_SETUP)
 272         {
 273                 weapon_setup(WEP_HAGAR);
 274                 self.current_ammo = ammo_rockets;
 275
 276                 self.hagar_load = 0;
 277                 self.hagarload_loaded = FALSE;
 278         }
 279         else if (req == WR_CHECKAMMO1)
 280         {
 281                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 282                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 283                 return ammo_amount;
 284         }
 285         else if (req == WR_CHECKAMMO2)
 286         {
 287                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 288                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 289                 return ammo_amount;
 290         }
 291         else if (req == WR_RELOAD)
 292         {
 293                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 294         }
 295         return TRUE;
 296 };
 297 #endif
 298 #ifdef CSQC
 299 float w_hagar(float req)
 300 {
 301         if(req == WR_IMPACTEFFECT)
 302         {
 303                 vector org2;
 304                 org2 = w_org + w_backoff * 6;
 305                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 306                 if(!w_issilent)
 307                 {
 308                         if (w_random<0.15)
 309                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 310                         else if (w_random<0.7)
 311                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 312                         else
 313                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 314                 }
 315         }
 316         else if(req == WR_PRECACHE)
 317         {
 318                 precache_sound("weapons/hagexp1.wav");
 319                 precache_sound("weapons/hagexp2.wav");
 320                 precache_sound("weapons/hagexp3.wav");
 321         }
 322         else if (req == WR_SUICIDEMESSAGE)
 323                 w_deathtypestring = _("%s played with tiny rockets");
 324         else if (req == WR_KILLMESSAGE)
 325         {
 326                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 327                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 328                 else // unchecked: SPLASH, SECONDARY
 329                         w_deathtypestring = _("%s was pummeled by %s");
 330         }
 331         return TRUE;
 332 }
 333 #endif
 334 #endif