qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 .entity queuenext;
   8 .entity queueprev;
   9
  10 void W_Hagar_Explode (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Explode2 (void)
  19 {
  20         self.event_damage = SUB_Null;
  21         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  22
  23         remove (self);
  24 }
  25
  26 void W_Hagar_Touch (void)
  27 {
  28         PROJECTILE_TOUCH;
  29         self.use ();
  30 }
  31
  32 void W_Hagar_Touch2 (void)
  33 {
  34         PROJECTILE_TOUCH;
  35
  36         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  37                 self.use();
  38         } else {
  39                 self.cnt++;
  40                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  41                 self.angles = vectoangles (self.velocity);
  42                 self.owner = world;
  43                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  44         }
  45 }
  46
  47 void W_Hagar_Attack (void)
  48 {
  49         local entity missile;
  50
  51         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  52
  53         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  54
  55         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  56
  57         missile = spawn ();
  58         missile.owner = missile.realowner = self;
  59         missile.classname = "missile";
  60         missile.bot_dodge = TRUE;
  61         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  62         missile.touch = W_Hagar_Touch;
  63         missile.use = W_Hagar_Explode;
  64         missile.think = adaptor_think2use_hittype_splash;
  65         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  66         PROJECTILE_MAKETRIGGER(missile);
  67         missile.projectiledeathtype = WEP_HAGAR;
  68         setorigin (missile, w_shotorg);
  69         setsize(missile, '0 0 0', '0 0 0');
  70
  71         missile.movetype = MOVETYPE_FLY;
  72         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  73
  74         missile.angles = vectoangles (missile.velocity);
  75         missile.flags = FL_PROJECTILE;
  76
  77         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  78
  79         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  80 }
  81
  82 void W_Hagar_Attack2 (void)
  83 {
  84         local entity missile;
  85
  86         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  87
  88         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  89
  90         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  91
  92         missile = spawn ();
  93         missile.owner = missile.realowner = self;
  94         missile.classname = "missile";
  95         missile.bot_dodge = TRUE;
  96         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  97         missile.touch = W_Hagar_Touch2;
  98         missile.cnt = 0;
  99         missile.use = W_Hagar_Explode2;
 100         missile.think = adaptor_think2use_hittype_splash;
 101         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 102         PROJECTILE_MAKETRIGGER(missile);
 103         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 108         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 109
 110         missile.angles = vectoangles (missile.velocity);
 111         missile.flags = FL_PROJECTILE;
 112
 113         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 114
 115         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 116 }
 117
 118 .float hagarload_refire, hagarload_loaded;
 119
 120 void W_Hagar_Attack2_Load (void)
 121 {
 122         if not(autocvar_g_balance_hagar_secondary)
 123                 return;
 124
 125         local entity missile, prevmissile, firstmissile;
 126         local float counter, shots;
 127         local vector s;
 128         vector forward, right, up;
 129
 130         if(self.BUTTON_ATCK2 && !self.hagarload_loaded)
 131         {
 132                 if(self.hagarload_refire < time)
 133                 {
 134                         self.hagar_load += 1;
 135                         if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_maxload)
 136                                 self.hagarload_loaded = TRUE;
 137
 138                         self.hagarload_refire = time + autocvar_g_balance_hagar_secondary_refire;
 139                 }
 140         }
 141         else if(self.hagar_load)
 142         {
 143                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 144                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 145
 146                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 147
 148                 forward = v_forward;
 149                 right = v_right;
 150                 up = v_up;
 151
 152                 shots = self.hagar_load;
 153                 missile = world;
 154                 while (counter < shots)
 155                 {
 156
 157                         missile = spawn ();
 158                         missile.owner = missile.realowner = self;
 159                         missile.classname = "missile";
 160                         missile.bot_dodge = TRUE;
 161                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 162                         if(shots == 1) {
 163                                 missile.queuenext = missile;
 164                                 missile.queueprev = missile;
 165                         }
 166                         else if(counter == 0) { // first projectile, store in firstmissile for now
 167                                 firstmissile = missile;
 168                         }
 169                         else if(counter == shots - 1) { // last projectile, link up with first projectile
 170                                 prevmissile.queuenext = missile;
 171                                 firstmissile.queueprev = missile;
 172                                 missile.queuenext = firstmissile;
 173                                 missile.queueprev = prevmissile;
 174                         }
 175                         else { // else link up with previous projectile
 176                                 prevmissile.queuenext = missile;
 177                                 missile.queueprev = prevmissile;
 178                         }
 179
 180                         prevmissile = missile;
 181
 182                         missile.touch = W_Hagar_Touch;
 183                         missile.use = W_Hagar_Explode;
 184                         missile.think = adaptor_think2use_hittype_splash;
 185                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 186                         PROJECTILE_MAKETRIGGER(missile);
 187                         missile.projectiledeathtype = WEP_HAGAR;
 188                         setorigin (missile, w_shotorg);
 189                         setsize(missile, '0 0 0', '0 0 0');
 190
 191                         missile.movetype = MOVETYPE_FLY;
 192
 193                         s = '0 0 0';
 194                         if (counter == 0)
 195                                 s = '0 0 0';
 196                         else
 197                         {
 198                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 199                                 s_y = v_forward_x;
 200                                 s_z = v_forward_y;
 201                         }
 202                         s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 203                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 204
 205                         missile.angles = vectoangles (missile.velocity);
 206                         missile.flags = FL_PROJECTILE;
 207
 208                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 209
 210                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 211
 212                         counter = counter + 1;
 213                 }
 214
 215                 self.hagar_load = 0;
 216                 self.hagarload_loaded = FALSE;
 217         }
 218 }
 219
 220 void spawnfunc_weapon_hagar (void)
 221 {
 222         weapon_defaultspawnfunc(WEP_HAGAR);
 223 }
 224
 225 float w_hagar(float req)
 226 {
 227         float ammo_amount;
 228         if (req == WR_AIM)
 229                 if (random()>0.15)
 230                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 231                 else
 232                 {
 233                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 234                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 235                 }
 236         else if (req == WR_THINK)
 237         {
 238                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 239                         weapon_action(self.weapon, WR_RELOAD);
 240                 else if (self.BUTTON_ATCK && !self.hagar_load) // not while loading secondary fire
 241                 {
 242                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 243                         {
 244                                 W_Hagar_Attack();
 245                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 246                         }
 247                 }
 248                 else if(autocvar_g_balance_hagar_secondary_load)
 249                         W_Hagar_Attack2_Load(); // must run each frame
 250                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 251                 {
 252                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 253                         {
 254                                 W_Hagar_Attack2();
 255                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 256                         }
 257                 }
 258         }
 259         else if (req == WR_PRECACHE)
 260         {
 261                 precache_model ("models/weapons/g_hagar.md3");
 262                 precache_model ("models/weapons/v_hagar.md3");
 263                 precache_model ("models/weapons/h_hagar.iqm");
 264                 precache_sound ("weapons/hagar_fire.wav");
 265                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 266         }
 267         else if (req == WR_SETUP)
 268         {
 269                 weapon_setup(WEP_HAGAR);
 270                 self.current_ammo = ammo_rockets;
 271         }
 272         else if (req == WR_CHECKAMMO1)
 273         {
 274                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 275                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 276                 return ammo_amount;
 277         }
 278         else if (req == WR_CHECKAMMO2)
 279         {
 280                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 281                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 282                 return ammo_amount;
 283         }
 284         else if (req == WR_RELOAD)
 285         {
 286                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 287         }
 288         return TRUE;
 289 };
 290 #endif
 291 #ifdef CSQC
 292 float w_hagar(float req)
 293 {
 294         if(req == WR_IMPACTEFFECT)
 295         {
 296                 vector org2;
 297                 org2 = w_org + w_backoff * 6;
 298                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 299                 if(!w_issilent)
 300                 {
 301                         if (w_random<0.15)
 302                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 303                         else if (w_random<0.7)
 304                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 305                         else
 306                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 307                 }
 308         }
 309         else if(req == WR_PRECACHE)
 310         {
 311                 precache_sound("weapons/hagexp1.wav");
 312                 precache_sound("weapons/hagexp2.wav");
 313                 precache_sound("weapons/hagexp3.wav");
 314         }
 315         else if (req == WR_SUICIDEMESSAGE)
 316                 w_deathtypestring = _("%s played with tiny rockets");
 317         else if (req == WR_KILLMESSAGE)
 318         {
 319                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 320                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 321                 else // unchecked: SPLASH, SECONDARY
 322                         w_deathtypestring = _("%s was pummeled by %s");
 323         }
 324         return TRUE;
 325 }
 326 #endif
 327 #endif