qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_Unregister()
  14 {
  15         if(self.owner && self.owner.lastrocket == self)
  16         {
  17                 self.owner.lastrocket = world;
  18                 // self.owner.rl_release = 1;
  19         }
  20 }
  21
  22 void W_Mine_Explode ()
  23 {
  24         W_Mine_Unregister();
  25
  26         if(other.takedamage == DAMAGE_AIM)
  27                 if(other.classname == "player")
  28                         if(IsDifferentTeam(self.owner, other))
  29                                 if(IsFlying(other))
  30                                         AnnounceTo(self.owner, "airshot");
  31
  32         self.event_damage = SUB_Null;
  33         self.takedamage = DAMAGE_NO;
  34
  35         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  36
  37         if (self.owner.weapon == WEP_MINE_LAYER)
  38         {
  39                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  40                 {
  41                         self.owner.cnt = WEP_MINE_LAYER;
  42                         ATTACK_FINISHED(self.owner) = time;
  43                         self.owner.switchweapon = w_getbestweapon(self.owner);
  44                 }
  45                 if(g_laserguided_missile)
  46                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_minelayer_refire") * W_WeaponRateFactor();
  47         }
  48         remove (self);
  49 }
  50
  51 void W_Mine_DoRemoteExplode ()
  52 {
  53         W_Mine_Unregister();
  54
  55         self.event_damage = SUB_Null;
  56         self.takedamage = DAMAGE_NO;
  57
  58         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  59
  60         if (self.owner.weapon == WEP_MINE_LAYER)
  61         {
  62                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  63                 {
  64                         self.owner.cnt = WEP_MINE_LAYER;
  65                         ATTACK_FINISHED(self.owner) = time;
  66                         self.owner.switchweapon = w_getbestweapon(self.owner);
  67                 }
  68                 if(g_laserguided_missile)
  69                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_minelayer_refire") * W_WeaponRateFactor();
  70         }
  71         remove (self);
  72 }
  73
  74 void W_Mine_RemoteExplode()
  75 {
  76         if(self.owner.deadflag == DEAD_NO)
  77         if(self.owner.lastrocket)
  78         {
  79                 if((self.spawnshieldtime >= 0)
  80                         ? (time >= self.spawnshieldtime) // timer
  81                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
  82                 )
  83                 {
  84                         W_Mine_DoRemoteExplode();
  85                 }
  86         }
  87 }
  88
  89 void W_Mine_Think (void)
  90 {
  91         entity e;
  92         vector desireddir, olddir, newdir, desiredorigin, goal;
  93 #if 0
  94         float cosminang, cosmaxang, cosang;
  95 #endif
  96         float turnrate, velspeed, f;
  97         self.nextthink = time;
  98         if (time > self.cnt)
  99         {
 100                 other = world;
 101                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 102                 W_Mine_Explode ();
 103                 return;
 104         }
 105
 106         if(g_laserguided_missile)
 107         {
 108                 // accelerate
 109                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 110                 velspeed = cvar("g_balance_minelayer_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 111                 if (velspeed > 0)
 112                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_minelayer_laserguided_speedaccel") * frametime, velspeed);
 113         }
 114         else
 115         {
 116                 // accelerate
 117                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 118                 velspeed = cvar("g_balance_minelayer_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 119                 if (velspeed > 0)
 120                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_minelayer_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 121         }
 122
 123         // laser guided, or remote detonation
 124         if (self.owner.weapon == WEP_MINE_LAYER)
 125         {
 126                 if(g_laserguided_missile)
 127                 {
 128                         if(self.rl_detonate_later)
 129                                 W_Mine_RemoteExplode();
 130
 131                         if(cvar("g_balance_minelayer_laserguided_allow_steal"))
 132                         {
 133                                 if(self.owner.laser_on)
 134                                 {
 135                                         if(self.attack_finished_single < time)
 136                                         {
 137                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 138                                                 //self.enemy = FindLaserTarget(self, 0.7, 0.7);
 139                                         }
 140
 141                                         if(!self.enemy)
 142                                                 self.enemy = self.owner.weaponentity.lasertarget;
 143                                 }
 144                                 else self.enemy = world;
 145                         }
 146                         else // don't allow stealing: always target my owner's laser (if it exists)
 147                                 self.enemy = self.owner.weaponentity.lasertarget;
 148
 149                         if(self.enemy != world)
 150                         {
 151                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 152                                 velspeed = vlen(self.velocity);
 153                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 154                                 turnrate = cvar("g_balance_minelayer_laserguided_turnrate");//0.65;                                             // how fast to turn
 155                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 156                                 olddir = normalize(self.velocity);                                      // get my current direction
 157                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 158                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 159                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 160
 161                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 162                         }
 163                 }
 164                 else
 165                 {
 166                         if(self == self.owner.lastrocket)
 167                         if not(self.owner.rl_release)
 168                         if not(self.BUTTON_ATCK2)
 169                         if(cvar("g_balance_minelayer_guiderate"))
 170                         if(time > self.pushltime)
 171                         if(self.owner.deadflag == DEAD_NO)
 172                         {
 173                                 f = cvar("g_balance_minelayer_guideratedelay");
 174                                 if(f)
 175                                         f = bound(0, (time - self.pushltime) / f, 1);
 176                                 else
 177                                         f = 1;
 178
 179                                 velspeed = vlen(self.velocity);
 180
 181                                 makevectors(self.owner.v_angle);
 182                                 desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 183                                 desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 184                                 olddir = normalize(self.velocity);
 185
 186 #if 0
 187                                 // disabled this code because it doesn't do what I want it to do :P
 188                                 cosminang = cos(cvar("g_balance_minelayer_guidefadeangle") * DEG2RAD);
 189                                 cosmaxang = cos(cvar("g_balance_minelayer_guidemaxangle") * DEG2RAD);
 190                                 cosang = desireddir * normalize(self.origin - desiredorigin);
 191                                 if(cosminang == cosmaxang)
 192                                         f *= (cosang >= cosminang);
 193                                 else
 194                                         f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 195 #endif
 196
 197                                 if(!self.count)
 198                                 {
 199                                         pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 200                                         // TODO add a better sound here
 201                                         sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 202                                         self.count = 1;
 203                                 }
 204                         }
 205
 206                         if(self.rl_detonate_later)
 207                                 W_Mine_RemoteExplode();
 208                 }
 209         }
 210
 211         if(self.csqcprojectile_clientanimate == 0)
 212                 UpdateCSQCProjectile(self);
 213 }
 214
 215 void W_Mine_Touch (void)
 216 {
 217         W_Mine_Unregister();
 218
 219         PROJECTILE_TOUCH;
 220         W_Mine_Explode ();
 221 }
 222
 223 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 224 {
 225         if (self.health <= 0)
 226                 return;
 227         self.health = self.health - damage;
 228         self.angles = vectoangles(self.velocity);
 229         if (self.health <= 0)
 230                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 231 }
 232
 233 void W_Mine_Attack (void)
 234 {
 235         local entity missile;
 236         local entity flash;
 237
 238         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 239                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 240
 241         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_minelayer_damage"));
 242         pointparticles(particleeffectnum("minelayer_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 243
 244         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 245         missile.owner = self;
 246         self.lastrocket = missile;
 247         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 248                 missile.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 249         else
 250                 missile.spawnshieldtime = -1;
 251         missile.pushltime = time + cvar("g_balance_minelayer_guidedelay");
 252         missile.classname = "rocket";
 253         missile.bot_dodge = TRUE;
 254         missile.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 255
 256         missile.takedamage = DAMAGE_YES;
 257         missile.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 258         missile.health = cvar("g_balance_minelayer_health");
 259         missile.event_damage = W_Mine_Damage;
 260
 261         missile.movetype = MOVETYPE_FLY;
 262         PROJECTILE_MAKETRIGGER(missile);
 263         missile.projectiledeathtype = WEP_MINE_LAYER;
 264         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 265
 266         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 267         if(g_laserguided_missile && self.laser_on)
 268                 W_SetupProjectileVelocity(missile, cvar("g_balance_minelayer_laserguided_speedstart"), 0);
 269         else
 270                 W_SetupProjectileVelocity(missile, cvar("g_balance_minelayer_speedstart"), 0);
 271         missile.angles = vectoangles (missile.velocity);
 272
 273         missile.touch = W_Mine_Touch;
 274         missile.think = W_Mine_Think;
 275         missile.nextthink = time;
 276         missile.cnt = time + cvar("g_balance_minelayer_lifetime");
 277         missile.flags = FL_PROJECTILE;
 278
 279         CSQCProjectile(missile, cvar("g_balance_minelayer_guiderate") == 0 && cvar("g_balance_minelayer_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 280
 281         // muzzle flash for 1st person view
 282         flash = spawn ();
 283         setmodel (flash, "models/flash.md3"); // precision set below
 284         SUB_SetFade (flash, time, 0.1);
 285         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 286         W_AttachToShotorg(flash, '5 0 0');
 287
 288         // common properties
 289 }
 290
 291 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 292
 293 float w_minelayer(float req)
 294 {
 295         entity rock;
 296         float rockfound;
 297         if (req == WR_AIM)
 298         {
 299                 // aim and decide to fire if appropriate
 300                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 301                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 302                 {
 303                         // decide whether to detonate rockets
 304                         local entity missile, targetlist, targ;
 305                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 306                         local float selfdamage, teamdamage, enemydamage;
 307                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 308                         coredamage = cvar("g_balance_minelayer_damage");
 309                         edgeradius = cvar("g_balance_minelayer_radius");
 310                         recipricoledgeradius = 1 / edgeradius;
 311                         selfdamage = 0;
 312                         teamdamage = 0;
 313                         enemydamage = 0;
 314                         targetlist = findchainfloat(bot_attack, TRUE);
 315                         missile = find(world, classname, "rocket");
 316                         while (missile)
 317                         {
 318                                 if (missile.owner != self)
 319                                 {
 320                                         missile = find(missile, classname, "rocket");
 321                                         continue;
 322                                 }
 323                                 targ = targetlist;
 324                                 while (targ)
 325                                 {
 326                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 327                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 328                                         // count potential damage according to type of target
 329                                         if (targ == self)
 330                                                 selfdamage = selfdamage + d;
 331                                         else if (targ.team == self.team && teams_matter)
 332                                                 teamdamage = teamdamage + d;
 333                                         else if (bot_shouldattack(targ))
 334                                                 enemydamage = enemydamage + d;
 335                                         targ = targ.chain;
 336                                 }
 337                                 missile = find(missile, classname, "rocket");
 338                         }
 339                         local float desirabledamage;
 340                         desirabledamage = enemydamage;
 341                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 342                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 343                         if (self.team && teamplay != 1)
 344                                 desirabledamage = desirabledamage - teamdamage;
 345
 346                         missile = find(world, classname, "rocket");
 347                         while (missile)
 348                         {
 349                                 if (missile.owner != self)
 350                                 {
 351                                         missile = find(missile, classname, "rocket");
 352                                         continue;
 353                                 }
 354                                 makevectors(missile.v_angle);
 355                                 targ = targetlist;
 356                                 if (skill > 9) // normal players only do this for the target they are tracking
 357                                 {
 358                                         targ = targetlist;
 359                                         while (targ)
 360                                         {
 361                                                 if (
 362                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 363                                                         && desirabledamage > 0.1*coredamage
 364                                                 )self.BUTTON_ATCK2 = TRUE;
 365                                                 targ = targ.chain;
 366                                         }
 367                                 }else{
 368                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 369                                         //As the distance gets larger, a correct detonation gets near imposible
 370                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 371                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 372                                                 if(self.enemy.classname == "player")
 373                                                         if(desirabledamage >= 0.1*coredamage)
 374                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 375                                                                         self.BUTTON_ATCK2 = TRUE;
 376                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 377                                 }
 378
 379                                 missile = find(missile, classname, "rocket");
 380                         }
 381                         // if we would be doing at X percent of the core damage, detonate it
 382                         // but don't fire a new shot at the same time!
 383                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 384                                 self.BUTTON_ATCK2 = TRUE;
 385                         if ((skill > 6.5) && (selfdamage > self.health))
 386                                 self.BUTTON_ATCK2 = FALSE;
 387                         //if(self.BUTTON_ATCK2 == TRUE)
 388                         //      dprint(ftos(desirabledamage),"\n");
 389                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 390                 }
 391         }
 392         else if (req == WR_THINK)
 393         {
 394                 if(g_laserguided_missile)
 395                 {
 396                         if (self.BUTTON_ATCK && self.rl_release)
 397                         {
 398                                 rockfound = 0;
 399                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 400                                 {
 401                                         if(!rock.rl_detonate_later)
 402                                         {
 403                                                 rock.rl_detonate_later = TRUE;
 404                                                 rockfound = 1;
 405                                         }
 406                                 }
 407                                 if(rockfound)
 408                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 409                                 else
 410                                 {
 411                                         if (weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 412                                         {
 413                                                 W_Mine_Attack();
 414                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 415                                         }
 416                                 }
 417                                 self.rl_release = 0;
 418                         }
 419                         if (!self.BUTTON_ATCK)
 420                                 self.rl_release = 1;
 421                         if (self.BUTTON_ATCK2)
 422                         if(self.exteriorweaponentity.attack_finished_single < time)
 423                         {
 424                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 425                                 self.laser_on = !self.laser_on;
 426                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 427                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 428                         }
 429                 }
 430                 else
 431                 {
 432                         if (self.BUTTON_ATCK)
 433                         {
 434                                 if(self.rl_release || cvar("g_balance_minelayer_guidestop"))
 435                                 if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 436                                 {
 437                                         W_Mine_Attack();
 438                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 439                                         self.rl_release = 0;
 440                                 }
 441                         }
 442                         else
 443                                 self.rl_release = 1;
 444
 445                         if (self.BUTTON_ATCK2)
 446                         {
 447                                 rockfound = 0;
 448                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 449                                 {
 450                                         if(!rock.rl_detonate_later)
 451                                         {
 452                                                 rock.rl_detonate_later = TRUE;
 453                                                 rockfound = 1;
 454                                         }
 455                                 }
 456                                 if(rockfound)
 457                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 458                         }
 459                 }
 460         }
 461         else if (req == WR_PRECACHE)
 462         {
 463                 precache_model ("models/flash.md3");
 464                 precache_model ("models/weapons/g_rl.md3");
 465                 precache_model ("models/weapons/v_rl.md3");
 466                 precache_model ("models/weapons/h_rl.iqm");
 467                 precache_sound ("weapons/rocket_det.wav");
 468                 precache_sound ("weapons/rocket_fire.wav");
 469                 precache_sound ("weapons/rocket_mode.wav");
 470                 if (g_laserguided_missile)
 471                 {
 472                         precache_model ("models/laser_dot.mdl"); // mine layer
 473                 }
 474         }
 475         else if (req == WR_SETUP)
 476         {
 477                 weapon_setup(WEP_MINE_LAYER);
 478                 self.rl_release = 1;
 479         }
 480         else if (req == WR_CHECKAMMO1)
 481         {
 482                 // don't switch while guiding a missile
 483                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 484                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 485                         return FALSE;
 486         }
 487         else if (req == WR_CHECKAMMO2)
 488                 return FALSE;
 489         else if (req == WR_RESETPLAYER)
 490         {
 491                 self.rl_release = 0;
 492         }
 493         return TRUE;
 494 };
 495 #endif
 496 #ifdef CSQC
 497 float w_minelayer(float req)
 498 {
 499         if(req == WR_IMPACTEFFECT)
 500         {
 501                 vector org2;
 502                 org2 = w_org + w_backoff * 12;
 503                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 504                 if(!w_issilent)
 505                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 506         }
 507         else if(req == WR_PRECACHE)
 508         {
 509                 precache_sound("weapons/rocket_impact.wav");
 510         }
 511         else if (req == WR_SUICIDEMESSAGE)
 512                 w_deathtypestring = "%s exploded";
 513         else if (req == WR_KILLMESSAGE)
 514         {
 515                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 516                         w_deathtypestring = "%s got too close to %s's rocket";
 517                 else if(w_deathtype & HITTYPE_SPLASH)
 518                         w_deathtypestring = "%s almost dodged %s's rocket";
 519                 else
 520                         w_deathtypestring = "%s ate %s's rocket";
 521         }
 522         return TRUE;
 523 }
 524 #endif
 525 #endif