qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_ca_layout");
 144                                         HUD_Write_PanelCvar_q("_dom_layout");
 145                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 146                                         break;
 147                                 case HUD_PANEL_PRESSEDKEYS:
 148                                         HUD_Write_PanelCvar_q("_aspect");
 149                                         HUD_Write_PanelCvar_q("_attack");
 150                                         break;
 151                                 case HUD_PANEL_ENGINEINFO:
 152                                         HUD_Write_PanelCvar_q("_framecounter_time");
 153                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 154                                         break;
 155                                 case HUD_PANEL_INFOMESSAGES:
 156                                         HUD_Write_PanelCvar_q("_flip");
 157                                         break;
 158                                 case HUD_PANEL_PHYSICS:
 159                                         HUD_Write_PanelCvar_q("_speed_unit");
 160                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 161                                         HUD_Write_PanelCvar_q("_speed_max");
 162                                         HUD_Write_PanelCvar_q("_speed_vertical");
 163                                         HUD_Write_PanelCvar_q("_topspeed");
 164                                         HUD_Write_PanelCvar_q("_topspeed_time");
 165                                         HUD_Write_PanelCvar_q("_acceleration_max");
 166                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_baralign");
 169                                         HUD_Write_PanelCvar_q("_progressbar");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 171                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 172                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 173                                         HUD_Write_PanelCvar_q("_text");
 174                                         HUD_Write_PanelCvar_q("_text_scale");
 175                                         break;
 176                                 case HUD_PANEL_CENTERPRINT:
 177                                         HUD_Write_PanelCvar_q("_align");
 178                                         HUD_Write_PanelCvar_q("_flip");
 179                                         HUD_Write_PanelCvar_q("_fontscale");
 180                                         HUD_Write_PanelCvar_q("_time");
 181                                         HUD_Write_PanelCvar_q("_fade_in");
 182                                         HUD_Write_PanelCvar_q("_fade_out");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 189                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 190                                         break;
 191                         }
 192                         HUD_Write("\n");
 193                 }
 194                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 195
 196                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 197                 fclose(fh);
 198         }
 199         else
 200                 printf(_("^1Couldn't write to %s\n"), filename);
 201 }
 202
 203 void HUD_Configure_Exit_Force()
 204 {
 205         if (menu_enabled)
 206         {
 207                 menu_enabled = 0;
 208                 localcmd("togglemenu\n");
 209         }
 210         cvar_set("_hud_configure", "0");
 211 }
 212
 213 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 214 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 215 {
 216         float i;
 217         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 218         vector myTarget;
 219         myTarget = myPos;
 220
 221         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 222                 panel = hud_panel[i];
 223                 if(panel == highlightedPanel) continue;
 224                 HUD_Panel_UpdatePosSize()
 225                 if(!panel_enabled) continue;
 226
 227                 panel_pos -= '1 1 0' * panel_bg_border;
 228                 panel_size += '2 2 0' * panel_bg_border;
 229
 230                 if(myPos_y + mySize_y < panel_pos_y)
 231                         continue;
 232                 if(myPos_y > panel_pos_y + panel_size_y)
 233                         continue;
 234
 235                 if(myPos_x + mySize_x < panel_pos_x)
 236                         continue;
 237                 if(myPos_x > panel_pos_x + panel_size_x)
 238                         continue;
 239
 240                 // OK, there IS a collision.
 241
 242                 myCenter_x = myPos_x + 0.5 * mySize_x;
 243                 myCenter_y = myPos_y + 0.5 * mySize_y;
 244
 245                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 246                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 247
 248                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 249                 {
 250                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 251                                 myTarget_x = panel_pos_x - mySize_x;
 252                         else // push it upwards
 253                                 myTarget_y = panel_pos_y - mySize_y;
 254                 }
 255                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 256                 {
 257                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 258                                 myTarget_x = panel_pos_x + panel_size_x;
 259                         else // push it upwards
 260                                 myTarget_y = panel_pos_y - mySize_y;
 261                 }
 262                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 263                 {
 264                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 265                                 myTarget_x = panel_pos_x - mySize_x;
 266                         else // push it downwards
 267                                 myTarget_y = panel_pos_y + panel_size_y;
 268                 }
 269                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 270                 {
 271                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 272                                 myTarget_x = panel_pos_x + panel_size_x;
 273                         else // push it downwards
 274                                 myTarget_y = panel_pos_y + panel_size_y;
 275                 }
 276                 //if(cvar("hud_configure_checkcollisions_debug"))
 277                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 278         }
 279
 280         return myTarget;
 281 }
 282
 283 void HUD_Panel_SetPos(vector pos)
 284 {
 285         panel = highlightedPanel;
 286         HUD_Panel_UpdatePosSize()
 287         vector mySize;
 288         mySize = panel_size;
 289
 290         //if(cvar("hud_configure_checkcollisions_debug"))
 291                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 292
 293         if(autocvar_hud_configure_grid)
 294         {
 295                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 296                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 297         }
 298
 299         if(hud_configure_checkcollisions)
 300                 pos = HUD_Panel_CheckMove(pos, mySize);
 301
 302         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 303         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 304
 305         string s;
 306         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 307
 308         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 309 }
 310
 311 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 312 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 313         float i;
 314
 315         vector targEndPos;
 316
 317         float dist_x, dist_y;
 318         float ratio;
 319         ratio = mySize_x/mySize_y;
 320
 321         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 322                 panel = hud_panel[i];
 323                 if(panel == highlightedPanel) continue;
 324                 HUD_Panel_UpdatePosSize()
 325                 if(!panel_enabled) continue;
 326
 327                 panel_pos -= '1 1 0' * panel_bg_border;
 328                 panel_size += '2 2 0' * panel_bg_border;
 329
 330                 targEndPos = panel_pos + panel_size;
 331
 332                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 333                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 334                         continue;
 335
 336                 if (resizeCorner == 1)
 337                 {
 338                         // check if this panel is on our way
 339                         if (resizeorigin_x <= panel_pos_x)
 340                                 continue;
 341                         if (resizeorigin_y <= panel_pos_y)
 342                                 continue;
 343                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 344                                 continue;
 345                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 346                                 continue;
 347
 348                         // there is a collision:
 349                         // detect which side of the panel we are facing is actually limiting the resizing
 350                         // (which side the resize direction finds for first) and reduce the size up to there
 351                         //
 352                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 353                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 354                         dist_x = resizeorigin_x - targEndPos_x;
 355                         dist_y = resizeorigin_y - targEndPos_y;
 356                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 357                                 mySize_x = min(mySize_x, dist_x);
 358                         else
 359                                 mySize_y = min(mySize_y, dist_y);
 360                 }
 361                 else if (resizeCorner == 2)
 362                 {
 363                         if (resizeorigin_x >= targEndPos_x)
 364                                 continue;
 365                         if (resizeorigin_y <= panel_pos_y)
 366                                 continue;
 367                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 368                                 continue;
 369                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 370                                 continue;
 371
 372                         dist_x = panel_pos_x - resizeorigin_x;
 373                         dist_y = resizeorigin_y - targEndPos_y;
 374                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 375                                 mySize_x = min(mySize_x, dist_x);
 376                         else
 377                                 mySize_y = min(mySize_y, dist_y);
 378                 }
 379                 else if (resizeCorner == 3)
 380                 {
 381                         if (resizeorigin_x <= panel_pos_x)
 382                                 continue;
 383                         if (resizeorigin_y >= targEndPos_y)
 384                                 continue;
 385                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 386                                 continue;
 387                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 388                                 continue;
 389
 390                         dist_x = resizeorigin_x - targEndPos_x;
 391                         dist_y = panel_pos_y - resizeorigin_y;
 392                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 393                                 mySize_x = min(mySize_x, dist_x);
 394                         else
 395                                 mySize_y = min(mySize_y, dist_y);
 396                 }
 397                 else if (resizeCorner == 4)
 398                 {
 399                         if (resizeorigin_x >= targEndPos_x)
 400                                 continue;
 401                         if (resizeorigin_y >= targEndPos_y)
 402                                 continue;
 403                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 404                                 continue;
 405                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 406                                 continue;
 407
 408                         dist_x = panel_pos_x - resizeorigin_x;
 409                         dist_y = panel_pos_y - resizeorigin_y;
 410                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 411                                 mySize_x = min(mySize_x, dist_x);
 412                         else
 413                                 mySize_y = min(mySize_y, dist_y);
 414                 }
 415                 //if(cvar("hud_configure_checkcollisions_debug"))
 416                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 417         }
 418
 419         return mySize;
 420 }
 421
 422 void HUD_Panel_SetPosSize(vector mySize)
 423 {
 424         panel = highlightedPanel;
 425         HUD_Panel_UpdatePosSize()
 426         vector resizeorigin;
 427         resizeorigin = panel_click_resizeorigin;
 428         local noref vector myPos; // fteqcc sucks
 429
 430         // minimum panel size cap
 431         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 432         mySize_y = max(0.025 * vid_conheight, mySize_y);
 433
 434         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 435         {
 436                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 437                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 438         }
 439
 440         // collision testing|
 441         // -----------------+
 442
 443         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 444         if(resizeCorner == 1) {
 445                 myPos_x = resizeorigin_x - mySize_x;
 446                 myPos_y = resizeorigin_y - mySize_y;
 447         } else if(resizeCorner == 2) {
 448                 myPos_x = resizeorigin_x;
 449                 myPos_y = resizeorigin_y - mySize_y;
 450         } else if(resizeCorner == 3) {
 451                 myPos_x = resizeorigin_x - mySize_x;
 452                 myPos_y = resizeorigin_y;
 453         } else { // resizeCorner == 4
 454                 myPos_x = resizeorigin_x;
 455                 myPos_y = resizeorigin_y;
 456         }
 457
 458         // left/top screen edges
 459         if(myPos_x < 0)
 460                 mySize_x = mySize_x + myPos_x;
 461         if(myPos_y < 0)
 462                 mySize_y = mySize_y + myPos_y;
 463
 464         // bottom/right screen edges
 465         if(myPos_x + mySize_x > vid_conwidth)
 466                 mySize_x = vid_conwidth - myPos_x;
 467         if(myPos_y + mySize_y > vid_conheight)
 468                 mySize_y = vid_conheight - myPos_y;
 469
 470         //if(cvar("hud_configure_checkcollisions_debug"))
 471                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 472
 473         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 474         if(autocvar_hud_configure_grid)
 475         {
 476                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 477                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 478         }
 479
 480         if(hud_configure_checkcollisions)
 481                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 482
 483         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 484         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 485         mySize_y = max(0.025 * vid_conheight, mySize_y);
 486
 487         // do another pos check, as size might have changed by now
 488         if(resizeCorner == 1) {
 489                 myPos_x = resizeorigin_x - mySize_x;
 490                 myPos_y = resizeorigin_y - mySize_y;
 491         } else if(resizeCorner == 2) {
 492                 myPos_x = resizeorigin_x;
 493                 myPos_y = resizeorigin_y - mySize_y;
 494         } else if(resizeCorner == 3) {
 495                 myPos_x = resizeorigin_x - mySize_x;
 496                 myPos_y = resizeorigin_y;
 497         } else { // resizeCorner == 4
 498                 myPos_x = resizeorigin_x;
 499                 myPos_y = resizeorigin_y;
 500         }
 501
 502         //if(cvar("hud_configure_checkcollisions_debug"))
 503                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 504
 505         string s;
 506         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 507         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 508
 509         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 510         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 511 }
 512
 513 float pressed_key_time;
 514 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 515 void HUD_Panel_Arrow_Action(float nPrimary)
 516 {
 517         if(!highlightedPanel)
 518                 return;
 519
 520         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 521
 522         float step;
 523         if(autocvar_hud_configure_grid)
 524         {
 525                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 526                 {
 527                         if (hudShiftState & S_SHIFT)
 528                                 step = hud_configure_realGridSize_y;
 529                         else
 530                                 step = 2 * hud_configure_realGridSize_y;
 531                 }
 532                 else
 533                 {
 534                         if (hudShiftState & S_SHIFT)
 535                                 step = hud_configure_realGridSize_x;
 536                         else
 537                                 step = 2 * hud_configure_realGridSize_x;
 538                 }
 539         }
 540         else
 541         {
 542                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 543                         step = vid_conheight;
 544                 else
 545                         step = vid_conwidth;
 546                 if (hudShiftState & S_SHIFT)
 547                         step = (step / 256); // more precision
 548                 else
 549                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 550         }
 551
 552         panel = highlightedPanel;
 553         HUD_Panel_UpdatePosSize()
 554
 555         highlightedPanel_initial_pos = panel_pos;
 556         highlightedPanel_initial_size = panel_size;
 557
 558         if (hudShiftState & S_ALT) // resize
 559         {
 560                 highlightedAction = 1;
 561                 if(nPrimary == K_UPARROW)
 562                         resizeCorner = 1;
 563                 else if(nPrimary == K_RIGHTARROW)
 564                         resizeCorner = 2;
 565                 else if(nPrimary == K_LEFTARROW)
 566                         resizeCorner = 3;
 567                 else // if(nPrimary == K_DOWNARROW)
 568                         resizeCorner = 4;
 569
 570                 // ctrl+arrow reduces the size, instead of increasing it
 571                 // Note that ctrl disables collisions check too, but it's fine
 572                 // since we don't collide with anything reducing the size
 573                 if (hudShiftState & S_CTRL) {
 574                         step = -step;
 575                         resizeCorner = 5 - resizeCorner;
 576                 }
 577
 578                 vector mySize;
 579                 mySize = panel_size;
 580                 panel_click_resizeorigin = panel_pos;
 581                 if(resizeCorner == 1) {
 582                         panel_click_resizeorigin += mySize;
 583                         mySize_y += step;
 584                 } else if(resizeCorner == 2) {
 585                         panel_click_resizeorigin_y += mySize_y;
 586                         mySize_x += step;
 587                 } else if(resizeCorner == 3) {
 588                         panel_click_resizeorigin_x += mySize_x;
 589                         mySize_x += step;
 590                 } else { // resizeCorner == 4
 591                         mySize_y += step;
 592                 }
 593                 HUD_Panel_SetPosSize(mySize);
 594         }
 595         else // move
 596         {
 597                 highlightedAction = 2;
 598                 vector pos;
 599                 pos = panel_pos;
 600                 if(nPrimary == K_UPARROW)
 601                         pos_y -= step;
 602                 else if(nPrimary == K_DOWNARROW)
 603                         pos_y += step;
 604                 else if(nPrimary == K_LEFTARROW)
 605                         pos_x -= step;
 606                 else // if(nPrimary == K_RIGHTARROW)
 607                         pos_x += step;
 608
 609                 HUD_Panel_SetPos(pos);
 610         }
 611
 612         panel = highlightedPanel;
 613         HUD_Panel_UpdatePosSize()
 614
 615         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 616         {
 617                 // backup!
 618                 panel_pos_backup = highlightedPanel_initial_pos;
 619                 panel_size_backup = highlightedPanel_initial_size;
 620                 highlightedPanel_backup = highlightedPanel;
 621         }
 622 }
 623
 624 const float S_MOUSE1 = 1;
 625 const float S_MOUSE2 = 2;
 626 const float S_MOUSE3 = 4;
 627 float mouseClicked;
 628 float prevMouseClicked; // previous state
 629 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 630 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 631
 632 void HUD_Panel_EnableMenu();
 633 entity tab_panels[HUD_PANEL_MAX];
 634 entity tab_panel;
 635 vector tab_panel_pos;
 636 float tab_backward;
 637 void HUD_Panel_FirstInDrawQ(float id);
 638 void reset_tab_panels()
 639 {
 640         int i;
 641         for(i = 0; i < HUD_PANEL_NUM; ++i)
 642                 tab_panels[i] = world;
 643 }
 644 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 645 {
 646         string s;
 647
 648         if(bInputType == 2)
 649                 return false;
 650
 651         if(!autocvar__hud_configure)
 652                 return false;
 653
 654         if(bInputType == 3)
 655         {
 656                 mousepos_x = nPrimary;
 657                 mousepos_y = nSecondary;
 658                 return true;
 659         }
 660
 661         // block any input while a menu dialog is fading
 662         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 663         if(autocvar__menu_alpha)
 664         {
 665                 hudShiftState = 0;
 666                 mouseClicked = 0;
 667                 return true;
 668         }
 669
 670         // allow console bind to work
 671         string con_keys;
 672         float keys;
 673         con_keys = findkeysforcommand("toggleconsole", 0);
 674         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 675
 676         float hit_con_bind = 0, i;
 677         for (i = 0; i < keys; ++i)
 678         {
 679                 if(nPrimary == stof(argv(i)))
 680                         hit_con_bind = 1;
 681         }
 682
 683         if(bInputType == 0) {
 684                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 685                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 686                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 687         }
 688         else if(bInputType == 1) {
 689                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 690                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 691                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 692         }
 693
 694         if(nPrimary == K_CTRL)
 695         {
 696                 if (bInputType == 1) //ctrl has been released
 697                 {
 698                         if (tab_panel)
 699                         {
 700                                 //switch to selected panel
 701                                 highlightedPanel = tab_panel;
 702                                 highlightedAction = 0;
 703                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 704                         }
 705                         tab_panel = world;
 706                         reset_tab_panels();
 707                 }
 708         }
 709
 710         if(nPrimary == K_MOUSE1)
 711         {
 712                 if(bInputType == 0) // key pressed
 713                         mouseClicked |= S_MOUSE1;
 714                 else if(bInputType == 1) // key released
 715                         mouseClicked -= (mouseClicked & S_MOUSE1);
 716         }
 717         else if(nPrimary == K_MOUSE2)
 718         {
 719                 if(bInputType == 0) // key pressed
 720                         mouseClicked |= S_MOUSE2;
 721                 else if(bInputType == 1) // key released
 722                         mouseClicked -= (mouseClicked & S_MOUSE2);
 723         }
 724         else if(nPrimary == K_ESCAPE)
 725         {
 726                 if (bInputType == 1)
 727                         return true;
 728                 menu_enabled = 1;
 729                 localcmd("menu_showhudexit\n");
 730         }
 731         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 732         {
 733                 if (bInputType == 1)
 734                         return true;
 735                 if (!menu_enabled)
 736                         cvar_set("_hud_configure", "0");
 737         }
 738         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 739         {
 740                 if (bInputType == 1 || mouseClicked)
 741                         return true;
 742
 743                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 744                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 745                 //(it should only after every other panel of the hud)
 746                 //It's a minor bug anyway, we can live with it
 747
 748                 entity starting_panel;
 749                 entity old_tab_panel = tab_panel;
 750                 if (!tab_panel) //first press of TAB
 751                 {
 752                         if (highlightedPanel)
 753                         {
 754                                 panel = highlightedPanel;
 755                                 HUD_Panel_UpdatePosSize()
 756                         }
 757                         else
 758                                 panel_pos = '0 0 0';
 759                         starting_panel = highlightedPanel;
 760                         tab_panel_pos = panel_pos; //to compute level
 761                 }
 762                 else
 763                 {
 764                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 765                                 reset_tab_panels();
 766                         starting_panel = tab_panel;
 767                 }
 768                 tab_backward = (hudShiftState & S_SHIFT);
 769
 770                 float k, level = 0, start_pos_x;
 771                 vector candidate_pos = '0 0 0';
 772                 const float LEVELS_NUM = 4;
 773                 float level_height = vid_conheight / LEVELS_NUM;
 774 :find_tab_panel
 775                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 776                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 777                 start_pos_x = tab_panel_pos_x;
 778                 tab_panel = world;
 779                 k=0;
 780                 while(++k)
 781                 {
 782                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 783                         {
 784                                 panel = hud_panel[i];
 785                                 if (panel == tab_panels[i] || panel == starting_panel)
 786                                         continue;
 787                                 HUD_Panel_UpdatePosSize()
 788                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 789                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 790                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 791                                 {
 792                                         tab_panel = panel;
 793                                         tab_panel_pos = candidate_pos = panel_pos;
 794                                 }
 795                         }
 796                         if (tab_panel)
 797                                 break;
 798                         if (k == LEVELS_NUM) //tab_panel not found
 799                         {
 800                                 reset_tab_panels();
 801                                 if (!old_tab_panel)
 802                                 {
 803                                         tab_panel = world;
 804                                         return true;
 805                                 }
 806                                 starting_panel = old_tab_panel;
 807                                 old_tab_panel = world;
 808                                 goto find_tab_panel; //u must find tab_panel!
 809                         }
 810                         if (!tab_backward)
 811                         {
 812                                 level = mod(level + level_height, vid_conheight);
 813                                 start_pos_x = 0;
 814                                 candidate_pos_x = vid_conwidth;
 815                         }
 816                         else
 817                         {
 818                                 level = mod(level - level_height, vid_conheight);
 819                                 start_pos_x = vid_conwidth;
 820                                 candidate_pos_x = 0;
 821                         }
 822                 }
 823
 824                 tab_panels[tab_panel.panel_id] = tab_panel;
 825         }
 826         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 827         {
 828                 if (bInputType == 1 || mouseClicked)
 829                         return true;
 830
 831                 if (highlightedPanel)
 832                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 833                 else
 834                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 835         }
 836         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 837         {
 838                 if (bInputType == 1 || mouseClicked)
 839                         return true;
 840
 841                 if (highlightedPanel)
 842                 {
 843                         panel = highlightedPanel;
 844                         HUD_Panel_UpdatePosSize()
 845                         panel_size_copied = panel_size;
 846                 }
 847         }
 848         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 849         {
 850                 if (bInputType == 1 || mouseClicked)
 851                         return true;
 852
 853                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 854                         return true;
 855
 856                 panel = highlightedPanel;
 857                 HUD_Panel_UpdatePosSize()
 858
 859                 // reduce size if it'd go beyond screen boundaries
 860                 vector tmp_size = panel_size_copied;
 861                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 862                         tmp_size_x = vid_conwidth - panel_pos_x;
 863                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 864                         tmp_size_y = vid_conheight - panel_pos_y;
 865
 866                 if (panel_size == tmp_size)
 867                         return true;
 868
 869                 // backup first!
 870                 panel_pos_backup = panel_pos;
 871                 panel_size_backup = panel_size;
 872                 highlightedPanel_backup = highlightedPanel;
 873
 874                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 875                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 876         }
 877         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 878         {
 879                 if (bInputType == 1 || mouseClicked)
 880                         return true;
 881                 //restore previous values
 882                 if (highlightedPanel_backup)
 883                 {
 884                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 885                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 886                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 887                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 888                         highlightedPanel_backup = world;
 889                 }
 890         }
 891         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 892         {
 893                 if (bInputType == 1)
 894                 {
 895                         pressed_key_time = 0;
 896                         return true;
 897                 }
 898                 else if (pressed_key_time == 0)
 899                         pressed_key_time = time;
 900
 901                 if (!mouseClicked)
 902                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 903         }
 904         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 905         {
 906                 if (bInputType == 1)
 907                         return true;
 908                 if (highlightedPanel)
 909                         HUD_Panel_EnableMenu();
 910         }
 911         else if(hit_con_bind)
 912                 return false;
 913
 914         return true;
 915 }
 916
 917 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 918 {
 919         float i, j = 0, border;
 920
 921         while(j < HUD_PANEL_NUM)
 922         {
 923                 i = panel_order[j];
 924                 j += 1;
 925
 926                 panel = hud_panel[i];
 927                 HUD_Panel_UpdatePosSize()
 928
 929                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 930
 931                 // move
 932                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 933                 {
 934                         return 1;
 935                 }
 936                 // resize from topleft border
 937                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 938                 {
 939                         return 2;
 940                 }
 941                 // resize from topright border
 942                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 943                 {
 944                         return 3;
 945                 }
 946                 // resize from bottomleft border
 947                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 948                 {
 949                         return 3;
 950                 }
 951                 // resize from bottomright border
 952                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 953                 {
 954                         return 2;
 955                 }
 956         }
 957         return 0;
 958 }
 959
 960 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 961 void HUD_Panel_FirstInDrawQ(float id)
 962 {
 963         float i;
 964         var float place = -1;
 965         // find out where in the array our current id is, save into place
 966         for(i = 0; i < HUD_PANEL_NUM; ++i)
 967         {
 968                 if(panel_order[i] == id)
 969                 {
 970                         place = i;
 971                         break;
 972                 }
 973         }
 974         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 975         if(place == -1)
 976                 place = HUD_PANEL_NUM - 1;
 977
 978         // move all ids up by one step in the array until "place"
 979         for(i = place; i > 0; --i)
 980         {
 981                 panel_order[i] = panel_order[i-1];
 982         }
 983         // now save the new top id
 984         panel_order[0] = id;
 985
 986         // let's save them into the cvar by some strcat trickery
 987         string s = "";
 988         for(i = 0; i < HUD_PANEL_NUM; ++i)
 989         {
 990                 s = strcat(s, ftos(panel_order[i]), " ");
 991         }
 992         cvar_set("_hud_panelorder", s);
 993         if(hud_panelorder_prev)
 994                 strunzone(hud_panelorder_prev);
 995         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 996 }
 997
 998 void HUD_Panel_Highlight(float allow_move)
 999 {
1000         float i, j = 0, border;
1001
1002         while(j < HUD_PANEL_NUM)
1003         {
1004                 i = panel_order[j];
1005                 j += 1;
1006
1007                 panel = hud_panel[i];
1008                 HUD_Panel_UpdatePosSize()
1009
1010                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1011
1012                 // move
1013                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1014                 {
1015                         highlightedPanel = hud_panel[i];
1016                         HUD_Panel_FirstInDrawQ(i);
1017                         highlightedAction = 1;
1018                         panel_click_distance = mousepos - panel_pos;
1019                         return;
1020                 }
1021                 // resize from topleft border
1022                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1023                 {
1024                         highlightedPanel = hud_panel[i];
1025                         HUD_Panel_FirstInDrawQ(i);
1026                         highlightedAction = 2;
1027                         resizeCorner = 1;
1028                         panel_click_distance = mousepos - panel_pos;
1029                         panel_click_resizeorigin = panel_pos + panel_size;
1030                         return;
1031                 }
1032                 // resize from topright border
1033                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1034                 {
1035                         highlightedPanel = hud_panel[i];
1036                         HUD_Panel_FirstInDrawQ(i);
1037                         highlightedAction = 2;
1038                         resizeCorner = 2;
1039                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1040                         panel_click_distance_y = mousepos_y - panel_pos_y;
1041                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1042                         return;
1043                 }
1044                 // resize from bottomleft border
1045                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1046                 {
1047                         highlightedPanel = hud_panel[i];
1048                         HUD_Panel_FirstInDrawQ(i);
1049                         highlightedAction = 2;
1050                         resizeCorner = 3;
1051                         panel_click_distance_x = mousepos_x - panel_pos_x;
1052                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1053                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1054                         return;
1055                 }
1056                 // resize from bottomright border
1057                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1058                 {
1059                         highlightedPanel = hud_panel[i];
1060                         HUD_Panel_FirstInDrawQ(i);
1061                         highlightedAction = 2;
1062                         resizeCorner = 4;
1063                         panel_click_distance = panel_size - mousepos + panel_pos;
1064                         panel_click_resizeorigin = panel_pos;
1065                         return;
1066                 }
1067         }
1068         highlightedPanel = world;
1069         highlightedAction = 0;
1070 }
1071
1072 void HUD_Panel_EnableMenu()
1073 {
1074         menu_enabled = 2;
1075         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1076 }
1077 float mouse_over_panel;
1078 void HUD_Panel_Mouse()
1079 {
1080         if(autocvar__menu_alpha == 1)
1081                 return;
1082
1083         if (!autocvar_hud_cursormode)
1084         {
1085                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1086
1087                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1088                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1089         }
1090
1091         if(mouseClicked)
1092         {
1093                 if(prevMouseClicked == 0)
1094                 {
1095                         if (tab_panel)
1096                         {
1097                                 //stop ctrl-tab selection
1098                                 tab_panel = world;
1099                                 reset_tab_panels();
1100                         }
1101                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1102                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1103                         if (highlightedPanel)
1104                         {
1105                                 highlightedPanel_initial_pos = panel_pos;
1106                                 highlightedPanel_initial_size = panel_size;
1107                         }
1108                         // doubleclick check
1109                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1110                         {
1111                                 mouseClicked = 0; // to prevent spam, I guess.
1112                                 HUD_Panel_EnableMenu();
1113                         }
1114                         else
1115                         {
1116                                 if (mouseClicked & S_MOUSE1)
1117                                 {
1118                                         prevMouseClickedTime = time;
1119                                         prevMouseClickedPos = mousepos;
1120                                 }
1121                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1122                         }
1123                 }
1124                 else
1125                 {
1126                         panel = highlightedPanel;
1127                         HUD_Panel_UpdatePosSize()
1128                 }
1129
1130                 if (highlightedPanel)
1131                 {
1132                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1133                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1134                         {
1135                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1136                                 // backup!
1137                                 panel_pos_backup = highlightedPanel_initial_pos;
1138                                 panel_size_backup = highlightedPanel_initial_size;
1139                                 highlightedPanel_backup = highlightedPanel;
1140                         }
1141                         else
1142                                 // in case the clicked panel is inside another panel and we aren't
1143                                 // moving it, avoid the immediate "fix" of its position/size
1144                                 // (often unwanted and hateful) by disabling collisions check
1145                                 hud_configure_checkcollisions = false;
1146                 }
1147
1148                 if(highlightedAction == 1)
1149                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1150                 else if(highlightedAction == 2)
1151                 {
1152                         vector mySize = '0 0 0';
1153                         if(resizeCorner == 1) {
1154                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1155                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1156                         } else if(resizeCorner == 2) {
1157                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1158                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1159                         } else if(resizeCorner == 3) {
1160                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1161                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1162                         } else { // resizeCorner == 4
1163                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1164                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1165                         }
1166                         HUD_Panel_SetPosSize(mySize);
1167                 }
1168         }
1169         else
1170         {
1171                 if(menu_enabled == 2)
1172                         mouse_over_panel = 0;
1173                 else
1174                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1175                 if (mouse_over_panel && !tab_panel)
1176                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1177         }
1178         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1179         const vector cursorsize = '32 32 0';
1180         float cursor_alpha = 1 - autocvar__menu_alpha;
1181
1182         if(!mouse_over_panel)
1183                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1184         else if(mouse_over_panel == 1)
1185                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1186         else if(mouse_over_panel == 2)
1187                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1188         else
1189                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1190
1191         prevMouseClicked = mouseClicked;
1192 }
1193 void HUD_Configure_DrawGrid()
1194 {
1195         float i;
1196         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1197         {
1198                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1199                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1200                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
1201                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
1202                 vector s;
1203                 // x-axis
1204                 s = eX + eY * vid_conheight;
1205                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
1206                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1207                 // y-axis
1208                 s = eY + eX * vid_conwidth;
1209                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
1210                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1211         }
1212 }
1213
1214 float _menu_alpha_prev;
1215 void HUD_Configure_Frame()
1216 {
1217         float i;
1218         if(autocvar__hud_configure)
1219         {
1220                 if(isdemo() || intermission == 2)
1221                 {
1222                         HUD_Configure_Exit_Force();
1223                         return;
1224                 }
1225
1226                 if(!hud_configure_prev || hud_configure_prev == -1)
1227                 {
1228                         if(autocvar_hud_cursormode)
1229                                 setcursormode(1);
1230                         hudShiftState = 0;
1231                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1232                                 hud_panel[panel_order[i]].update_time = time;
1233                 }
1234
1235                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1236                 if(autocvar__menu_alpha != _menu_alpha_prev)
1237                 {
1238                         if(autocvar__menu_alpha == 0)
1239                                 menu_enabled = 0;
1240                         _menu_alpha_prev = autocvar__menu_alpha;
1241                 }
1242
1243                 HUD_Configure_DrawGrid();
1244         }
1245         else if(hud_configure_prev)
1246         {
1247                 if(menu_enabled)
1248                         menu_enabled = 0;
1249                 if(autocvar_hud_cursormode)
1250                         setcursormode(0);
1251         }
1252 }
1253
1254 const float hlBorderSize = 4;
1255 const string hlBorder = "gfx/hud/default/border_highlighted";
1256 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1257 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1258 {
1259         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1260         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1261         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1262         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1263         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1264 }
1265
1266 void HUD_Configure_PostDraw()
1267 {
1268         if(autocvar__hud_configure)
1269         {
1270                 if(tab_panel)
1271                 {
1272                         panel = tab_panel;
1273                         HUD_Panel_UpdatePosSize()
1274                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1275                 }
1276                 if(highlightedPanel)
1277                 {
1278                         panel = highlightedPanel;
1279                         HUD_Panel_UpdatePosSize()
1280                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
1281                 }
1282         }
1283 }