qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
  18         bullets = cvar("g_balance_shotgun_primary_bullets");
  19         d = cvar("g_balance_shotgun_primary_damage");
  20         f = cvar("g_balance_shotgun_primary_force");
  21         spread = cvar("g_balance_shotgun_primary_spread");
  22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
  23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
  24
  25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_primary_damage"));
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
  33
  34         // casing code
  35         if (cvar("g_casings") >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void W_Shotgun_Attack2 (void)
  50 {
  51         float   sc;
  52         float   ammoamount;
  53         float   bullets;
  54         float   d;
  55         float   f;
  56         float   spread;
  57         float   bulletspeed;
  58         float   bulletconstant;
  59         local entity flash;
  60
  61         ammoamount = cvar("g_balance_shotgun_secondary_ammo");
  62         bullets = cvar("g_balance_shotgun_secondary_bullets");
  63         d = cvar("g_balance_shotgun_secondary_damage");
  64         f = cvar("g_balance_shotgun_secondary_force");
  65         spread = cvar("g_balance_shotgun_secondary_spread");
  66         bulletspeed = cvar("g_balance_shotgun_secondary_speed");
  67         bulletconstant = cvar("g_balance_shotgun_secondary_bulletconstant");
  68
  69         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_secondary_damage"));
  70         for (sc = 0;sc < bullets;sc = sc + 1)
  71                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN | HITTYPE_SECONDARY, 0, 1, bulletconstant);
  72         endFireBallisticBullet();
  73         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  74                 self.ammo_shells = self.ammo_shells - ammoamount;
  75
  76         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_secondary_ammo"));
  77
  78         // casing code
  79         if (cvar("g_casings") >= 1)
  80                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  81                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  82
  83         flash = spawn();
  84         setmodel(flash, "models/uziflash.md3"); // precision set below
  85         flash.scale = 1.2;
  86         flash.think = SUB_Remove;
  87         flash.nextthink = time + 0.06;
  88         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  89         W_AttachToShotorg(flash, '5 0 0');
  90 }
  91
  92 void shotgun_meleethink (void)
  93 {
  94         makevectors(self.owner.v_angle);
  95         vector angle;
  96         angle = v_forward;
  97
  98         // broken? fix, needs to be easier to hit
  99         //WarpZone_tracebox_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") - (v_right + v_up) * cvar("g_balance_shotgun_secondary_melee_size"), self.owner.origin + self.owner.view_ofs + (v_right + v_up) * cvar("g_balance_shotgun_secondary_melee_size"), self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 100         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 101
 102         // apply the damage
 103         if(trace_fraction < 1)
 104         {
 105                 vector force;
 106                 force = angle * cvar("g_balance_shotgun_secondary_force");
 107                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage"), WEP_SHOTGUN, self.owner.origin + self.owner.view_ofs, force);
 108         }
 109         remove(self);
 110 }
 111
 112 void W_Shotgun_Attack3 (void)
 113 {
 114         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 115
 116         entity meleetemp;
 117         meleetemp = spawn();
 118         meleetemp.owner = self;
 119         meleetemp.think = shotgun_meleethink;
 120         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
 121 }
 122
 123 // weapon frames
 124 void shotgun_fire2_03()
 125 {
 126         W_Shotgun_Attack2();
 127         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 128 }
 129 void shotgun_fire2_02()
 130 {
 131         W_Shotgun_Attack2();
 132         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_03);
 133 }
 134
 135 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 136
 137 float w_shotgun(float req)
 138 {
 139         if (req == WR_AIM)
 140                 if(vlen(self.origin-self.enemy.origin)>200)
 141                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 142                 else
 143                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 144         else if (req == WR_THINK)
 145         {
 146                 if (self.BUTTON_ATCK)
 147                 if (weapon_prepareattack(0, cvar("g_balance_shotgun_primary_refire")))
 148                 {
 149                         W_Shotgun_Attack();
 150                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
 151                 }
 152                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
 153                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
 154                 {
 155                         if(cvar("g_balance_shotgun_secondary_melee"))
 156                         {
 157                                 // force playback of the anim by switching to another anim (that we never play) here...
 158                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack3);
 159                         }
 160                         else
 161                         {
 162                                 W_Shotgun_Attack2();
 163                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_02);
 164                         }
 165                 }
 166         }
 167         else if (req == WR_PRECACHE)
 168         {
 169                 precache_model ("models/uziflash.md3");
 170                 precache_model ("models/weapons/g_shotgun.md3");
 171                 precache_model ("models/weapons/v_shotgun.md3");
 172                 precache_model ("models/weapons/h_shotgun.iqm");
 173                 precache_sound ("misc/itempickup.wav");
 174                 precache_sound ("weapons/shotgun_fire.wav");
 175         }
 176         else if (req == WR_SETUP)
 177                 weapon_setup(WEP_SHOTGUN);
 178         else if (req == WR_CHECKAMMO1)
 179                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
 180         else if (req == WR_CHECKAMMO2)
 181         {
 182                 if(cvar("g_balance_shotgun_secondary_melee"))
 183                         return TRUE;
 184                 return self.ammo_shells >= cvar("g_balance_shotgun_secondary_ammo") * 3;
 185         }
 186         return TRUE;
 187 };
 188 #endif
 189 #ifdef CSQC
 190 float w_shotgun(float req)
 191 {
 192         if(req == WR_IMPACTEFFECT)
 193         {
 194                 vector org2;
 195                 org2 = w_org + w_backoff * 2;
 196                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 197                 if(!w_issilent)
 198                 {
 199                         if(w_random < 0.05)
 200                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 201                         else if(w_random < 0.1)
 202                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 203                         else if(w_random < 0.2)
 204                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 205                 }
 206         }
 207         else if(req == WR_PRECACHE)
 208         {
 209                 precache_sound("weapons/ric1.wav");
 210                 precache_sound("weapons/ric2.wav");
 211                 precache_sound("weapons/ric3.wav");
 212         }
 213         else if (req == WR_SUICIDEMESSAGE)
 214                 w_deathtypestring = "did the impossible";
 215         else if (req == WR_KILLMESSAGE)
 216         {
 217                 w_deathtypestring = "was gunned by"; // unchecked: SECONDARY
 218         }
 219         return TRUE;
 220 }
 221 #endif
 222 #endif