qcsrc/server/w_hlac.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HLAC, w_hlac, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hlac", "hlac", _("Heavy Laser Assault Cannon"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_HLAC_Touch (void)
   7 {
   8         PROJECTILE_TOUCH;
   9
  10         self.event_damage = SUB_Null;
  11
  12         if(self.projectiledeathtype & HITTYPE_SECONDARY)
  13                 RadiusDamage (self, self.owner, autocvar_g_balance_hlac_secondary_damage, autocvar_g_balance_hlac_secondary_edgedamage, autocvar_g_balance_hlac_secondary_radius, world, autocvar_g_balance_hlac_secondary_force, self.projectiledeathtype, other);
  14         else
  15                 RadiusDamage (self, self.owner, autocvar_g_balance_hlac_primary_damage, autocvar_g_balance_hlac_primary_edgedamage, autocvar_g_balance_hlac_primary_radius, world, autocvar_g_balance_hlac_primary_force, self.projectiledeathtype, other);
  16
  17         remove (self);
  18 }
  19
  20 void W_HLAC_Attack (void)
  21 {
  22         local entity missile;
  23     float spread;
  24
  25         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_reload_ammo);
  26
  27     spread = autocvar_g_balance_hlac_primary_spread_min + (autocvar_g_balance_hlac_primary_spread_add * self.misc_bulletcounter);
  28     spread = min(spread,autocvar_g_balance_hlac_primary_spread_max);
  29     if(self.crouch)
  30         spread = spread * autocvar_g_balance_hlac_primary_spread_crouchmod;
  31
  32         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON, autocvar_g_balance_hlac_primary_damage);
  33         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  34         if (!g_norecoil)
  35         {
  36                 self.punchangle_x = random () - 0.5;
  37                 self.punchangle_y = random () - 0.5;
  38         }
  39
  40         missile = spawn ();
  41         missile.owner = self;
  42         missile.classname = "hlacbolt";
  43         missile.bot_dodge = TRUE;
  44
  45     missile.bot_dodgerating = autocvar_g_balance_hlac_primary_damage;
  46
  47         missile.movetype = MOVETYPE_FLY;
  48         PROJECTILE_MAKETRIGGER(missile);
  49
  50         setorigin (missile, w_shotorg);
  51         setsize(missile, '0 0 0', '0 0 0');
  52
  53         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_primary_speed, spread);
  54         //missile.angles = vectoangles (missile.velocity); // csqc
  55
  56         missile.touch = W_HLAC_Touch;
  57         missile.think = SUB_Remove;
  58
  59     missile.nextthink = time + autocvar_g_balance_hlac_primary_lifetime;
  60
  61         missile.flags = FL_PROJECTILE;
  62         missile.projectiledeathtype = WEP_HLAC;
  63
  64         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
  65
  66         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  67 }
  68
  69 void W_HLAC_Attack2f (void)
  70 {
  71         local entity missile;
  72     float spread;
  73
  74     spread = autocvar_g_balance_hlac_secondary_spread;
  75
  76
  77     if(self.crouch)
  78         spread = spread * autocvar_g_balance_hlac_secondary_spread_crouchmod;
  79
  80         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON, autocvar_g_balance_hlac_secondary_damage);
  81         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  82
  83         missile = spawn ();
  84         missile.owner = self;
  85         missile.classname = "hlacbolt";
  86         missile.bot_dodge = TRUE;
  87
  88     missile.bot_dodgerating = autocvar_g_balance_hlac_secondary_damage;
  89
  90         missile.movetype = MOVETYPE_FLY;
  91         PROJECTILE_MAKETRIGGER(missile);
  92
  93         setorigin (missile, w_shotorg);
  94         setsize(missile, '0 0 0', '0 0 0');
  95
  96         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_secondary_speed, spread);
  97         //missile.angles = vectoangles (missile.velocity); // csqc
  98
  99         missile.touch = W_HLAC_Touch;
 100         missile.think = SUB_Remove;
 101
 102     missile.nextthink = time + autocvar_g_balance_hlac_secondary_lifetime;
 103
 104         missile.flags = FL_PROJECTILE;
 105         missile.projectiledeathtype = WEP_HLAC | HITTYPE_SECONDARY;
 106
 107         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
 108
 109         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 110 }
 111
 112 void W_HLAC_Attack2 (void)
 113 {
 114     float i;
 115
 116         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_hlac_secondary_ammo, autocvar_g_balance_hlac_reload_ammo);
 117
 118     for(i=autocvar_g_balance_hlac_secondary_shots;i>0;--i)
 119         W_HLAC_Attack2f();
 120
 121         if (!g_norecoil)
 122         {
 123                 self.punchangle_x = random () - 0.5;
 124                 self.punchangle_y = random () - 0.5;
 125         }
 126 }
 127
 128 // weapon frames
 129 void HLAC_fire1_02()
 130 {
 131         if(self.weapon != self.switchweapon) // abort immediately if switching
 132         {
 133                 w_ready();
 134                 return;
 135         }
 136
 137         if (self.BUTTON_ATCK)
 138         {
 139                 if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 140                 {
 141                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 142                         w_ready();
 143                         return;
 144                 }
 145
 146                 ATTACK_FINISHED(self) = time + autocvar_g_balance_hlac_primary_refire * W_WeaponRateFactor();
 147                 W_HLAC_Attack();
 148                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
 149         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 150         }
 151         else
 152         {
 153                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_animtime, w_ready);
 154         }
 155 };
 156
 157 void spawnfunc_weapon_hlac (void)
 158 {
 159         weapon_defaultspawnfunc(WEP_HLAC);
 160 }
 161
 162 float w_hlac(float req)
 163 {
 164         float ammo_amount;
 165         if (req == WR_AIM)
 166         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hlac_primary_speed, 0, autocvar_g_balance_hlac_primary_lifetime, FALSE);
 167         else if (req == WR_THINK)
 168         {
 169                 if(autocvar_g_balance_hlac_reload_ammo && self.clip_load < min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo)) // forced reload
 170                         weapon_action(self.weapon, WR_RELOAD);
 171                 else if (self.BUTTON_ATCK)
 172                 {
 173                         if (weapon_prepareattack(0, autocvar_g_balance_hlac_primary_refire))
 174                         {
 175                                 self.misc_bulletcounter = 0;
 176                                 W_HLAC_Attack();
 177                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 178                         }
 179                 }
 180
 181                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hlac_secondary)
 182                 {
 183                         if (weapon_prepareattack(1, autocvar_g_balance_hlac_secondary_refire))
 184                         {
 185                                 W_HLAC_Attack2();
 186                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hlac_secondary_animtime, w_ready);
 187                         }
 188                 }
 189         }
 190         else if (req == WR_PRECACHE)
 191         {
 192         precache_model ("models/weapons/g_hlac.md3");
 193                 precache_model ("models/weapons/v_hlac.md3");
 194                 precache_model ("models/weapons/h_hlac.iqm");
 195                 precache_sound ("weapons/lasergun_fire.wav");
 196                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 197
 198         }
 199         else if (req == WR_SETUP)
 200         {
 201                 weapon_setup(WEP_HLAC);
 202                 self.current_ammo = ammo_cells;
 203         }
 204         else if (req == WR_CHECKAMMO1)
 205         {
 206                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_primary_ammo;
 207                 ammo_amount += self.weapon_load[WEP_HLAC] >= autocvar_g_balance_hlac_primary_ammo;
 208                 return ammo_amount;
 209         }
 210         else if (req == WR_CHECKAMMO2)
 211         {
 212                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_secondary_ammo;
 213                 ammo_amount += self.weapon_load[WEP_HLAC] >= autocvar_g_balance_hlac_secondary_ammo;
 214                 return ammo_amount;
 215         }
 216         else if (req == WR_RELOAD)
 217         {
 218                 W_Reload(min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo), autocvar_g_balance_hlac_reload_ammo, autocvar_g_balance_hlac_reload_time, "weapons/reload.wav");
 219         }
 220         return TRUE;
 221 };
 222 #endif
 223 #ifdef CSQC
 224 float w_hlac(float req)
 225 {
 226         if(req == WR_IMPACTEFFECT)
 227         {
 228                 vector org2;
 229                 org2 = w_org + w_backoff * 6;
 230                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 231                 if(!w_issilent)
 232                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 233         }
 234         else if(req == WR_PRECACHE)
 235         {
 236                 precache_sound("weapons/laserimpact.wav");
 237         }
 238         else if (req == WR_SUICIDEMESSAGE)
 239                 w_deathtypestring = _("%s should have used a smaller gun");
 240         else if (req == WR_KILLMESSAGE)
 241                 w_deathtypestring = _("%s was cut down by %s");
 242         return TRUE;
 243 }
 244 #endif
 245 #endif