qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? string_null : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
 323 void reset_map(float dorespawn)
 324 {
 325         entity oldself;
 326         oldself = self;
 327
 328         if(time <= game_starttime && round_handler_IsActive())
 329                 round_handler_Reset(game_starttime + 1);
 330
 331         if(g_race || g_cts)
 332                 race_ReadyRestart();
 333         else MUTATOR_CALLHOOK(reset_map_global);
 334
 335         lms_lowest_lives = 999;
 336         lms_next_place = player_count;
 337
 338         for(self = world; (self = nextent(self)); )
 339         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
 340         {
 341                 if(self.reset)
 342                 {
 343                         self.reset();
 344                         continue;
 345                 }
 346
 347                 if(self.team_saved)
 348                         self.team = self.team_saved;
 349
 350                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 351                         remove(self);
 352         }
 353
 354         // Waypoints and assault start come LAST
 355         for(self = world; (self = nextent(self)); )
 356         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
 357         {
 358                 if(self.reset2)
 359                 {
 360                         self.reset2();
 361                         continue;
 362                 }
 363         }
 364
 365         // Moving the player reset code here since the player-reset depends
 366         // on spawnpoint entities which have to be reset first --blub
 367         if(dorespawn)
 368         if(!MUTATOR_CALLHOOK(reset_map_players))
 369         FOR_EACH_CLIENT(self) // reset all players
 370         {
 371                 /*
 372                 only reset players if a restart countdown is active
 373                 this can either be due to cvar sv_ready_restart_after_countdown having set
 374                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 375                 sv_ready_restart_after_countdown is not used and countdown is still running
 376                 */
 377                 if (restart_mapalreadyrestarted || (time < game_starttime))
 378                 {
 379                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 380                         if (self.classname == "player") {
 381                                 //PlayerScore_Clear(self);
 382                                 if(g_lms)
 383                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 384                                 self.killcount = 0;
 385                                 //stop the player from moving so that he stands still once he gets respawned
 386                                 self.velocity = '0 0 0';
 387                                 self.avelocity = '0 0 0';
 388                                 self.movement = '0 0 0';
 389                                 PutClientInServer();
 390                         }
 391                 }
 392         }
 393
 394         if(g_keyhunt)
 395                 kh_Controller_SetThink_NoMsg(autocvar_g_balance_keyhunt_delay_round+(game_starttime - time), kh_StartRound);
 396
 397         self = oldself;
 398 }
 399
 400 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 401 void ReadyRestart_think()
 402 {
 403         restart_mapalreadyrestarted = 1;
 404         reset_map(TRUE);
 405         Score_ClearAll();
 406         remove(self);
 407
 408         return;
 409 }
 410
 411 // Forces a restart of the game without actually reloading the map // this is a mess...
 412 void ReadyRestart_force()
 413 {
 414         entity tmp_player, restart_timer;
 415
 416         bprint("^1Server is restarting...\n");
 417
 418         VoteReset();
 419
 420         // clear overtime, we have to decrease timelimit to its original value again.
 421         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 422
 423         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 424
 425         readyrestart_happened = 1;
 426         game_starttime = time;
 427         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 428
 429         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 430
 431         // disable the warmup global for the server
 432         inWarmupStage = 0; // once the game is restarted the game is in match stage
 433
 434         // reset the .ready status of all players (also spectators)
 435         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 436         readycount = 0;
 437         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 438
 439         // lock teams with lockonrestart
 440         if(autocvar_teamplay_lockonrestart && teamplay)
 441         {
 442                 lockteams = 1;
 443                 bprint("^1The teams are now locked.\n");
 444         }
 445
 446         //initiate the restart-countdown-announcer entity
 447         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 448         {
 449                 restart_timer = spawn();
 450                 restart_timer.think = ReadyRestart_think;
 451                 restart_timer.nextthink = game_starttime;
 452         }
 453
 454         // after a restart every players number of allowed timeouts gets reset, too
 455         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 456
 457         //reset map immediately if this cvar is not set
 458         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 459
 460         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 461 }
 462
 463 void ReadyRestart()
 464 {
 465         // no arena, assault support yet...
 466         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 467                 localcmd("restart\n");
 468         else
 469                 localcmd("\nsv_hook_gamerestart\n");
 470
 471         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 472         // Otherwise scores could be manipulated during the countdown.
 473         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 474
 475         ReadyRestart_force();
 476
 477         return;
 478 }
 479
 480 // Count the players who are ready and determine whether or not to restart the match
 481 void ReadyCount()
 482 {
 483         entity tmp_player;
 484         float ready_needed_factor, ready_needed_count;
 485         float t_ready = 0, t_players = 0;
 486
 487         FOR_EACH_REALPLAYER(tmp_player)
 488         {
 489                 ++t_players;
 490                 if(tmp_player.ready) { ++t_ready; }
 491         }
 492
 493         readycount = t_ready;
 494
 495         Nagger_ReadyCounted();
 496
 497         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 498         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 499
 500         if(readycount >= ready_needed_count)
 501         {
 502                 ReadyRestart();
 503         }
 504
 505         return;
 506 }
 507
 508
 509 // ======================================
 510 //  Supporting functions for VoteCommand
 511 // ======================================
 512
 513 float Votecommand_check_assignment(entity caller, float assignment)
 514 {
 515         float from_server = (!caller);
 516
 517         if((assignment == VC_ASGNMNT_BOTH)
 518                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 519                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 520         {
 521                 return TRUE;
 522         }
 523
 524         return FALSE;
 525 }
 526
 527 string VoteCommand_extractcommand(string input, float startpos, float argc)
 528 {
 529         string output;
 530
 531         if((argc - 1) < startpos)
 532                 output = "";
 533         else
 534                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 535
 536         return output;
 537 }
 538
 539 float VoteCommand_checknasty(string vote_command)
 540 {
 541         if((strstrofs(vote_command, ";", 0) >= 0)
 542                 || (strstrofs(vote_command, "\n", 0) >= 0)
 543                 || (strstrofs(vote_command, "\r", 0) >= 0)
 544                 || (strstrofs(vote_command, "$", 0) >= 0))
 545                 return FALSE;
 546
 547         return TRUE;
 548 }
 549
 550 float VoteCommand_checkinlist(string vote_command, string list)
 551 {
 552         string l = strcat(" ", list, " ");
 553
 554         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 555                 return TRUE;
 556
 557         return FALSE;
 558 }
 559
 560 string ValidateMap(string validated_map, entity caller)
 561 {
 562         validated_map = MapInfo_FixName(validated_map);
 563
 564         if(!validated_map)
 565         {
 566                 print_to(caller, "This map is not available on this server.");
 567                 return string_null;
 568         }
 569
 570         if(!autocvar_sv_vote_override_mostrecent && caller)
 571         {
 572                 if(Map_IsRecent(validated_map))
 573                 {
 574                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 575                         return string_null;
 576                 }
 577         }
 578
 579         if(!MapInfo_CheckMap(validated_map))
 580         {
 581                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 582                 return string_null;
 583         }
 584
 585         return validated_map;
 586 }
 587
 588 float VoteCommand_checkargs(float startpos, float argc)
 589 {
 590         float p, q, check, minargs;
 591         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 592         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 593         string charlist, arg;
 594         float checkmate;
 595
 596         if(cmdrestriction == "")
 597                 return TRUE;
 598
 599         ++startpos; // skip command name
 600
 601         // check minimum arg count
 602
 603         // 0 args: argc == startpos
 604         // 1 args: argc == startpos + 1
 605         // ...
 606
 607         minargs = stof(cmdrestriction);
 608         if(argc - startpos < minargs)
 609                 return FALSE;
 610
 611         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 612
 613         for(;;)
 614         {
 615                 // we know that at any time, startpos <= argc - minargs
 616                 // so this means: argc-minargs >= startpos >= argc, thus
 617                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 618                 // have been seen already
 619
 620                 if(startpos >= argc) // all args checked? GOOD
 621                         break;
 622
 623                 if(p < 0) // no more args? FAIL
 624                 {
 625                         // exception: exactly minargs left, this one included
 626                         if(argc - startpos == minargs)
 627                                 break;
 628
 629                         // otherwise fail
 630                         return FALSE;
 631                 }
 632
 633                 // cut to next semicolon
 634                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 635                 if(q < 0)
 636                         charlist = substring(cmdrestriction, p+1, -1);
 637                 else
 638                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 639
 640                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 641                 // charlist = strreplace("^^", ";", charlist);
 642
 643                 if(charlist != "")
 644                 {
 645                         // verify the arg only contains allowed chars
 646                         arg = argv(startpos);
 647                         checkmate = strlen(arg);
 648                         for(check = 0; check < checkmate; ++check)
 649                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 650                                         return FALSE; // not allowed character
 651                         // all characters are allowed. FINE.
 652                 }
 653
 654                 ++startpos;
 655                 --minargs;
 656                 p = q;
 657         }
 658
 659         return TRUE;
 660 }
 661
 662 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 663 {
 664         string first_command;
 665
 666         first_command = argv(startpos);
 667
 668         if not(VoteCommand_checkinlist(first_command, vote_list))
 669                 return FALSE;
 670
 671         if not(VoteCommand_checkargs(startpos, argc))
 672                 return FALSE;
 673
 674         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 675         {
 676                 case "kick":
 677                 case "kickban": // catch all kick/kickban commands
 678                 {
 679                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 680                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 681
 682                         if(accepted > 0)
 683                         {
 684                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 685                                 string command_arguments;
 686
 687                                 if(first_command == "kickban")
 688                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 689                                 else
 690                                         command_arguments = reason;
 691
 692                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 693                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 694                         }
 695                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 696
 697                         break;
 698                 }
 699
 700                 case "map":
 701                 case "chmap":
 702                 case "gotomap": // re-direct all map selection commands to gotomap
 703                 {
 704                         vote_command = ValidateMap(argv(startpos + 1), caller);
 705                         if not(vote_command) { return FALSE; }
 706                         vote_parsed_command = strcat("gotomap ", vote_command);
 707                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 708
 709                         break;
 710                 }
 711
 712                 default:
 713                 {
 714                         vote_parsed_command = vote_command;
 715                         vote_parsed_display = strzone(strcat("^1", vote_command));
 716
 717                         break;
 718                 }
 719         }
 720
 721         return TRUE;
 722 }
 723
 724
 725 // =======================
 726 //  Command Sub-Functions
 727 // =======================
 728
 729 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 730 {
 731         switch(request)
 732         {
 733                 case CMD_REQUEST_COMMAND:
 734                 {
 735                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 736                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 737
 738                         else // everything went okay, continue changing vote
 739                         {
 740                                 print_to(caller, "^1You abstained from your vote.");
 741                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 742                                 msg_entity = caller;
 743                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 744                         }
 745
 746                         return;
 747                 }
 748
 749                 default:
 750                 case CMD_REQUEST_USAGE:
 751                 {
 752                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 753                         print_to(caller, "  No arguments required.");
 754                         return;
 755                 }
 756         }
 757 }
 758
 759 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 760 {
 761         switch(request)
 762         {
 763                 case CMD_REQUEST_COMMAND:
 764                 {
 765                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 766                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 767                                 || (autocvar_sv_vote_nospectators == 0));
 768
 769                         float tmp_playercount = 0;
 770                         entity tmp_player;
 771
 772                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 773
 774                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 775                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 776                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 777                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 778                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 779                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 780                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 781
 782                         else // everything went okay, continue with calling the vote
 783                         {
 784                                 vote_caller = caller; // remember who called the vote
 785                                 vote_called = VOTE_NORMAL;
 786                                 vote_called_command = strzone(vote_parsed_command);
 787                                 vote_called_display = strzone(vote_parsed_display);
 788                                 vote_endtime = time + autocvar_sv_vote_timeout;
 789
 790                                 if(caller)
 791                                 {
 792                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 793                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 794                                         msg_entity = caller;
 795                                 }
 796
 797                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 798                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 799
 800                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 801                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 802                                 Nagger_VoteChanged();
 803                                 VoteCount(TRUE); // needed if you are the only one
 804                         }
 805
 806                         return;
 807                 }
 808
 809                 default:
 810                 case CMD_REQUEST_USAGE:
 811                 {
 812                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 813                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 814                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 815                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 816                         return;
 817                 }
 818         }
 819 }
 820
 821 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 822 {
 823         switch(request)
 824         {
 825                 case CMD_REQUEST_COMMAND:
 826                 {
 827                         if(autocvar_sv_vote_master)
 828                         {
 829                                 switch(strtolower(argv(2)))
 830                                 {
 831                                         case "do":
 832                                         {
 833                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 834
 835                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 836                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 837                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 838
 839                                                 else // everything went okay, proceed with command
 840                                                 {
 841                                                         localcmd(strcat(vote_parsed_command, "\n"));
 842                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 843                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 844                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 845                                                 }
 846
 847                                                 return;
 848                                         }
 849
 850                                         case "login":
 851                                         {
 852                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 853                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 854                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 855
 856                                                 else // everything went okay, proceed with giving this player master privilages
 857                                                 {
 858                                                         caller.vote_master = TRUE;
 859                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 860                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 861                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 862                                                 }
 863
 864                                                 return;
 865                                         }
 866
 867                                         default: // calling a vote for master
 868                                         {
 869                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 870                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 871                                                         || (autocvar_sv_vote_nospectators == 0));
 872
 873                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 874                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 875                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 876                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 877
 878                                                 else // everything went okay, continue with creating vote
 879                                                 {
 880                                                         vote_caller = caller;
 881                                                         vote_called = VOTE_MASTER;
 882                                                         vote_called_command = strzone("XXX");
 883                                                         vote_called_display = strzone("^3master");
 884                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 885
 886                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 887                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 888
 889                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 890                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 891                                                         Nagger_VoteChanged();
 892                                                         VoteCount(TRUE); // needed if you are the only one
 893                                                 }
 894
 895                                                 return;
 896                                         }
 897                                 }
 898                         }
 899                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 900
 901                         return;
 902                 }
 903
 904                 default:
 905                 case CMD_REQUEST_USAGE:
 906                 {
 907                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 908                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 909                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 910                         return;
 911                 }
 912         }
 913 }
 914
 915 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 916 {
 917         switch(request)
 918         {
 919                 case CMD_REQUEST_COMMAND:
 920                 {
 921                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 922                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 923                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 924
 925                         else // everything went okay, continue changing vote
 926                         {
 927                                 print_to(caller, "^1You rejected the vote.");
 928                                 caller.vote_selection = VOTE_SELECT_REJECT;
 929                                 msg_entity = caller;
 930                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 931                         }
 932
 933                         return;
 934                 }
 935
 936                 default:
 937                 case CMD_REQUEST_USAGE:
 938                 {
 939                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 940                         print_to(caller, "  No arguments required.");
 941                         return;
 942                 }
 943         }
 944 }
 945
 946 void VoteCommand_status(float request, entity caller) // BOTH
 947 {
 948         switch(request)
 949         {
 950                 case CMD_REQUEST_COMMAND:
 951                 {
 952                         if(vote_called)
 953                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 954                         else
 955                                 print_to(caller, "^1No vote called.");
 956
 957                         return;
 958                 }
 959
 960                 default:
 961                 case CMD_REQUEST_USAGE:
 962                 {
 963                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 964                         print_to(caller, "  No arguments required.");
 965                         return;
 966                 }
 967         }
 968 }
 969
 970 void VoteCommand_stop(float request, entity caller) // BOTH
 971 {
 972         switch(request)
 973         {
 974                 case CMD_REQUEST_COMMAND:
 975                 {
 976                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 977                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 978                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 979
 980                         return;
 981                 }
 982
 983                 default:
 984                 case CMD_REQUEST_USAGE:
 985                 {
 986                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 987                         print_to(caller, "  No arguments required.");
 988                         return;
 989                 }
 990         }
 991 }
 992
 993 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 994 {
 995         switch(request)
 996         {
 997                 case CMD_REQUEST_COMMAND:
 998                 {
 999                         if not(vote_called) { print_to(caller, "^1No vote called."); }
1000                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1001
1002                         else // everything went okay, continue changing vote
1003                         {
1004                                 print_to(caller, "^1You accepted the vote.");
1005                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1006                                 msg_entity = caller;
1007                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1008                         }
1009
1010                         return;
1011                 }
1012
1013                 default:
1014                 case CMD_REQUEST_USAGE:
1015                 {
1016                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1017                         print_to(caller, "  No arguments required.");
1018                         return;
1019                 }
1020         }
1021 }
1022
1023 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1024 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1025 void VoteCommand_(float request)
1026 {
1027         switch(request)
1028         {
1029                 case CMD_REQUEST_COMMAND:
1030                 {
1031
1032                         return;
1033                 }
1034
1035                 default:
1036                 case CMD_REQUEST_USAGE:
1037                 {
1038                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1039                         print_to(caller, "  No arguments required.");
1040                         return;
1041                 }
1042         }
1043 }
1044 */
1045
1046
1047 // ================================
1048 //  Macro system for vote commands
1049 // ================================
1050
1051 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1052 #define VOTE_COMMANDS(request,caller,arguments,command) \
1053         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1054         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1055         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1056         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1057         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1058         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1059         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1060         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1061         /* nothing */
1062
1063 void VoteCommand_macro_help(entity caller, float argc)
1064 {
1065         string command_origin = GetCommandPrefix(caller);
1066
1067         if(argc == 2) // help display listing all commands
1068         {
1069                 print_to(caller, "\nVoting commands:\n");
1070                 #define VOTE_COMMAND(name,function,description,assignment) \
1071                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1072
1073                 VOTE_COMMANDS(0, caller, 0, "")
1074                 #undef VOTE_COMMAND
1075
1076                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1077                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1078                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1079         }
1080         else // usage for individual command
1081         {
1082                 #define VOTE_COMMAND(name,function,description,assignment) \
1083                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1084
1085                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1086                 #undef VOTE_COMMAND
1087         }
1088
1089         return;
1090 }
1091
1092 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1093 {
1094         #define VOTE_COMMAND(name,function,description,assignment) \
1095                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1096
1097         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1098         #undef VOTE_COMMAND
1099
1100         return FALSE;
1101 }
1102
1103
1104 // ======================================
1105 //  Main function handling vote commands
1106 // ======================================
1107
1108 void VoteCommand(float request, entity caller, float argc, string vote_command)
1109 {
1110         // Guide for working with argc arguments by example:
1111         // argc:   1    - 2      - 3     - 4
1112         // argv:   0    - 1      - 2     - 3
1113         // cmd     vote - master - login - password
1114
1115         switch(request)
1116         {
1117                 case CMD_REQUEST_COMMAND:
1118                 {
1119                         if(VoteCommand_macro_command(caller, argc, vote_command))
1120                                 return;
1121                 }
1122
1123                 default:
1124                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1125                 case CMD_REQUEST_USAGE:
1126                 {
1127                         VoteCommand_macro_help(caller, argc);
1128                         return;
1129                 }
1130         }
1131 }