qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 .float minelayer_load;
  10
  11 void W_MineLayer_SetAmmoCounter()
  12 {
  13         // set clip_load to the weapon we have switched to, if the gun uses reloading
  14         if(!autocvar_g_balance_minelayer_reload_ammo)
  15                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  16         else
  17         {
  18                 self.clip_load = self.minelayer_load;
  19                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  20         }
  21 }
  22
  23 void W_MineLayer_ReloadedAndReady()
  24 {
  25         float t;
  26
  27         // now do the ammo transfer
  28         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  29         while(self.clip_load < autocvar_g_balance_minelayer_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  30         {
  31                 self.clip_load += 1;
  32                 self.ammo_rockets -= 1;
  33         }
  34         self.minelayer_load = self.clip_load;
  35
  36         t = ATTACK_FINISHED(self) - autocvar_g_balance_minelayer_reload_time - 1;
  37         ATTACK_FINISHED(self) = t;
  38         w_ready();
  39 }
  40
  41 void W_MineLayer_Reload()
  42 {
  43         // return if reloading is disabled for this weapon
  44         if(!autocvar_g_balance_minelayer_reload_ammo)
  45                 return;
  46
  47         if(!W_ReloadCheck(self.ammo_rockets))
  48                 return;
  49
  50         float t;
  51
  52         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  53
  54         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_minelayer_reload_time + 1;
  55         ATTACK_FINISHED(self) = t;
  56
  57         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_minelayer_reload_time, W_MineLayer_ReloadedAndReady);
  58
  59         self.old_clip_load = self.clip_load;
  60         self.clip_load = -1;
  61 }
  62
  63 void spawnfunc_weapon_minelayer (void)
  64 {
  65         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  66 }
  67
  68 void W_Mine_Stick ()
  69 {
  70         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  71
  72         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  73
  74         entity newmine;
  75         newmine = spawn();
  76         newmine.classname = self.classname;
  77
  78         newmine.bot_dodge = self.bot_dodge;
  79         newmine.bot_dodgerating = self.bot_dodgerating;
  80
  81         newmine.owner = self.owner;
  82         setsize(newmine, '-4 -4 -4', '4 4 4');
  83         setorigin(newmine, self.origin);
  84         setmodel(newmine, "models/mine.md3");
  85         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  86
  87         newmine.takedamage = self.takedamage;
  88         newmine.damageforcescale = self.damageforcescale;
  89         newmine.health = self.health;
  90         newmine.event_damage = self.event_damage;
  91         newmine.spawnshieldtime = self.spawnshieldtime;
  92
  93         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  94         newmine.projectiledeathtype = self.projectiledeathtype;
  95
  96         newmine.mine_time = self.mine_time;
  97
  98         newmine.touch = SUB_Null;
  99         newmine.think = W_Mine_Think;
 100         newmine.nextthink = time;
 101         newmine.cnt = self.cnt;
 102         newmine.flags = self.flags;
 103
 104         remove(self);
 105         self = newmine;
 106 }
 107
 108 void W_Mine_Explode ()
 109 {
 110         if(other.takedamage == DAMAGE_AIM)
 111                 if(other.classname == "player")
 112                         if(IsDifferentTeam(self.owner, other))
 113                                 if(IsFlying(other))
 114                                         AnnounceTo(self.owner, "airshot");
 115
 116         self.event_damage = SUB_Null;
 117         self.takedamage = DAMAGE_NO;
 118
 119         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
 120
 121         if (self.owner.weapon == WEP_MINE_LAYER)
 122         {
 123                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 124                 {
 125                         self.owner.cnt = WEP_MINE_LAYER;
 126                         ATTACK_FINISHED(self.owner) = time;
 127                         self.owner.switchweapon = w_getbestweapon(self.owner);
 128                 }
 129         }
 130         remove (self);
 131 }
 132
 133 void W_Mine_DoRemoteExplode ()
 134 {
 135         self.event_damage = SUB_Null;
 136         self.takedamage = DAMAGE_NO;
 137
 138         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 139
 140         if (self.owner.weapon == WEP_MINE_LAYER)
 141         {
 142                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 143                 {
 144                         self.owner.cnt = WEP_MINE_LAYER;
 145                         ATTACK_FINISHED(self.owner) = time;
 146                         self.owner.switchweapon = w_getbestweapon(self.owner);
 147                 }
 148         }
 149         remove (self);
 150 }
 151
 152 void W_Mine_RemoteExplode ()
 153 {
 154         if(self.owner.deadflag == DEAD_NO)
 155                 if((self.spawnshieldtime >= 0)
 156                         ? (time >= self.spawnshieldtime) // timer
 157                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 158                 )
 159                 {
 160                         W_Mine_DoRemoteExplode();
 161                 }
 162 }
 163
 164 void W_Mine_ProximityExplode ()
 165 {
 166         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 167         if(autocvar_g_balance_minelayer_protection)
 168         {
 169                 entity head;
 170                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 171                 while(head)
 172                 {
 173                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 174                                 return;
 175                         head = head.chain;
 176                 }
 177         }
 178
 179         self.mine_time = 0;
 180         W_Mine_Explode();
 181 }
 182
 183 void W_Mine_Think (void)
 184 {
 185         entity head;
 186
 187         self.nextthink = time;
 188         if (time > self.cnt)
 189         {
 190                 other = world;
 191                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 192                 W_Mine_Explode();
 193                 return;
 194         }
 195
 196         // a player's mines shall explode if he disconnects or dies
 197         // TODO: Do this on team change too
 198         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 199         {
 200                 other = world;
 201                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 202                 W_Mine_Explode();
 203                 return;
 204         }
 205
 206         // set the mine for detonation when a foe gets close enough
 207         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 208         while(head)
 209         {
 210                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 211                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 212                 if(!self.mine_time)
 213                 {
 214                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 215                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 216                 }
 217                 head = head.chain;
 218         }
 219
 220         // explode if it's time to
 221         if(self.mine_time && time >= self.mine_time)
 222                 W_Mine_ProximityExplode();
 223
 224         // remote detonation
 225         if (self.owner.weapon == WEP_MINE_LAYER)
 226         if (self.owner.deadflag == DEAD_NO)
 227         if (self.minelayer_detonate)
 228                 W_Mine_RemoteExplode();
 229 }
 230
 231 void W_Mine_Touch (void)
 232 {
 233         PROJECTILE_TOUCH;
 234         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 235                 W_Mine_Stick();
 236         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 237                 self.velocity = '0 0 0';
 238 }
 239
 240 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 241 {
 242         if (self.health <= 0)
 243                 return;
 244         self.health = self.health - damage;
 245         self.angles = vectoangles(self.velocity);
 246         if (self.health <= 0)
 247                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 248 }
 249
 250 void W_Mine_Attack (void)
 251 {
 252         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load <= 0)
 253                 return; // reloading, so we are done
 254
 255         entity mine;
 256         entity flash;
 257
 258         // scan how many mines we placed, and return if we reached our limit
 259         if(autocvar_g_balance_minelayer_limit)
 260         {
 261                 self.minelayer_mines = 0;
 262                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 263                         self.minelayer_mines += 1;
 264
 265                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 266                 {
 267                         // the refire delay keeps this message from being spammed
 268                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 269                         play2(self, "weapons/unavailable.wav");
 270                         return;
 271                 }
 272         }
 273
 274         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 275         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 276
 277         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 278         mine.owner = self;
 279         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 280                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 281         else
 282                 mine.spawnshieldtime = -1;
 283         mine.classname = "mine";
 284         mine.bot_dodge = TRUE;
 285         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 286
 287         mine.takedamage = DAMAGE_YES;
 288         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 289         mine.health = autocvar_g_balance_minelayer_health;
 290         mine.event_damage = W_Mine_Damage;
 291
 292         mine.movetype = MOVETYPE_TOSS;
 293         PROJECTILE_MAKETRIGGER(mine);
 294         mine.projectiledeathtype = WEP_MINE_LAYER;
 295         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 296
 297         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 298         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 299         mine.angles = vectoangles (mine.velocity);
 300
 301         mine.touch = W_Mine_Touch;
 302         mine.think = W_Mine_Think;
 303         mine.nextthink = time;
 304         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 305         mine.flags = FL_PROJECTILE;
 306
 307         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 308
 309         // muzzle flash for 1st person view
 310         flash = spawn ();
 311         setmodel (flash, "models/flash.md3"); // precision set below
 312         SUB_SetFade (flash, time, 0.1);
 313         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 314         W_AttachToShotorg(flash, '5 0 0');
 315
 316         // common properties
 317
 318         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 319
 320         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 321         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 322         {
 323                 if(autocvar_g_balance_minelayer_reload_ammo)
 324                 {
 325                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 326                         self.minelayer_load = self.clip_load;
 327                 }
 328                 else
 329                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 330         }
 331 }
 332
 333 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 334
 335 float w_minelayer(float req)
 336 {
 337         entity mine;
 338         float minfound;
 339         if (req == WR_AIM)
 340         {
 341                 // aim and decide to fire if appropriate
 342                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 343                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 344                 {
 345                         // decide whether to detonate mines
 346                         entity targetlist, targ;
 347                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 348                         float selfdamage, teamdamage, enemydamage;
 349                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 350                         coredamage = autocvar_g_balance_minelayer_damage;
 351                         edgeradius = autocvar_g_balance_minelayer_radius;
 352                         recipricoledgeradius = 1 / edgeradius;
 353                         selfdamage = 0;
 354                         teamdamage = 0;
 355                         enemydamage = 0;
 356                         targetlist = findchainfloat(bot_attack, TRUE);
 357                         mine = find(world, classname, "mine");
 358                         while (mine)
 359                         {
 360                                 if (mine.owner != self)
 361                                 {
 362                                         mine = find(mine, classname, "mine");
 363                                         continue;
 364                                 }
 365                                 targ = targetlist;
 366                                 while (targ)
 367                                 {
 368                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 369                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 370                                         // count potential damage according to type of target
 371                                         if (targ == self)
 372                                                 selfdamage = selfdamage + d;
 373                                         else if (targ.team == self.team && teams_matter)
 374                                                 teamdamage = teamdamage + d;
 375                                         else if (bot_shouldattack(targ))
 376                                                 enemydamage = enemydamage + d;
 377                                         targ = targ.chain;
 378                                 }
 379                                 mine = find(mine, classname, "mine");
 380                         }
 381                         float desirabledamage;
 382                         desirabledamage = enemydamage;
 383                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 384                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 385                         if (teams_matter && self.team)
 386                                 desirabledamage = desirabledamage - teamdamage;
 387
 388                         mine = find(world, classname, "mine");
 389                         while (mine)
 390                         {
 391                                 if (mine.owner != self)
 392                                 {
 393                                         mine = find(mine, classname, "mine");
 394                                         continue;
 395                                 }
 396                                 makevectors(mine.v_angle);
 397                                 targ = targetlist;
 398                                 if (skill > 9) // normal players only do this for the target they are tracking
 399                                 {
 400                                         targ = targetlist;
 401                                         while (targ)
 402                                         {
 403                                                 if (
 404                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 405                                                         && desirabledamage > 0.1*coredamage
 406                                                 )self.BUTTON_ATCK2 = TRUE;
 407                                                 targ = targ.chain;
 408                                         }
 409                                 }else{
 410                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 411                                         //As the distance gets larger, a correct detonation gets near imposible
 412                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 413                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 414                                                 if(self.enemy.classname == "player")
 415                                                         if(desirabledamage >= 0.1*coredamage)
 416                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 417                                                                         self.BUTTON_ATCK2 = TRUE;
 418                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 419                                 }
 420
 421                                 mine = find(mine, classname, "mine");
 422                         }
 423                         // if we would be doing at X percent of the core damage, detonate it
 424                         // but don't fire a new shot at the same time!
 425                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 426                                 self.BUTTON_ATCK2 = TRUE;
 427                         if ((skill > 6.5) && (selfdamage > self.health))
 428                                 self.BUTTON_ATCK2 = FALSE;
 429                         //if(self.BUTTON_ATCK2 == TRUE)
 430                         //      dprint(ftos(desirabledamage),"\n");
 431                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 432                 }
 433         }
 434         else if (req == WR_THINK)
 435         {
 436                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 437                         W_MineLayer_Reload();
 438                 else if (self.BUTTON_ATCK)
 439                 {
 440                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 441                         {
 442                                 W_Mine_Attack();
 443                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 444                         }
 445                 }
 446
 447                 else if (self.BUTTON_ATCK2)
 448                 {
 449                         minfound = 0;
 450                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 451                         {
 452                                 if(!mine.minelayer_detonate)
 453                                 {
 454                                         mine.minelayer_detonate = TRUE;
 455                                         minfound = 1;
 456                                 }
 457                         }
 458                         if(minfound)
 459                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 460                 }
 461
 462         if(self.wish_reload)
 463         {
 464             if(self.switchweapon == self.weapon)
 465             {
 466                 if(self.weaponentity.state == WS_READY)
 467                 {
 468                     self.wish_reload = 0;
 469                     W_MineLayer_Reload();
 470                 }
 471             }
 472         }
 473         }
 474         else if (req == WR_PRECACHE)
 475         {
 476                 precache_model ("models/flash.md3");
 477                 precache_model ("models/mine.md3");
 478                 precache_model ("models/weapons/g_minelayer.md3");
 479                 precache_model ("models/weapons/v_minelayer.md3");
 480                 precache_model ("models/weapons/h_minelayer.iqm");
 481                 precache_sound ("weapons/mine_det.wav");
 482                 precache_sound ("weapons/mine_fire.wav");
 483                 precache_sound ("weapons/mine_stick.wav");
 484                 precache_sound ("weapons/mine_trigger.wav");
 485         }
 486         else if (req == WR_SETUP)
 487         {
 488                 weapon_setup(WEP_MINE_LAYER);
 489                 W_MineLayer_SetAmmoCounter();
 490         }
 491         else if (req == WR_CHECKAMMO1)
 492         {
 493                 // don't switch while placing a mine
 494                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 495                         && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 496                         return FALSE;
 497         }
 498         else if (req == WR_CHECKAMMO2)
 499         {
 500                 return FALSE;
 501         }
 502         else if (req == WR_RELOAD)
 503         {
 504                 W_MineLayer_Reload();
 505         }
 506         return TRUE;
 507 };
 508 #endif
 509 #ifdef CSQC
 510 float w_minelayer(float req)
 511 {
 512         if(req == WR_IMPACTEFFECT)
 513         {
 514                 vector org2;
 515                 org2 = w_org + w_backoff * 12;
 516                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 517                 if(!w_issilent)
 518                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 519         }
 520         else if(req == WR_PRECACHE)
 521         {
 522                 precache_sound("weapons/mine_exp.wav");
 523         }
 524         else if (req == WR_SUICIDEMESSAGE)
 525                 w_deathtypestring = "%s exploded";
 526         else if (req == WR_KILLMESSAGE)
 527         {
 528                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 529                         w_deathtypestring = "%s got too close to %s's mine";
 530                 else if(w_deathtype & HITTYPE_SPLASH)
 531                         w_deathtypestring = "%s almost dodged %s's mine";
 532                 else
 533                         w_deathtypestring = "%s stepped on %s's mine";
 534         }
 535         return TRUE;
 536 }
 537 #endif
 538 #endif