qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set clip_load to the weapon we have switched to, if the gun uses reloading
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  13         else
  14         {
  15                 self.clip_load = self.shotgun_load;
  16                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  17         }
  18 }
  19
  20 void W_Shotgun_ReloadedAndReady()
  21 {
  22         float t;
  23
  24         // now do the ammo transfer
  25         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  26         while(self.clip_load < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more ammo than we have
  27         {
  28                 self.clip_load += 1;
  29                 self.ammo_shells -= 1;
  30         }
  31         self.shotgun_load = self.clip_load;
  32
  33         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  34         ATTACK_FINISHED(self) = t;
  35         w_ready();
  36 }
  37
  38 void W_Shotgun_Reload()
  39 {
  40         // return if reloading is disabled for this weapon
  41         if(!autocvar_g_balance_shotgun_reload_ammo)
  42                 return;
  43
  44         if(!W_ReloadCheck(self.ammo_shells))
  45                 return;
  46
  47         float t;
  48
  49         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  50
  51         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  52         ATTACK_FINISHED(self) = t;
  53
  54         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  55
  56         self.old_clip_load = self.clip_load;
  57         self.clip_load = -1;
  58 }
  59
  60 void W_Shotgun_Attack (void)
  61 {
  62         float   sc;
  63         float   ammoamount;
  64         float   bullets;
  65         float   d;
  66         float   f;
  67         float   spread;
  68         float   bulletspeed;
  69         float   bulletconstant;
  70         local entity flash;
  71
  72         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  73         bullets = autocvar_g_balance_shotgun_primary_bullets;
  74         d = autocvar_g_balance_shotgun_primary_damage;
  75         f = autocvar_g_balance_shotgun_primary_force;
  76         spread = autocvar_g_balance_shotgun_primary_spread;
  77         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  78         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  79
  80         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  81         for (sc = 0;sc < bullets;sc = sc + 1)
  82                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  83         endFireBallisticBullet();
  84
  85         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  86
  87         // casing code
  88         if (autocvar_g_casings >= 1)
  89                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  90                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  91
  92         // muzzle flash for 1st person view
  93         flash = spawn();
  94         setmodel(flash, "models/uziflash.md3"); // precision set below
  95         flash.think = SUB_Remove;
  96         flash.nextthink = time + 0.06;
  97         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  98         W_AttachToShotorg(flash, '5 0 0');
  99
 100         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 101         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 102         {
 103                 if(autocvar_g_balance_shotgun_reload_ammo)
 104                 {
 105                         self.clip_load -= ammoamount;
 106                         self.shotgun_load = self.clip_load;
 107                 }
 108                 else
 109                         self.ammo_shells -= ammoamount;
 110         }
 111 }
 112
 113 void shotgun_meleethink (void)
 114 {
 115         // store time when we started swinging down inside self.cnt
 116         if(!self.cnt)
 117                 self.cnt = time;
 118
 119         makevectors(self.owner.v_angle);
 120         vector angle;
 121         angle = v_forward;
 122
 123         float meleetime;
 124         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 125
 126         // perform trace
 127         float f;
 128         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 129         vector targpos;
 130         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 131
 132         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 133
 134         // apply the damage, also remove self
 135         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 136         {
 137                 vector force;
 138                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 139                 if(accuracy_isgooddamage(self.owner, trace_ent))
 140                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 141                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 142                 remove(self);
 143         }
 144         else if(time >= self.cnt + meleetime) // missed, remove ent
 145                 remove(self);
 146         else // continue swinging the weapon in hope of hitting someone :)
 147                 self.nextthink = time;
 148 }
 149
 150 void W_Shotgun_Attack2 (void)
 151 {
 152         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 153         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 154
 155         entity meleetemp;
 156         meleetemp = spawn();
 157         meleetemp.owner = self;
 158         meleetemp.think = shotgun_meleethink;
 159         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 160         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 161 }
 162
 163 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 164
 165 .float shotgun_primarytime;
 166
 167 float w_shotgun(float req)
 168 {
 169         if (req == WR_AIM)
 170                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 171                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 172                 else
 173                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 174         else if (req == WR_THINK)
 175         {
 176                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 177                         W_Shotgun_Reload();
 178                 else
 179                 {
 180                         if (self.BUTTON_ATCK)
 181                         {
 182                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 183                                 {
 184                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 185                                         {
 186                                                 W_Shotgun_Attack();
 187                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 188                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 189                                         }
 190                                 }
 191                         }
 192                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 193                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 194                         {
 195                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 196                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 197                         }
 198                 }
 199         if(self.wish_reload)
 200         {
 201             if(self.switchweapon == self.weapon)
 202             {
 203                 if(self.weaponentity.state == WS_READY)
 204                 {
 205                     self.wish_reload = 0;
 206                     W_Shotgun_Reload();
 207                 }
 208             }
 209         }
 210         }
 211         else if (req == WR_PRECACHE)
 212         {
 213                 precache_model ("models/uziflash.md3");
 214                 precache_model ("models/weapons/g_shotgun.md3");
 215                 precache_model ("models/weapons/v_shotgun.md3");
 216                 precache_model ("models/weapons/h_shotgun.iqm");
 217                 precache_sound ("misc/itempickup.wav");
 218                 precache_sound ("weapons/shotgun_fire.wav");
 219                 precache_sound ("weapons/shotgun_melee.wav");
 220                 precache_sound ("weapons/reload.wav");
 221         }
 222         else if (req == WR_SETUP)
 223         {
 224                 weapon_setup(WEP_SHOTGUN);
 225                 W_Shotgun_SetAmmoCounter();
 226         }
 227         else if (req == WR_CHECKAMMO1)
 228         {
 229                 if(autocvar_g_balance_shotgun_reload_ammo)
 230                         return self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 231                 else
 232                         return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 233         }
 234         else if (req == WR_CHECKAMMO2)
 235         {
 236                 return TRUE;
 237         }
 238         else if (req == WR_RELOAD)
 239         {
 240                 W_Shotgun_Reload();
 241         }
 242         return TRUE;
 243 };
 244 #endif
 245 #ifdef CSQC
 246 .float prevric;
 247 float w_shotgun(float req)
 248 {
 249         if(req == WR_IMPACTEFFECT)
 250         {
 251                 vector org2;
 252                 org2 = w_org + w_backoff * 2;
 253                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 254                 if(!w_issilent && time - self.prevric > 0.25)
 255                 {
 256                         if(w_random < 0.0165)
 257                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 258                         else if(w_random < 0.033)
 259                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 260                         else if(w_random < 0.05)
 261                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 262                         self.prevric = time;
 263                 }
 264         }
 265         else if(req == WR_PRECACHE)
 266         {
 267                 precache_sound("weapons/ric1.wav");
 268                 precache_sound("weapons/ric2.wav");
 269                 precache_sound("weapons/ric3.wav");
 270         }
 271         else if (req == WR_SUICIDEMESSAGE)
 272                 w_deathtypestring = "%s did the impossible";
 273         else if (req == WR_KILLMESSAGE)
 274         {
 275                 if(w_deathtype & HITTYPE_SECONDARY)
 276                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 277                 else
 278                         w_deathtypestring = "%s was gunned by %s";
 279         }
 280         return TRUE;
 281 }
 282 #endif
 283 #endif