qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/all.qh"
   7 #include "../round_handler.qh"
   8 #include <common/t_items.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/constants.qh>
  11 #include <common/monsters/all.qh>
  12 #include <common/notifications/all.qh>
  13 #include <common/util.qh>
  14 #include <common/weapons/all.qh>
  15 #include <common/state.qh>
  16 #include <lib/csqcmodel/sv_model.qh>
  17
  18 .int state;
  19
  20 .float weapon_frametime;
  21
  22 float W_WeaponRateFactor()
  23 {
  24         float t = 1.0 / g_weaponratefactor;
  25
  26         MUTATOR_CALLHOOK(WeaponRateFactor, t);
  27         t = weapon_rate;
  28
  29         return t;
  30 }
  31
  32 float W_WeaponSpeedFactor()
  33 {
  34         float t = 1.0 * g_weaponspeedfactor;
  35
  36         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
  37         t = ret_float;
  38
  39         return t;
  40 }
  41
  42
  43 bool CL_Weaponentity_CustomizeEntityForClient()
  44 {
  45         SELFPARAM();
  46         this.viewmodelforclient = this.owner;
  47         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
  48         return true;
  49 }
  50
  51 vector CL_Weapon_GetShotOrg(int wpn)
  52 {
  53         entity wi = Weapons_from(wpn);
  54         entity e = spawn();
  55         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  56         vector ret = e.movedir;
  57         CL_WeaponEntity_SetModel(e, "", false);
  58         remove(e);
  59         return ret;
  60 }
  61
  62 ..entity weaponentity_fld;
  63 .float m_alpha;
  64
  65 void CL_Weaponentity_Think()
  66 {
  67         SELFPARAM();
  68         this.nextthink = time;
  69         if (intermission_running) this.frame = this.anim_idle.x;
  70         .entity weaponentity = this.weaponentity_fld;
  71         if (this.owner.(weaponentity) != this)
  72         {
  73                 // owner has new gun; remove self
  74                 if (this.weaponchild) remove(this.weaponchild);
  75                 remove(this);
  76                 return;
  77         }
  78         if (IS_DEAD(self.owner))
  79         {
  80                 // owner died; disappear
  81                 this.model = "";
  82                 if (this.weaponchild) this.weaponchild.model = "";
  83                 return;
  84         }
  85         if (this.weaponname != this.owner.weaponname
  86             || this.dmg != this.owner.modelindex
  87             || this.deadflag != this.owner.deadflag)
  88         {
  89                 // owner changed weapons; update appearance
  90                 this.weaponname = this.owner.weaponname;
  91                 this.dmg = this.owner.modelindex;
  92                 this.deadflag = this.owner.deadflag;
  93
  94                 CL_WeaponEntity_SetModel(this, this.owner.weaponname, true);
  95         }
  96
  97         this.alpha = -1;  // TODO: don't render this entity at all
  98
  99         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 100         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 101         else this.m_alpha  = 1;
 102
 103         if (this.weaponchild)
 104         {
 105                 this.weaponchild.alpha = this.alpha;
 106                 this.weaponchild.effects = this.effects;
 107         }
 108 }
 109
 110 void CL_ExteriorWeaponentity_Think()
 111 {
 112         SELFPARAM();
 113         this.nextthink = time;
 114         if (this.owner.exteriorweaponentity != this)
 115         {
 116                 remove(this);
 117                 return;
 118         }
 119         if (IS_DEAD(self.owner))
 120         {
 121                 this.model = "";
 122                 return;
 123         }
 124         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 125             || this.deadflag != this.owner.deadflag)
 126         {
 127                 this.weaponname = this.owner.weaponname;
 128                 this.dmg = this.owner.modelindex;
 129                 this.deadflag = this.owner.deadflag;
 130                 if (this.owner.weaponname != "")
 131                 {
 132                         _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 133                         setsize(this, '0 0 0', '0 0 0');
 134                 }
 135                 else this.model = "";
 136
 137                 int tag_found;
 138                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 139                 {
 140                         this.tag_index = tag_found;
 141                         this.tag_entity = this.owner;
 142                 }
 143                 else
 144                 {
 145                         setattachment(this, this.owner, "bip01 r hand");
 146                 }
 147         }
 148         this.effects = this.owner.effects;
 149         this.effects |= EF_LOWPRECISION;
 150         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 151         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 152         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 153         else this.alpha = 1;
 154
 155     Weapon wep = PS(this.owner).m_weapon;
 156         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner.clientcolors);
 157         this.colormap = this.owner.colormap;
 158
 159         CSQCMODEL_AUTOUPDATE(this);
 160 }
 161
 162 // spawning weaponentity for client
 163 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 164 {
 165         entity view = actor.(weaponentity) = new(weaponentity);
 166         view.solid = SOLID_NOT;
 167         view.owner = actor;
 168         setmodel(view, MDL_Null);  // precision set when changed
 169         setorigin(view, '0 0 0');
 170         view.weaponentity_fld = weaponentity;
 171         view.think = CL_Weaponentity_Think;
 172         view.nextthink = time;
 173         view.viewmodelforclient = actor;
 174         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 175
 176         if (weaponentity == weaponentities[0])
 177         {
 178                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 179                 exterior.solid = SOLID_NOT;
 180                 exterior.owner = actor;
 181                 setorigin(exterior, '0 0 0');
 182                 exterior.think = CL_ExteriorWeaponentity_Think;
 183                 exterior.nextthink = time;
 184
 185                 CSQCMODEL_AUTOINIT(exterior);
 186         }
 187 }
 188
 189 // Weapon subs
 190 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 191 {
 192         PS(actor).m_weapon = WEP_Null;
 193         PS(actor).m_switchingweapon = WEP_Null;
 194         entity this = actor.(weaponentity);
 195         if (this)
 196         {
 197                 this.state = WS_CLEAR;
 198                 this.effects = 0;
 199         }
 200 }
 201
 202 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 203 {
 204         entity this = actor.(weaponentity);
 205         if (this) this.state = WS_READY;
 206         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 207 }
 208
 209 .float prevdryfire;
 210 .float prevwarntime;
 211 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 212 {
 213     SELFPARAM();
 214         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 215         bool ammo = false;
 216         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
 217         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
 218         if (ammo) return true;
 219         // always keep the Mine Layer if we placed mines, so that we can detonate them
 220         if (thiswep == WEP_MINE_LAYER)
 221                 for (entity mine; (mine = find(mine, classname, "mine")); )
 222                         if (mine.owner == actor) return false;
 223
 224         if (thiswep == WEP_SHOTGUN)
 225                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 226
 227         if (thiswep == PS(actor).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 228         {
 229                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 230                 actor.prevdryfire = time;
 231         }
 232
 233         // check if the other firing mode has enough ammo
 234         bool ammo_other = false;
 235         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
 236         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
 237         if (ammo_other)
 238         {
 239                 if (time - actor.prevwarntime > 1)
 240                 {
 241                         Send_Notification(
 242                                 NOTIF_ONE,
 243                                 actor,
 244                                 MSG_MULTI,
 245                                 ITEM_WEAPON_PRIMORSEC,
 246                                 thiswep.m_id,
 247                                 secondary,
 248                                 (1 - secondary)
 249                                          );
 250                 }
 251                 actor.prevwarntime = time;
 252         }
 253         else  // this weapon is totally unable to fire, switch to another one
 254         {
 255                 W_SwitchToOtherWeapon(actor);
 256         }
 257
 258         return false;
 259 }
 260
 261 .float race_penalty;
 262 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 263 {
 264         if (actor.weaponentity == NULL) return true;
 265         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 266
 267         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 268         // if all players readied up and the countdown is running
 269         if (time < game_starttime || time < actor.race_penalty) return false;
 270
 271         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 272                 return false;
 273
 274         // do not even think about shooting if switching
 275         if (PS(actor).m_switchweapon != PS(actor).m_weapon) return false;
 276
 277         if (attacktime >= 0)
 278         {
 279                 int slot = weaponslot(weaponentity);
 280                 // don't fire if previous attack is not finished
 281                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 282                 entity this = actor.(weaponentity);
 283                 // don't fire while changing weapon
 284                 if (this.state != WS_READY) return false;
 285         }
 286         return true;
 287 }
 288
 289 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 290 {
 291         entity this = actor.(weaponentity);
 292         if (this == NULL) return;
 293         this.state = WS_INUSE;
 294
 295         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 296
 297         // if the weapon hasn't been firing continuously, reset the timer
 298         if (attacktime >= 0)
 299         {
 300                 int slot = weaponslot(weaponentity);
 301                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 302                 {
 303                         ATTACK_FINISHED(actor, slot) = time;
 304                         // dprint("resetting attack finished to ", ftos(time), "\n");
 305                 }
 306                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
 307         }
 308         actor.bulletcounter += 1;
 309         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 310 }
 311
 312 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 313 {
 314         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 315         {
 316                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 317                 return true;
 318         }
 319         return false;
 320 }
 321
 322 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
 323
 324 /**
 325  * @param t defer thinking until time + t
 326  * @param func next think function
 327  */
 328 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 329         .entity weaponentity, int fire) func)
 330 {
 331         entity this = actor.(weaponentity);
 332         if (this == NULL) return;
 333         bool restartanim;
 334         if (fr == WFRAME_DONTCHANGE)
 335         {
 336                 fr = this.wframe;
 337                 restartanim = false;
 338         }
 339         else
 340         {
 341                 restartanim = fr != WFRAME_IDLE;
 342         }
 343
 344         vector of = v_forward;
 345         vector or = v_right;
 346         vector ou = v_up;
 347
 348         vector a = '0 0 0';
 349     this.wframe = fr;
 350     if (fr == WFRAME_IDLE) a = this.anim_idle;
 351     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 352     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 353     else  // if (fr == WFRAME_RELOAD)
 354         a = this.anim_reload;
 355     a.z *= g_weaponratefactor;
 356
 357         v_forward = of;
 358         v_right = or;
 359         v_up = ou;
 360
 361         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 362                         "Tried to override initial weapon think function - should this really happen?");
 363
 364         t *= W_WeaponRateFactor();
 365
 366         // VorteX: haste can be added here
 367         if (this.weapon_think == w_ready)
 368         {
 369                 this.weapon_nextthink = time;
 370                 // dprint("started firing at ", ftos(time), "\n");
 371         }
 372         if (this.weapon_nextthink < time - actor.weapon_frametime * 1.5
 373             || this.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 374         {
 375                 this.weapon_nextthink = time;
 376                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 377         }
 378         this.weapon_nextthink += t;
 379         if (weaponentity == weaponentities[0]) STAT(WEAPON_NEXTTHINK, actor) = this.weapon_nextthink;
 380         this.weapon_think = func;
 381         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 382
 383         if (this)
 384         {
 385                 FOREACH_CLIENT(true, LAMBDA(
 386                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 387                                 wframe_send(it, this, a, restartanim);
 388                 ));
 389         }
 390
 391         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 392         {
 393                 int act = (fr == WFRAME_FIRE2 && (PS(actor).m_weapon == WEP_SHOCKWAVE || PS(actor).m_weapon == WEP_SHOTGUN))
 394                         ? ANIMACTION_MELEE
 395                         : ANIMACTION_SHOOT
 396                         ;
 397                 animdecide_setaction(actor, act, restartanim);
 398         }
 399         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 400         {
 401                 actor.anim_upper_action = 0;
 402         }
 403 }
 404
 405 bool forbidWeaponUse(entity player)
 406 {
 407         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 408         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 409         if (player.player_blocked) return true;
 410         if (STAT(FROZEN, player)) return true;
 411         if (player.weapon_blocked) return true;
 412         return false;
 413 }
 414
 415 .bool hook_switchweapon;
 416
 417 void W_WeaponFrame(entity actor)
 418 {
 419         .entity weaponentity = weaponentities[0];  // TODO: unhardcode
 420         entity this = actor.(weaponentity);
 421         if (frametime) actor.weapon_frametime = frametime;
 422
 423         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 424
 425
 426         if (forbidWeaponUse(actor))
 427         {
 428                 if (actor.(weaponentity).state != WS_CLEAR)
 429                 {
 430                         Weapon wpn = PS(actor).m_weapon;
 431                         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 432                         return;
 433                 }
 434         }
 435
 436         if (PS(actor).m_switchweapon == WEP_Null)
 437         {
 438                 PS(actor).m_weapon = WEP_Null;
 439                 PS(actor).m_switchingweapon = WEP_Null;
 440                 this.state = WS_CLEAR;
 441                 actor.weaponname = "";
 442                 // actor.items &= ~IT_AMMO;
 443                 return;
 444         }
 445
 446         makevectors(actor.v_angle);
 447         vector fo = v_forward;  // save them in case the weapon think functions change it
 448         vector ri = v_right;
 449         vector up = v_up;
 450
 451         // Change weapon
 452         if (PS(actor).m_weapon != PS(actor).m_switchweapon)
 453         {
 454                 switch (this.state)
 455                 {
 456                         default:
 457                                 LOG_WARNINGF("unhandled weaponentity (%i) state for player (%i): %d\n", this, actor, this.state);
 458                                 break;
 459                         case WS_INUSE:
 460                         case WS_RAISE:
 461                                 break;
 462                         case WS_CLEAR:
 463                         {
 464                                 // end switching!
 465                                 Weapon newwep = PS(actor).m_switchweapon;
 466                                 PS(actor).m_switchingweapon = newwep;
 467
 468                                 // the two weapon entities will notice this has changed and update their models
 469                                 PS(actor).m_weapon = newwep;
 470                                 actor.weaponname = newwep.mdl;
 471                                 actor.bulletcounter = 0;
 472                                 actor.ammo_field = newwep.ammo_field;
 473                                 newwep.wr_setup(newwep);
 474                                 this.state = WS_RAISE;
 475
 476                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 477                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 478                                 {
 479                                         actor.clip_load = actor.(weapon_load[PS(actor).m_switchweapon.m_id]);
 480                                         actor.clip_size = newwep.reloading_ammo;
 481                                 }
 482                                 else
 483                                 {
 484                                         actor.clip_load = actor.clip_size = 0;
 485                                 }
 486
 487                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 488                                 break;
 489                         }
 490                         case WS_DROP:
 491                         {
 492                                 // in dropping phase we can switch at any time
 493                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 494                                 break;
 495                         }
 496                         case WS_READY:
 497                         {
 498                                 // start switching!
 499                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 500                                 entity oldwep = PS(actor).m_weapon;
 501
 502                                 // set up weapon switch think in the future, and start drop anim
 503                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + actor.weapon_frametime * 0.5)
 504                                 {
 505                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 506                                         this.state = WS_DROP;
 507                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 508                                 }
 509                                 break;
 510                         }
 511                 }
 512         }
 513
 514         // LordHavoc: network timing test code
 515         // if (actor.button0)
 516         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 517
 518         Weapon w = PS(actor).m_weapon;
 519
 520         // call the think code which may fire the weapon
 521         // and do so multiple times to resolve framerate dependency issues if the
 522         // server framerate is very low and the weapon fire rate very high
 523         for (int c = 0; c < W_TICSPERFRAME; ++c)
 524         {
 525                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 526                 {
 527                         if (PS(actor).m_weapon == PS(actor).m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 528                         w = WEP_Null;
 529                 }
 530
 531                 v_forward = fo;
 532                 v_right = ri;
 533                 v_up = up;
 534
 535                 bool block_weapon = false;
 536                 {
 537                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 538                         Weapon off = actor.offhand;
 539                         if (off && !(actor.weapons & WEPSET(HOOK)))
 540                         {
 541                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 542                         }
 543                         else
 544                         {
 545                                 if (key_pressed && PS(actor).m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 546                                         W_SwitchWeapon(WEP_HOOK);
 547                                 actor.hook_switchweapon = key_pressed;
 548                                 Weapon h = WEP_HOOK;
 549                                 block_weapon = (PS(actor).m_weapon == h && (PHYS_INPUT_BUTTON_ATCK(actor) || key_pressed));
 550                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 551                         }
 552                 }
 553
 554                 v_forward = fo;
 555                 v_right = ri;
 556                 v_up = up;
 557
 558                 if (!block_weapon)
 559                 {
 560             Weapon e = PS(actor).m_weapon;
 561                         if (w != WEP_Null)
 562                         {
 563                                 e.wr_think(e, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 564                         }
 565                         else
 566                         {
 567                                 e.wr_gonethink(e);
 568                         }
 569                 }
 570
 571                 if (time + actor.weapon_frametime * 0.5 >= this.weapon_nextthink)
 572                 {
 573                         if (this.weapon_think)
 574                         {
 575                                 v_forward = fo;
 576                                 v_right = ri;
 577                                 v_up = up;
 578                                 Weapon wpn = PS(actor).m_weapon;
 579                                 this.weapon_think(wpn, actor, weaponentity,
 580                                         PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 581                         }
 582                         else
 583                         {
 584                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 585                         }
 586                 }
 587         }
 588 }
 589
 590 void W_AttachToShotorg(entity actor, entity flash, vector offset)
 591 {
 592         .entity weaponentity = weaponentities[0];
 593         flash.owner = actor;
 594         flash.angles_z = random() * 360;
 595
 596         entity view = actor.(weaponentity);
 597         entity exterior = actor.exteriorweaponentity;
 598
 599         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 600         else setattachment(flash, view, "tag_shot");
 601         setorigin(flash, offset);
 602
 603         entity xflash = spawn();
 604         copyentity(flash, xflash);
 605
 606         flash.viewmodelforclient = actor;
 607
 608         if (view.oldorigin.x > 0)
 609         {
 610                 setattachment(xflash, exterior, "");
 611                 setorigin(xflash, view.oldorigin + offset);
 612         }
 613         else
 614         {
 615                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 616                 else setattachment(xflash, exterior, "tag_shot");
 617                 setorigin(xflash, offset);
 618         }
 619 }
 620
 621 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 622 {
 623         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor)) return;
 624
 625         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 626
 627         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 628         if (wep.reloading_ammo)
 629         {
 630                 actor.clip_load -= ammo_use;
 631                 actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 632         }
 633         else if (wep.ammo_field != ammo_none)
 634         {
 635                 actor.(wep.ammo_field) -= ammo_use;
 636                 if (actor.(wep.ammo_field) < 0)
 637                 {
 638                         backtrace(sprintf(
 639                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 640                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 641                                 ammo_use,
 642                                 wep.netname,
 643                                 GetAmmoPicture(wep.ammo_field),
 644                                 actor.netname,
 645                                 actor.(wep.ammo_field)
 646                                              ));
 647                 }
 648         }
 649 }
 650
 651 // weapon reloading code
 652
 653 .float reload_ammo_amount, reload_ammo_min, reload_time;
 654 .float reload_complain;
 655 .string reload_sound;
 656
 657 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 658 {
 659         // finish the reloading process, and do the ammo transfer
 660
 661         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 662
 663         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 664         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 665         {
 666                 actor.clip_load = actor.reload_ammo_amount;
 667         }
 668         else
 669         {
 670                 // make sure we don't add more ammo than we have
 671                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 672                 actor.clip_load += load;
 673                 actor.(actor.ammo_field) -= load;
 674         }
 675         actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 676
 677         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 678         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 679         // so your weapon is disabled for a few seconds without reason
 680
 681         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 682
 683         Weapon wpn = Weapons_from(PS(actor).m_weapon.m_id);
 684         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 685 }
 686
 687 void W_Reload(entity actor, float sent_ammo_min, Sound sent_sound)
 688 {
 689     TC(Sound, sent_sound);
 690         .entity weaponentity = weaponentities[0];
 691         // set global values to work with
 692         Weapon e = PS(actor).m_weapon;
 693
 694         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 695
 696         actor.reload_ammo_min = sent_ammo_min;
 697         actor.reload_ammo_amount = e.reloading_ammo;
 698         actor.reload_time = e.reloading_time;
 699         if (actor.reload_sound) strunzone(actor.reload_sound);
 700         actor.reload_sound = strzone(Sound_fixpath(sent_sound));
 701
 702         // don't reload weapons that don't have the RELOADABLE flag
 703         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 704         {
 705                 LOG_TRACE(
 706                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 707                 return;
 708         }
 709
 710         // return if reloading is disabled for this weapon
 711         if (!actor.reload_ammo_amount) return;
 712
 713         // our weapon is fully loaded, no need to reload
 714         if (actor.clip_load >= actor.reload_ammo_amount) return;
 715
 716         // no ammo, so nothing to load
 717         if (actor.ammo_field != ammo_none)
 718         {
 719                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
 720                 {
 721                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 722                         {
 723                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 724                                 {
 725                                         play2(actor, SND(UNAVAILABLE));
 726                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", PS(actor).m_weapon.m_name, "\n"));
 727                                         actor.reload_complain = time + 1;
 728                                 }
 729                                 // switch away if the amount of ammo is not enough to keep using this weapon
 730                                 Weapon w = PS(actor).m_weapon;
 731                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
 732                                 {
 733                                         actor.clip_load = -1;  // reload later
 734                                         W_SwitchToOtherWeapon(actor);
 735                                 }
 736                                 return;
 737                         }
 738                 }
 739         }
 740
 741         entity this = actor.(weaponentity);
 742         if (this)
 743         {
 744                 if (this.wframe == WFRAME_RELOAD) return;
 745
 746                 // allow switching away while reloading, but this will cause a new reload!
 747                 this.state = WS_READY;
 748         }
 749
 750         // now begin the reloading process
 751
 752         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 753
 754         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 755         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 756         // so your weapon is disabled for a few seconds without reason
 757
 758         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
 759
 760         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
 761
 762         if (actor.clip_load < 0) actor.clip_load = 0;
 763         actor.old_clip_load = actor.clip_load;
 764         actor.clip_load = actor.(weapon_load[PS(actor).m_weapon.m_id]) = -1;
 765 }
 766
 767 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
 768 {
 769     SELFPARAM();
 770         Weapon w = Weapons_from(weapon_type);
 771         weapon_dropevent_item = weapon_item;
 772         WITH(entity, self, player, w.event(w));
 773 }