qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 .entity queuenext;
   8 .entity queueprev;
   9
  10 void W_Hagar_Explode (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Explode2 (void)
  19 {
  20         self.event_damage = SUB_Null;
  21         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  22
  23         remove (self);
  24 }
  25
  26 void W_Hagar_Touch (void)
  27 {
  28         PROJECTILE_TOUCH;
  29         self.use ();
  30 }
  31
  32 void W_Hagar_Touch2 (void)
  33 {
  34         PROJECTILE_TOUCH;
  35
  36         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  37                 self.use();
  38         } else {
  39                 self.cnt++;
  40                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  41                 self.angles = vectoangles (self.velocity);
  42                 self.owner = world;
  43                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  44         }
  45 }
  46
  47 void W_Hagar_Attack (void)
  48 {
  49         local entity missile;
  50
  51         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  52
  53         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  54
  55         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  56
  57         missile = spawn ();
  58         missile.owner = missile.realowner = self;
  59         missile.classname = "missile";
  60         missile.bot_dodge = TRUE;
  61         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  62         missile.touch = W_Hagar_Touch;
  63         missile.use = W_Hagar_Explode;
  64         missile.think = adaptor_think2use_hittype_splash;
  65         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  66         PROJECTILE_MAKETRIGGER(missile);
  67         missile.projectiledeathtype = WEP_HAGAR;
  68         setorigin (missile, w_shotorg);
  69         setsize(missile, '0 0 0', '0 0 0');
  70
  71         missile.movetype = MOVETYPE_FLY;
  72         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  73
  74         missile.angles = vectoangles (missile.velocity);
  75         missile.flags = FL_PROJECTILE;
  76
  77         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  78
  79         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  80 }
  81
  82 void W_Hagar_Attack2 (void)
  83 {
  84         local entity missile;
  85
  86         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  87
  88         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  89
  90         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  91
  92         missile = spawn ();
  93         missile.owner = missile.realowner = self;
  94         missile.classname = "missile";
  95         missile.bot_dodge = TRUE;
  96         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  97         missile.touch = W_Hagar_Touch2;
  98         missile.cnt = 0;
  99         missile.use = W_Hagar_Explode2;
 100         missile.think = adaptor_think2use_hittype_splash;
 101         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 102         PROJECTILE_MAKETRIGGER(missile);
 103         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 108         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 109
 110         missile.angles = vectoangles (missile.velocity);
 111         missile.flags = FL_PROJECTILE;
 112
 113         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 114
 115         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 116 }
 117
 118 .float hagarload_refire;
 119 void W_Hagar_Attack2_Load (void)
 120 {
 121         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 122         {
 123                 W_SwitchToOtherWeapon(self);
 124                 return;
 125         }
 126
 127         local entity missile, prevmissile, firstmissile;
 128         local float counter, shots, loaded;
 129         local float used_ammo, enough_ammo;
 130         local vector s;
 131         vector forward, right, up;
 132
 133         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_maxload;
 134
 135         // check if we have enough ammo for another rocket
 136         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 137         if(autocvar_g_balance_hagar_reload_ammo)
 138                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 139         else
 140                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 141
 142         if(self.BUTTON_ATCK2 && !loaded && enough_ammo)
 143         {
 144                 // we can attempt to load another rocket
 145                 if(self.hagarload_refire < time)
 146                 {
 147                         self.hagar_load += 1;
 148                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 149
 150                         self.hagarload_refire = time + autocvar_g_balance_hagar_secondary_refire;
 151                 }
 152         }
 153         else if(self.hagar_load && (!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && !autocvar_g_balance_hagar_secondary_load_canhold)))
 154         {
 155                 // time to release the rockets we've loaded
 156
 157                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 158
 159                 W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 160                 pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 161
 162                 forward = v_forward;
 163                 right = v_right;
 164                 up = v_up;
 165
 166                 shots = self.hagar_load;
 167                 missile = world;
 168                 while (counter < shots)
 169                 {
 170                         missile = spawn ();
 171                         missile.owner = missile.realowner = self;
 172                         missile.classname = "missile";
 173                         missile.bot_dodge = TRUE;
 174                         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 175
 176                         if(shots == 1) {
 177                                 missile.queuenext = missile;
 178                                 missile.queueprev = missile;
 179                         }
 180                         else if(counter == 0) { // first projectile, store in firstmissile for now
 181                                 firstmissile = missile;
 182                         }
 183                         else if(counter == shots - 1) { // last projectile, link up with first projectile
 184                                 prevmissile.queuenext = missile;
 185                                 firstmissile.queueprev = missile;
 186                                 missile.queuenext = firstmissile;
 187                                 missile.queueprev = prevmissile;
 188                         }
 189                         else { // else link up with previous projectile
 190                                 prevmissile.queuenext = missile;
 191                                 missile.queueprev = prevmissile;
 192                         }
 193                         prevmissile = missile;
 194
 195                         missile.touch = W_Hagar_Touch; // not bouncy
 196                         missile.use = W_Hagar_Explode2;
 197                         missile.think = adaptor_think2use_hittype_splash;
 198                         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 199                         PROJECTILE_MAKETRIGGER(missile);
 200                         missile.projectiledeathtype = WEP_HAGAR;
 201                         setorigin (missile, w_shotorg);
 202                         setsize(missile, '0 0 0', '0 0 0');
 203                         missile.movetype = MOVETYPE_FLY;
 204
 205                         s = '0 0 0';
 206                         if (counter == 0)
 207                                 s = '0 0 0';
 208                         else
 209                         {
 210                                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 211                                 s_y = v_forward_x;
 212                                 s_z = v_forward_y;
 213                         }
 214                         s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 215                         W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 216
 217                         missile.angles = vectoangles (missile.velocity);
 218                         missile.flags = FL_PROJECTILE;
 219
 220                         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 221
 222                         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 223
 224                         counter = counter + 1;
 225                 }
 226
 227                 self.hagar_load = 0;
 228         }
 229 }
 230
 231 void spawnfunc_weapon_hagar (void)
 232 {
 233         weapon_defaultspawnfunc(WEP_HAGAR);
 234 }
 235
 236 float w_hagar(float req)
 237 {
 238         float ammo_amount;
 239         if (req == WR_AIM)
 240                 if (random()>0.15)
 241                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 242                 else
 243                 {
 244                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 245                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 246                 }
 247         else if (req == WR_THINK)
 248         {
 249                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 250                         weapon_action(self.weapon, WR_RELOAD);
 251                 else if (self.BUTTON_ATCK && !self.hagar_load) // not while loading the secondary fire
 252                 {
 253                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 254                         {
 255                                 W_Hagar_Attack();
 256                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 257                         }
 258                 }
 259                 else if(autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary)
 260                         W_Hagar_Attack2_Load(); // must run each frame
 261                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 262                 {
 263                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 264                         {
 265                                 W_Hagar_Attack2();
 266                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 267                         }
 268                 }
 269         }
 270         else if (req == WR_PRECACHE)
 271         {
 272                 precache_model ("models/weapons/g_hagar.md3");
 273                 precache_model ("models/weapons/v_hagar.md3");
 274                 precache_model ("models/weapons/h_hagar.iqm");
 275                 precache_sound ("weapons/hagar_fire.wav");
 276                 precache_sound ("weapons/hagar_load.wav");
 277                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 278         }
 279         else if (req == WR_SETUP)
 280         {
 281                 weapon_setup(WEP_HAGAR);
 282                 self.current_ammo = ammo_rockets;
 283
 284                 self.hagar_load = 0;
 285         }
 286         else if (req == WR_CHECKAMMO1)
 287         {
 288                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 289                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 290                 return ammo_amount;
 291         }
 292         else if (req == WR_CHECKAMMO2)
 293         {
 294                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 295                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 296                 return ammo_amount;
 297         }
 298         else if (req == WR_RELOAD)
 299         {
 300                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 301         }
 302         return TRUE;
 303 };
 304 #endif
 305 #ifdef CSQC
 306 float w_hagar(float req)
 307 {
 308         if(req == WR_IMPACTEFFECT)
 309         {
 310                 vector org2;
 311                 org2 = w_org + w_backoff * 6;
 312                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 313                 if(!w_issilent)
 314                 {
 315                         if (w_random<0.15)
 316                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 317                         else if (w_random<0.7)
 318                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 319                         else
 320                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 321                 }
 322         }
 323         else if(req == WR_PRECACHE)
 324         {
 325                 precache_sound("weapons/hagexp1.wav");
 326                 precache_sound("weapons/hagexp2.wav");
 327                 precache_sound("weapons/hagexp3.wav");
 328         }
 329         else if (req == WR_SUICIDEMESSAGE)
 330                 w_deathtypestring = _("%s played with tiny rockets");
 331         else if (req == WR_KILLMESSAGE)
 332         {
 333                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 334                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 335                 else // unchecked: SPLASH, SECONDARY
 336                         w_deathtypestring = _("%s was pummeled by %s");
 337         }
 338         return TRUE;
 339 }
 340 #endif
 341 #endif