qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 .entity queuenext;
   8 .entity queueprev;
   9
  10 void W_Hagar_Explode (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Explode2 (void)
  19 {
  20         self.event_damage = SUB_Null;
  21         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  22
  23         remove (self);
  24 }
  25
  26 void W_Hagar_Touch (void)
  27 {
  28         PROJECTILE_TOUCH;
  29         self.use ();
  30 }
  31
  32 void W_Hagar_Touch2 (void)
  33 {
  34         PROJECTILE_TOUCH;
  35
  36         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  37                 self.use();
  38         } else {
  39                 self.cnt++;
  40                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  41                 self.angles = vectoangles (self.velocity);
  42                 self.owner = world;
  43                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  44         }
  45 }
  46
  47 void W_Hagar_Attack (void)
  48 {
  49         local entity missile;
  50
  51         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  52
  53         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  54
  55         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  56
  57         missile = spawn ();
  58         missile.owner = missile.realowner = self;
  59         missile.classname = "missile";
  60         missile.bot_dodge = TRUE;
  61         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  62         missile.touch = W_Hagar_Touch;
  63         missile.use = W_Hagar_Explode;
  64         missile.think = adaptor_think2use_hittype_splash;
  65         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  66         PROJECTILE_MAKETRIGGER(missile);
  67         missile.projectiledeathtype = WEP_HAGAR;
  68         setorigin (missile, w_shotorg);
  69         setsize(missile, '0 0 0', '0 0 0');
  70
  71         missile.movetype = MOVETYPE_FLY;
  72         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  73
  74         missile.angles = vectoangles (missile.velocity);
  75         missile.flags = FL_PROJECTILE;
  76
  77         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  78
  79         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  80 }
  81
  82 void W_Hagar_Attack2 (void)
  83 {
  84         local entity missile;
  85
  86         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  87
  88         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  89
  90         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  91
  92         missile = spawn ();
  93         missile.owner = missile.realowner = self;
  94         missile.classname = "missile";
  95         missile.bot_dodge = TRUE;
  96         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  97         missile.touch = W_Hagar_Touch2;
  98         missile.cnt = 0;
  99         missile.use = W_Hagar_Explode2;
 100         missile.think = adaptor_think2use_hittype_splash;
 101         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 102         PROJECTILE_MAKETRIGGER(missile);
 103         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 108         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 109
 110         missile.angles = vectoangles (missile.velocity);
 111         missile.flags = FL_PROJECTILE;
 112
 113         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 114
 115         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 116 }
 117
 118 .float hagarload_refire, hagarload_loaded;
 119
 120 void W_Hagar_Attack2_Load (void)
 121 {
 122         if not(autocvar_g_balance_hagar_secondary)
 123                 return;
 124
 125         local entity missile, prevmissile, firstmissile;
 126         local float counter, shots;
 127         local vector s;
 128         vector forward, right, up;
 129
 130         if(self.BUTTON_ATCK2 && !self.hagarload_loaded)
 131         {
 132                 if(self.hagarload_refire < time)
 133                 {
 134                         self.hagar_load += 1;
 135                         if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_maxload)
 136                                 self.hagarload_loaded = TRUE;
 137
 138                         self.hagarload_refire = time + autocvar_g_balance_hagar_secondary_refire;
 139                 }
 140         }
 141         else if(self.hagar_load)
 142         {
 143                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 144                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 145
 146                 forward = v_forward;
 147                 right = v_right;
 148                 up = v_up;
 149
 150                 shots = self.hagar_load;
 151                 missile = world;
 152                 while (counter < shots)
 153                 {
 154
 155                         missile = spawn ();
 156                         missile.owner = missile.realowner = self;
 157                         missile.classname = "missile";
 158                         missile.bot_dodge = TRUE;
 159                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 160                         if(shots == 1) {
 161                                 missile.queuenext = missile;
 162                                 missile.queueprev = missile;
 163                         }
 164                         else if(counter == 0) { // first projectile, store in firstmissile for now
 165                                 firstmissile = missile;
 166                         }
 167                         else if(counter == shots - 1) { // last projectile, link up with first projectile
 168                                 prevmissile.queuenext = missile;
 169                                 firstmissile.queueprev = missile;
 170                                 missile.queuenext = firstmissile;
 171                                 missile.queueprev = prevmissile;
 172                         }
 173                         else { // else link up with previous projectile
 174                                 prevmissile.queuenext = missile;
 175                                 missile.queueprev = prevmissile;
 176                         }
 177
 178                         prevmissile = missile;
 179
 180                         missile.touch = W_Hagar_Touch;
 181                         missile.use = W_Hagar_Explode;
 182                         missile.think = adaptor_think2use_hittype_splash;
 183                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 184                         PROJECTILE_MAKETRIGGER(missile);
 185                         missile.projectiledeathtype = WEP_HAGAR;
 186                         setorigin (missile, w_shotorg);
 187                         setsize(missile, '0 0 0', '0 0 0');
 188
 189                         missile.movetype = MOVETYPE_FLY;
 190
 191                         s = '0 0 0';
 192                         if (counter == 0)
 193                                 s = '0 0 0';
 194                         else
 195                         {
 196                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 197                                 s_y = v_forward_x;
 198                                 s_z = v_forward_y;
 199                         }
 200                         s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 201                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 202
 203                         missile.angles = vectoangles (missile.velocity);
 204                         missile.flags = FL_PROJECTILE;
 205
 206                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 207
 208                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 209
 210                         counter = counter + 1;
 211                 }
 212
 213                 self.hagar_load = 0;
 214                 self.hagarload_loaded = FALSE;
 215         }
 216 }
 217
 218 void spawnfunc_weapon_hagar (void)
 219 {
 220         weapon_defaultspawnfunc(WEP_HAGAR);
 221 }
 222
 223 float w_hagar(float req)
 224 {
 225         float ammo_amount;
 226         if (req == WR_AIM)
 227                 if (random()>0.15)
 228                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 229                 else
 230                 {
 231                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 232                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 233                 }
 234         else if (req == WR_THINK)
 235         {
 236                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 237                         weapon_action(self.weapon, WR_RELOAD);
 238                 else if (self.BUTTON_ATCK)
 239                 {
 240                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 241                         {
 242                                 W_Hagar_Attack();
 243                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 244                         }
 245                 }
 246                 else if(autocvar_g_balance_hagar_secondary_load)
 247                         W_Hagar_Attack2_Load();
 248                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 249                 {
 250                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 251                         {
 252                                 W_Hagar_Attack2();
 253                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 254                         }
 255                 }
 256         }
 257         else if (req == WR_PRECACHE)
 258         {
 259                 precache_model ("models/weapons/g_hagar.md3");
 260                 precache_model ("models/weapons/v_hagar.md3");
 261                 precache_model ("models/weapons/h_hagar.iqm");
 262                 precache_sound ("weapons/hagar_fire.wav");
 263                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 264         }
 265         else if (req == WR_SETUP)
 266         {
 267                 weapon_setup(WEP_HAGAR);
 268                 self.current_ammo = ammo_rockets;
 269         }
 270         else if (req == WR_CHECKAMMO1)
 271         {
 272                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 273                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 274                 return ammo_amount;
 275         }
 276         else if (req == WR_CHECKAMMO2)
 277         {
 278                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 279                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 280                 return ammo_amount;
 281         }
 282         else if (req == WR_RELOAD)
 283         {
 284                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 285         }
 286         return TRUE;
 287 };
 288 #endif
 289 #ifdef CSQC
 290 float w_hagar(float req)
 291 {
 292         if(req == WR_IMPACTEFFECT)
 293         {
 294                 vector org2;
 295                 org2 = w_org + w_backoff * 6;
 296                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 297                 if(!w_issilent)
 298                 {
 299                         if (w_random<0.15)
 300                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 301                         else if (w_random<0.7)
 302                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 303                         else
 304                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 305                 }
 306         }
 307         else if(req == WR_PRECACHE)
 308         {
 309                 precache_sound("weapons/hagexp1.wav");
 310                 precache_sound("weapons/hagexp2.wav");
 311                 precache_sound("weapons/hagexp3.wav");
 312         }
 313         else if (req == WR_SUICIDEMESSAGE)
 314                 w_deathtypestring = _("%s played with tiny rockets");
 315         else if (req == WR_KILLMESSAGE)
 316         {
 317                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 318                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 319                 else // unchecked: SPLASH, SECONDARY
 320                         w_deathtypestring = _("%s was pummeled by %s");
 321         }
 322         return TRUE;
 323 }
 324 #endif
 325 #endif