qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 .float prevstrengthsound;
 134 .float prevstrengthsoundattempt;
 135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
 136 {
 137         float nudge = 1; // added to traceline target and subtracted from result
 138         local float oldsolid;
 139         vector vecs, dv;
 140         oldsolid = ent.dphitcontentsmask;
 141         if(ent.weapon == WEP_CAMPINGRIFLE)
 142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         else
 144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         if(antilag)
 146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 147                 // passing world, because we do NOT want it to touch dphitcontentsmask
 148         else
 149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 151
 152         vector vf, vr, vu;
 153         vf = v_forward;
 154         vr = v_right;
 155         vu = v_up;
 156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 157         v_forward = vf;
 158         v_right = vr;
 159         v_up = vu;
 160
 161         // track max damage
 162         if not(inWarmupStage) {
 163                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 164         }
 165
 166         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 167
 168         if(ent.weaponentity.movedir_x > 0)
 169                 vecs = ent.weaponentity.movedir;
 170         else
 171                 vecs = '0 0 0';
 172         if(debug_shotorg != '0 0 0')
 173                 vecs = debug_shotorg;
 174
 175         dv = v_right * -vecs_y + v_up * vecs_z;
 176         w_shotorg = ent.origin + ent.view_ofs + dv;
 177
 178         // now move the shotorg forward as much as requested if possible
 179         if(antilag)
 180         {
 181                 if(ent.antilag_debug)
 182                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 183                 else
 184                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 185         }
 186         else
 187                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 188         w_shotorg = trace_endpos - v_forward * nudge;
 189         // calculate the shotdir from the chosen shotorg
 190         w_shotdir = normalize(w_shotend - w_shotorg);
 191
 192         if (antilag)
 193         if (!ent.cvar_cl_noantilag)
 194         {
 195                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 196                 {
 197                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 198                         if (!trace_ent.takedamage)
 199                         {
 200                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 201                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 202                                 {
 203                                         entity e;
 204                                         e = trace_ent;
 205                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 206                                         if(trace_ent == e)
 207                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 208                                 }
 209                         }
 210                 }
 211                 else if(cvar("g_antilag") == 3) // client side hitscan
 212                 {
 213                         // this part MUST use prydon cursor
 214                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 215                         if (ent.cursor_trace_ent != ent)         // just to make sure
 216                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 217                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 218                         {
 219                                 // verify that the shot would miss without antilag
 220                                 // (avoids an issue where guns would always shoot at their origin)
 221                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 222                                 if (!trace_ent.takedamage)
 223                                 {
 224                                         // verify that the shot would hit if altered
 225                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 226                                         if (trace_ent == ent.cursor_trace_ent)
 227                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 228                                         else
 229                                                 print("antilag fail\n");
 230                                 }
 231                         }
 232                 }
 233         }
 234
 235         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 236
 237         if (!g_norecoil)
 238                 ent.punchangle_x = recoil * -1;
 239
 240         if (snd != "")
 241         {
 242                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 243         }
 244
 245         if(ent.items & IT_STRENGTH)
 246         if(!g_minstagib)
 247         if(
 248                 (time > ent.prevstrengthsound + cvar("sv_strengthsound_antispam_time"))
 249                 ||
 250                 (time > ent.prevstrengthsoundattempt + cvar("sv_strengthsound_antispam_refire_threshold"))
 251         ) // prevent insane sound spam
 252         {
 253                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 254                 ent.prevstrengthsound = time;
 255         }
 256         ent.prevstrengthsoundattempt = time;
 257
 258         // nudge w_shotend so a trace to w_shotend hits
 259         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 260 };
 261
 262 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
 263 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 264 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 265 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 266 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
 267
 268 float CL_Weaponentity_CustomizeEntityForClient()
 269 {
 270         self.viewmodelforclient = self.owner;
 271         if(other.classname == "spectator")
 272                 if(other.enemy == self.owner)
 273                         self.viewmodelforclient = other;
 274         return TRUE;
 275 }
 276
 277 float qcweaponanimation;
 278 vector weapon_offset = '0 -10 0';
 279 vector weapon_adjust = '10 0 -15';
 280 .vector weapon_morph0origin;
 281 .vector weapon_morph0angles;
 282 .float  weapon_morph0time;
 283 .vector weapon_morph1origin;
 284 .vector weapon_morph1angles;
 285 .float  weapon_morph1time;
 286 .vector weapon_morph2origin;
 287 .vector weapon_morph2angles;
 288 .float  weapon_morph2time;
 289 .vector weapon_morph3origin;
 290 .vector weapon_morph3angles;
 291 .float  weapon_morph3time;
 292 .vector weapon_morph4origin;
 293 .vector weapon_morph4angles;
 294 .float  weapon_morph4time;
 295 .string weaponname;
 296 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 297
 298 /*
 299  * supported formats:
 300  *
 301  * 1. simple animated model, muzzle flash handling on h_ model:
 302  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 303  *      tags:
 304  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 305  *        shell = casings ejection point (must be on the right hand side of the gun)
 306  *        weapon = attachment for v_tuba.md3
 307  *    v_tuba.md3 - first and third person model
 308  *    g_tuba.md3 - pickup model
 309  *
 310  * 2. simple animated model, muzzle flash handling on v_ model:
 311  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 312  *      tags:
 313  *        weapon = attachment for v_tuba.md3
 314  *    v_tuba.md3 - first and third person model
 315  *      tags:
 316  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 317  *        shell = casings ejection point (must be on the right hand side of the gun)
 318  *    g_tuba.md3 - pickup model
 319  *
 320  * 3. fully animated model, muzzle flash handling on h_ model:
 321  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 322  *      tags:
 323  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 324  *        shell = casings ejection point (must be on the right hand side of the gun)
 325  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 326  *    v_tuba.md3 - third person model
 327  *    g_tuba.md3 - pickup model
 328  *
 329  * 4. fully animated model, muzzle flash handling on v_ model:
 330  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 331  *      tags:
 332  *        shot = muzzle end (shot origin)
 333  *        shell = casings ejection point (must be on the right hand side of the gun)
 334  *    v_tuba.md3 - third person model
 335  *      tags:
 336  *        shot = muzzle end (for muzzle flashes)
 337  *    g_tuba.md3 - pickup model
 338  */
 339
 340 // writes:
 341 //   self.origin, self.angles
 342 //   self.weaponentity
 343 //   self.movedir, self.view_ofs
 344 //   attachment stuff
 345 //   anim stuff
 346 // to free:
 347 //   call again with ""
 348 //   remove the ent
 349 void CL_WeaponEntity_SetModel(string name)
 350 {
 351         string animfilename;
 352         float animfile;
 353         float v_shot_idx;
 354         if (name != "")
 355         {
 356                 // if there is a child entity, hide it until we're sure we use it
 357                 if (self.weaponentity)
 358                         self.weaponentity.model = "";
 359                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 360                 v_shot_idx = gettagindex(self, "shot"); // used later
 361                 if(!v_shot_idx)
 362                         v_shot_idx = gettagindex(self, "tag_shot");
 363
 364                 if(qcweaponanimation)
 365                 {
 366                         self.angles = '0 0 0';
 367                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 368                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 369                         self.movedir_x += 32;
 370                         self.spawnorigin = self.movedir;
 371                         // oldorigin - not calculated here
 372                 }
 373                 else
 374                 {
 375                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 376                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 377                         animfile = fopen(animfilename, FILE_READ);
 378                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 379                         self.anim_fire1  = '0 1 0.01';
 380                         self.anim_fire2  = '1 1 0.01';
 381                         self.anim_idle   = '2 1 0.01';
 382                         self.anim_reload = '3 1 0.01';
 383                         if (animfile >= 0)
 384                         {
 385                                 animparseerror = FALSE;
 386                                 self.anim_fire1  = animparseline(animfile);
 387                                 self.anim_fire2  = animparseline(animfile);
 388                                 self.anim_idle   = animparseline(animfile);
 389                                 self.anim_reload = animparseline(animfile);
 390                                 fclose(animfile);
 391                                 if (animparseerror)
 392                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 393                         }
 394
 395                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 396                         // if we don't, this is a "real" animated model
 397                         if(gettagindex(self, "weapon"))
 398                         {
 399                                 if (!self.weaponentity)
 400                                         self.weaponentity = spawn();
 401                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 402                                 setattachment(self.weaponentity, self, "weapon");
 403                         }
 404                         else if(gettagindex(self, "tag_weapon"))
 405                         {
 406                                 if (!self.weaponentity)
 407                                         self.weaponentity = spawn();
 408                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 409                                 setattachment(self.weaponentity, self, "tag_weapon");
 410                         }
 411                         else
 412                         {
 413                                 if(self.weaponentity)
 414                                         remove(self.weaponentity);
 415                                 self.weaponentity = world;
 416                         }
 417
 418                         setorigin(self,'0 0 0');
 419                         self.angles = '0 0 0';
 420                         self.frame = 0;
 421                         self.viewmodelforclient = world;
 422
 423                         float idx;
 424
 425                         if(v_shot_idx) // v_ model attached to invisible h_ model
 426                         {
 427                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 428                         }
 429                         else
 430                         {
 431                                 idx = gettagindex(self, "shot");
 432                                 if(!idx)
 433                                         idx = gettagindex(self, "tag_shot");
 434                                 if(idx)
 435                                         self.movedir = gettaginfo(self, idx);
 436                                 else
 437                                 {
 438                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 439                                         self.movedir = '0 0 0';
 440                                 }
 441                         }
 442
 443                         if(self.weaponentity) // v_ model attached to invisible h_ model
 444                         {
 445                                 idx = gettagindex(self.weaponentity, "shell");
 446                                 if(!idx)
 447                                         idx = gettagindex(self.weaponentity, "tag_shell");
 448                                 if(idx)
 449                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 450                         }
 451                         else
 452                                 idx = 0;
 453                         if(!idx)
 454                         {
 455                                 idx = gettagindex(self, "shell");
 456                                 if(!idx)
 457                                         idx = gettagindex(self, "tag_shell");
 458                                 if(idx)
 459                                         self.spawnorigin = gettaginfo(self, idx);
 460                                 else
 461                                 {
 462                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 463                                         self.spawnorigin = self.movedir;
 464                                 }
 465                         }
 466
 467                         if(v_shot_idx)
 468                         {
 469                                 self.oldorigin = '0 0 0'; // use regular attachment
 470                         }
 471                         else
 472                         {
 473                                 if(self.weaponentity)
 474                                 {
 475                                         idx = gettagindex(self, "weapon");
 476                                         if(!idx)
 477                                                 idx = gettagindex(self, "tag_weapon");
 478                                 }
 479                                 else
 480                                 {
 481                                         idx = gettagindex(self, "handle");
 482                                         if(!idx)
 483                                                 idx = gettagindex(self, "tag_handle");
 484                                 }
 485                                 if(idx)
 486                                 {
 487                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 488                                 }
 489                                 else
 490                                 {
 491                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 492                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 493                                 }
 494                         }
 495
 496                         self.viewmodelforclient = self.owner;
 497                 }
 498         }
 499         else
 500         {
 501                 self.model = "";
 502                 if(self.weaponentity)
 503                         remove(self.weaponentity);
 504                 self.weaponentity = world;
 505                 self.movedir = '0 0 0';
 506                 self.spawnorigin = '0 0 0';
 507                 self.oldorigin = '0 0 0';
 508                 self.anim_fire1  = '0 1 0.01';
 509                 self.anim_fire2  = '0 1 0.01';
 510                 self.anim_idle   = '0 1 0.01';
 511                 self.anim_reload = '0 1 0.01';
 512         }
 513
 514         self.view_ofs = '0 0 0';
 515
 516         if(self.movedir_x >= 0)
 517         {
 518                 vector v0;
 519                 v0 = self.movedir;
 520                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 521                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 522         }
 523         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 524         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 525
 526         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 527
 528         // check if an instant weapon switch occurred
 529         if (qcweaponanimation)
 530         {
 531                 if (self.state == WS_READY)
 532                 {
 533                         self.angles = '0 0 0';
 534                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 535                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 536                 }
 537         }
 538         else
 539                 setorigin(self, self.view_ofs);
 540         // reset animstate now
 541         self.wframe = WFRAME_IDLE;
 542         self.weapon_morph0time = 0;
 543         self.weapon_morph1time = 0;
 544         self.weapon_morph2time = 0;
 545         self.weapon_morph3time = 0;
 546         self.weapon_morph4time = 0;
 547         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 548 }
 549
 550 vector CL_Weapon_GetShotOrg(float wpn)
 551 {
 552         entity wi, oldself;
 553         vector ret;
 554         wi = get_weaponinfo(wpn);
 555         oldself = self;
 556         self = spawn();
 557         CL_WeaponEntity_SetModel(wi.mdl);
 558         ret = self.movedir;
 559         CL_WeaponEntity_SetModel("");
 560         remove(self);
 561         self = oldself;
 562         return ret;
 563 }
 564
 565 void CL_Weaponentity_Think()
 566 {
 567         float tb;
 568         self.nextthink = time;
 569         if (intermission_running)
 570                 self.frame = self.anim_idle_x;
 571         if (self.owner.weaponentity != self)
 572         {
 573                 if (self.weaponentity)
 574                         remove(self.weaponentity);
 575                 remove(self);
 576                 return;
 577         }
 578         if (self.owner.deadflag != DEAD_NO)
 579         {
 580                 self.model = "";
 581                 if (self.weaponentity)
 582                         self.weaponentity.model = "";
 583                 return;
 584         }
 585         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 586         {
 587                 self.cnt = self.owner.weapon;
 588                 self.dmg = self.owner.modelindex;
 589                 self.deadflag = self.owner.deadflag;
 590
 591                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 592         }
 593
 594         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 595         self.effects = self.owner.effects & EFMASK_CHEAP;
 596         self.effects &~= EF_LOWPRECISION;
 597         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 598         self.effects &~= EF_TELEPORT_BIT;
 599         self.effects &~= EF_RESTARTANIM_BIT;
 600         self.effects |= tb;
 601
 602         if(self.owner.alpha == default_player_alpha)
 603                 self.alpha = default_weapon_alpha;
 604         else if(self.owner.alpha != 0)
 605                 self.alpha = self.owner.alpha;
 606         else
 607                 self.alpha = 1;
 608
 609         self.colormap = self.owner.colormap;
 610         if (self.weaponentity)
 611         {
 612                 self.weaponentity.effects = self.effects;
 613                 self.weaponentity.alpha = self.alpha;
 614                 self.weaponentity.colormap = self.colormap;
 615         }
 616
 617         self.angles = '0 0 0';
 618         local float f;
 619         f = 0;
 620         if (self.state == WS_RAISE && !intermission_running)
 621         {
 622                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 623                 self.angles_x = -90 * f * f;
 624                 if (qcweaponanimation)
 625                 {
 626                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 627                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 628                 }
 629         }
 630         else if (self.state == WS_DROP && !intermission_running)
 631         {
 632                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 633                 self.angles_x = -90 * f * f;
 634                 if (qcweaponanimation)
 635                 {
 636                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 637                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 638                 }
 639         }
 640         else if (self.state == WS_CLEAR)
 641         {
 642                 f = 1;
 643                 self.angles_x = -90 * f * f;
 644                 if (qcweaponanimation)
 645                 {
 646                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 647                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 648                 }
 649         }
 650         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 651         {
 652                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 653                 f = 1 - pow(1 - f, 3);
 654                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 655                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 656         }
 657         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 658         {
 659                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 660                 f = 1 - pow(1 - f, 3);
 661                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 662                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 663         }
 664         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 665         {
 666                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 667                 f = 1 - pow(1 - f, 3);
 668                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 669                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 670         }
 671         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 672         {
 673                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 674                 f = 1 - pow(1 - f, 3);
 675                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 676                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 677         }
 678         else if (qcweaponanimation)
 679         {
 680                 // begin a new idle morph
 681                 self.owner.weapon_morph0time   = time;
 682                 self.owner.weapon_morph0angles = self.angles;
 683                 self.owner.weapon_morph0origin = self.origin;
 684
 685                 float r;
 686                 float t;
 687
 688                 r = random();
 689                 if (r < 0.1)
 690                 {
 691                         // turn gun to the left to look at it
 692                         t = 2;
 693                         self.owner.weapon_morph1time   = time + t * 0.2;
 694                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 695                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 696                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 697
 698                         self.owner.weapon_morph2time   = time + t * 0.6;
 699                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 700                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 701                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 702
 703                         self.owner.weapon_morph3time   = time + t;
 704                         self.owner.weapon_morph3angles = '0 0 0';
 705                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 706                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 707                 }
 708                 else if (r < 0.2)
 709                 {
 710                         // raise the gun a bit
 711                         t = 2;
 712                         self.owner.weapon_morph1time   = time + t * 0.2;
 713                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 714                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 715                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 716
 717                         self.owner.weapon_morph2time   = time + t * 0.5;
 718                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 719                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 720                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 721
 722                         self.owner.weapon_morph3time   = time + t;
 723                         self.owner.weapon_morph3angles = '0 0 0';
 724                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 725                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 726                 }
 727                 else if (r < 0.3)
 728                 {
 729                         // tweak it a bit
 730                         t = 5;
 731                         self.owner.weapon_morph1time   = time + t * 0.3;
 732                         self.owner.weapon_morph1angles = randomvec() * 6;
 733                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 734                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 735
 736                         self.owner.weapon_morph2time   = time + t * 0.7;
 737                         self.owner.weapon_morph2angles = randomvec() * 6;
 738                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 739                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 740
 741                         self.owner.weapon_morph3time   = time + t;
 742                         self.owner.weapon_morph3angles = '0 0 0';
 743                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 744                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 745                 }
 746                 else
 747                 {
 748                         // hold it mostly steady
 749                         t = random() * 6 + 4;
 750                         self.owner.weapon_morph1time   = time + t * 0.2;
 751                         self.owner.weapon_morph1angles = randomvec() * 1;
 752                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 753                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 754
 755                         self.owner.weapon_morph2time   = time + t * 0.5;
 756                         self.owner.weapon_morph2angles = randomvec() * 1;
 757                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 758                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 759
 760                         self.owner.weapon_morph3time   = time + t * 0.7;
 761                         self.owner.weapon_morph3angles = randomvec() * 1;
 762                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 763                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 764                 }
 765
 766                 self.owner.weapon_morph4time   = time + t;
 767                 self.owner.weapon_morph4angles = '0 0 0';
 768                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 769                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 770
 771         }
 772 };
 773
 774 void CL_ExteriorWeaponentity_Think()
 775 {
 776         float tag_found;
 777         vector ang;
 778         self.nextthink = time;
 779         if (self.owner.exteriorweaponentity != self)
 780         {
 781                 remove(self);
 782                 return;
 783         }
 784         if (self.owner.deadflag != DEAD_NO)
 785         {
 786                 self.model = "";
 787                 return;
 788         }
 789         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 790         {
 791                 self.cnt = self.owner.weapon;
 792                 self.dmg = self.owner.modelindex;
 793                 self.deadflag = self.owner.deadflag;
 794                 if (self.owner.weaponname != "")
 795                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 796                 else
 797                         self.model = "";
 798
 799                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 800                 {
 801                         self.tag_index = tag_found;
 802                         self.tag_entity = self.owner;
 803                 }
 804                 else
 805                         setattachment(self, self.owner, "bip01 r hand");
 806
 807                 // if that didn't find a tag, hide the exterior weapon model
 808                 if (!self.tag_index)
 809                         self.model = "";
 810         }
 811         self.effects = self.owner.effects;
 812         if(sv_pitch_min == sv_pitch_max)
 813                 self.effects |= EF_LOWPRECISION;
 814         else
 815                 self.effects &~= EF_LOWPRECISION;
 816         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 817         if(self.owner.alpha == default_player_alpha)
 818                 self.alpha = default_weapon_alpha;
 819         else if(self.owner.alpha != 0)
 820                 self.alpha = self.owner.alpha;
 821         else
 822                 self.alpha = 1;
 823
 824         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 825         ang_y = 0;
 826         ang_z = 0;
 827
 828         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 829         {
 830                 ang_y = self.owner.v_angle_y;
 831                 makevectors(ang);
 832                 var vector v = v_forward;
 833                 var float t = self.tag_entity.frame1time;
 834                 var float f = self.tag_entity.frame;
 835                 self.tag_entity.frame1time = time;
 836                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
 837                 gettaginfo(self.tag_entity, self.tag_index);
 838                 self.tag_entity.frame1time = t;
 839                 self.tag_entity.frame = f;
 840                 // untransform v according to this coordinate space
 841                 vector w;
 842                 w_x = v_forward * v;
 843                 w_y = -v_right * v;
 844                 w_z = v_up * v;
 845                 self.angles = vectoangles(w);
 846         }
 847         else
 848         {
 849                 ang_x = -/* don't ask */ang_x;
 850                 self.angles = ang;
 851         }
 852
 853         self.colormap = self.owner.colormap;
 854 };
 855
 856 // spawning weaponentity for client
 857 void CL_SpawnWeaponentity()
 858 {
 859         self.weaponentity = spawn();
 860         self.weaponentity.classname = "weaponentity";
 861         self.weaponentity.solid = SOLID_NOT;
 862         self.weaponentity.owner = self;
 863         setmodel(self.weaponentity, ""); // precision set when changed
 864         setorigin(self.weaponentity, '0 0 0');
 865         self.weaponentity.angles = '0 0 0';
 866         self.weaponentity.viewmodelforclient = self;
 867         self.weaponentity.flags = 0;
 868         self.weaponentity.think = CL_Weaponentity_Think;
 869         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 870         self.weaponentity.nextthink = time;
 871
 872         self.exteriorweaponentity = spawn();
 873         self.exteriorweaponentity.classname = "exteriorweaponentity";
 874         self.exteriorweaponentity.solid = SOLID_NOT;
 875         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 876         self.exteriorweaponentity.owner = self;
 877         setorigin(self.exteriorweaponentity, '0 0 0');
 878         self.exteriorweaponentity.angles = '0 0 0';
 879         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 880         self.exteriorweaponentity.nextthink = time;
 881 };
 882
 883 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 884 {
 885         msg_entity = e;
 886         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 887         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 888         WriteByte(MSG_ONE, wpn);
 889         WriteString(MSG_ONE, wpnname);
 890         WriteByte(MSG_ONE, type);
 891 }
 892
 893 .float hasweapon_complain_spam;
 894
 895 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 896 {
 897         local float weaponbit, f;
 898         local entity oldself;
 899
 900         if(time < self.hasweapon_complain_spam)
 901                 complain = 0;
 902         if(complain)
 903                 self.hasweapon_complain_spam = time + 0.2;
 904
 905         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 906         {
 907                 if (complain)
 908                         sprint(self, "Invalid weapon\n");
 909                 return FALSE;
 910         }
 911         weaponbit = W_WeaponBit(wpn);
 912         if (cl.weapons & weaponbit)
 913         {
 914                 if (andammo)
 915                 {
 916                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 917                         {
 918                                 f = 1;
 919                         }
 920                         else
 921                         {
 922                                 oldself = self;
 923                                 self = cl;
 924                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 925                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 926
 927                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 928                                 local entity mine;
 929                                 if(wpn == WEP_MINE_LAYER)
 930                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 931                                         f = 1;
 932
 933                                 self = oldself;
 934                         }
 935                         if (!f)
 936                         {
 937                                 if (complain)
 938                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 939                                 {
 940                                         play2(cl, "weapons/unavailable.wav");
 941                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 942                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 943                                 }
 944                                 return FALSE;
 945                         }
 946                 }
 947                 return TRUE;
 948         }
 949         if (complain)
 950         {
 951                 // DRESK - 3/16/07
 952                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 953                 if(weaponsInMap & weaponbit)
 954                 {
 955                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 956                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 957
 958                         if(cvar("g_showweaponspawns"))
 959                         {
 960                                 entity e;
 961                                 string s;
 962
 963                                 e = get_weaponinfo(wpn);
 964                                 s = e.model2;
 965
 966                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 967                                 {
 968                                         if(e.classname == "droppedweapon")
 969                                                 continue;
 970                                         if not(e.flags & FL_ITEM)
 971                                                 continue;
 972                                         WaypointSprite_Spawn(
 973                                                 s,
 974                                                 1, 0,
 975                                                 world, e.origin,
 976                                                 self, 0,
 977                                                 world, enemy,
 978                                                 0
 979                                         );
 980                                 }
 981                         }
 982                 }
 983                 else
 984                 {
 985                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 986                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 987                 }
 988
 989                 play2(cl, "weapons/unavailable.wav");
 990         }
 991         return FALSE;
 992 };
 993
 994 // Weapon subs
 995 void w_clear()
 996 {
 997         if (self.weapon != -1)
 998                 self.weapon = 0;
 999         if (self.weaponentity)
1000         {
1001                 self.weaponentity.state = WS_CLEAR;
1002                 self.weaponentity.effects = 0;
1003         }
1004 };
1005
1006 void w_ready()
1007 {
1008         if (self.weaponentity)
1009                 self.weaponentity.state = WS_READY;
1010         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1011 };
1012
1013 // Setup weapon for client (after this raise frame will be launched)
1014 void weapon_setup(float windex)
1015 {
1016         entity e;
1017         qcweaponanimation = cvar("sv_qcweaponanimation");
1018         e = get_weaponinfo(windex);
1019         self.items &~= IT_AMMO;
1020         self.items = self.items | e.items;
1021
1022         // the two weapon entities will notice this has changed and update their models
1023         self.weapon = windex;
1024         self.weaponname = e.mdl;
1025         self.bulletcounter = 0;
1026 };
1027
1028 // perform weapon to attack (weaponstate and attack_finished check is here)
1029 void W_SwitchToOtherWeapon(entity pl)
1030 {
1031         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1032         float w, ww;
1033         w = W_WeaponBit(pl.weapon);
1034         pl.weapons &~= w;
1035         ww = w_getbestweapon(pl);
1036         pl.weapons |= w;
1037         if(ww)
1038                 W_SwitchWeapon_Force(pl, ww);
1039 }
1040 .float prevdryfire;
1041 float weapon_prepareattack_checkammo(float secondary)
1042 {
1043         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1044         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1045         {
1046                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1047                 local entity mine;
1048                 if(self.weapon == WEP_MINE_LAYER)
1049                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1050                         return FALSE;
1051
1052                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1053                 {
1054                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1055                         self.prevdryfire = time;
1056                 }
1057
1058                 W_SwitchToOtherWeapon(self);
1059                 return FALSE;
1060         }
1061         return TRUE;
1062 }
1063 .float race_penalty;
1064 float weapon_prepareattack_check(float secondary, float attacktime)
1065 {
1066         if(!weapon_prepareattack_checkammo(secondary))
1067                 return FALSE;
1068
1069         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1070         //if all players readied up and the countdown is running
1071         if(time < game_starttime || time < self.race_penalty) {
1072                 return FALSE;
1073         }
1074
1075         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1076                 return FALSE;
1077
1078         // do not even think about shooting if switching
1079         if(self.switchweapon != self.weapon)
1080                 return FALSE;
1081
1082         if(attacktime >= 0)
1083         {
1084                 // don't fire if previous attack is not finished
1085                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1086                         return FALSE;
1087                 // don't fire while changing weapon
1088                 if (self.weaponentity.state != WS_READY)
1089                         return FALSE;
1090         }
1091
1092         return TRUE;
1093 }
1094 float weapon_prepareattack_do(float secondary, float attacktime)
1095 {
1096         self.weaponentity.state = WS_INUSE;
1097
1098         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1099
1100         // if the weapon hasn't been firing continuously, reset the timer
1101         if(attacktime >= 0)
1102         {
1103                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1104                 {
1105                         ATTACK_FINISHED(self) = time;
1106                         //dprint("resetting attack finished to ", ftos(time), "\n");
1107                 }
1108                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1109         }
1110         self.bulletcounter += 1;
1111         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1112         return TRUE;
1113 }
1114 float weapon_prepareattack(float secondary, float attacktime)
1115 {
1116         if(weapon_prepareattack_check(secondary, attacktime))
1117         {
1118                 weapon_prepareattack_do(secondary, attacktime);
1119                 return TRUE;
1120         }
1121         else
1122                 return FALSE;
1123 }
1124
1125 void weapon_thinkf(float fr, float t, void() func)
1126 {
1127         vector a;
1128         vector of, or, ou;
1129         float restartanim;
1130
1131         if(fr == WFRAME_DONTCHANGE)
1132         {
1133                 fr = self.weaponentity.wframe;
1134                 restartanim = FALSE;
1135         }
1136         else if (fr == WFRAME_IDLE)
1137                 restartanim = FALSE;
1138         else
1139                 restartanim = TRUE;
1140
1141         of = v_forward;
1142         or = v_right;
1143         ou = v_up;
1144
1145         if (self.weaponentity)
1146         {
1147                 self.weaponentity.wframe = fr;
1148                 if (qcweaponanimation)
1149                 {
1150                         if (fr != WFRAME_IDLE)
1151                         {
1152                                 self.weapon_morph0time = time;
1153                                 self.weapon_morph0angles = self.weaponentity.angles;
1154                                 self.weapon_morph0origin = self.weaponentity.origin;
1155
1156                                 self.weapon_morph1angles = '0 0 0';
1157                                 self.weapon_morph1time = time + t;
1158                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1159                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1160
1161                                 self.weapon_morph2angles = '0 0 0';
1162                                 self.weapon_morph2time = time + t;
1163                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1164                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1165
1166                                 self.weapon_morph3angles = '0 0 0';
1167                                 self.weapon_morph3time = time + t;
1168                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1169                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1170
1171                                 self.weapon_morph4angles = '0 0 0';
1172                                 self.weapon_morph4time = time + t;
1173                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1174                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1175
1176                                 if (fr == WFRAME_FIRE1)
1177                                 {
1178                                         self.weapon_morph1angles = '5 0 0';
1179                                         self.weapon_morph1time = time + t * 0.1;
1180                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1181                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1182                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1183                                 }
1184                                 else if (fr == WFRAME_FIRE2)
1185                                 {
1186                                         self.weapon_morph1angles = '10 0 0';
1187                                         self.weapon_morph1time = time + t * 0.1;
1188                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1189                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1190                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1191                                 }
1192                                 else if (fr == WFRAME_RELOAD)
1193                                 {
1194                                         self.weapon_morph1time = time + t * 0.05;
1195                                         self.weapon_morph1angles = '-10 40 0';
1196                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1197                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1198
1199                                         self.weapon_morph2time = time + t * 0.15;
1200                                         self.weapon_morph2angles = '-10 40 5';
1201                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1202                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1203
1204                                         self.weapon_morph3time = time + t * 0.25;
1205                                         self.weapon_morph3angles = '-10 40 0';
1206                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1207                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1208                                 }
1209                         }
1210                 }
1211                 else
1212                 {
1213                         if (fr == WFRAME_IDLE)
1214                                 a = self.weaponentity.anim_idle;
1215                         else if (fr == WFRAME_FIRE1)
1216                                 a = self.weaponentity.anim_fire1;
1217                         else if (fr == WFRAME_FIRE2)
1218                                 a = self.weaponentity.anim_fire2;
1219                         else if (fr == WFRAME_RELOAD)
1220                                 a = self.weaponentity.anim_reload;
1221                         a_z *= g_weaponratefactor;
1222                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1223                 }
1224         }
1225
1226         v_forward = of;
1227         v_right = or;
1228         v_up = ou;
1229
1230         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1231         {
1232                 backtrace("Tried to override initial weapon think function - should this really happen?");
1233         }
1234
1235         t *= W_WeaponRateFactor();
1236
1237         // VorteX: haste can be added here
1238         if (self.weapon_think == w_ready)
1239         {
1240                 self.weapon_nextthink = time;
1241                 //dprint("started firing at ", ftos(time), "\n");
1242         }
1243         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1244         {
1245                 self.weapon_nextthink = time;
1246                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1247         }
1248         self.weapon_nextthink = self.weapon_nextthink + t;
1249         self.weapon_think = func;
1250         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1251
1252         if (restartanim)
1253         if (t)
1254         if (!self.crouch) // shoot anim stands up, this looks bad
1255         {
1256                 local vector anim;
1257                 anim = self.anim_shoot;
1258                 anim_z = anim_y / (t + sys_frametime);
1259                 setanim(self, anim, FALSE, TRUE, TRUE);
1260         }
1261 };
1262
1263 void weapon_boblayer1(float spd, vector org)
1264 {
1265         // VorteX: haste can be added here
1266 };
1267
1268 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1269 {
1270         vector mdirection;
1271         float mspeed;
1272         float outspeed;
1273         float nstyle;
1274         vector outvelocity;
1275
1276         mvelocity = mvelocity * g_weaponspeedfactor;
1277
1278         mdirection = normalize(mvelocity);
1279         mspeed = vlen(mvelocity);
1280
1281         nstyle = cvar("g_projectiles_newton_style");
1282         if(nstyle == 0 || forceAbsolute)
1283         {
1284                 // absolute velocity
1285                 outvelocity = mvelocity;
1286         }
1287         else if(nstyle == 1)
1288         {
1289                 // true Newtonian projectiles
1290                 outvelocity = pvelocity + mvelocity;
1291         }
1292         else if(nstyle == 2)
1293         {
1294                 // true Newtonian projectiles with automatic aim adjustment
1295                 //
1296                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1297                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1298                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1299                 // PLUS SIGN!
1300                 // not defined?
1301                 // then...
1302                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1303                 // velocity without mdirection component > mspeed
1304                 // fire at smallest possible mspeed that works?
1305                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1306
1307                 vector solution;
1308                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1309                 if(solution_z)
1310                         outspeed = solution_y; // the larger one
1311                 else
1312                 {
1313                         //outspeed = 0; // slowest possible shot
1314                         outspeed = solution_x; // the real part (that is, the average!)
1315                         //dprint("impossible shot, adjusting\n");
1316                 }
1317
1318                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1319                 outvelocity = mdirection * outspeed;
1320         }
1321         else if(nstyle == 3)
1322         {
1323                 // pseudo-Newtonian:
1324                 outspeed = mspeed + mdirection * pvelocity;
1325                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1326                 outvelocity = mdirection * outspeed;
1327         }
1328         else if(nstyle == 4)
1329         {
1330                 // tZorkian:
1331                 outspeed = mspeed + vlen(pvelocity);
1332                 outvelocity = mdirection * outspeed;
1333         }
1334         else
1335                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1336
1337         return outvelocity;
1338 }
1339
1340 void W_AttachToShotorg(entity flash, vector offset)
1341 {
1342         entity xflash;
1343         flash.owner = self;
1344         flash.angles_z = random() * 360;
1345         if(qcweaponanimation)
1346         {
1347                 setorigin(flash, w_shotorg + w_shotdir * 50);
1348                 flash.angles = vectoangles(w_shotdir);
1349                 flash.angles_z = random() * 360;
1350         }
1351         else
1352         {
1353                 if(gettagindex(self.weaponentity, "shot"))
1354                         setattachment(flash, self.weaponentity, "shot");
1355                 else
1356                         setattachment(flash, self.weaponentity, "tag_shot");
1357                 setorigin(flash, offset);
1358
1359                 xflash = spawn();
1360                 copyentity(flash, xflash);
1361
1362                 flash.viewmodelforclient = self;
1363
1364                 if(self.weaponentity.oldorigin_x > 0)
1365                 {
1366                         setattachment(xflash, self.exteriorweaponentity, "");
1367                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1368                 }
1369                 else
1370                 {
1371                         if(gettagindex(self.exteriorweaponentity, "shot"))
1372                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1373                         else
1374                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1375                         setorigin(xflash, offset);
1376                 }
1377         }
1378 }
1379
1380 vector cliptoplane(vector v, vector p)
1381 {
1382         return v - (v * p) * p;
1383 }
1384
1385 vector solve_cubic_pq(float p, float q)
1386 {
1387         float D, u, v, a;
1388         D = q*q/4.0 + p*p*p/27.0;
1389         if(D < 0)
1390         {
1391                 // irreducibilis
1392                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1393                 u = sqrt(-4.0/3.0 * p);
1394                 // a in range 0..pi/3
1395                 // cos(a)
1396                 // cos(a + 2pi/3)
1397                 // cos(a + 4pi/3)
1398                 return
1399                         u *
1400                         (
1401                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1402                                 +
1403                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1404                                 +
1405                                 '0 0 1' * cos(a)
1406                         );
1407         }
1408         else if(D == 0)
1409         {
1410                 // simple
1411                 if(p == 0)
1412                         return '0 0 0';
1413                 u = 3*q/p;
1414                 v = -u/2;
1415                 if(u >= v)
1416                         return '1 1 0' * v + '0 0 1' * u;
1417                 else
1418                         return '0 1 1' * v + '1 0 0' * u;
1419         }
1420         else
1421         {
1422                 // cardano
1423                 u = cbrt(-q/2.0 + sqrt(D));
1424                 v = cbrt(-q/2.0 - sqrt(D));
1425                 return '1 1 1' * (u + v);
1426         }
1427 }
1428 vector solve_cubic_abcd(float a, float b, float c, float d)
1429 {
1430         // y = 3*a*x + b
1431         // x = (y - b) / 3a
1432         float p, q;
1433         vector v;
1434         p = (9*a*c - 3*b*b);
1435         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1436         v = solve_cubic_pq(p, q);
1437         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1438         if(a < 0)
1439                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1440         return v;
1441 }
1442
1443 vector findperpendicular(vector v)
1444 {
1445         vector p;
1446         p_x = v_z;
1447         p_y = -v_x;
1448         p_z = v_y;
1449         return normalize(cliptoplane(p, v));
1450 }
1451
1452 vector W_CalculateProjectileSpread(vector forward, float spread)
1453 {
1454         float sigma;
1455         vector v1, v2;
1456         float dx, dy, r;
1457         float sstyle;
1458         spread *= g_weaponspreadfactor;
1459         if(spread <= 0)
1460                 return forward;
1461         sstyle = cvar("g_projectiles_spread_style");
1462
1463         if(sstyle == 0)
1464         {
1465                 // this is the baseline for the spread value!
1466                 // standard deviation: sqrt(2/5)
1467                 // density function: sqrt(1-r^2)
1468                 return forward + randomvec() * spread;
1469         }
1470         else if(sstyle == 1)
1471         {
1472                 // same thing, basically
1473                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1474         }
1475         else if(sstyle == 2)
1476         {
1477                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1478                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1479                 v1 = findperpendicular(forward);
1480                 v2 = cross(forward, v1);
1481                 // random point on unit circle
1482                 dx = random() * 2 * M_PI;
1483                 dy = sin(dx);
1484                 dx = cos(dx);
1485                 // radius in our dist function
1486                 r = random();
1487                 r = sqrt(r);
1488                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1489         }
1490         else if(sstyle == 3) // gauss 3d
1491         {
1492                 sigma = spread * 0.44721359549996; // match baseline stddev
1493                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1494                 v1 = forward;
1495                 v1_x += gsl_ran_gaussian(sigma);
1496                 v1_y += gsl_ran_gaussian(sigma);
1497                 v1_z += gsl_ran_gaussian(sigma);
1498                 return v1;
1499         }
1500         else if(sstyle == 4) // gauss 2d
1501         {
1502                 sigma = spread * 0.44721359549996; // match baseline stddev
1503                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1504                 v1_x = gsl_ran_gaussian(sigma);
1505                 v1_y = gsl_ran_gaussian(sigma);
1506                 v1_z = gsl_ran_gaussian(sigma);
1507                 return normalize(forward + cliptoplane(v1, forward));
1508         }
1509         else if(sstyle == 5) // 1-r
1510         {
1511                 sigma = spread * 1.154700538379252; // match baseline stddev
1512                 v1 = findperpendicular(forward);
1513                 v2 = cross(forward, v1);
1514                 // random point on unit circle
1515                 dx = random() * 2 * M_PI;
1516                 dy = sin(dx);
1517                 dx = cos(dx);
1518                 // radius in our dist function
1519                 r = random();
1520                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1521                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1522         }
1523         else if(sstyle == 6) // 1-r^2
1524         {
1525                 sigma = spread * 1.095445115010332; // match baseline stddev
1526                 v1 = findperpendicular(forward);
1527                 v2 = cross(forward, v1);
1528                 // random point on unit circle
1529                 dx = random() * 2 * M_PI;
1530                 dy = sin(dx);
1531                 dx = cos(dx);
1532                 // radius in our dist function
1533                 r = random();
1534                 r = sqrt(1 - r);
1535                 r = sqrt(1 - r);
1536                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1537         }
1538         else if(sstyle == 7) // (1-r) (2-r)
1539         {
1540                 sigma = spread * 1.224744871391589; // match baseline stddev
1541                 v1 = findperpendicular(forward);
1542                 v2 = cross(forward, v1);
1543                 // random point on unit circle
1544                 dx = random() * 2 * M_PI;
1545                 dy = sin(dx);
1546                 dx = cos(dx);
1547                 // radius in our dist function
1548                 r = random();
1549                 r = 1 - sqrt(r);
1550                 r = 1 - sqrt(r);
1551                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1552         }
1553         else
1554                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1555         return '0 0 0';
1556         /*
1557          * how to derive falloff functions:
1558          * rho(r) := (2-r) * (1-r);
1559          * a : 0;
1560          * b : 1;
1561          * rhor(r) := r * rho(r);
1562          * cr(t) := integrate(rhor(r), r, a, t);
1563          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1564          * variance : scr(b) / cr(b);
1565          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1566          * sqrt(0.4 / variance), numer;
1567          */
1568 }
1569
1570 #if 0
1571 float mspercallsum;
1572 float mspercallsstyle;
1573 float mspercallcount;
1574 #endif
1575 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1576 {
1577         if(missile.owner == world)
1578                 error("Unowned missile");
1579
1580         dir = dir + upDir * (pUpSpeed / pSpeed);
1581         dir_z += pZSpeed / pSpeed;
1582         pSpeed *= vlen(dir);
1583         dir = normalize(dir);
1584
1585 #if 0
1586         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1587         {
1588                 mspercallsum = mspercallcount = 0;
1589                 mspercallsstyle = cvar("g_projectiles_spread_style");
1590         }
1591         mspercallsum -= gettime(GETTIME_HIRES);
1592 #endif
1593         dir = W_CalculateProjectileSpread(dir, spread);
1594 #if 0
1595         mspercallsum += gettime(GETTIME_HIRES);
1596         mspercallcount += 1;
1597         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1598 #endif
1599
1600         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1601 }
1602
1603 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1604 {
1605         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1606 }
1607
1608 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1609 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)