qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/mutators_include.qh"
  14
  15 #include "../../common/constants.qh"
  16 #include "../../common/mapinfo.qh"
  17 #include "../../common/notifications.qh"
  18 #include "../../common/playerstats.qh"
  19 #include "../../common/util.qh"
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 float Nagger_SendEntity(entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if(readycount)
  45         {
  46                 nags |= 1;
  47                 if(to.ready == 0)
  48                         nags |= 2;
  49         }
  50         if(vote_called)
  51         {
  52                 nags |= 4;
  53                 if(to.vote_selection == 0)
  54                         nags |= 8;
  55         }
  56         if(warmup_stage)
  57                 nags |= 16;
  58
  59         if(sendflags & 64)
  60                 nags |= 64;
  61
  62         if(sendflags & 128)
  63                 nags |= 128;
  64
  65         if(!(nags & 4)) // no vote called? send no string
  66                 nags &= ~(64 | 128);
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if(nags & 64)
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if(nags & 128)
  79                 WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if(nags & 1)
  82         {
  83                 for(i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  86                                 if(!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if(nagger)
 103                 nagger.SendFlags |= 128;
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if(nagger)
 109                 nagger.SendFlags |= 64;
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if(nagger)
 115                 nagger.SendFlags |= 1;
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller))
 122                 return vote_caller.netname;
 123         return vote_caller_name;
 124 }
 125
 126 // =======================
 127 //  Game logic for voting
 128 // =======================
 129
 130 void VoteReset()
 131 {
 132         entity tmp_player;
 133
 134         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 135
 136         if(vote_called)
 137         {
 138                 strunzone(vote_called_command);
 139                 strunzone(vote_called_display);
 140                 strunzone(vote_caller_name);
 141         }
 142
 143         vote_called = VOTE_NULL;
 144         vote_caller = world;
 145         vote_caller_name = string_null;
 146         vote_endtime = 0;
 147
 148         vote_called_command = string_null;
 149         vote_called_display = string_null;
 150
 151         vote_parsed_command = string_null;
 152         vote_parsed_display = string_null;
 153
 154         Nagger_VoteChanged();
 155 }
 156
 157 void VoteStop(entity stopper)
 158 {
 159         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 160         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 161
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 164
 165         VoteReset();
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if((vote_called == VOTE_MASTER) && vote_caller)
 173                 vote_caller.vote_master = 1;
 174         else
 175                 localcmd(strcat(vote_called_command, "\n"));
 176
 177         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 178
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 181 }
 182
 183 void VoteReject()
 184 {
 185         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 186         VoteReset();
 187         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 188 }
 189
 190 void VoteTimeout()
 191 {
 192         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 193         VoteReset();
 194         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 195 }
 196
 197 void VoteSpam(float notvoters, float mincount, string result)
 198 {
 199         bprint(strcat(
 200                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 201                 strcat("^2:^1", ftos(vote_reject_count)),
 202                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 203                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 204                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 205
 206         if(autocvar_sv_eventlog)
 207         {
 208                 GameLogEcho(strcat(
 209                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 210                         strcat(":", ftos(vote_reject_count)),
 211                         strcat(":", ftos(vote_abstain_count)),
 212                         strcat(":", ftos(notvoters)),
 213                         strcat(":", ftos(mincount))));
 214         }
 215 }
 216
 217 void VoteCount(float first_count)
 218 {
 219         // declarations
 220         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 221
 222         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 223                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 224                                 || (autocvar_sv_vote_nospectators == 0));
 225
 226         float vote_player_count = 0, notvoters = 0;
 227         float vote_real_player_count = 0, vote_real_accept_count = 0;
 228         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 229         float vote_needed_of_voted, final_needed_votes;
 230         float vote_factor_overall, vote_factor_of_voted;
 231
 232         entity tmp_player;
 233
 234         Nagger_VoteCountChanged();
 235
 236         // add up all the votes from each connected client
 237         FOR_EACH_REALCLIENT(tmp_player)
 238         {
 239                 ++vote_player_count;
 240                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 241
 242                 switch(tmp_player.vote_selection)
 243                 {
 244                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 245                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 246                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 247                         default: break;
 248                 }
 249         }
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset();
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if(!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if(vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if(vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if(time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if(autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if(vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if(vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if(vote_endtime > 0) // a vote was called
 336         if(time > vote_endtime) // time is up
 337         {
 338                 VoteCount(false);
 339         }
 340
 341         return;
 342 }
 343
 344
 345 // =======================
 346 //  Game logic for warmup
 347 // =======================
 348
 349 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 350 void reset_map(float dorespawn)
 351 {SELFPARAM();
 352
 353         if(time <= game_starttime && round_handler_IsActive())
 354                 round_handler_Reset(game_starttime);
 355
 356         MUTATOR_CALLHOOK(reset_map_global);
 357
 358         for(entity e = world; (e = nextent(e)); )
 359         {
 360                 setself(e);
 361                 if(IS_NOT_A_CLIENT(self))
 362                 {
 363                         if(self.reset)
 364                         {
 365                                 self.reset();
 366                                 continue;
 367                         }
 368
 369                         if(self.team_saved)
 370                                 self.team = self.team_saved;
 371
 372                         if(self.flags & FL_PROJECTILE) // remove any projectiles left
 373                                 remove(self);
 374                 }
 375         }
 376
 377         // Waypoints and assault start come LAST
 378         for(entity e = world; (e = nextent(e)); )
 379         {
 380                 setself(e);
 381                 if(IS_NOT_A_CLIENT(self))
 382                 {
 383                         if(self.reset2)
 384                         {
 385                                 self.reset2();
 386                                 continue;
 387                         }
 388                 }
 389         }
 390
 391         entity e;
 392         FOR_EACH_PLAYER(e)
 393         if(e.frozen)
 394         {
 395                 SELFCALL(e, Unfreeze(self));
 396                 SELFCALL_DONE();
 397         }
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if(dorespawn)
 402         if(!MUTATOR_CALLHOOK(reset_map_players))
 403         FOR_EACH_CLIENT(e) // reset all players
 404         {
 405                 setself(e);
 406                 /*
 407                 only reset players if a restart countdown is active
 408                 this can either be due to cvar sv_ready_restart_after_countdown having set
 409                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 410                 sv_ready_restart_after_countdown is not used and countdown is still running
 411                 */
 412                 if (restart_mapalreadyrestarted || (time < game_starttime))
 413                 {
 414                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 415                         if (IS_PLAYER(self)) {
 416                                 //PlayerScore_Clear(self);
 417                                 self.killcount = 0;
 418                                 //stop the player from moving so that he stands still once he gets respawned
 419                                 self.velocity = '0 0 0';
 420                                 self.avelocity = '0 0 0';
 421                                 self.movement = '0 0 0';
 422                                 PutClientInServer();
 423                         }
 424                 }
 425         }
 426
 427         if(g_keyhunt)
 428                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 429
 430         setself(this);
 431 }
 432
 433 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 434 void ReadyRestart_think()
 435 {SELFPARAM();
 436         restart_mapalreadyrestarted = 1;
 437         reset_map(true);
 438         Score_ClearAll();
 439         remove(self);
 440
 441         return;
 442 }
 443
 444 // Forces a restart of the game without actually reloading the map // this is a mess...
 445 void ReadyRestart_force()
 446 {
 447         entity tmp_player, restart_timer;
 448
 449         bprint("^1Server is restarting...\n");
 450
 451         VoteReset();
 452
 453         // clear overtime, we have to decrease timelimit to its original value again.
 454         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 455
 456         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 457
 458         readyrestart_happened = 1;
 459         game_starttime = time + RESTART_COUNTDOWN;
 460
 461         // clear player attributes
 462         FOR_EACH_CLIENT(tmp_player)
 463         {
 464                 tmp_player.alivetime = 0;
 465                 tmp_player.killcount = 0;
 466                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 467         }
 468
 469         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 470
 471         // disable the warmup global for the server
 472         warmup_stage = 0; // once the game is restarted the game is in match stage
 473
 474         // reset the .ready status of all players (also spectators)
 475         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 476         readycount = 0;
 477         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 478
 479         // lock teams with lockonrestart
 480         if(autocvar_teamplay_lockonrestart && teamplay)
 481         {
 482                 lockteams = 1;
 483                 bprint("^1The teams are now locked.\n");
 484         }
 485
 486         //initiate the restart-countdown-announcer entity
 487         if(autocvar_sv_ready_restart_after_countdown)
 488         {
 489                 restart_timer = spawn();
 490                 restart_timer.think = ReadyRestart_think;
 491                 restart_timer.nextthink = game_starttime;
 492         }
 493
 494         // after a restart every players number of allowed timeouts gets reset, too
 495         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 496
 497         //reset map immediately if this cvar is not set
 498         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 499
 500         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 501 }
 502
 503 void ReadyRestart()
 504 {
 505         // no arena, assault support yet...
 506         if(g_assault | gameover | intermission_running | race_completing)
 507                 localcmd("restart\n");
 508         else
 509                 localcmd("\nsv_hook_gamerestart\n");
 510
 511         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 512         // Otherwise scores could be manipulated during the countdown.
 513         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 514
 515         ReadyRestart_force();
 516
 517         return;
 518 }
 519
 520 // Count the players who are ready and determine whether or not to restart the match
 521 void ReadyCount()
 522 {
 523         entity tmp_player;
 524         float ready_needed_factor, ready_needed_count;
 525         float t_ready = 0, t_players = 0;
 526
 527         FOR_EACH_REALCLIENT(tmp_player)
 528         {
 529                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 530                 {
 531                         ++t_players;
 532                         if(tmp_player.ready) { ++t_ready; }
 533                 }
 534         }
 535
 536         readycount = t_ready;
 537
 538         Nagger_ReadyCounted();
 539
 540         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 541         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 542
 543         if(readycount >= ready_needed_count)
 544         {
 545                 ReadyRestart();
 546         }
 547
 548         return;
 549 }
 550
 551
 552 // ======================================
 553 //  Supporting functions for VoteCommand
 554 // ======================================
 555
 556 float Votecommand_check_assignment(entity caller, float assignment)
 557 {
 558         float from_server = (!caller);
 559
 560         if((assignment == VC_ASGNMNT_BOTH)
 561                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 562                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 563         {
 564                 return true;
 565         }
 566
 567         return false;
 568 }
 569
 570 string VoteCommand_extractcommand(string input, float startpos, float argc)
 571 {
 572         string output;
 573
 574         if((argc - 1) < startpos)
 575                 output = "";
 576         else
 577                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 578
 579         return output;
 580 }
 581
 582 float VoteCommand_checknasty(string vote_command)
 583 {
 584         if((strstrofs(vote_command, ";", 0) >= 0)
 585                 || (strstrofs(vote_command, "\n", 0) >= 0)
 586                 || (strstrofs(vote_command, "\r", 0) >= 0)
 587                 || (strstrofs(vote_command, "$", 0) >= 0))
 588                 return false;
 589
 590         return true;
 591 }
 592
 593 float VoteCommand_checkinlist(string vote_command, string list)
 594 {
 595         string l = strcat(" ", list, " ");
 596
 597         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 598                 return true;
 599
 600         return false;
 601 }
 602
 603 string ValidateMap(string validated_map, entity caller)
 604 {
 605         validated_map = MapInfo_FixName(validated_map);
 606
 607         if (!validated_map)
 608         {
 609                 print_to(caller, "This map is not available on this server.");
 610                 return string_null;
 611         }
 612
 613         if(!autocvar_sv_vote_override_mostrecent && caller)
 614         {
 615                 if(Map_IsRecent(validated_map))
 616                 {
 617                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 618                         return string_null;
 619                 }
 620         }
 621
 622         if(!MapInfo_CheckMap(validated_map))
 623         {
 624                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 625                 return string_null;
 626         }
 627
 628         return validated_map;
 629 }
 630
 631 float VoteCommand_checkargs(float startpos, float argc)
 632 {
 633         float p, q, check, minargs;
 634         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 635         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 636         string charlist, arg;
 637         float checkmate;
 638
 639         if(cmdrestriction == "")
 640                 return true;
 641
 642         ++startpos; // skip command name
 643
 644         // check minimum arg count
 645
 646         // 0 args: argc == startpos
 647         // 1 args: argc == startpos + 1
 648         // ...
 649
 650         minargs = stof(cmdrestriction);
 651         if(argc - startpos < minargs)
 652                 return false;
 653
 654         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 655
 656         for (;;)
 657         {
 658                 // we know that at any time, startpos <= argc - minargs
 659                 // so this means: argc-minargs >= startpos >= argc, thus
 660                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 661                 // have been seen already
 662
 663                 if(startpos >= argc) // all args checked? GOOD
 664                         break;
 665
 666                 if(p < 0) // no more args? FAIL
 667                 {
 668                         // exception: exactly minargs left, this one included
 669                         if(argc - startpos == minargs)
 670                                 break;
 671
 672                         // otherwise fail
 673                         return false;
 674                 }
 675
 676                 // cut to next semicolon
 677                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 678                 if(q < 0)
 679                         charlist = substring(cmdrestriction, p+1, -1);
 680                 else
 681                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 682
 683                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 684                 // charlist = strreplace("^^", ";", charlist);
 685
 686                 if(charlist != "")
 687                 {
 688                         // verify the arg only contains allowed chars
 689                         arg = argv(startpos);
 690                         checkmate = strlen(arg);
 691                         for(check = 0; check < checkmate; ++check)
 692                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 693                                         return false; // not allowed character
 694                         // all characters are allowed. FINE.
 695                 }
 696
 697                 ++startpos;
 698                 --minargs;
 699                 p = q;
 700         }
 701
 702         return true;
 703 }
 704
 705 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 706 {
 707         string first_command;
 708
 709         first_command = argv(startpos);
 710
 711         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 712                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 713                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 714         );*/
 715
 716         if(
 717                 (autocvar_sv_vote_limit > 0)
 718                 &&
 719                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 720         )
 721                 return false;
 722
 723         if (!VoteCommand_checkinlist(first_command, vote_list))
 724                 return false;
 725
 726         if (!VoteCommand_checkargs(startpos, argc))
 727                 return false;
 728
 729         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 730         {
 731                 case "kick":
 732                 case "kickban": // catch all kick/kickban commands
 733                 {
 734                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 735                         float accepted = VerifyClientEntity(victim, true, false);
 736
 737                         if(accepted > 0)
 738                         {
 739                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 740                                 string command_arguments;
 741
 742                                 if(first_command == "kickban")
 743                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 744                                 else
 745                                         command_arguments = reason;
 746
 747                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 748                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 749                         }
 750                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 751
 752                         break;
 753                 }
 754
 755                 case "map":
 756                 case "chmap":
 757                 case "gotomap": // re-direct all map selection commands to gotomap
 758                 {
 759                         vote_command = ValidateMap(argv(startpos + 1), caller);
 760                         if (!vote_command) { return false; }
 761                         vote_parsed_command = strcat("gotomap ", vote_command);
 762                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 763
 764                         break;
 765                 }
 766
 767                 default:
 768                 {
 769                         vote_parsed_command = vote_command;
 770                         vote_parsed_display = strzone(strcat("^1", vote_command));
 771
 772                         break;
 773                 }
 774         }
 775
 776         return true;
 777 }
 778
 779
 780 // =======================
 781 //  Command Sub-Functions
 782 // =======================
 783
 784 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 785 {
 786         switch(request)
 787         {
 788                 case CMD_REQUEST_COMMAND:
 789                 {
 790                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 791                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 792
 793                         else // everything went okay, continue changing vote
 794                         {
 795                                 print_to(caller, "^1You abstained from your vote.");
 796                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 797                                 msg_entity = caller;
 798                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 799                         }
 800
 801                         return;
 802                 }
 803
 804                 default:
 805                 case CMD_REQUEST_USAGE:
 806                 {
 807                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 808                         print_to(caller, "  No arguments required.");
 809                         return;
 810                 }
 811         }
 812 }
 813
 814 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 815 {
 816         switch(request)
 817         {
 818                 case CMD_REQUEST_COMMAND:
 819                 {
 820                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 821                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 822                                 || (autocvar_sv_vote_nospectators == 0));
 823
 824                         float tmp_playercount = 0;
 825                         entity tmp_player;
 826
 827                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 828
 829                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 830                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 831                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 832                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 833                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 834                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 835                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 836                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 837                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 838
 839                         else // everything went okay, continue with calling the vote
 840                         {
 841                                 vote_caller = caller; // remember who called the vote
 842                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 843                                 vote_called = VOTE_NORMAL;
 844                                 vote_called_command = strzone(vote_parsed_command);
 845                                 vote_called_display = strzone(vote_parsed_display);
 846                                 vote_endtime = time + autocvar_sv_vote_timeout;
 847
 848                                 if(caller)
 849                                 {
 850                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 851                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 852                                         msg_entity = caller;
 853                                 }
 854
 855                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 856                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 857
 858                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 859                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 860                                 Nagger_VoteChanged();
 861                                 VoteCount(true); // needed if you are the only one
 862                         }
 863
 864                         return;
 865                 }
 866
 867                 default:
 868                 case CMD_REQUEST_USAGE:
 869                 {
 870                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 871                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 872                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 873                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 874                         return;
 875                 }
 876         }
 877 }
 878
 879 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 880 {
 881         switch(request)
 882         {
 883                 case CMD_REQUEST_COMMAND:
 884                 {
 885                         if(autocvar_sv_vote_master)
 886                         {
 887                                 switch(strtolower(argv(2)))
 888                                 {
 889                                         case "do":
 890                                         {
 891                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 892
 893                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 894                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 895                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 896
 897                                                 else // everything went okay, proceed with command
 898                                                 {
 899                                                         localcmd(strcat(vote_parsed_command, "\n"));
 900                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 901                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 902                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 903                                                 }
 904
 905                                                 return;
 906                                         }
 907
 908                                         case "login":
 909                                         {
 910                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 911                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 912                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 913
 914                                                 else // everything went okay, proceed with giving this player master privilages
 915                                                 {
 916                                                         caller.vote_master = true;
 917                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 918                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 919                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 920                                                 }
 921
 922                                                 return;
 923                                         }
 924
 925                                         default: // calling a vote for master
 926                                         {
 927                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 928                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 929                                                         || (autocvar_sv_vote_nospectators == 0));
 930
 931                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 932                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 933                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 934                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 935
 936                                                 else // everything went okay, continue with creating vote
 937                                                 {
 938                                                         vote_caller = caller;
 939                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 940                                                         vote_called = VOTE_MASTER;
 941                                                         vote_called_command = strzone("XXX");
 942                                                         vote_called_display = strzone("^3master");
 943                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 944
 945                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 946                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 947
 948                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 949                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 950                                                         Nagger_VoteChanged();
 951                                                         VoteCount(true); // needed if you are the only one
 952                                                 }
 953
 954                                                 return;
 955                                         }
 956                                 }
 957                         }
 958                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 959
 960                         return;
 961                 }
 962
 963                 default:
 964                 case CMD_REQUEST_USAGE:
 965                 {
 966                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 967                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 968                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 969                         return;
 970                 }
 971         }
 972 }
 973
 974 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 975 {
 976         switch(request)
 977         {
 978                 case CMD_REQUEST_COMMAND:
 979                 {
 980                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 981                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 982                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 983
 984                         else // everything went okay, continue changing vote
 985                         {
 986                                 print_to(caller, "^1You rejected the vote.");
 987                                 caller.vote_selection = VOTE_SELECT_REJECT;
 988                                 msg_entity = caller;
 989                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 990                         }
 991
 992                         return;
 993                 }
 994
 995                 default:
 996                 case CMD_REQUEST_USAGE:
 997                 {
 998                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 999                         print_to(caller, "  No arguments required.");
1000                         return;
1001                 }
1002         }
1003 }
1004
1005 void VoteCommand_status(float request, entity caller) // BOTH
1006 {
1007         switch(request)
1008         {
1009                 case CMD_REQUEST_COMMAND:
1010                 {
1011                         if(vote_called)
1012                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1013                         else
1014                                 print_to(caller, "^1No vote called.");
1015
1016                         return;
1017                 }
1018
1019                 default:
1020                 case CMD_REQUEST_USAGE:
1021                 {
1022                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1023                         print_to(caller, "  No arguments required.");
1024                         return;
1025                 }
1026         }
1027 }
1028
1029 void VoteCommand_stop(float request, entity caller) // BOTH
1030 {
1031         switch(request)
1032         {
1033                 case CMD_REQUEST_COMMAND:
1034                 {
1035                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1036                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1037                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1038
1039                         return;
1040                 }
1041
1042                 default:
1043                 case CMD_REQUEST_USAGE:
1044                 {
1045                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1046                         print_to(caller, "  No arguments required.");
1047                         return;
1048                 }
1049         }
1050 }
1051
1052 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1053 {
1054         switch(request)
1055         {
1056                 case CMD_REQUEST_COMMAND:
1057                 {
1058                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1059                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1060
1061                         else // everything went okay, continue changing vote
1062                         {
1063                                 print_to(caller, "^1You accepted the vote.");
1064                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1065                                 msg_entity = caller;
1066                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1067                         }
1068
1069                         return;
1070                 }
1071
1072                 default:
1073                 case CMD_REQUEST_USAGE:
1074                 {
1075                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1076                         print_to(caller, "  No arguments required.");
1077                         return;
1078                 }
1079         }
1080 }
1081
1082 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1083 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1084 void VoteCommand_(float request)
1085 {
1086         switch(request)
1087         {
1088                 case CMD_REQUEST_COMMAND:
1089                 {
1090
1091                         return;
1092                 }
1093
1094                 default:
1095                 case CMD_REQUEST_USAGE:
1096                 {
1097                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1098                         print_to(caller, "  No arguments required.");
1099                         return;
1100                 }
1101         }
1102 }
1103 */
1104
1105
1106 // ================================
1107 //  Macro system for vote commands
1108 // ================================
1109
1110 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1111 #define VOTE_COMMANDS(request,caller,arguments,command) \
1112         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1113         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1114         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1115         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1116         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1117         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1118         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1119         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1120         /* nothing */
1121
1122 void VoteCommand_macro_help(entity caller, float argc)
1123 {
1124         string command_origin = GetCommandPrefix(caller);
1125
1126         if(argc == 2 || argv(2) == "help") // help display listing all commands
1127         {
1128                 print_to(caller, "\nVoting commands:\n");
1129                 #define VOTE_COMMAND(name,function,description,assignment) \
1130                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1131
1132                 VOTE_COMMANDS(0, caller, 0, "");
1133                 #undef VOTE_COMMAND
1134
1135                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1136                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1137                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1138         }
1139         else // usage for individual command
1140         {
1141                 #define VOTE_COMMAND(name,function,description,assignment) \
1142                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1143
1144                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1145                 #undef VOTE_COMMAND
1146         }
1147
1148         return;
1149 }
1150
1151 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1152 {
1153         #define VOTE_COMMAND(name,function,description,assignment) \
1154                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1155
1156         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1157         #undef VOTE_COMMAND
1158
1159         return false;
1160 }
1161
1162
1163 // ======================================
1164 //  Main function handling vote commands
1165 // ======================================
1166
1167 void VoteCommand(float request, entity caller, float argc, string vote_command)
1168 {
1169         // Guide for working with argc arguments by example:
1170         // argc:   1    - 2      - 3     - 4
1171         // argv:   0    - 1      - 2     - 3
1172         // cmd     vote - master - login - password
1173
1174         switch(request)
1175         {
1176                 case CMD_REQUEST_COMMAND:
1177                 {
1178                         if(VoteCommand_macro_command(caller, argc, vote_command))
1179                                 return;
1180                 }
1181
1182                 default:
1183                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1184                 case CMD_REQUEST_USAGE:
1185                 {
1186                         VoteCommand_macro_help(caller, argc);
1187                         return;
1188                 }
1189         }
1190 }