qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set clip_load to the weapon we have switched to, if the gun uses reloading
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  13         else
  14         {
  15                 self.clip_load = self.shotgun_load;
  16                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  17         }
  18 }
  19
  20 void W_Shotgun_ReloadedAndReady()
  21 {
  22         float t;
  23
  24         // now do the ammo transfer
  25         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  26         while(self.clip_load < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more ammo than we have
  27         {
  28                 self.clip_load += 1;
  29                 self.ammo_shells -= 1;
  30         }
  31         self.shotgun_load = self.clip_load;
  32
  33         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  34         ATTACK_FINISHED(self) = t;
  35         w_ready();
  36 }
  37
  38 void W_Shotgun_Reload()
  39 {
  40         // return if reloading is disabled for this weapon
  41         if(!autocvar_g_balance_shotgun_reload_ammo)
  42                 return;
  43
  44         if(!W_ReloadCheck(self.ammo_shells))
  45                 return;
  46
  47         float t;
  48
  49         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  50
  51         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  52         ATTACK_FINISHED(self) = t;
  53
  54         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  55
  56         self.old_clip_load = self.clip_load;
  57         self.clip_load = -1;
  58 }
  59
  60 void W_Shotgun_Attack (void)
  61 {
  62         float   sc;
  63         float   ammoamount;
  64         float   bullets;
  65         float   d;
  66         float   f;
  67         float   spread;
  68         float   bulletspeed;
  69         float   bulletconstant;
  70         local entity flash;
  71
  72         if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load <= 0)
  73                 return; // reloading, so we are done
  74
  75         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  76         bullets = autocvar_g_balance_shotgun_primary_bullets;
  77         d = autocvar_g_balance_shotgun_primary_damage;
  78         f = autocvar_g_balance_shotgun_primary_force;
  79         spread = autocvar_g_balance_shotgun_primary_spread;
  80         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  81         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  82
  83         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  84         for (sc = 0;sc < bullets;sc = sc + 1)
  85                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  86         endFireBallisticBullet();
  87
  88         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  89
  90         // casing code
  91         if (autocvar_g_casings >= 1)
  92                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  93                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  94
  95         // muzzle flash for 1st person view
  96         flash = spawn();
  97         setmodel(flash, "models/uziflash.md3"); // precision set below
  98         flash.think = SUB_Remove;
  99         flash.nextthink = time + 0.06;
 100         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 101         W_AttachToShotorg(flash, '5 0 0');
 102
 103         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 104         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 105         {
 106                 if(autocvar_g_balance_shotgun_reload_ammo)
 107                 {
 108                         self.clip_load -= ammoamount;
 109                         self.shotgun_load = self.clip_load;
 110                 }
 111                 else
 112                         self.ammo_shells -= ammoamount;
 113         }
 114 }
 115
 116 void shotgun_meleethink (void)
 117 {
 118         // store time when we started swinging down inside self.cnt
 119         if(!self.cnt)
 120                 self.cnt = time;
 121
 122         makevectors(self.owner.v_angle);
 123         vector angle;
 124         angle = v_forward;
 125
 126         float meleetime;
 127         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 128
 129         // perform trace
 130         float f;
 131         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 132         vector targpos;
 133         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 134
 135         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 136
 137         // apply the damage, also remove self
 138         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 139         {
 140                 vector force;
 141                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 142                 if(accuracy_isgooddamage(self.owner, trace_ent))
 143                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 144                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 145                 remove(self);
 146         }
 147         else if(time >= self.cnt + meleetime) // missed, remove ent
 148                 remove(self);
 149         else // continue swinging the weapon in hope of hitting someone :)
 150                 self.nextthink = time;
 151 }
 152
 153 void W_Shotgun_Attack2 (void)
 154 {
 155         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 156         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 157
 158         entity meleetemp;
 159         meleetemp = spawn();
 160         meleetemp.owner = self;
 161         meleetemp.think = shotgun_meleethink;
 162         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 163         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 164 }
 165
 166 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 167
 168 .float shotgun_primarytime;
 169
 170 float w_shotgun(float req)
 171 {
 172         if (req == WR_AIM)
 173                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 174                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 175                 else
 176                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 177         else if (req == WR_THINK)
 178         {
 179                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 180                         W_Shotgun_Reload();
 181                 else
 182                 {
 183                         if (self.BUTTON_ATCK)
 184                         {
 185                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 186                                 {
 187                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 188                                         {
 189                                                 W_Shotgun_Attack();
 190                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 191                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 192                                         }
 193                                 }
 194                         }
 195                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 196                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 197                         {
 198                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 199                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 200                         }
 201                 }
 202         if(self.wish_reload)
 203         {
 204             if(self.switchweapon == self.weapon)
 205             {
 206                 if(self.weaponentity.state == WS_READY)
 207                 {
 208                     self.wish_reload = 0;
 209                     W_Shotgun_Reload();
 210                 }
 211             }
 212         }
 213         }
 214         else if (req == WR_PRECACHE)
 215         {
 216                 precache_model ("models/uziflash.md3");
 217                 precache_model ("models/weapons/g_shotgun.md3");
 218                 precache_model ("models/weapons/v_shotgun.md3");
 219                 precache_model ("models/weapons/h_shotgun.iqm");
 220                 precache_sound ("misc/itempickup.wav");
 221                 precache_sound ("weapons/shotgun_fire.wav");
 222                 precache_sound ("weapons/shotgun_melee.wav");
 223                 precache_sound ("weapons/reload.wav");
 224         }
 225         else if (req == WR_SETUP)
 226         {
 227                 weapon_setup(WEP_SHOTGUN);
 228                 W_Shotgun_SetAmmoCounter();
 229         }
 230         else if (req == WR_CHECKAMMO1)
 231         {
 232                 if(autocvar_g_balance_shotgun_reload_ammo)
 233                         return self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 234                 else
 235                         return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 236         }
 237         else if (req == WR_CHECKAMMO2)
 238         {
 239                 return TRUE;
 240         }
 241         else if (req == WR_RELOAD)
 242         {
 243                 W_Shotgun_Reload();
 244         }
 245         return TRUE;
 246 };
 247 #endif
 248 #ifdef CSQC
 249 .float prevric;
 250 float w_shotgun(float req)
 251 {
 252         if(req == WR_IMPACTEFFECT)
 253         {
 254                 vector org2;
 255                 org2 = w_org + w_backoff * 2;
 256                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 257                 if(!w_issilent && time - self.prevric > 0.25)
 258                 {
 259                         if(w_random < 0.0165)
 260                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 261                         else if(w_random < 0.033)
 262                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 263                         else if(w_random < 0.05)
 264                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 265                         self.prevric = time;
 266                 }
 267         }
 268         else if(req == WR_PRECACHE)
 269         {
 270                 precache_sound("weapons/ric1.wav");
 271                 precache_sound("weapons/ric2.wav");
 272                 precache_sound("weapons/ric3.wav");
 273         }
 274         else if (req == WR_SUICIDEMESSAGE)
 275                 w_deathtypestring = "%s did the impossible";
 276         else if (req == WR_KILLMESSAGE)
 277         {
 278                 if(w_deathtype & HITTYPE_SECONDARY)
 279                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 280                 else
 281                         w_deathtypestring = "%s was gunned by %s";
 282         }
 283         return TRUE;
 284 }
 285 #endif
 286 #endif