qcsrc/server/waypointsprites.qc

   1 ..entity owned_by_field;
   2 .float rule;
   3 .string model1;
   4 .string model2;
   5 .string model3;
   6
   7 .float(entity) waypointsprite_visible_for_player;
   8
   9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  10 {
  11         if(m1 != e.model1)
  12         {
  13                 e.model1 = m1;
  14                 e.SendFlags |= 2;
  15         }
  16         if(m2 != e.model2)
  17         {
  18                 e.model2 = m2;
  19                 e.SendFlags |= 4;
  20         }
  21         if(m3 != e.model3)
  22         {
  23                 e.model3 = m3;
  24                 e.SendFlags |= 8;
  25         }
  26 }
  27
  28 void WaypointSprite_UpdateHealth(entity e, float f)
  29 {
  30         f = bound(0, f, e.max_health);
  31         if(f != e.health || e.pain_finished)
  32         {
  33                 e.health = f;
  34                 e.pain_finished = 0;
  35                 e.SendFlags |= 0x80;
  36         }
  37 }
  38
  39 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  40 {
  41         if(f != e.max_health || e.pain_finished)
  42         {
  43                 e.max_health = f;
  44                 e.pain_finished = 0;
  45                 e.SendFlags |= 0x80;
  46         }
  47 }
  48
  49 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  50 {
  51         if(f != e.pain_finished || e.max_health)
  52         {
  53                 e.max_health = 0;
  54                 e.pain_finished = f;
  55                 e.SendFlags |= 0x80;
  56         }
  57 }
  58
  59 void WaypointSprite_UpdateOrigin(entity e, vector o)
  60 {
  61         if(o != e.origin)
  62         {
  63                 setorigin(e, o);
  64                 e.SendFlags |= 64;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateRule(entity e, float t, float r)
  69 {
  70         // no check, as this is never called without doing an actual change (usually only once)
  71         e.rule = r;
  72         e.team = t;
  73         e.SendFlags |= 1;
  74 }
  75
  76 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  77 {
  78         // no check, as this is never called without doing an actual change (usually only once)
  79         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  80         e.colormod = col;
  81         e.SendFlags |= 32;
  82 }
  83
  84 .float waypointsprite_pingtime;
  85 .float waypointsprite_helpmetime;
  86 void WaypointSprite_Ping(entity e)
  87 {
  88         // anti spam
  89         if(time < e.waypointsprite_pingtime)
  90                 return;
  91         e.waypointsprite_pingtime = time + 0.3;
  92         // ALWAYS sends (this causes a radar circle), thus no check
  93         e.cnt |= 0x80;
  94         e.SendFlags |= 32;
  95 }
  96
  97 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
  98
  99 void WaypointSprite_HelpMePing(entity e)
 100 {
 101         WaypointSprite_Ping(e);
 102         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 103         e.SendFlags |= 32;
 104 }
 105
 106 void WaypointSprite_FadeOutIn(entity e, float t)
 107 {
 108         if(!e.fade_time)
 109         {
 110                 e.fade_time = t;
 111                 e.teleport_time = time + t;
 112         }
 113         else if(t < (e.teleport_time - time))
 114         {
 115                 // accelerate the waypoint's dying
 116                 // ensure:
 117                 //   (e.teleport_time - time) / wp.fade_time stays
 118                 //   e.teleport_time = time + fadetime
 119                 float current_fadetime;
 120                 current_fadetime = e.teleport_time - time;
 121                 e.teleport_time = time + t;
 122                 e.fade_time = e.fade_time * t / current_fadetime;
 123         }
 124
 125         e.SendFlags |= 16;
 126 }
 127
 128 void WaypointSprite_Init()
 129 {
 130         waypointsprite_limitedrange = autocvar_g_waypointsprite_limitedrange;
 131         waypointsprite_deployed_lifetime = autocvar_g_waypointsprite_deployed_lifetime;
 132         waypointsprite_deadlifetime = autocvar_g_waypointsprite_deadlifetime;
 133 }
 134 void WaypointSprite_InitClient(entity e)
 135 {
 136 }
 137
 138 void WaypointSprite_Kill(entity wp)
 139 {
 140         if(!wp)
 141                 return;
 142         if(wp.owner)
 143                 wp.owner.(wp.owned_by_field) = world;
 144         remove(wp);
 145 }
 146
 147 void WaypointSprite_Disown(entity wp, float fadetime)
 148 {
 149         if(!wp)
 150                 return;
 151         if(wp.classname != "sprite_waypoint")
 152         {
 153                 backtrace("Trying to disown a non-waypointsprite");
 154                 return;
 155         }
 156         if(wp.owner)
 157         {
 158                 if(wp.exteriormodeltoclient == wp.owner)
 159                         wp.exteriormodeltoclient = world;
 160                 wp.owner.(wp.owned_by_field) = world;
 161                 wp.owner = world;
 162
 163                 WaypointSprite_FadeOutIn(wp, fadetime);
 164         }
 165 }
 166
 167 void WaypointSprite_Think()
 168 {
 169         float doremove;
 170
 171         doremove = FALSE;
 172
 173         if(self.fade_time)
 174         {
 175                 if(time >= self.teleport_time)
 176                         doremove = TRUE;
 177         }
 178
 179         if(self.exteriormodeltoclient)
 180                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 181
 182         if(doremove)
 183                 WaypointSprite_Kill(self);
 184         else
 185                 self.nextthink = time; // WHY?!?
 186 }
 187
 188 float WaypointSprite_visible_for_player(entity e)
 189 {
 190         // personal waypoints
 191         if(self.enemy)
 192                 if(self.enemy != other)
 193                         return FALSE;
 194
 195         // team waypoints
 196         if(self.team && self.rule == SPRITERULE_DEFAULT)
 197         {
 198                 if(self.team != other.team)
 199                         return FALSE;
 200                 if(other.classname != "player")
 201                         return FALSE;
 202         }
 203
 204         return TRUE;
 205 }
 206
 207 float WaypointSprite_Customize()
 208 {
 209         // this is not in SendEntity because it shall run every frame, not just every update
 210
 211         // make spectators see what the player would see
 212         entity e;
 213         e = other;
 214         if(e.classname == "spectator")
 215                 e = e.enemy;
 216
 217         return self.waypointsprite_visible_for_player(e);
 218 }
 219
 220 float WaypointSprite_SendEntity(entity to, float sendflags)
 221 {
 222         float dt;
 223
 224         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 225
 226         sendflags = sendflags & 0x7F;
 227
 228         if(g_nexball)
 229                 sendflags &~= 0x80;
 230         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 231                 sendflags |= 0x80;
 232
 233         WriteByte(MSG_ENTITY, sendflags);
 234
 235         if(sendflags & 0x80)
 236         {
 237                 if(self.max_health)
 238                 {
 239                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 240                 }
 241                 else
 242                 {
 243                         dt = self.pain_finished - time;
 244                         dt = bound(0, dt * 32, 16383);
 245                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 246                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 247                 }
 248         }
 249
 250         if(sendflags & 64)
 251         {
 252                 WriteCoord(MSG_ENTITY, self.origin_x);
 253                 WriteCoord(MSG_ENTITY, self.origin_y);
 254                 WriteCoord(MSG_ENTITY, self.origin_z);
 255         }
 256
 257         if(sendflags & 1)
 258         {
 259                 WriteByte(MSG_ENTITY, self.team);
 260                 WriteByte(MSG_ENTITY, self.rule);
 261         }
 262
 263         if(sendflags & 2)
 264                 WriteString(MSG_ENTITY, self.model1);
 265
 266         if(sendflags & 4)
 267                 WriteString(MSG_ENTITY, self.model2);
 268
 269         if(sendflags & 8)
 270                 WriteString(MSG_ENTITY, self.model3);
 271
 272         if(sendflags & 16)
 273         {
 274                 WriteCoord(MSG_ENTITY, self.fade_time);
 275                 WriteCoord(MSG_ENTITY, self.teleport_time);
 276                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 277                 float f;
 278                 f = 0;
 279                 if(self.currentammo)
 280                         f |= 1; // hideable
 281                 if(self.exteriormodeltoclient == to)
 282                         f |= 2; // my own
 283                 WriteByte(MSG_ENTITY, f);
 284         }
 285
 286         if(sendflags & 32)
 287         {
 288                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 289                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 290                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 291                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 292
 293                 dt = (self.waypointsprite_helpmetime - time) / 0.1;
 294                 if(dt < 0)
 295                         dt = 0;
 296                 if(dt > 255)
 297                         dt = 255;
 298                 WriteByte(MSG_ENTITY, dt);
 299         }
 300
 301         return TRUE;
 302 }
 303
 304 void WaypointSprite_Reset()
 305 {
 306         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 307
 308         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 309                 WaypointSprite_Kill(self);
 310 }
 311
 312 entity WaypointSprite_Spawn(
 313         string spr, // sprite
 314         float lifetime, float maxdistance, // lifetime, max distance
 315         entity ref, vector ofs, // position
 316         entity showto, float t, // show to whom? Use a flag to indicate a team
 317         entity own, .entity ownfield, // remove when own gets killed
 318         float hideable, // true when it should be controlled by cl_hidewaypoints
 319         float icon, vector rgb // initial icon and color
 320 )
 321 {
 322         entity wp;
 323         wp = spawn();
 324         wp.classname = "sprite_waypoint";
 325         wp.teleport_time = time + lifetime;
 326         wp.fade_time = lifetime;
 327         wp.exteriormodeltoclient = ref;
 328         if(ref)
 329         {
 330                 wp.view_ofs = ofs;
 331                 setorigin(wp, ref.origin + ofs);
 332         }
 333         else
 334                 setorigin(wp, ofs);
 335         wp.enemy = showto;
 336         wp.team = t;
 337         wp.owner = own;
 338         wp.currentammo = hideable;
 339         if(own)
 340         {
 341                 if(own.ownfield)
 342                         remove(own.ownfield);
 343                 own.ownfield = wp;
 344                 wp.owned_by_field = ownfield;
 345         }
 346         wp.fade_rate = maxdistance;
 347         wp.think = WaypointSprite_Think;
 348         wp.nextthink = time;
 349         wp.model1 = spr;
 350         wp.customizeentityforclient = WaypointSprite_Customize;
 351         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 352         wp.reset2 = WaypointSprite_Reset;
 353         wp.cnt = icon;
 354         wp.colormod = rgb;
 355         Net_LinkEntity(wp, FALSE, 0, WaypointSprite_SendEntity);
 356         return wp;
 357 }
 358
 359 entity WaypointSprite_SpawnFixed(
 360         string spr,
 361         vector ofs,
 362         entity own,
 363         .entity ownfield,
 364         float icon, vector rgb // initial icon and color
 365 )
 366 {
 367         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE, icon, rgb);
 368 }
 369
 370 .entity waypointsprite_deployed_fixed;
 371 entity WaypointSprite_DeployFixed(
 372         string spr,
 373         float limited_range,
 374         vector ofs,
 375         float icon, vector rgb // initial icon and color
 376 )
 377 {
 378         float t, maxdistance;
 379         if(teamplay)
 380                 t = self.team;
 381         else
 382                 t = 0;
 383         if(limited_range)
 384                 maxdistance = waypointsprite_limitedrange;
 385         else
 386                 maxdistance = 0;
 387         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE, icon, rgb);
 388 }
 389
 390 .entity waypointsprite_deployed_personal;
 391 entity WaypointSprite_DeployPersonal(
 392         string spr,
 393         vector ofs,
 394         float icon, vector rgb // initial icon and color
 395 )
 396 {
 397         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, FALSE, icon, rgb);
 398 }
 399
 400 .entity waypointsprite_attached;
 401 .entity waypointsprite_attachedforcarrier;
 402 entity WaypointSprite_Attach(
 403         string spr,
 404         float limited_range,
 405         float icon, vector rgb // initial icon and color
 406 )
 407 {
 408         float t, maxdistance;
 409         if(self.waypointsprite_attachedforcarrier)
 410                 return world; // can't attach to FC
 411         if(teamplay)
 412                 t = self.team;
 413         else
 414                 t = 0;
 415         if(limited_range)
 416                 maxdistance = waypointsprite_limitedrange;
 417         else
 418                 maxdistance = 0;
 419         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE, icon, rgb);
 420 }
 421
 422 entity WaypointSprite_AttachCarrier(
 423         string spr,
 424         entity carrier,
 425         float icon, vector rgb // initial icon and color
 426 )
 427 {
 428         entity e;
 429         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 430         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE, icon, rgb);
 431         if(e)
 432         {
 433                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent) * 2);
 434                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent));
 435         }
 436         return e;
 437 }
 438
 439 void WaypointSprite_DetachCarrier(entity carrier)
 440 {
 441         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 442 }
 443
 444 void WaypointSprite_ClearPersonal()
 445 {
 446         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 447 }
 448
 449 void WaypointSprite_ClearOwned()
 450 {
 451         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 452         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 453         WaypointSprite_Kill(self.waypointsprite_attached);
 454 }
 455
 456 void WaypointSprite_PlayerDead()
 457 {
 458         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 459         WaypointSprite_DetachCarrier(self);
 460 }
 461
 462 void WaypointSprite_PlayerGone()
 463 {
 464         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 465         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 466         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 467         WaypointSprite_DetachCarrier(self);
 468 }