qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/weapons/accuracy.qh>
  27 #include <server/world.qh>
  28
  29 // =============================================
  30 //  Server side voting code, reworked by Samual
  31 //  Last updated: December 27th, 2011
  32 // =============================================
  33
  34 //  Nagger for players to know status of voting
  35 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  36 {
  37         int nags, i, f, b;
  38         entity e;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         nags = 0;
  52         if (readycount)
  53         {
  54                 nags |= BIT(0);
  55                 if (to.ready == 0) nags |= BIT(1);
  56         }
  57         if (vote_called)
  58         {
  59                 nags |= BIT(2);
  60                 if (to.vote_selection == 0) nags |= BIT(3);
  61         }
  62         if (warmup_stage) nags |= BIT(4);
  63
  64         if (sendflags & BIT(6)) nags |= BIT(6);
  65
  66         if (sendflags & BIT(7)) nags |= BIT(7);
  67
  68         if (!(nags & 4))  // no vote called? send no string
  69                 nags &= ~(BIT(6) | BIT(7));
  70
  71         WriteByte(MSG_ENTITY, nags);
  72
  73         if (nags & BIT(6))
  74         {
  75                 WriteByte(MSG_ENTITY, vote_accept_count);
  76                 WriteByte(MSG_ENTITY, vote_reject_count);
  77                 WriteByte(MSG_ENTITY, vote_needed_overall);
  78                 WriteChar(MSG_ENTITY, to.vote_selection);
  79         }
  80
  81         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  82
  83         if (nags & 1)
  84         {
  85                 for (i = 1; i <= maxclients; i += 8)
  86                 {
  87                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  88                                 if (!IS_REAL_CLIENT(e) || e.ready)
  89                                         f |= b;
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteReset()
 129 {
 130         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 131
 132         if (vote_called)
 133         {
 134                 strfree(vote_called_command);
 135                 strfree(vote_called_display);
 136                 strfree(vote_caller_name);
 137         }
 138
 139         vote_called = VOTE_NULL;
 140         vote_caller = NULL;
 141         vote_endtime = 0;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 ++vote_player_count;
 223                 if (IS_PLAYER(it))   ++vote_real_player_count;
 224                 switch (it.vote_selection)
 225                 {
 226                         case VOTE_SELECT_REJECT:
 227                         { ++vote_reject_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 229                         }
 230                         case VOTE_SELECT_ACCEPT:
 231                         { ++vote_accept_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 233                         }
 234                         case VOTE_SELECT_ABSTAIN:
 235                         { ++vote_abstain_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 237                         }
 238                         default: break;
 239                 }
 240         });
 241
 242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 243         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 244         {
 245                 if (vote_caller)   vote_caller.vote_waittime = 0;
 246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 247                 VoteReset();
 248                 return;
 249         }
 250
 251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 252         if (!spectators_allowed && (vote_real_player_count > 0))
 253         {
 254                 vote_accept_count = vote_real_accept_count;
 255                 vote_reject_count = vote_real_reject_count;
 256                 vote_abstain_count = vote_real_abstain_count;
 257                 vote_player_count = vote_real_player_count;
 258         }
 259
 260         // people who have no opinion in any way :D
 261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 262
 263         // determine the goal for the vote to be passed or rejected normally
 264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 266
 267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 270
 271         // are there any players at all on the server? it could be an admin vote
 272         if (vote_player_count == 0 && first_count)
 273         {
 274                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 275                 VoteAccept();
 276                 return;
 277         }
 278
 279         // since there ARE players, finally calculate the result of the vote
 280         if (vote_accept_count >= vote_needed_overall)
 281         {
 282                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 288         {
 289                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 290                 VoteReject();
 291                 return;
 292         }
 293
 294         // there is not enough votes in either direction, now lets just calculate what the voters have said
 295         if (time > vote_endtime)
 296         {
 297                 final_needed_votes = vote_needed_overall;
 298
 299                 if (autocvar_sv_vote_majority_factor_of_voted)
 300                 {
 301                         if (vote_accept_count >= vote_needed_of_voted)
 302                         {
 303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 304                                 VoteAccept();
 305                                 return;
 306                         }
 307
 308                         if (vote_accept_count + vote_reject_count > 0)
 309                         {
 310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 311                                 VoteReject();
 312                                 return;
 313                         }
 314
 315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 316                 }
 317
 318                 // it didn't pass or fail, so not enough votes to even make a decision.
 319                 VoteSpam(notvoters, final_needed_votes, "timeout");
 320                 VoteTimeout();
 321         }
 322 }
 323
 324 void VoteThink()
 325 {
 326         if (vote_endtime > 0)        // a vote was called
 327         {
 328                 if (time > vote_endtime) // time is up
 329                         VoteCount(false);
 330         }
 331 }
 332
 333
 334 // =======================
 335 //  Game logic for warmup
 336 // =======================
 337
 338 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 339 void reset_map(bool dorespawn)
 340 {
 341         if (time <= game_starttime)
 342         {
 343                 if (game_stopped)
 344                         return;
 345
 346                 PlayerStats_GameReport_Reset_All();
 347                 if (round_handler_IsActive())
 348                         round_handler_Reset(game_starttime);
 349         }
 350
 351         if (shuffleteams_on_reset_map)
 352         {
 353                 shuffleteams();
 354                 shuffleteams_on_reset_map = false;
 355         }
 356
 357         FOREACH_CLIENT(true, {
 358                 if (time <= game_starttime)
 359                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 360                 if (!IS_PLAYER(it))
 361                         continue;
 362                 if (STAT(FROZEN, it))
 363                         Unfreeze(it, false);
 364                 player_powerups_remove_all(it);
 365                 entity store = PS(it);
 366                 if (store)
 367                 {
 368                         Inventory_clear(store.inventory);
 369                         Inventory_update(store);
 370                 }
 371         });
 372
 373         MUTATOR_CALLHOOK(reset_map_global);
 374
 375         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 376         {
 377                 if(IS_CLIENT(it))
 378                         continue;
 379                 if (it.reset)
 380                 {
 381                         it.reset(it);
 382                         continue;
 383                 }
 384                 if (it.team_saved) it.team = it.team_saved;
 385                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 386         });
 387
 388         // Waypoints and assault start come LAST
 389         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 390                 if (it.reset2) it.reset2(it);
 391         });
 392
 393         // Moving the player reset code here since the player-reset depends
 394         // on spawnpoint entities which have to be reset first --blub
 395         if (dorespawn)
 396         {
 397                 if (!MUTATOR_CALLHOOK(reset_map_players))
 398                 {
 399                         FOREACH_CLIENT(IS_PLAYER(it),
 400                         {
 401                                 // PlayerScore_Clear(it);
 402                                 CS(it).killcount = 0;
 403                                 // stop the player from moving so that he stands still once he gets respawned
 404                                 it.velocity = '0 0 0';
 405                                 it.avelocity = '0 0 0';
 406                                 CS(it).movement = '0 0 0';
 407                                 PutClientInServer(it);
 408                         });
 409                 }
 410         }
 411 }
 412
 413 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 414 void ReadyRestart_think(entity this)
 415 {
 416         reset_map(true);
 417         Score_ClearAll();
 418         delete(this);
 419 }
 420
 421 // Forces a restart of the game without actually reloading the map // this is a mess...
 422 void ReadyRestart_force()
 423 {
 424         if (time <= game_starttime && game_stopped)
 425                 return;
 426
 427         bprint("^1Match is restarting...\n");
 428
 429         VoteReset();
 430
 431         // clear overtime, we have to decrease timelimit to its original value again.
 432         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 433                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 434         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 435
 436         if(warmup_stage)
 437                 game_starttime = time; // Warmup: No countdown in warmup
 438         else
 439                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 440
 441         // clear player attributes
 442         FOREACH_CLIENT(IS_PLAYER(it), {
 443                 it.alivetime = 0;
 444                 CS(it).killcount = 0;
 445         });
 446
 447         // if we're ending the warmup stage call the corresponding hook
 448         if(!warmup_stage)
 449                 localcmd("\nsv_hook_warmupend\n");
 450
 451         // reset the .ready status of all players (also spectators)
 452         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 453         readycount = 0;
 454         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 455
 456         // lock teams with lockonrestart
 457         if (autocvar_teamplay_lockonrestart && teamplay)
 458                 lockteams = !warmup_stage;
 459
 460         // initiate the restart-countdown-announcer entity
 461         if (sv_ready_restart_after_countdown && !warmup_stage)
 462         {
 463                 entity restart_timer = new_pure(restart_timer);
 464                 setthink(restart_timer, ReadyRestart_think);
 465                 restart_timer.nextthink = game_starttime;
 466         }
 467
 468         // after a restart every players number of allowed timeouts gets reset, too
 469         if (autocvar_sv_timeout)
 470         {
 471                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 472         }
 473
 474         if (!sv_ready_restart_after_countdown || warmup_stage) reset_map(true);
 475         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 476 }
 477
 478 void ReadyRestart(bool forceWarmupEnd)
 479 {
 480         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 481         else localcmd("\nsv_hook_readyrestart\n");
 482
 483         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 484         // Otherwise scores could be manipulated during the countdown.
 485         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 486
 487         if(forceWarmupEnd)
 488                 warmup_stage = 0; // forcefully end warmup and go to match stage
 489         else
 490                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 491
 492         ReadyRestart_force();
 493 }
 494
 495 // Count the players who are ready and determine whether or not to restart the match
 496 void ReadyCount()
 497 {
 498         float ready_needed_factor, ready_needed_count;
 499         float t_ready = 0, t_players = 0;
 500
 501         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 502                 ++t_players;
 503                 if (it.ready) ++t_ready;
 504         });
 505
 506         readycount = t_ready;
 507
 508         Nagger_ReadyCounted();
 509
 510         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 511         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 512
 513         if (readycount >= ready_needed_count) ReadyRestart(true);
 514 }
 515
 516
 517 // ======================================
 518 //  Supporting functions for VoteCommand
 519 // ======================================
 520
 521 float Votecommand_check_assignment(entity caller, float assignment)
 522 {
 523         float from_server = (!caller);
 524
 525         if ((assignment == VC_ASGNMNT_BOTH)
 526             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 527             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 528
 529         return false;
 530 }
 531
 532 string VoteCommand_extractcommand(string input, float startpos, int argc)
 533 {
 534         string output;
 535
 536         if ((argc - 1) < startpos) output = "";
 537         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 538
 539         return output;
 540 }
 541
 542 float VoteCommand_checknasty(string vote_command)
 543 {
 544         if ((strstrofs(vote_command, ";", 0) >= 0)
 545             || (strstrofs(vote_command, "\n", 0) >= 0)
 546             || (strstrofs(vote_command, "\r", 0) >= 0)
 547             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 548
 549         return true;
 550 }
 551
 552 // NOTE: requires input to be surrounded by spaces
 553 string VoteCommand_checkreplacements(string input)
 554 {
 555         string output = input;
 556         // allow gotomap replacements
 557         output = strreplace(" map ", " gotomap ", output);
 558         output = strreplace(" chmap ", " gotomap ", output);
 559         return output;
 560 }
 561
 562 float VoteCommand_checkinlist(string vote_command, string list)
 563 {
 564         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 565
 566         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 567
 568         return false;
 569 }
 570
 571 string ValidateMap(string validated_map, entity caller)
 572 {
 573         validated_map = MapInfo_FixName(validated_map);
 574
 575         if (!validated_map)
 576         {
 577                 print_to(caller, "This map is not available on this server.");
 578                 return string_null;
 579         }
 580
 581         if (!autocvar_sv_vote_override_mostrecent && caller)
 582         {
 583                 if (Map_IsRecent(validated_map))
 584                 {
 585                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 586                         return string_null;
 587                 }
 588         }
 589
 590         if (!MapInfo_CheckMap(validated_map))
 591         {
 592                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 593                 return string_null;
 594         }
 595
 596         return validated_map;
 597 }
 598
 599 float VoteCommand_checkargs(float startpos, int argc)
 600 {
 601         float p, q, check, minargs;
 602         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 603         string cmdrestriction = "";  // No we don't.
 604         string charlist, arg;
 605         float checkmate;
 606
 607         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 608                 cmdrestriction = cvar_string(cvarname);
 609         else
 610                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 611
 612         if (cmdrestriction == "") return true;
 613
 614         ++startpos;  // skip command name
 615
 616         // check minimum arg count
 617
 618         // 0 args: argc == startpos
 619         // 1 args: argc == startpos + 1
 620         // ...
 621
 622         minargs = stof(cmdrestriction);
 623         if (argc - startpos < minargs) return false;
 624
 625         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 626
 627         for ( ; ; )
 628         {
 629                 // we know that at any time, startpos <= argc - minargs
 630                 // so this means: argc-minargs >= startpos >= argc, thus
 631                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 632                 // have been seen already
 633
 634                 if (startpos >= argc) // all args checked? GOOD
 635                         break;
 636
 637                 if (p < 0)            // no more args? FAIL
 638                 {
 639                         // exception: exactly minargs left, this one included
 640                         if (argc - startpos == minargs) break;
 641
 642                         // otherwise fail
 643                         return false;
 644                 }
 645
 646                 // cut to next semicolon
 647                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 648                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 649                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 650
 651                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 652                 // charlist = strreplace("^^", ";", charlist);
 653
 654                 if (charlist != "")
 655                 {
 656                         // verify the arg only contains allowed chars
 657                         arg = argv(startpos);
 658                         checkmate = strlen(arg);
 659                         for (check = 0; check < checkmate; ++check)
 660                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 661                         // not allowed character
 662                         // all characters are allowed. FINE.
 663                 }
 664
 665                 ++startpos;
 666                 --minargs;
 667                 p = q;
 668         }
 669
 670         return true;
 671 }
 672
 673 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 674 {
 675         string first_command = argv(startpos);
 676         int missing_chars = argv_start_index(startpos);
 677
 678         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 679                 return 0;
 680
 681         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 682
 683         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 684
 685         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 686         {
 687                 case MUT_VOTEPARSE_CONTINUE: { break; }
 688                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 689                 case MUT_VOTEPARSE_INVALID: { return -1; }
 690                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 691         }
 692
 693         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 694         {
 695                 case "kick":
 696                 case "kickban":    // catch all kick/kickban commands
 697                 {
 698                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 699                         float accepted = VerifyClientEntity(victim, true, false);
 700
 701                         if (accepted > 0)
 702                         {
 703                                 string reason = "No reason provided";
 704                                 if(argc > next_token)
 705                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 706
 707                                 string command_arguments = reason;
 708                                 if (first_command == "kickban")
 709                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 710
 711                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 712                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 713                         }
 714                         else
 715                         {
 716                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 717                                 return 0;
 718                         }
 719
 720                         break;
 721                 }
 722
 723                 case "map":
 724                 case "chmap":
 725                 case "gotomap":  // re-direct all map selection commands to gotomap
 726                 {
 727                         vote_command = ValidateMap(argv(startpos + 1), caller);
 728                         if (!vote_command)  return -1;
 729                         vote_parsed_command = strcat("gotomap ", vote_command);
 730                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 731
 732                         break;
 733                 }
 734
 735                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 736                 // maybe fallback instead of aborting if map name is invalid?
 737                 case "nextmap":
 738                 {
 739                         vote_command = ValidateMap(argv(startpos + 1), caller);
 740                         if (!vote_command)  return -1;
 741                         vote_parsed_command = strcat("nextmap ", vote_command);
 742                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 743
 744                         break;
 745                 }
 746
 747                 case "timelimit": // include restrictions on the maximum votable time limit
 748                 {
 749                         float timelimit_vote = stof(argv(startpos + 1));
 750                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 751                         {
 752                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 753                                 return -1;
 754                         }
 755                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 756                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 757                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 758
 759                         break;
 760                 }
 761
 762                 case "restart":
 763                 case "resetmatch":  // re-direct all match restarting to resetmatch
 764                 {
 765                         vote_parsed_command = "resetmatch";
 766                         vote_parsed_display = strzone("^1resetmatch");
 767
 768                         break;
 769                 }
 770
 771                 case "allready":
 772                 {
 773                         if(!warmup_stage) {
 774                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 775                                 return -1;
 776                         }
 777
 778                         vote_parsed_command = vote_command;
 779                         vote_parsed_display = strzone(strcat("^1", vote_command));
 780                         break;
 781                 }
 782
 783                 default:
 784                 {
 785                         vote_parsed_command = vote_command;
 786                         vote_parsed_display = strzone(strcat("^1", vote_command));
 787
 788                         break;
 789                 }
 790         }
 791
 792         return 1;
 793 }
 794
 795
 796 // =======================
 797 //  Command Sub-Functions
 798 // =======================
 799
 800 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 801 {
 802         switch (request)
 803         {
 804                 case CMD_REQUEST_COMMAND:
 805                 {
 806                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 807                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 808                         {
 809                                 print_to(caller, "^1You have already voted.");
 810                         }
 811
 812                         else  // everything went okay, continue changing vote
 813                         {
 814                                 print_to(caller, "^1You abstained from your vote.");
 815                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 816                                 msg_entity = caller;
 817                                 if (!autocvar_sv_vote_singlecount)
 818                                         VoteCount(false);
 819                         }
 820
 821                         return;
 822                 }
 823
 824                 default:
 825                 case CMD_REQUEST_USAGE:
 826                 {
 827                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 828                         print_to(caller, "  No arguments required.");
 829                         return;
 830                 }
 831         }
 832 }
 833
 834 void print_available_commands_to(entity caller)
 835 {
 836         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 837 }
 838
 839 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 840 {
 841         switch (request)
 842         {
 843                 case CMD_REQUEST_COMMAND:
 844                 {
 845                         float tmp_playercount = 0;
 846                         int parse_error;
 847
 848                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 849
 850                         if (!autocvar_sv_vote_call && caller)
 851                         {
 852                                 print_to(caller, "^1Vote calling is not allowed.");
 853                         }
 854                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 855                         {
 856                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 857                         }
 858                         else if (vote_called)
 859                         {
 860                                 print_to(caller, "^1There is already a vote called.");
 861                         }
 862                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 863                         {
 864                                 print_to(caller, "^1Only players can call a vote.");
 865                         }
 866                         else if (caller && !IS_CLIENT(caller))
 867                         {
 868                                 print_to(caller, "^1Only connected clients can vote.");
 869                         }
 870                         else if (timeout_status && vote_command != "timein")
 871                         {
 872                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 873                         }
 874                         else if (caller && (time < caller.vote_waittime))
 875                         {
 876                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 877                         }
 878                         else if (!VoteCommand_checknasty(vote_command))
 879                         {
 880                                 print_to(caller, "^1Syntax error in command.");
 881                         }
 882                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 883                         {
 884                                 if(parse_error == 0)
 885                                 {
 886                                         if (vote_called_command == "")
 887                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 888                                         else
 889                                                 print_to(caller, "^1This command is not acceptable or not available.");
 890                                 }
 891                         }
 892                         else  // everything went okay, continue with calling the vote
 893                         {
 894                                 vote_caller = caller;  // remember who called the vote
 895                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 896                                 vote_called = VOTE_NORMAL;
 897                                 vote_called_command = strzone(vote_parsed_command);
 898                                 vote_called_display = strzone(vote_parsed_display);
 899                                 vote_endtime = time + autocvar_sv_vote_timeout;
 900
 901                                 if (caller)
 902                                 {
 903                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 904                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 905                                         msg_entity = caller;
 906                                 }
 907
 908                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 909
 910                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 911                                 if (autocvar_sv_eventlog)
 912                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 913                                 Nagger_VoteChanged();
 914                                 VoteCount(true);  // needed if you are the only one
 915
 916                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 917                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 918                         }
 919
 920                         return;
 921                 }
 922
 923                 default:
 924                 case CMD_REQUEST_USAGE:
 925                 {
 926                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 927                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 928                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 929                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 930                         print_available_commands_to(caller);
 931                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 932                         return;
 933                 }
 934         }
 935 }
 936
 937 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 938 {
 939         switch (request)
 940         {
 941                 case CMD_REQUEST_COMMAND:
 942                 {
 943                         if (autocvar_sv_vote_master)
 944                         {
 945                                 switch (strtolower(argv(2)))
 946                                 {
 947                                         case "do":
 948                                         {
 949                                                 int parse_error;
 950                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 951
 952                                                 if (!caller.vote_master)
 953                                                         print_to(caller, "^1You do not have vote master privileges.");
 954                                                 else if (!VoteCommand_checknasty(vote_command))
 955                                                 {
 956                                                         print_to(caller, "^1Syntax error in command.");
 957                                                 }
 958                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 959                                                 {
 960                                                         if(parse_error == 0)
 961                                                         {
 962                                                                 if (vote_called_command == "")
 963                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 964                                                                 else
 965                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 966                                                         }
 967                                                 }
 968                                                 else  // everything went okay, proceed with command
 969                                                 {
 970                                                         localcmd(strcat(vote_parsed_command, "\n"));
 971                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 972                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 973                                                         if (autocvar_sv_eventlog)
 974                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 975                                                 }
 976
 977                                                 return;
 978                                         }
 979
 980                                         case "login":
 981                                         {
 982                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 983                                                 else if (caller.vote_master)
 984                                                 {
 985                                                         print_to(caller, "^1You are already logged in as vote master.");
 986                                                 }
 987                                                 else if (autocvar_sv_vote_master_password != argv(3))
 988                                                 {
 989                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 990                                                 }
 991                                                 else  // everything went okay, proceed with giving this player master privilages
 992                                                 {
 993                                                         caller.vote_master = true;
 994                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 995                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 996                                                         if (autocvar_sv_eventlog)
 997                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 998                                                 }
 999
1000                                                 return;
1001                                         }
1002
1003                                         default:  // calling a vote for master
1004                                         {
1005                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1006                                                 else if (vote_called)
1007                                                 {
1008                                                         print_to(caller, "^1There is already a vote called.");
1009                                                 }
1010                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1011                                                 {
1012                                                         print_to(caller, "^1Only players can call a vote.");
1013                                                 }
1014                                                 else if (timeout_status)
1015                                                 {
1016                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1017                                                 }
1018                                                 else  // everything went okay, continue with creating vote
1019                                                 {
1020                                                         vote_caller = caller;
1021                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1022                                                         vote_called = VOTE_MASTER;
1023                                                         vote_called_command = strzone("XXX");
1024                                                         vote_called_display = strzone("^3master");
1025                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1026
1027                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1028                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1029
1030                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1031                                                         if (autocvar_sv_eventlog)
1032                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1033                                                         Nagger_VoteChanged();
1034                                                         VoteCount(true);  // needed if you are the only one
1035                                                 }
1036
1037                                                 return;
1038                                         }
1039                                 }
1040                         }
1041                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1042
1043                         return;
1044                 }
1045
1046                 default:
1047                 case CMD_REQUEST_USAGE:
1048                 {
1049                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1050                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1051                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1052                         return;
1053                 }
1054         }
1055 }
1056
1057 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1058 {
1059         switch (request)
1060         {
1061                 case CMD_REQUEST_COMMAND:
1062                 {
1063                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1064                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1065                         {
1066                                 print_to(caller, "^1You have already voted.");
1067                         }
1068                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1069                         {
1070                                 VoteStop(caller);
1071                         }
1072
1073                         else  // everything went okay, continue changing vote
1074                         {
1075                                 print_to(caller, "^1You rejected the vote.");
1076                                 caller.vote_selection = VOTE_SELECT_REJECT;
1077                                 msg_entity = caller;
1078                                 if (!autocvar_sv_vote_singlecount)
1079                                         VoteCount(false);
1080                         }
1081
1082                         return;
1083                 }
1084
1085                 default:
1086                 case CMD_REQUEST_USAGE:
1087                 {
1088                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1089                         print_to(caller, "  No arguments required.");
1090                         return;
1091                 }
1092         }
1093 }
1094
1095 void VoteCommand_status(int request, entity caller)  // BOTH
1096 {
1097         switch (request)
1098         {
1099                 case CMD_REQUEST_COMMAND:
1100                 {
1101                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1102                         else print_to(caller, "^1No vote called.");
1103
1104                         return;
1105                 }
1106
1107                 default:
1108                 case CMD_REQUEST_USAGE:
1109                 {
1110                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1111                         print_to(caller, "  No arguments required.");
1112                         return;
1113                 }
1114         }
1115 }
1116
1117 void VoteCommand_stop(int request, entity caller)  // BOTH
1118 {
1119         switch (request)
1120         {
1121                 case CMD_REQUEST_COMMAND:
1122                 {
1123                         if (!vote_called)   print_to(caller, "^1No vote called.");
1124                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1125                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1126                         return;
1127                 }
1128
1129                 default:
1130                 case CMD_REQUEST_USAGE:
1131                 {
1132                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1133                         print_to(caller, "  No arguments required.");
1134                         return;
1135                 }
1136         }
1137 }
1138
1139 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1140 {
1141         switch (request)
1142         {
1143                 case CMD_REQUEST_COMMAND:
1144                 {
1145                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1146                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1147                         {
1148                                 print_to(caller, "^1You have already voted.");
1149                         }
1150                         else  // everything went okay, continue changing vote
1151                         {
1152                                 print_to(caller, "^1You accepted the vote.");
1153                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1154                                 msg_entity = caller;
1155                                 if (!autocvar_sv_vote_singlecount)
1156                                         VoteCount(false);
1157                         }
1158
1159                         return;
1160                 }
1161
1162                 default:
1163                 case CMD_REQUEST_USAGE:
1164                 {
1165                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1166                         print_to(caller, "  No arguments required.");
1167                         return;
1168                 }
1169         }
1170 }
1171
1172 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1173 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1174 void VoteCommand_(int request)
1175 {
1176     switch(request)
1177     {
1178         case CMD_REQUEST_COMMAND:
1179         {
1180
1181             return;
1182         }
1183
1184         default:
1185         case CMD_REQUEST_USAGE:
1186         {
1187             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1188             print_to(caller, "  No arguments required.");
1189             return;
1190         }
1191     }
1192 }
1193 */
1194
1195
1196 // ================================
1197 //  Macro system for vote commands
1198 // ================================
1199
1200 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1201 #define VOTE_COMMANDS(request, caller, arguments, command) \
1202         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1203         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1204         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1205         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1206         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1207         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1208         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1209         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1210         /* nothing */
1211
1212 void VoteCommand_macro_help(entity caller, int argc)
1213 {
1214         string command_origin = GetCommandPrefix(caller);
1215
1216         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1217         {
1218                 print_to(caller, "\nVoting commands:\n");
1219                 #define VOTE_COMMAND(name, function, description, assignment) \
1220                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1221
1222                 VOTE_COMMANDS(0, caller, 0, "");
1223                 #undef VOTE_COMMAND
1224
1225                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1226                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1227                 print_available_commands_to(caller);
1228         }
1229         else  // usage for individual command
1230         {
1231                 #define VOTE_COMMAND(name, function, description, assignment) \
1232                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1233
1234                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1235                 #undef VOTE_COMMAND
1236
1237                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1238                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1239                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1240                 else if (argv(2) != "")
1241                         print_to(caller, "No documentation exists for this vote");
1242         }
1243 }
1244
1245 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1246 {
1247         #define VOTE_COMMAND(name, function, description, assignment) \
1248                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1249
1250         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1251         #undef VOTE_COMMAND
1252
1253         return false;
1254 }
1255
1256
1257 // ======================================
1258 //  Main function handling vote commands
1259 // ======================================
1260
1261 void VoteCommand(int request, entity caller, int argc, string vote_command)
1262 {
1263         // Guide for working with argc arguments by example:
1264         // argc:   1    - 2      - 3     - 4
1265         // argv:   0    - 1      - 2     - 3
1266         // cmd     vote - master - login - password
1267
1268         switch (request)
1269         {
1270                 case CMD_REQUEST_COMMAND:
1271                 {
1272                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1273                 }
1274
1275                 default:
1276                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1277                 case CMD_REQUEST_USAGE:
1278                 {
1279                         VoteCommand_macro_help(caller, argc);
1280                         return;
1281                 }
1282         }
1283 }