qcsrc/server/w_minstanex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINSTANEX, w_minstanex, IT_CELLS, 7, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "minstanex", "minstanex", _("MinstaNex"))
   3 #else
   4 #ifdef SVQC
   5 .float minstanex_lasthit;
   6 .float jump_interval;
   7
   8 void W_MinstaNex_Attack (void)
   9 {
  10         float flying;
  11         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  12
  13         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  14
  15         yoda = 0;
  16         damage_goodhits = 0;
  17         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_MINSTANEX);
  18
  19         if(yoda && flying)
  20                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  21         if(damage_goodhits && self.minstanex_lasthit)
  22         {
  23                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  24                 damage_goodhits = 0; // only every second time
  25         }
  26
  27         self.minstanex_lasthit = damage_goodhits;
  28
  29         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  30
  31         // teamcolor / hit beam effect
  32         vector v;
  33         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  34         if(teamplay)
  35         {
  36             switch(self.team)
  37             {
  38             case NUM_TEAM_1:   // Red
  39                 if(damage_goodhits)
  40                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  41                 else
  42                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  43                 break;
  44             case NUM_TEAM_2:   // Blue
  45                 if(damage_goodhits)
  46                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  47                 else
  48                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  49                 break;
  50             case NUM_TEAM_3:   // Yellow
  51                 if(damage_goodhits)
  52                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  53                 else
  54                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  55                 break;
  56             case NUM_TEAM_4:   // Pink
  57                 if(damage_goodhits)
  58                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  59                 else
  60                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
  61                 break;
  62             }
  63         }
  64         else
  65                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
  66
  67         W_DecreaseAmmo(ammo_cells, ((g_minstagib) ? 1 : autocvar_g_balance_minstanex_ammo), autocvar_g_balance_minstanex_reload_ammo);
  68 }
  69
  70 void spawnfunc_weapon_minstanex (void); // defined in t_items.qc
  71
  72 float w_minstanex(float req)
  73 {
  74         float ammo_amount;
  75         float minstanex_ammo;
  76
  77         // now multiple WR_s use this
  78         minstanex_ammo = ((g_minstagib) ? 1 : autocvar_g_balance_minstanex_ammo);
  79
  80         if (req == WR_AIM)
  81         {
  82                 if(self.ammo_cells > 0)
  83                         self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  84                 else
  85                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_laser_primary_speed, 0, autocvar_g_balance_laser_primary_lifetime, FALSE);
  86         }
  87         else if (req == WR_THINK)
  88         {
  89                 // if the laser uses load, we also consider its ammo for reloading
  90                 if(autocvar_g_balance_minstanex_reload_ammo && autocvar_g_balance_minstanex_laser_ammo && self.clip_load < min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo)) // forced reload
  91                         weapon_action(self.weapon, WR_RELOAD);
  92                 else if(autocvar_g_balance_minstanex_reload_ammo && self.clip_load < minstanex_ammo) // forced reload
  93                         weapon_action(self.weapon, WR_RELOAD);
  94                 else if (self.BUTTON_ATCK)
  95                 {
  96                         if (weapon_prepareattack(0, autocvar_g_balance_minstanex_refire))
  97                         {
  98                                 W_MinstaNex_Attack();
  99                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minstanex_animtime, w_ready);
 100                         }
 101                 }
 102                 else if (self.BUTTON_ATCK2)
 103                 {
 104                         if (self.jump_interval <= time)
 105                         if (weapon_prepareattack(1, -1))
 106                         {
 107                                 // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 108                                 self.jump_interval = time + autocvar_g_balance_minstanex_laser_refire * W_WeaponRateFactor();
 109
 110                                 // decrease ammo for the laser?
 111                                 if(autocvar_g_balance_minstanex_laser_ammo)
 112                                         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_minstanex_laser_ammo, autocvar_g_balance_minstanex_reload_ammo);
 113
 114                                 // ugly minstagib hack to reuse the fire mode of the laser
 115                                 float w;
 116                                 w = self.weapon;
 117                                 self.weapon = WEP_LASER;
 118                                 W_Laser_Attack(2);
 119                                 self.weapon = w;
 120
 121                                 // now do normal refire
 122                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_minstanex_laser_animtime, w_ready);
 123                         }
 124                 }
 125         }
 126         else if (req == WR_PRECACHE)
 127         {
 128                 precache_model ("models/nexflash.md3");
 129                 precache_model ("models/weapons/g_minstanex.md3");
 130                 precache_model ("models/weapons/v_minstanex.md3");
 131                 precache_model ("models/weapons/h_minstanex.iqm");
 132                 precache_sound ("weapons/minstanexfire.wav");
 133                 precache_sound ("weapons/nexwhoosh1.wav");
 134                 precache_sound ("weapons/nexwhoosh2.wav");
 135                 precache_sound ("weapons/nexwhoosh3.wav");
 136                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 137                 w_laser(WR_PRECACHE);
 138         }
 139         else if (req == WR_SETUP)
 140         {
 141                 weapon_setup(WEP_MINSTANEX);
 142                 self.current_ammo = ammo_cells;
 143                 self.minstanex_lasthit = 0;
 144         }
 145         else if (req == WR_CHECKAMMO1)
 146         {
 147                 ammo_amount = self.ammo_cells >= minstanex_ammo;
 148                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= minstanex_ammo;
 149                 return ammo_amount;
 150         }
 151         else if (req == WR_CHECKAMMO2)
 152         {
 153                 if(!autocvar_g_balance_minstanex_laser_ammo)
 154                         return TRUE;
 155                 ammo_amount = self.ammo_cells >= autocvar_g_balance_minstanex_laser_ammo;
 156                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= autocvar_g_balance_minstanex_laser_ammo;
 157                 return ammo_amount;
 158         }
 159         else if (req == WR_RESETPLAYER)
 160         {
 161                 self.minstanex_lasthit = 0;
 162         }
 163         else if (req == WR_RELOAD)
 164         {
 165                 float used_ammo;
 166                 if(autocvar_g_balance_minstanex_laser_ammo)
 167                         used_ammo = min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo);
 168                 else
 169                         used_ammo = minstanex_ammo;
 170
 171                 W_Reload(used_ammo, autocvar_g_balance_minstanex_reload_ammo, autocvar_g_balance_minstanex_reload_time, "weapons/reload.wav");
 172         }
 173         else if (req == WR_SUICIDEMESSAGE)
 174         {
 175                 return WEAPON_THINKING_WITH_PORTALS;
 176         }
 177         else if (req == WR_KILLMESSAGE)
 178         {
 179                 return WEAPON_MINSTANEX_MURDER;
 180         }
 181         return TRUE;
 182 }
 183 #endif
 184 #ifdef CSQC
 185 float w_minstanex(float req)
 186 {
 187         if(req == WR_IMPACTEFFECT)
 188         {
 189                 vector org2;
 190                 org2 = w_org + w_backoff * 6;
 191                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 192                 if(!w_issilent)
 193                         sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 194         }
 195         else if(req == WR_PRECACHE)
 196         {
 197                 precache_sound("weapons/neximpact.wav");
 198         }
 199         return TRUE;
 200 }
 201 #endif
 202 #endif