qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 .float minelayer_load;
  10
  11 void W_MineLayer_SetAmmoCounter()
  12 {
  13         // set clip_load to the weapon we have switched to, if the gun uses reloading
  14         if(!autocvar_g_balance_minelayer_reload_ammo)
  15                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  16         else
  17         {
  18                 self.clip_load = self.minelayer_load;
  19                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  20         }
  21 }
  22
  23 void W_MineLayer_ReloadedAndReady()
  24 {
  25         float t;
  26
  27         // now do the ammo transfer
  28         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  29         while(self.clip_load < autocvar_g_balance_minelayer_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  30         {
  31                 self.clip_load += 1;
  32                 self.ammo_rockets -= 1;
  33         }
  34         self.minelayer_load = self.clip_load;
  35
  36         t = ATTACK_FINISHED(self) - autocvar_g_balance_minelayer_reload_time - 1;
  37         ATTACK_FINISHED(self) = t;
  38         w_ready();
  39 }
  40
  41 void W_MineLayer_Reload()
  42 {
  43         // return if reloading is disabled for this weapon
  44         if(!autocvar_g_balance_minelayer_reload_ammo)
  45                 return;
  46
  47         if(!W_ReloadCheck(self.ammo_rockets))
  48                 return;
  49
  50         float t;
  51
  52         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  53
  54         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_minelayer_reload_time + 1;
  55         ATTACK_FINISHED(self) = t;
  56
  57         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_minelayer_reload_time, W_MineLayer_ReloadedAndReady);
  58
  59         self.old_clip_load = self.clip_load;
  60         self.clip_load = -1;
  61 }
  62
  63 void spawnfunc_weapon_minelayer (void)
  64 {
  65         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  66 }
  67
  68 void W_Mine_Stick ()
  69 {
  70         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  71
  72         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  73
  74         entity newmine;
  75         newmine = spawn();
  76         newmine.classname = self.classname;
  77
  78         newmine.bot_dodge = self.bot_dodge;
  79         newmine.bot_dodgerating = self.bot_dodgerating;
  80
  81         newmine.owner = self.owner;
  82         setsize(newmine, '-4 -4 -4', '4 4 4');
  83         setorigin(newmine, self.origin);
  84         setmodel(newmine, "models/mine.md3");
  85         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  86
  87         newmine.takedamage = self.takedamage;
  88         newmine.damageforcescale = self.damageforcescale;
  89         newmine.health = self.health;
  90         newmine.event_damage = self.event_damage;
  91         newmine.spawnshieldtime = self.spawnshieldtime;
  92
  93         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  94         newmine.projectiledeathtype = self.projectiledeathtype;
  95
  96         newmine.mine_time = self.mine_time;
  97
  98         newmine.touch = SUB_Null;
  99         newmine.think = W_Mine_Think;
 100         newmine.nextthink = time;
 101         newmine.cnt = self.cnt;
 102         newmine.flags = self.flags;
 103
 104         remove(self);
 105         self = newmine;
 106 }
 107
 108 void W_Mine_Explode ()
 109 {
 110         if(other.takedamage == DAMAGE_AIM)
 111                 if(other.classname == "player")
 112                         if(IsDifferentTeam(self.owner, other))
 113                                 if(IsFlying(other))
 114                                         AnnounceTo(self.owner, "airshot");
 115
 116         self.event_damage = SUB_Null;
 117         self.takedamage = DAMAGE_NO;
 118
 119         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
 120
 121         if (self.owner.weapon == WEP_MINE_LAYER)
 122         {
 123                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 124                 {
 125                         self.owner.cnt = WEP_MINE_LAYER;
 126                         ATTACK_FINISHED(self.owner) = time;
 127                         self.owner.switchweapon = w_getbestweapon(self.owner);
 128                 }
 129         }
 130         remove (self);
 131 }
 132
 133 void W_Mine_DoRemoteExplode ()
 134 {
 135         self.event_damage = SUB_Null;
 136         self.takedamage = DAMAGE_NO;
 137
 138         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 139
 140         if (self.owner.weapon == WEP_MINE_LAYER)
 141         {
 142                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 143                 {
 144                         self.owner.cnt = WEP_MINE_LAYER;
 145                         ATTACK_FINISHED(self.owner) = time;
 146                         self.owner.switchweapon = w_getbestweapon(self.owner);
 147                 }
 148         }
 149         remove (self);
 150 }
 151
 152 void W_Mine_RemoteExplode ()
 153 {
 154         if(self.owner.deadflag == DEAD_NO)
 155                 if((self.spawnshieldtime >= 0)
 156                         ? (time >= self.spawnshieldtime) // timer
 157                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 158                 )
 159                 {
 160                         W_Mine_DoRemoteExplode();
 161                 }
 162 }
 163
 164 void W_Mine_ProximityExplode ()
 165 {
 166         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 167         if(autocvar_g_balance_minelayer_protection)
 168         {
 169                 entity head;
 170                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 171                 while(head)
 172                 {
 173                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 174                                 return;
 175                         head = head.chain;
 176                 }
 177         }
 178
 179         self.mine_time = 0;
 180         W_Mine_Explode();
 181 }
 182
 183 void W_Mine_Think (void)
 184 {
 185         entity head;
 186
 187         self.nextthink = time;
 188         if (time > self.cnt)
 189         {
 190                 other = world;
 191                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 192                 W_Mine_Explode();
 193                 return;
 194         }
 195
 196         // a player's mines shall explode if he disconnects or dies
 197         // TODO: Do this on team change too
 198         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 199         {
 200                 other = world;
 201                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 202                 W_Mine_Explode();
 203                 return;
 204         }
 205
 206         // set the mine for detonation when a foe gets close enough
 207         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 208         while(head)
 209         {
 210                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 211                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 212                 if(!self.mine_time)
 213                 {
 214                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 215                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 216                 }
 217                 head = head.chain;
 218         }
 219
 220         // explode if it's time to
 221         if(self.mine_time && time >= self.mine_time)
 222                 W_Mine_ProximityExplode();
 223
 224         // remote detonation
 225         if (self.owner.weapon == WEP_MINE_LAYER)
 226         if (self.owner.deadflag == DEAD_NO)
 227         if (self.minelayer_detonate)
 228                 W_Mine_RemoteExplode();
 229 }
 230
 231 void W_Mine_Touch (void)
 232 {
 233         PROJECTILE_TOUCH;
 234         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 235                 W_Mine_Stick();
 236         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 237                 self.velocity = '0 0 0';
 238 }
 239
 240 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 241 {
 242         if (self.health <= 0)
 243                 return;
 244         self.health = self.health - damage;
 245         self.angles = vectoangles(self.velocity);
 246         if (self.health <= 0)
 247                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 248 }
 249
 250 void W_Mine_Attack (void)
 251 {
 252         entity mine;
 253         entity flash;
 254
 255         // scan how many mines we placed, and return if we reached our limit
 256         if(autocvar_g_balance_minelayer_limit)
 257         {
 258                 self.minelayer_mines = 0;
 259                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 260                         self.minelayer_mines += 1;
 261
 262                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 263                 {
 264                         // the refire delay keeps this message from being spammed
 265                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 266                         play2(self, "weapons/unavailable.wav");
 267                         return;
 268                 }
 269         }
 270
 271         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 272         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 273
 274         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 275         mine.owner = self;
 276         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 277                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 278         else
 279                 mine.spawnshieldtime = -1;
 280         mine.classname = "mine";
 281         mine.bot_dodge = TRUE;
 282         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 283
 284         mine.takedamage = DAMAGE_YES;
 285         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 286         mine.health = autocvar_g_balance_minelayer_health;
 287         mine.event_damage = W_Mine_Damage;
 288
 289         mine.movetype = MOVETYPE_TOSS;
 290         PROJECTILE_MAKETRIGGER(mine);
 291         mine.projectiledeathtype = WEP_MINE_LAYER;
 292         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 293
 294         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 295         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 296         mine.angles = vectoangles (mine.velocity);
 297
 298         mine.touch = W_Mine_Touch;
 299         mine.think = W_Mine_Think;
 300         mine.nextthink = time;
 301         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 302         mine.flags = FL_PROJECTILE;
 303
 304         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 305
 306         // muzzle flash for 1st person view
 307         flash = spawn ();
 308         setmodel (flash, "models/flash.md3"); // precision set below
 309         SUB_SetFade (flash, time, 0.1);
 310         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 311         W_AttachToShotorg(flash, '5 0 0');
 312
 313         // common properties
 314
 315         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 316
 317         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 318         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 319         {
 320                 if(autocvar_g_balance_minelayer_reload_ammo)
 321                 {
 322                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 323                         self.minelayer_load = self.clip_load;
 324                 }
 325                 else
 326                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 327         }
 328 }
 329
 330 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 331
 332 float w_minelayer(float req)
 333 {
 334         entity mine;
 335         float minfound;
 336         if (req == WR_AIM)
 337         {
 338                 // aim and decide to fire if appropriate
 339                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 340                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 341                 {
 342                         // decide whether to detonate mines
 343                         entity targetlist, targ;
 344                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 345                         float selfdamage, teamdamage, enemydamage;
 346                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 347                         coredamage = autocvar_g_balance_minelayer_damage;
 348                         edgeradius = autocvar_g_balance_minelayer_radius;
 349                         recipricoledgeradius = 1 / edgeradius;
 350                         selfdamage = 0;
 351                         teamdamage = 0;
 352                         enemydamage = 0;
 353                         targetlist = findchainfloat(bot_attack, TRUE);
 354                         mine = find(world, classname, "mine");
 355                         while (mine)
 356                         {
 357                                 if (mine.owner != self)
 358                                 {
 359                                         mine = find(mine, classname, "mine");
 360                                         continue;
 361                                 }
 362                                 targ = targetlist;
 363                                 while (targ)
 364                                 {
 365                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 366                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 367                                         // count potential damage according to type of target
 368                                         if (targ == self)
 369                                                 selfdamage = selfdamage + d;
 370                                         else if (targ.team == self.team && teams_matter)
 371                                                 teamdamage = teamdamage + d;
 372                                         else if (bot_shouldattack(targ))
 373                                                 enemydamage = enemydamage + d;
 374                                         targ = targ.chain;
 375                                 }
 376                                 mine = find(mine, classname, "mine");
 377                         }
 378                         float desirabledamage;
 379                         desirabledamage = enemydamage;
 380                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 381                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 382                         if (teams_matter && self.team)
 383                                 desirabledamage = desirabledamage - teamdamage;
 384
 385                         mine = find(world, classname, "mine");
 386                         while (mine)
 387                         {
 388                                 if (mine.owner != self)
 389                                 {
 390                                         mine = find(mine, classname, "mine");
 391                                         continue;
 392                                 }
 393                                 makevectors(mine.v_angle);
 394                                 targ = targetlist;
 395                                 if (skill > 9) // normal players only do this for the target they are tracking
 396                                 {
 397                                         targ = targetlist;
 398                                         while (targ)
 399                                         {
 400                                                 if (
 401                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 402                                                         && desirabledamage > 0.1*coredamage
 403                                                 )self.BUTTON_ATCK2 = TRUE;
 404                                                 targ = targ.chain;
 405                                         }
 406                                 }else{
 407                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 408                                         //As the distance gets larger, a correct detonation gets near imposible
 409                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 410                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 411                                                 if(self.enemy.classname == "player")
 412                                                         if(desirabledamage >= 0.1*coredamage)
 413                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 414                                                                         self.BUTTON_ATCK2 = TRUE;
 415                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 416                                 }
 417
 418                                 mine = find(mine, classname, "mine");
 419                         }
 420                         // if we would be doing at X percent of the core damage, detonate it
 421                         // but don't fire a new shot at the same time!
 422                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 423                                 self.BUTTON_ATCK2 = TRUE;
 424                         if ((skill > 6.5) && (selfdamage > self.health))
 425                                 self.BUTTON_ATCK2 = FALSE;
 426                         //if(self.BUTTON_ATCK2 == TRUE)
 427                         //      dprint(ftos(desirabledamage),"\n");
 428                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 429                 }
 430         }
 431         else if (req == WR_THINK)
 432         {
 433                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 434                         W_MineLayer_Reload();
 435                 else if (self.BUTTON_ATCK)
 436                 {
 437                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 438                         {
 439                                 W_Mine_Attack();
 440                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 441                         }
 442                 }
 443
 444                 else if (self.BUTTON_ATCK2)
 445                 {
 446                         minfound = 0;
 447                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 448                         {
 449                                 if(!mine.minelayer_detonate)
 450                                 {
 451                                         mine.minelayer_detonate = TRUE;
 452                                         minfound = 1;
 453                                 }
 454                         }
 455                         if(minfound)
 456                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 457                 }
 458
 459         if(self.wish_reload)
 460         {
 461             if(self.switchweapon == self.weapon)
 462             {
 463                 if(self.weaponentity.state == WS_READY)
 464                 {
 465                     self.wish_reload = 0;
 466                     W_MineLayer_Reload();
 467                 }
 468             }
 469         }
 470         }
 471         else if (req == WR_PRECACHE)
 472         {
 473                 precache_model ("models/flash.md3");
 474                 precache_model ("models/mine.md3");
 475                 precache_model ("models/weapons/g_minelayer.md3");
 476                 precache_model ("models/weapons/v_minelayer.md3");
 477                 precache_model ("models/weapons/h_minelayer.iqm");
 478                 precache_sound ("weapons/mine_det.wav");
 479                 precache_sound ("weapons/mine_fire.wav");
 480                 precache_sound ("weapons/mine_stick.wav");
 481                 precache_sound ("weapons/mine_trigger.wav");
 482         }
 483         else if (req == WR_SETUP)
 484         {
 485                 weapon_setup(WEP_MINE_LAYER);
 486                 W_MineLayer_SetAmmoCounter();
 487         }
 488         else if (req == WR_CHECKAMMO1)
 489         {
 490                 // don't switch while placing a mine
 491                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 492                         && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 493                         return FALSE;
 494         }
 495         else if (req == WR_CHECKAMMO2)
 496         {
 497                 return FALSE;
 498         }
 499         else if (req == WR_RELOAD)
 500         {
 501                 W_MineLayer_Reload();
 502         }
 503         return TRUE;
 504 };
 505 #endif
 506 #ifdef CSQC
 507 float w_minelayer(float req)
 508 {
 509         if(req == WR_IMPACTEFFECT)
 510         {
 511                 vector org2;
 512                 org2 = w_org + w_backoff * 12;
 513                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 514                 if(!w_issilent)
 515                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 516         }
 517         else if(req == WR_PRECACHE)
 518         {
 519                 precache_sound("weapons/mine_exp.wav");
 520         }
 521         else if (req == WR_SUICIDEMESSAGE)
 522                 w_deathtypestring = "%s exploded";
 523         else if (req == WR_KILLMESSAGE)
 524         {
 525                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 526                         w_deathtypestring = "%s got too close to %s's mine";
 527                 else if(w_deathtype & HITTYPE_SPLASH)
 528                         w_deathtypestring = "%s almost dodged %s's mine";
 529                 else
 530                         w_deathtypestring = "%s stepped on %s's mine";
 531         }
 532         return TRUE;
 533 }
 534 #endif
 535 #endif