qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick (entity to)
  15 {
  16         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         newmine.realowner = self.realowner;
  29         setsize(newmine, '-4 -4 -4', '4 4 4');
  30         setorigin(newmine, self.origin);
  31         setmodel(newmine, "models/mine.md3");
  32         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  33
  34         newmine.oldvelocity = self.velocity;
  35
  36         newmine.takedamage = self.takedamage;
  37         newmine.damageforcescale = self.damageforcescale;
  38         newmine.health = self.health;
  39         newmine.event_damage = self.event_damage;
  40         newmine.spawnshieldtime = self.spawnshieldtime;
  41         newmine.damagedbycontents = TRUE;
  42
  43         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  44         newmine.projectiledeathtype = self.projectiledeathtype;
  45
  46         newmine.mine_time = self.mine_time;
  47
  48         newmine.touch = SUB_Null;
  49         newmine.think = W_Mine_Think;
  50         newmine.nextthink = time;
  51         newmine.cnt = self.cnt;
  52         newmine.flags = self.flags;
  53
  54         remove(self);
  55         self = newmine;
  56
  57         if(to)
  58                 SetMovetypeFollow(self, to);
  59 }
  60
  61 void W_Mine_Explode ()
  62 {
  63         if(other.takedamage == DAMAGE_AIM)
  64                 if(other.classname == "player")
  65                         if(IsDifferentTeam(self.realowner, other))
  66                                 if(other.deadflag == DEAD_NO)
  67                                         if(IsFlying(other))
  68                                                 AnnounceTo(self.realowner, "airshot");
  69
  70         self.event_damage = SUB_Null;
  71         self.takedamage = DAMAGE_NO;
  72
  73         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  74
  75         if (self.realowner.weapon == WEP_MINE_LAYER)
  76         {
  77                 entity oldself;
  78                 oldself = self;
  79                 self = self.realowner;
  80                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  81                 {
  82                         self.cnt = WEP_MINE_LAYER;
  83                         ATTACK_FINISHED(self) = time;
  84                         self.switchweapon = w_getbestweapon(self);
  85                 }
  86                 self = oldself;
  87         }
  88         self.realowner.minelayer_mines -= 1;
  89         remove (self);
  90 }
  91
  92 void W_Mine_DoRemoteExplode ()
  93 {
  94         self.event_damage = SUB_Null;
  95         self.takedamage = DAMAGE_NO;
  96
  97         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
  98                 self.velocity = self.oldvelocity;
  99
 100         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 101
 102         if (self.realowner.weapon == WEP_MINE_LAYER)
 103         {
 104                 entity oldself;
 105                 oldself = self;
 106                 self = self.realowner;
 107                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 108                 {
 109                         self.cnt = WEP_MINE_LAYER;
 110                         ATTACK_FINISHED(self) = time;
 111                         self.switchweapon = w_getbestweapon(self);
 112                 }
 113                 self = oldself;
 114         }
 115         self.realowner.minelayer_mines -= 1;
 116         remove (self);
 117 }
 118
 119 void W_Mine_RemoteExplode ()
 120 {
 121         if(self.realowner.deadflag == DEAD_NO)
 122                 if((self.spawnshieldtime >= 0)
 123                         ? (time >= self.spawnshieldtime) // timer
 124                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 125                 )
 126                 {
 127                         W_Mine_DoRemoteExplode();
 128                 }
 129 }
 130
 131 void W_Mine_ProximityExplode ()
 132 {
 133         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 134         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 135         {
 136                 entity head;
 137                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 138                 while(head)
 139                 {
 140                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 141                                 return;
 142                         head = head.chain;
 143                 }
 144         }
 145
 146         self.mine_time = 0;
 147         W_Mine_Explode();
 148 }
 149
 150 float W_Mine_Count(entity e)
 151 {
 152         float minecount = 0;
 153         entity mine;
 154         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 155                 minecount += 1;
 156
 157         return minecount;
 158 }
 159
 160 void W_Mine_Think (void)
 161 {
 162         entity head;
 163
 164         self.nextthink = time;
 165
 166         if(self.movetype == MOVETYPE_FOLLOW)
 167         {
 168                 if(LostMovetypeFollow(self))
 169                 {
 170                         UnsetMovetypeFollow(self);
 171                         self.movetype = MOVETYPE_NONE;
 172                 }
 173         }
 174
 175         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 176         // TODO: replace this mine_trigger.wav sound with a real countdown
 177         if ((time > self.cnt) && (!self.mine_time))
 178         {
 179                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 180                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 181                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 182                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 183         }
 184
 185         // a player's mines shall explode if he disconnects or dies
 186         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 187         if(self.realowner.classname != "player" || self.realowner.deadflag != DEAD_NO)
 188         {
 189                 other = world;
 190                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 191                 W_Mine_Explode();
 192                 return;
 193         }
 194
 195         // set the mine for detonation when a foe gets close enough
 196         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 197         while(head)
 198         {
 199                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 200                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 201                 if(!self.mine_time)
 202                 {
 203                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 204                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 205                 }
 206                 head = head.chain;
 207         }
 208
 209         // explode if it's time to
 210         if(self.mine_time && time >= self.mine_time)
 211         {
 212                 W_Mine_ProximityExplode();
 213                 return;
 214         }
 215
 216         // remote detonation
 217         if (self.realowner.weapon == WEP_MINE_LAYER)
 218         if (self.realowner.deadflag == DEAD_NO)
 219         if (self.minelayer_detonate)
 220                 W_Mine_RemoteExplode();
 221 }
 222
 223 void W_Mine_Touch (void)
 224 {
 225         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 226                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 227
 228         PROJECTILE_TOUCH;
 229
 230         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 231         {
 232                 // hit a player
 233                 // don't stick
 234         }
 235         else
 236         {
 237                 W_Mine_Stick(other);
 238         }
 239 }
 240
 241 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245
 246         float is_from_enemy = (inflictor.realowner != self.realowner);
 247
 248         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 249                 return; // g_projectiles_damage says to halt
 250
 251         self.health = self.health - damage;
 252         self.angles = vectoangles(self.velocity);
 253
 254         if (self.health <= 0)
 255                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 256 }
 257
 258 void W_Mine_Attack (void)
 259 {
 260         entity mine;
 261         entity flash;
 262
 263         // scan how many mines we placed, and return if we reached our limit
 264         if(autocvar_g_balance_minelayer_limit)
 265         {
 266
 267                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 268                 {
 269                         // the refire delay keeps this message from being spammed
 270                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 271                         play2(self, "weapons/unavailable.wav");
 272                         return;
 273                 }
 274         }
 275
 276         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 277
 278         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, autocvar_g_balance_minelayer_damage);
 279         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 280
 281         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 282         mine.owner = mine.realowner = self;
 283         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 284                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 285         else
 286                 mine.spawnshieldtime = -1;
 287         mine.classname = "mine";
 288         mine.bot_dodge = TRUE;
 289         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 290
 291         mine.takedamage = DAMAGE_YES;
 292         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 293         mine.health = autocvar_g_balance_minelayer_health;
 294         mine.event_damage = W_Mine_Damage;
 295         mine.damagedbycontents = TRUE;
 296
 297         mine.movetype = MOVETYPE_TOSS;
 298         PROJECTILE_MAKETRIGGER(mine);
 299         mine.projectiledeathtype = WEP_MINE_LAYER;
 300         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 301
 302         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 303         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 304         mine.angles = vectoangles (mine.velocity);
 305
 306         mine.touch = W_Mine_Touch;
 307         mine.think = W_Mine_Think;
 308         mine.nextthink = time;
 309         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 310         mine.flags = FL_PROJECTILE;
 311
 312         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 313
 314         // muzzle flash for 1st person view
 315         flash = spawn ();
 316         setmodel (flash, "models/flash.md3"); // precision set below
 317         SUB_SetFade (flash, time, 0.1);
 318         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 319         W_AttachToShotorg(flash, '5 0 0');
 320
 321         // common properties
 322
 323         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 324
 325         self.minelayer_mines = W_Mine_Count(self);
 326 }
 327
 328 float W_PlacedMines(float detonate)
 329 {
 330         entity mine;
 331         float minfound = 0;
 332
 333         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 334         {
 335                 if(detonate)
 336                 {
 337                         if(!mine.minelayer_detonate)
 338                         {
 339                                 mine.minelayer_detonate = TRUE;
 340                                 minfound = 1;
 341                         }
 342                 }
 343                 else
 344                         minfound = 1;
 345         }
 346         return minfound;
 347 }
 348
 349 float w_minelayer(float req)
 350 {
 351         entity mine;
 352         float ammo_amount;
 353
 354         if (req == WR_AIM)
 355         {
 356                 // aim and decide to fire if appropriate
 357                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 358                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 359                 {
 360                         // decide whether to detonate mines
 361                         entity targetlist, targ;
 362                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 363                         float selfdamage, teamdamage, enemydamage;
 364                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 365                         coredamage = autocvar_g_balance_minelayer_damage;
 366                         edgeradius = autocvar_g_balance_minelayer_radius;
 367                         recipricoledgeradius = 1 / edgeradius;
 368                         selfdamage = 0;
 369                         teamdamage = 0;
 370                         enemydamage = 0;
 371                         targetlist = findchainfloat(bot_attack, TRUE);
 372                         mine = find(world, classname, "mine");
 373                         while (mine)
 374                         {
 375                                 if (mine.realowner != self)
 376                                 {
 377                                         mine = find(mine, classname, "mine");
 378                                         continue;
 379                                 }
 380                                 targ = targetlist;
 381                                 while (targ)
 382                                 {
 383                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 384                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 385                                         // count potential damage according to type of target
 386                                         if (targ == self)
 387                                                 selfdamage = selfdamage + d;
 388                                         else if (targ.team == self.team && teamplay)
 389                                                 teamdamage = teamdamage + d;
 390                                         else if (bot_shouldattack(targ))
 391                                                 enemydamage = enemydamage + d;
 392                                         targ = targ.chain;
 393                                 }
 394                                 mine = find(mine, classname, "mine");
 395                         }
 396                         float desirabledamage;
 397                         desirabledamage = enemydamage;
 398                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 399                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 400                         if (teamplay && self.team)
 401                                 desirabledamage = desirabledamage - teamdamage;
 402
 403                         mine = find(world, classname, "mine");
 404                         while (mine)
 405                         {
 406                                 if (mine.realowner != self)
 407                                 {
 408                                         mine = find(mine, classname, "mine");
 409                                         continue;
 410                                 }
 411                                 makevectors(mine.v_angle);
 412                                 targ = targetlist;
 413                                 if (skill > 9) // normal players only do this for the target they are tracking
 414                                 {
 415                                         targ = targetlist;
 416                                         while (targ)
 417                                         {
 418                                                 if (
 419                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 420                                                         && desirabledamage > 0.1*coredamage
 421                                                 )self.BUTTON_ATCK2 = TRUE;
 422                                                 targ = targ.chain;
 423                                         }
 424                                 }else{
 425                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 426                                         //As the distance gets larger, a correct detonation gets near imposible
 427                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 428                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 429                                                 if(self.enemy.classname == "player")
 430                                                         if(desirabledamage >= 0.1*coredamage)
 431                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 432                                                                         self.BUTTON_ATCK2 = TRUE;
 433                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 434                                 }
 435
 436                                 mine = find(mine, classname, "mine");
 437                         }
 438                         // if we would be doing at X percent of the core damage, detonate it
 439                         // but don't fire a new shot at the same time!
 440                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 441                                 self.BUTTON_ATCK2 = TRUE;
 442                         if ((skill > 6.5) && (selfdamage > self.health))
 443                                 self.BUTTON_ATCK2 = FALSE;
 444                         //if(self.BUTTON_ATCK2 == TRUE)
 445                         //      dprint(ftos(desirabledamage),"\n");
 446                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 447                 }
 448         }
 449         else if (req == WR_THINK)
 450         {
 451                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 452                 {
 453                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 454                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 455                                 weapon_action(self.weapon, WR_RELOAD);
 456                 }
 457                 else if (self.BUTTON_ATCK)
 458                 {
 459                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 460                         {
 461                                 W_Mine_Attack();
 462                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 463                         }
 464                 }
 465
 466                 if (self.BUTTON_ATCK2)
 467                 {
 468                         if(W_PlacedMines(TRUE))
 469                                 sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 470                 }
 471         }
 472         else if (req == WR_PRECACHE)
 473         {
 474                 precache_model ("models/flash.md3");
 475                 precache_model ("models/mine.md3");
 476                 precache_model ("models/weapons/g_minelayer.md3");
 477                 precache_model ("models/weapons/v_minelayer.md3");
 478                 precache_model ("models/weapons/h_minelayer.iqm");
 479                 precache_sound ("weapons/mine_det.wav");
 480                 precache_sound ("weapons/mine_fire.wav");
 481                 precache_sound ("weapons/mine_stick.wav");
 482                 precache_sound ("weapons/mine_trigger.wav");
 483                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 484         }
 485         else if (req == WR_SETUP)
 486         {
 487                 weapon_setup(WEP_MINE_LAYER);
 488                 self.current_ammo = ammo_rockets;
 489         }
 490         else if (req == WR_CHECKAMMO1)
 491         {
 492                 // don't switch while placing a mine
 493                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 494                 {
 495                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 496                         ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= autocvar_g_balance_minelayer_ammo;
 497                         return ammo_amount;
 498                 }
 499         }
 500         else if (req == WR_CHECKAMMO2)
 501         {
 502                 if (W_PlacedMines(FALSE))
 503                         return TRUE;
 504                 else
 505                         return FALSE;
 506         }
 507         else if (req == WR_RELOAD)
 508         {
 509                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 510         }
 511         return TRUE;
 512 }
 513 #endif
 514 #ifdef CSQC
 515 float w_minelayer(float req)
 516 {
 517         if(req == WR_IMPACTEFFECT)
 518         {
 519                 vector org2;
 520                 org2 = w_org + w_backoff * 12;
 521                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 522                 if(!w_issilent)
 523                         sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 524         }
 525         else if(req == WR_PRECACHE)
 526         {
 527                 precache_sound("weapons/mine_exp.wav");
 528         }
 529         else if (req == WR_SUICIDEMESSAGE)
 530                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 531                         w_deathtypestring = _("%s blew themself up with their minelayer");
 532                 else
 533                         w_deathtypestring = _("%s forgot about their mine");
 534         else if (req == WR_KILLMESSAGE)
 535         {
 536                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 537                         w_deathtypestring = _("%s got too close to %s's mine");
 538                 else if(w_deathtype & HITTYPE_SPLASH)
 539                         w_deathtypestring = _("%s almost dodged %s's mine");
 540                 else
 541                         w_deathtypestring = _("%s stepped on %s's mine");
 542         }
 543         return TRUE;
 544 }
 545 #endif
 546 #endif