qcsrc/server/weapons/throwing.qc

   1 #include "throwing.qh"
   2
   3 #include "weaponsystem.qh"
   4 #include "../resources.qh"
   5 #include "../items.qh"
   6 #include "../mutators/_mod.qh"
   7 #include <common/t_items.qh>
   8 #include "../g_damage.qh"
   9 #include <common/items/item.qh>
  10 #include <common/mapinfo.qh>
  11 #include <common/notifications/all.qh>
  12 #include <common/triggers/subs.qh>
  13 #include <common/util.qh>
  14 #include <common/weapons/_all.qh>
  15 #include <common/state.qh>
  16 #include <common/wepent.qh>
  17
  18 void thrown_wep_think(entity this)
  19 {
  20         this.nextthink = time;
  21         if(this.oldorigin != this.origin)
  22         {
  23                 this.SendFlags |= ISF_LOCATION;
  24                 this.oldorigin = this.origin;
  25         }
  26         this.owner = NULL;
  27         float timeleft = this.savenextthink - time;
  28         if(timeleft > 1)
  29                 SUB_SetFade(this, this.savenextthink - 1, 1);
  30         else if(timeleft > 0)
  31                 SUB_SetFade(this, time, timeleft);
  32         else
  33                 SUB_VanishOrRemove(this);
  34 }
  35
  36 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
  37 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo, .entity weaponentity)
  38 {
  39         float thisammo;
  40         string s;
  41         Weapon info = Weapons_from(wpn);
  42         int ammotype = info.ammo_type;
  43
  44         entity wep = new(droppedweapon);
  45         Item_SetLoot(wep, true);
  46         setorigin(wep, org);
  47         wep.velocity = velo;
  48         wep.owner = wep.enemy = own;
  49         wep.flags |= FL_TOSSED;
  50         wep.colormap = own.colormap;
  51         wep.glowmod = weaponentity_glowmod(info, own, own.clientcolors, own.(weaponentity));
  52         navigation_dynamicgoal_init(wep, false);
  53
  54         W_DropEvent(wr_drop,own,wpn,wep,weaponentity);
  55
  56         if(WepSet_FromWeapon(Weapons_from(wpn)) & WEPSET_SUPERWEAPONS)
  57         {
  58                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
  59                 {
  60                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
  61                 }
  62                 else
  63                 {
  64                         int superweapons = 1;
  65                         FOREACH(Weapons, it != WEP_Null, {
  66                                 WepSet set = it.m_wepset;
  67                                 if((set & WEPSET_SUPERWEAPONS) && (own.weapons & set)) ++superweapons;
  68                         });
  69                         if(superweapons <= 1)
  70                         {
  71                                 wep.superweapons_finished = own.superweapons_finished;
  72                                 own.superweapons_finished = 0;
  73                         }
  74                         else
  75                         {
  76                                 float timeleft = own.superweapons_finished - time;
  77                                 float weptimeleft = timeleft / superweapons;
  78                                 wep.superweapons_finished = time + weptimeleft;
  79                                 own.superweapons_finished -= weptimeleft;
  80                         }
  81                 }
  82         }
  83
  84         weapon_defaultspawnfunc(wep, info);
  85         if(startitem_failed)
  86                 return string_null;
  87         setthink(wep, thrown_wep_think);
  88         wep.savenextthink = wep.nextthink;
  89         wep.nextthink = min(wep.nextthink, time + 0.5);
  90         wep.pickup_anyway = true; // these are ALWAYS pickable
  91
  92         //wa = W_AmmoItemCode(wpn);
  93         if(ammotype == RESOURCE_NONE)
  94         {
  95                 return "";
  96         }
  97         else
  98         {
  99                 s = "";
 100
 101                 if(doreduce && g_weapon_stay == 2)
 102                 {
 103                         // if our weapon is loaded, give its load back to the player
 104                         int i = own.(weaponentity).m_weapon.m_id;
 105                         if(own.(weaponentity).(weapon_load[i]) > 0)
 106                         {
 107                                 GiveResource(own, ammotype, own.(weaponentity).(weapon_load[i]));
 108                                 own.(weaponentity).(weapon_load[i]) = -1; // schedule the weapon for reloading
 109                         }
 110                         SetResourceAmount(wep, ammotype, 0);
 111                 }
 112                 else if(doreduce)
 113                 {
 114                         // if our weapon is loaded, give its load back to the player
 115                         int i = own.(weaponentity).m_weapon.m_id;
 116                         if(own.(weaponentity).(weapon_load[i]) > 0)
 117                         {
 118                                 GiveResource(own, ammotype, own.(weaponentity).(weapon_load[i]));
 119                                 own.(weaponentity).(weapon_load[i]) = -1; // schedule the weapon for reloading
 120                         }
 121
 122                         float ownderammo = GetResourceAmount(own, ammotype);
 123                         thisammo = min(ownderammo, GetResourceAmount(wep, ammotype));
 124                         SetResourceAmount(wep, ammotype, thisammo);
 125                         SetResourceAmount(own, ammotype, ownderammo - thisammo);
 126
 127                         switch (ammotype)
 128                         {
 129                                 case RESOURCE_SHELLS:  s = sprintf("%s and %d shells", s, thisammo);  break;
 130                                 case RESOURCE_BULLETS: s = sprintf("%s and %d nails", s, thisammo);   break;
 131                                 case RESOURCE_ROCKETS: s = sprintf("%s and %d rockets", s, thisammo); break;
 132                                 case RESOURCE_CELLS:   s = sprintf("%s and %d cells", s, thisammo);   break;
 133                                 case RESOURCE_PLASMA:  s = sprintf("%s and %d plasma", s, thisammo);  break;
 134                                 case RESOURCE_FUEL:    s = sprintf("%s and %d fuel", s, thisammo);    break;
 135                         }
 136
 137                         s = substring(s, 5, -1);
 138                 }
 139                 return s;
 140         }
 141 }
 142
 143 bool W_IsWeaponThrowable(entity this, int w)
 144 {
 145         if (MUTATOR_CALLHOOK(ForbidDropCurrentWeapon, this, w))
 146                 return false;
 147         if (!autocvar_g_pickup_items)
 148                 return false;
 149         if (g_weaponarena)
 150                 return 0;
 151     if(w == WEP_Null.m_id)
 152         return false;
 153
 154         #if 0
 155         if(start_weapons & WepSet_FromWeapon(Weapons_from(w)))
 156         {
 157                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 158                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 159                         return false;
 160                 if((Weapons_from(w)).ammo_type == RESOURCE_NONE)
 161                         return false;
 162         }
 163         return true;
 164         #else
 165         return (Weapons_from(w)).weaponthrowable;
 166         #endif
 167 }
 168
 169 // toss current weapon
 170 void W_ThrowWeapon(entity this, .entity weaponentity, vector velo, vector delta, float doreduce)
 171 {
 172         Weapon w = this.(weaponentity).m_weapon;
 173         if (w == WEP_Null)
 174                 return; // just in case
 175         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon, this, this.(weaponentity)))
 176                 return;
 177         if(!autocvar_g_weapon_throwable)
 178                 return;
 179         if(this.(weaponentity).state != WS_READY)
 180                 return;
 181         if(!W_IsWeaponThrowable(this, w.m_id))
 182                 return;
 183
 184         WepSet set = WepSet_FromWeapon(w);
 185         if(!(this.weapons & set)) return;
 186         this.weapons &= ~set;
 187
 188         W_SwitchWeapon_Force(this, w_getbestweapon(this, weaponentity), weaponentity);
 189         string a = W_ThrowNewWeapon(this, w.m_id, doreduce, this.origin + delta, velo, weaponentity);
 190
 191         if(!a) return;
 192         Send_Notification(NOTIF_ONE, this, MSG_MULTI, ITEM_WEAPON_DROP, a, w.m_id);
 193 }
 194
 195 void SpawnThrownWeapon(entity this, vector org, Weapon wep, .entity weaponentity)
 196 {
 197         //entity wep = this.(weaponentity).m_weapon;
 198
 199         if(this.weapons & WepSet_FromWeapon(wep))
 200                 if(W_IsWeaponThrowable(this, wep.m_id))
 201                         W_ThrowNewWeapon(this, wep.m_id, false, org, randomvec() * 125 + '0 0 200', weaponentity);
 202 }