qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", _("Rocket Launcher"))
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_RocketLauncher_Reload()
   9 {
  10         W_Reload(ammo_rockets, autocvar_g_balance_rocketlauncher_ammo, autocvar_g_balance_rocketlauncher_reload_ammo, autocvar_g_balance_rocketlauncher_reload_time, "weapons/reload.wav");
  11 }
  12
  13 void W_Rocket_Unregister()
  14 {
  15         if(self.owner && self.owner.lastrocket == self)
  16         {
  17                 self.owner.lastrocket = world;
  18                 // self.owner.rl_release = 1;
  19         }
  20 }
  21
  22 void W_Rocket_Explode ()
  23 {
  24         W_Rocket_Unregister();
  25
  26         if(other.takedamage == DAMAGE_AIM)
  27                 if(other.classname == "player")
  28                         if(IsDifferentTeam(self.owner, other))
  29                                 if(IsFlying(other))
  30                                         AnnounceTo(self.owner, "airshot");
  31
  32         self.event_damage = SUB_Null;
  33         self.takedamage = DAMAGE_NO;
  34
  35         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_damage, autocvar_g_balance_rocketlauncher_edgedamage, autocvar_g_balance_rocketlauncher_radius, world, autocvar_g_balance_rocketlauncher_force, self.projectiledeathtype, other);
  36
  37         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  38         {
  39                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
  40                 {
  41                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  42                         ATTACK_FINISHED(self.owner) = time;
  43                         self.owner.switchweapon = w_getbestweapon(self.owner);
  44                 }
  45         }
  46         remove (self);
  47 }
  48
  49 void W_Rocket_DoRemoteExplode ()
  50 {
  51         W_Rocket_Unregister();
  52
  53         self.event_damage = SUB_Null;
  54         self.takedamage = DAMAGE_NO;
  55
  56         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_remote_damage, autocvar_g_balance_rocketlauncher_remote_edgedamage, autocvar_g_balance_rocketlauncher_remote_radius, world, autocvar_g_balance_rocketlauncher_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  57
  58         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  59         {
  60                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
  61                 {
  62                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  63                         ATTACK_FINISHED(self.owner) = time;
  64                         self.owner.switchweapon = w_getbestweapon(self.owner);
  65                 }
  66         }
  67         remove (self);
  68 }
  69
  70 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  71 {
  72         entity head, selected;
  73         vector dir;
  74         float dist, maxdist,// bestdist,
  75                 dot,// bestdot,
  76                 points, bestpoints;
  77         //bestdist = 9999;
  78         //bestdot = -2;
  79         bestpoints = 0;
  80         maxdist = 800;
  81         selected = world;
  82
  83         makevectors(e.angles);
  84
  85         head = find(world, classname, "laser_target");
  86         while(head)
  87         {
  88                 points = 0;
  89                 dir = normalize(head.origin - self.origin);
  90                 dot = dir * v_forward;
  91                 dist = vlen(head.origin - self.origin);
  92                 if(dist > maxdist)
  93                         dist = maxdist;
  94
  95                 // gain points for being in front
  96                 points = points + ((dot+1)*0.5) * 500
  97                         * (1 + crandom()*dot_variance);
  98                 // gain points for being close away
  99                 points = points + (1 - dist/maxdist) * 1000
 100                         * (1 + crandom()*dot_variance);
 101
 102                 traceline(e.origin, head.origin, TRUE, self);
 103                 if(trace_fraction < 1)
 104                 {
 105                         points = 0;
 106                 }
 107
 108                 if(points > bestpoints)//random() > 0.5)//
 109                 {
 110                         bestpoints = points;
 111                         selected = head;
 112                 }
 113
 114                 head = find(head, classname, "laser_target");
 115         }
 116
 117         //bprint(selected.owner.netname);
 118         //bprint("\n");
 119         return selected;
 120 }
 121
 122 void W_Rocket_RemoteExplode()
 123 {
 124         if(self.owner.deadflag == DEAD_NO)
 125         if(self.owner.lastrocket)
 126         {
 127                 if((self.spawnshieldtime >= 0)
 128                         ? (time >= self.spawnshieldtime) // timer
 129                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_rocketlauncher_remote_radius) // safety device
 130                 )
 131                 {
 132                         W_Rocket_DoRemoteExplode();
 133                 }
 134         }
 135 }
 136
 137 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 138 {
 139         if(thisdir * goaldir > maxturn_cos)
 140                 return goaldir;
 141         float f, m2;
 142         vector v;
 143         // solve:
 144         //   g = normalize(thisdir + goaldir * X)
 145         //   thisdir * g = maxturn
 146         //
 147         //   gg = thisdir + goaldir * X
 148         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 149         //
 150         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 151         f = thisdir * goaldir;
 152         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 153         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 154         m2 = maxturn_cos * maxturn_cos;
 155         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 156         return normalize(thisdir + goaldir * v_y); // the larger solution!
 157 }
 158
 159 void W_Rocket_Think (void)
 160 {
 161         vector desireddir, olddir, newdir, desiredorigin, goal;
 162 #if 0
 163         float cosminang, cosmaxang, cosang;
 164 #endif
 165         float velspeed, f;
 166         self.nextthink = time;
 167         if (time > self.cnt)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Rocket_Explode ();
 172                 return;
 173         }
 174
 175         // accelerate
 176         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 177         velspeed = autocvar_g_balance_rocketlauncher_speed * g_weaponspeedfactor - (self.velocity * v_forward);
 178         if (velspeed > 0)
 179                 self.velocity = self.velocity + v_forward * min(autocvar_g_balance_rocketlauncher_speedaccel * g_weaponspeedfactor * frametime, velspeed);
 180
 181         // laser guided, or remote detonation
 182         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 183         {
 184                 if(self == self.owner.lastrocket)
 185                 if not(self.owner.rl_release)
 186                 if not(self.BUTTON_ATCK2)
 187                 if(autocvar_g_balance_rocketlauncher_guiderate)
 188                 if(time > self.pushltime)
 189                 if(self.owner.deadflag == DEAD_NO)
 190                 {
 191                         f = autocvar_g_balance_rocketlauncher_guideratedelay;
 192                         if(f)
 193                                 f = bound(0, (time - self.pushltime) / f, 1);
 194                         else
 195                                 f = 1;
 196
 197                         velspeed = vlen(self.velocity);
 198
 199                         makevectors(self.owner.v_angle);
 200                         desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 201                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 202                         olddir = normalize(self.velocity);
 203
 204                         // now it gets tricky... we want to move like some curve to approximate the target direction
 205                         // but we are limiting the rate at which we can turn!
 206                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + autocvar_g_balance_rocketlauncher_guidegoal) * desireddir;
 207                         newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(autocvar_g_balance_rocketlauncher_guiderate * f * frametime * DEG2RAD));
 208
 209                         self.velocity = newdir * velspeed;
 210                         self.angles = vectoangles(self.velocity);
 211
 212                         if(!self.count)
 213                         {
 214                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 215                                 // TODO add a better sound here
 216                                 sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 217                                 self.count = 1;
 218                         }
 219                 }
 220
 221                 if(self.rl_detonate_later)
 222                         W_Rocket_RemoteExplode();
 223         }
 224
 225         if(self.csqcprojectile_clientanimate == 0)
 226                 UpdateCSQCProjectile(self);
 227 }
 228
 229 void W_Rocket_Touch (void)
 230 {
 231         if(WarpZone_Projectile_Touch())
 232         {
 233                 if(wasfreed(self))
 234                         W_Rocket_Unregister();
 235                 return;
 236         }
 237         W_Rocket_Unregister();
 238         W_Rocket_Explode ();
 239 }
 240
 241 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245         self.health = self.health - damage;
 246         self.angles = vectoangles(self.velocity);
 247         if (self.health <= 0)
 248                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 249 }
 250
 251 void W_Rocket_Attack (void)
 252 {
 253         local entity missile;
 254         local entity flash;
 255
 256         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 257         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 258         {
 259                 if(autocvar_g_balance_rocketlauncher_reload_ammo)
 260                 {
 261                         self.clip_load -= autocvar_g_balance_rocketlauncher_ammo;
 262                         self.weapon_load[WEP_ROCKET_LAUNCHER] = self.clip_load;
 263                 }
 264                 else
 265                         self.ammo_rockets -= autocvar_g_balance_rocketlauncher_ammo;
 266         }
 267
 268         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CHAN_WEAPON, autocvar_g_balance_rocketlauncher_damage);
 269         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 270
 271         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 272         missile.owner = self;
 273         self.lastrocket = missile;
 274         if(autocvar_g_balance_rocketlauncher_detonatedelay >= 0)
 275                 missile.spawnshieldtime = time + autocvar_g_balance_rocketlauncher_detonatedelay;
 276         else
 277                 missile.spawnshieldtime = -1;
 278         missile.pushltime = time + autocvar_g_balance_rocketlauncher_guidedelay;
 279         missile.classname = "rocket";
 280         missile.bot_dodge = TRUE;
 281         missile.bot_dodgerating = autocvar_g_balance_rocketlauncher_damage * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 282
 283         missile.takedamage = DAMAGE_YES;
 284         missile.damageforcescale = autocvar_g_balance_rocketlauncher_damageforcescale;
 285         missile.health = autocvar_g_balance_rocketlauncher_health;
 286         missile.event_damage = W_Rocket_Damage;
 287
 288         missile.movetype = MOVETYPE_FLY;
 289         PROJECTILE_MAKETRIGGER(missile);
 290         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 291         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 292
 293         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 294         W_SetupProjectileVelocity(missile, autocvar_g_balance_rocketlauncher_speedstart, 0);
 295         missile.angles = vectoangles (missile.velocity);
 296
 297         missile.touch = W_Rocket_Touch;
 298         missile.think = W_Rocket_Think;
 299         missile.nextthink = time;
 300         missile.cnt = time + autocvar_g_balance_rocketlauncher_lifetime;
 301         missile.flags = FL_PROJECTILE;
 302
 303         CSQCProjectile(missile, autocvar_g_balance_rocketlauncher_guiderate == 0 && autocvar_g_balance_rocketlauncher_speedaccel == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 304
 305         // muzzle flash for 1st person view
 306         flash = spawn ();
 307         setmodel (flash, "models/flash.md3"); // precision set below
 308         SUB_SetFade (flash, time, 0.1);
 309         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 310         W_AttachToShotorg(flash, '5 0 0');
 311
 312         // common properties
 313         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 314 }
 315
 316 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 317
 318 float w_rlauncher(float req)
 319 {
 320         entity rock;
 321         float rockfound;
 322         float ammo_amount;
 323
 324         if (req == WR_AIM)
 325         {
 326                 // aim and decide to fire if appropriate
 327                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_rocketlauncher_speed, 0, autocvar_g_balance_rocketlauncher_lifetime, FALSE);
 328                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 329                 {
 330                         // decide whether to detonate rockets
 331                         local entity missile, targetlist, targ;
 332                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 333                         local float selfdamage, teamdamage, enemydamage;
 334                         edgedamage = autocvar_g_balance_rocketlauncher_edgedamage;
 335                         coredamage = autocvar_g_balance_rocketlauncher_damage;
 336                         edgeradius = autocvar_g_balance_rocketlauncher_radius;
 337                         recipricoledgeradius = 1 / edgeradius;
 338                         selfdamage = 0;
 339                         teamdamage = 0;
 340                         enemydamage = 0;
 341                         targetlist = findchainfloat(bot_attack, TRUE);
 342                         missile = find(world, classname, "rocket");
 343                         while (missile)
 344                         {
 345                                 if (missile.owner != self)
 346                                 {
 347                                         missile = find(missile, classname, "rocket");
 348                                         continue;
 349                                 }
 350                                 targ = targetlist;
 351                                 while (targ)
 352                                 {
 353                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 354                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 355                                         // count potential damage according to type of target
 356                                         if (targ == self)
 357                                                 selfdamage = selfdamage + d;
 358                                         else if (targ.team == self.team && teams_matter)
 359                                                 teamdamage = teamdamage + d;
 360                                         else if (bot_shouldattack(targ))
 361                                                 enemydamage = enemydamage + d;
 362                                         targ = targ.chain;
 363                                 }
 364                                 missile = find(missile, classname, "rocket");
 365                         }
 366                         local float desirabledamage;
 367                         desirabledamage = enemydamage;
 368                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 369                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 370                         if (teams_matter && self.team)
 371                                 desirabledamage = desirabledamage - teamdamage;
 372
 373                         missile = find(world, classname, "rocket");
 374                         while (missile)
 375                         {
 376                                 if (missile.owner != self)
 377                                 {
 378                                         missile = find(missile, classname, "rocket");
 379                                         continue;
 380                                 }
 381                                 makevectors(missile.v_angle);
 382                                 targ = targetlist;
 383                                 if (skill > 9) // normal players only do this for the target they are tracking
 384                                 {
 385                                         targ = targetlist;
 386                                         while (targ)
 387                                         {
 388                                                 if (
 389                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 390                                                         && desirabledamage > 0.1*coredamage
 391                                                 )self.BUTTON_ATCK2 = TRUE;
 392                                                 targ = targ.chain;
 393                                         }
 394                                 }else{
 395                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 396                                         //As the distance gets larger, a correct detonation gets near imposible
 397                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 398                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 399                                                 if(self.enemy.classname == "player")
 400                                                         if(desirabledamage >= 0.1*coredamage)
 401                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 402                                                                         self.BUTTON_ATCK2 = TRUE;
 403                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 404                                 }
 405
 406                                 missile = find(missile, classname, "rocket");
 407                         }
 408                         // if we would be doing at X percent of the core damage, detonate it
 409                         // but don't fire a new shot at the same time!
 410                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 411                                 self.BUTTON_ATCK2 = TRUE;
 412                         if ((skill > 6.5) && (selfdamage > self.health))
 413                                 self.BUTTON_ATCK2 = FALSE;
 414                         //if(self.BUTTON_ATCK2 == TRUE)
 415                         //      dprint(ftos(desirabledamage),"\n");
 416                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 417                 }
 418         }
 419         else if (req == WR_THINK)
 420         {
 421                 if(autocvar_g_balance_rocketlauncher_reload_ammo && self.clip_load < autocvar_g_balance_rocketlauncher_ammo) // forced reload
 422                         W_RocketLauncher_Reload();
 423                 else
 424                 {
 425                         if (self.BUTTON_ATCK)
 426                         {
 427                                 if(self.rl_release || autocvar_g_balance_rocketlauncher_guidestop)
 428                                 if(weapon_prepareattack(0, autocvar_g_balance_rocketlauncher_refire))
 429                                 {
 430                                         W_Rocket_Attack();
 431                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_rocketlauncher_animtime, w_ready);
 432                                         self.rl_release = 0;
 433                                 }
 434                         }
 435                         else
 436                                 self.rl_release = 1;
 437
 438                         if (self.BUTTON_ATCK2)
 439                         {
 440                                 rockfound = 0;
 441                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 442                                 {
 443                                         if(!rock.rl_detonate_later)
 444                                         {
 445                                                 rock.rl_detonate_later = TRUE;
 446                                                 rockfound = 1;
 447                                         }
 448                                 }
 449                                 if(rockfound)
 450                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 451                         }
 452                 }
 453         }
 454         else if (req == WR_PRECACHE)
 455         {
 456                 precache_model ("models/flash.md3");
 457                 precache_model ("models/weapons/g_rl.md3");
 458                 precache_model ("models/weapons/v_rl.md3");
 459                 precache_model ("models/weapons/h_rl.iqm");
 460                 precache_sound ("weapons/rocket_det.wav");
 461                 precache_sound ("weapons/rocket_fire.wav");
 462                 precache_sound ("weapons/rocket_mode.wav");
 463                 precache_sound ("weapons/reload.wav");
 464         }
 465         else if (req == WR_SETUP)
 466         {
 467                 weapon_setup(WEP_ROCKET_LAUNCHER);
 468                 self.rl_release = 1;
 469         }
 470         else if (req == WR_CHECKAMMO1)
 471         {
 472                 // don't switch while guiding a missile
 473                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 474                 {
 475                         if(autocvar_g_balance_rocketlauncher_reload_ammo)
 476                         {
 477                                 if(self.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo && self.weapon_load[WEP_ROCKET_LAUNCHER] < autocvar_g_balance_rocketlauncher_ammo)
 478                                         ammo_amount = TRUE;
 479                         }
 480                         else if(self.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
 481                                 ammo_amount = TRUE;
 482                         return !ammo_amount;
 483                 }
 484         }
 485         else if (req == WR_CHECKAMMO2)
 486                 return FALSE;
 487         else if (req == WR_RESETPLAYER)
 488         {
 489                 self.rl_release = 0;
 490         }
 491         else if (req == WR_RELOAD)
 492         {
 493                 W_RocketLauncher_Reload();
 494         }
 495         return TRUE;
 496 };
 497 #endif
 498 #ifdef CSQC
 499 float w_rlauncher(float req)
 500 {
 501         if(req == WR_IMPACTEFFECT)
 502         {
 503                 vector org2;
 504                 org2 = w_org + w_backoff * 12;
 505                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 506                 if(!w_issilent)
 507                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 508         }
 509         else if(req == WR_PRECACHE)
 510         {
 511                 precache_sound("weapons/rocket_impact.wav");
 512         }
 513         else if (req == WR_SUICIDEMESSAGE)
 514                 w_deathtypestring = _("%s exploded");
 515         else if (req == WR_KILLMESSAGE)
 516         {
 517                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 518                         w_deathtypestring = _("%s got too close to %s's rocket");
 519                 else if(w_deathtype & HITTYPE_SPLASH)
 520                         w_deathtypestring = _("%s almost dodged %s's rocket");
 521                 else
 522                         w_deathtypestring = _("%s ate %s's rocket");
 523         }
 524         return TRUE;
 525 }
 526 #endif
 527 #endif