qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  27
  28         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  29         for (sc = 0;sc < bullets;sc = sc + 1)
  30                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  31         endFireBallisticBullet();
  32
  33         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  34
  35         // casing code
  36         if (autocvar_g_casings >= 1)
  37                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  38                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  39
  40         // muzzle flash for 1st person view
  41         flash = spawn();
  42         setmodel(flash, "models/uziflash.md3"); // precision set below
  43         flash.think = SUB_Remove;
  44         flash.nextthink = time + 0.06;
  45         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  46         W_AttachToShotorg(flash, '5 0 0');
  47 }
  48
  49 .float swing_prev;
  50 .entity swing_alreadyhit;
  51 void shotgun_meleethink (void)
  52 {
  53         // declarations
  54         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  55         vector targpos;
  56
  57         if(!self.cnt) // set start time of melee
  58         {
  59                 self.cnt = time;
  60                 W_PlayStrengthSound(self.realowner);
  61         }
  62
  63         makevectors(self.realowner.v_angle); // update values for v_* vectors
  64
  65         // calculate swing percentage based on time
  66         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  67         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
  68         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  69
  70         // check to see if we can still continue, otherwise give up now
  71         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)
  72         {
  73                 remove(self);
  74                 return;
  75         }
  76
  77         // if okay, perform the traces needed for this frame
  78         for(i=self.swing_prev; i < f; ++i)
  79         {
  80                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
  81
  82                 targpos = (self.realowner.origin + self.realowner.view_ofs
  83                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
  84                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
  85                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
  86
  87                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self.realowner, ANTILAG_LATENCY(self.realowner));
  88
  89                 // draw lightning beams for debugging
  90                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
  91                 //te_customflash(targpos, 40,  2, '1 1 1');
  92
  93                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
  94
  95                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
  96                         && (trace_ent.takedamage == DAMAGE_AIM)
  97                         && (trace_ent != self.swing_alreadyhit)
  98                         && (is_player || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
  99                 {
 100                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 101                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
 102                         else
 103                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 104
 105                         Damage(trace_ent, self.realowner, self.realowner,
 106                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 107                                 self.realowner.origin + self.realowner.view_ofs,
 108                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 109
 110                         if(accuracy_isgooddamage(self.realowner, trace_ent))
 111                                 accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage);
 112
 113                         // draw large red flash for debugging
 114                         //te_customflash(targpos, 200, 2, '15 0 0');
 115
 116                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 117                         {
 118                                 self.swing_alreadyhit = trace_ent;
 119                                 continue; // move along to next trace
 120                         }
 121                         else
 122                         {
 123                                 remove(self);
 124                                 return;
 125                         }
 126                 }
 127         }
 128
 129         if(time >= self.cnt + meleetime)
 130         {
 131                 // melee is finished
 132                 remove(self);
 133                 return;
 134         }
 135         else
 136         {
 137                 // set up next frame
 138                 self.swing_prev = i;
 139                 self.nextthink = time;
 140         }
 141 }
 142
 143 void W_Shotgun_Attack2 (void)
 144 {
 145         sound (self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 146         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 147
 148         entity meleetemp;
 149         meleetemp = spawn();
 150         meleetemp.owner = meleetemp.realowner = self;
 151         meleetemp.think = shotgun_meleethink;
 152         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 153         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 154 }
 155
 156 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 157
 158 .float shotgun_primarytime;
 159
 160 float w_shotgun(float req)
 161 {
 162         float ammo_amount;
 163         if (req == WR_AIM)
 164                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 165                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 166                 else
 167                 {
 168                         if(autocvar_g_antilag_bullets)
 169                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 170                         else
 171                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 172                 }
 173
 174         else if (req == WR_THINK)
 175         {
 176                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 177                 {
 178                         // don't force reload an empty shotgun if its melee attack is active
 179                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 180                                 weapon_action(self.weapon, WR_RELOAD);
 181                 }
 182                 else
 183                 {
 184                         if (self.BUTTON_ATCK)
 185                         {
 186                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 187                                 {
 188                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 189                                         {
 190                                                 W_Shotgun_Attack();
 191                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 192                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 193                                         }
 194                                 }
 195                         }
 196                 }
 197                 if (self.clip_load >= 0) // we are not currently reloading
 198                 if (!self.crouch) // we are not currently crouching; this fixes an exploit where your melee anim is not visible, and besides wouldn't make much sense
 199                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 200                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 201                 {
 202                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 203                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 204                 }
 205         }
 206         else if (req == WR_PRECACHE)
 207         {
 208                 precache_model ("models/uziflash.md3");
 209                 precache_model ("models/weapons/g_shotgun.md3");
 210                 precache_model ("models/weapons/v_shotgun.md3");
 211                 precache_model ("models/weapons/h_shotgun.iqm");
 212                 precache_sound ("misc/itempickup.wav");
 213                 precache_sound ("weapons/shotgun_fire.wav");
 214                 precache_sound ("weapons/shotgun_melee.wav");
 215                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 216         }
 217         else if (req == WR_SETUP)
 218         {
 219                 weapon_setup(WEP_SHOTGUN);
 220                 self.current_ammo = ammo_shells;
 221         }
 222         else if (req == WR_CHECKAMMO1)
 223         {
 224                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 225                 ammo_amount += self.(weapon_load[WEP_SHOTGUN]) >= autocvar_g_balance_shotgun_primary_ammo;
 226                 return ammo_amount;
 227         }
 228         else if (req == WR_CHECKAMMO2)
 229         {
 230                 // melee attack is always available
 231                 return TRUE;
 232         }
 233         else if (req == WR_RELOAD)
 234         {
 235                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 236         }
 237         return TRUE;
 238 }
 239 #endif
 240 #ifdef CSQC
 241 .float prevric;
 242 float w_shotgun(float req)
 243 {
 244         if(req == WR_IMPACTEFFECT)
 245         {
 246                 vector org2;
 247                 org2 = w_org + w_backoff * 2;
 248                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 249                 if(!w_issilent && time - self.prevric > 0.25)
 250                 {
 251                         if(w_random < 0.0165)
 252                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 253                         else if(w_random < 0.033)
 254                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 255                         else if(w_random < 0.05)
 256                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 257                         self.prevric = time;
 258                 }
 259         }
 260         else if(req == WR_PRECACHE)
 261         {
 262                 precache_sound("weapons/ric1.wav");
 263                 precache_sound("weapons/ric2.wav");
 264                 precache_sound("weapons/ric3.wav");
 265         }
 266         else if (req == WR_SUICIDEMESSAGE)
 267                 w_deathtypestring = _("%s is now thinking with portals");
 268         else if (req == WR_KILLMESSAGE)
 269         {
 270                 if(w_deathtype & HITTYPE_SECONDARY)
 271                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 272                 else
 273                         w_deathtypestring = _("%s was gunned by %s");
 274         }
 275         return TRUE;
 276 }
 277 #endif
 278 #endif