qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/mutators_include.qh"
  14
  15 #include "../../common/constants.qh"
  16 #include "../../common/mapinfo.qh"
  17 #include "../../common/notifications.qh"
  18 #include "../../common/playerstats.qh"
  19 #include "../../common/util.qh"
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 float Nagger_SendEntity(entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if(readycount)
  45         {
  46                 nags |= 1;
  47                 if(to.ready == 0)
  48                         nags |= 2;
  49         }
  50         if(vote_called)
  51         {
  52                 nags |= 4;
  53                 if(to.vote_selection == 0)
  54                         nags |= 8;
  55         }
  56         if(warmup_stage)
  57                 nags |= 16;
  58
  59         if(sendflags & 64)
  60                 nags |= 64;
  61
  62         if(sendflags & 128)
  63                 nags |= 128;
  64
  65         if(!(nags & 4)) // no vote called? send no string
  66                 nags &= ~(64 | 128);
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if(nags & 64)
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if(nags & 128)
  79                 WriteString(MSG_ENTITY, vote_called_display);
  80
  81         if(nags & 1)
  82         {
  83                 for(i = 1; i <= maxclients; i += 8)
  84                 {
  85                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  86                                 if(!IS_REAL_CLIENT(e) || e.ready)
  87                                         f |= b;
  88                         WriteByte(MSG_ENTITY, f);
  89                 }
  90         }
  91
  92         return true;
  93 }
  94
  95 void Nagger_Init()
  96 {
  97         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  98 }
  99
 100 void Nagger_VoteChanged()
 101 {
 102         if(nagger)
 103                 nagger.SendFlags |= 128;
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if(nagger)
 109                 nagger.SendFlags |= 64;
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if(nagger)
 115                 nagger.SendFlags |= 1;
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller))
 122                 return vote_caller.netname;
 123         return vote_caller_name;
 124 }
 125
 126 // =======================
 127 //  Game logic for voting
 128 // =======================
 129
 130 void VoteReset()
 131 {
 132         entity tmp_player;
 133
 134         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 135
 136         if(vote_called)
 137         {
 138                 strunzone(vote_called_command);
 139                 strunzone(vote_called_display);
 140                 strunzone(vote_caller_name);
 141         }
 142
 143         vote_called = VOTE_NULL;
 144         vote_caller = world;
 145         vote_caller_name = string_null;
 146         vote_endtime = 0;
 147
 148         vote_called_command = string_null;
 149         vote_called_display = string_null;
 150
 151         vote_parsed_command = string_null;
 152         vote_parsed_display = string_null;
 153
 154         Nagger_VoteChanged();
 155 }
 156
 157 void VoteStop(entity stopper)
 158 {
 159         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 160         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 161
 162         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 163         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 164
 165         VoteReset();
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if((vote_called == VOTE_MASTER) && vote_caller)
 173                 vote_caller.vote_master = 1;
 174         else
 175                 localcmd(strcat(vote_called_command, "\n"));
 176
 177         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 178
 179         VoteReset();
 180         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 181 }
 182
 183 void VoteReject()
 184 {
 185         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 186         VoteReset();
 187         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 188 }
 189
 190 void VoteTimeout()
 191 {
 192         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 193         VoteReset();
 194         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 195 }
 196
 197 void VoteSpam(float notvoters, float mincount, string result)
 198 {
 199         bprint(strcat(
 200                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 201                 strcat("^2:^1", ftos(vote_reject_count)),
 202                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 203                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 204                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 205
 206         if(autocvar_sv_eventlog)
 207         {
 208                 GameLogEcho(strcat(
 209                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 210                         strcat(":", ftos(vote_reject_count)),
 211                         strcat(":", ftos(vote_abstain_count)),
 212                         strcat(":", ftos(notvoters)),
 213                         strcat(":", ftos(mincount))));
 214         }
 215 }
 216
 217 void VoteCount(float first_count)
 218 {
 219         // declarations
 220         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 221
 222         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 223                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 224                                 || (autocvar_sv_vote_nospectators == 0));
 225
 226         float vote_player_count = 0, notvoters = 0;
 227         float vote_real_player_count = 0, vote_real_accept_count = 0;
 228         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 229         float vote_needed_of_voted, final_needed_votes;
 230         float vote_factor_overall, vote_factor_of_voted;
 231
 232         entity tmp_player;
 233
 234         Nagger_VoteCountChanged();
 235
 236         // add up all the votes from each connected client
 237         FOR_EACH_REALCLIENT(tmp_player)
 238         {
 239                 ++vote_player_count;
 240                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 241
 242                 switch(tmp_player.vote_selection)
 243                 {
 244                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 245                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 246                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 247                         default: break;
 248                 }
 249         }
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset();
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if(!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if(vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if(vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if(time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if(autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if(vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if(vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if(vote_endtime > 0) // a vote was called
 336         if(time > vote_endtime) // time is up
 337         {
 338                 VoteCount(false);
 339         }
 340
 341         return;
 342 }
 343
 344
 345 // =======================
 346 //  Game logic for warmup
 347 // =======================
 348
 349 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 350 void reset_map(float dorespawn)
 351 {
 352         entity oldself;
 353         oldself = self;
 354
 355         if(time <= game_starttime && round_handler_IsActive())
 356                 round_handler_Reset(game_starttime);
 357
 358         MUTATOR_CALLHOOK(reset_map_global);
 359
 360         // ALL the times need to be reset before .reset()ing each item
 361         // since Item_Reset schedules respawn of superweapons and powerups
 362         for(self = world; (self = nextent(self)); )
 363         if(IS_NOT_A_CLIENT(self))
 364         {
 365                 if(self.reset)
 366                         Item_ItemsTime_SetTime(self, 0);
 367         }
 368
 369         for(self = world; (self = nextent(self)); )
 370         if(IS_NOT_A_CLIENT(self))
 371         {
 372                 if(self.reset)
 373                 {
 374                         self.reset();
 375                         continue;
 376                 }
 377
 378                 if(self.team_saved)
 379                         self.team = self.team_saved;
 380
 381                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 382                         remove(self);
 383         }
 384
 385         // Waypoints and assault start come LAST
 386         for(self = world; (self = nextent(self)); )
 387         if(IS_NOT_A_CLIENT(self))
 388         {
 389                 if(self.reset2)
 390                 {
 391                         self.reset2();
 392                         continue;
 393                 }
 394         }
 395
 396         Item_ItemsTime_SetTimesForAllPlayers();
 397
 398         FOR_EACH_PLAYER(self)
 399         if(self.frozen)
 400                 Unfreeze(self);
 401
 402         // Moving the player reset code here since the player-reset depends
 403         // on spawnpoint entities which have to be reset first --blub
 404         if(dorespawn)
 405         if(!MUTATOR_CALLHOOK(reset_map_players))
 406         FOR_EACH_CLIENT(self) // reset all players
 407         {
 408                 /*
 409                 only reset players if a restart countdown is active
 410                 this can either be due to cvar sv_ready_restart_after_countdown having set
 411                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 412                 sv_ready_restart_after_countdown is not used and countdown is still running
 413                 */
 414                 if (restart_mapalreadyrestarted || (time < game_starttime))
 415                 {
 416                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 417                         if (IS_PLAYER(self)) {
 418                                 //PlayerScore_Clear(self);
 419                                 self.killcount = 0;
 420                                 //stop the player from moving so that he stands still once he gets respawned
 421                                 self.velocity = '0 0 0';
 422                                 self.avelocity = '0 0 0';
 423                                 self.movement = '0 0 0';
 424                                 PutClientInServer();
 425                         }
 426                 }
 427         }
 428
 429         if(g_keyhunt)
 430                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 431
 432         self = oldself;
 433 }
 434
 435 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 436 void ReadyRestart_think()
 437 {
 438         restart_mapalreadyrestarted = 1;
 439         reset_map(true);
 440         Score_ClearAll();
 441         remove(self);
 442
 443         return;
 444 }
 445
 446 // Forces a restart of the game without actually reloading the map // this is a mess...
 447 void ReadyRestart_force()
 448 {
 449         entity tmp_player, restart_timer;
 450
 451         bprint("^1Server is restarting...\n");
 452
 453         VoteReset();
 454
 455         // clear overtime, we have to decrease timelimit to its original value again.
 456         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 457
 458         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 459
 460         readyrestart_happened = 1;
 461         game_starttime = time + RESTART_COUNTDOWN;
 462
 463         // clear player attributes
 464         FOR_EACH_CLIENT(tmp_player)
 465         {
 466                 tmp_player.alivetime = 0;
 467                 tmp_player.killcount = 0;
 468                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 469         }
 470
 471         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 472
 473         // disable the warmup global for the server
 474         warmup_stage = 0; // once the game is restarted the game is in match stage
 475
 476         Item_ItemsTime_ResetTimes();
 477
 478         // reset the .ready status of all players (also spectators)
 479         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 480         readycount = 0;
 481         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 482
 483         // lock teams with lockonrestart
 484         if(autocvar_teamplay_lockonrestart && teamplay)
 485         {
 486                 lockteams = 1;
 487                 bprint("^1The teams are now locked.\n");
 488         }
 489
 490         //initiate the restart-countdown-announcer entity
 491         if(autocvar_sv_ready_restart_after_countdown)
 492         {
 493                 restart_timer = spawn();
 494                 restart_timer.think = ReadyRestart_think;
 495                 restart_timer.nextthink = game_starttime;
 496         }
 497
 498         // after a restart every players number of allowed timeouts gets reset, too
 499         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 500
 501         //reset map immediately if this cvar is not set
 502         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 503
 504         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 505 }
 506
 507 void ReadyRestart()
 508 {
 509         // no arena, assault support yet...
 510         if(g_assault | gameover | intermission_running | race_completing)
 511                 localcmd("restart\n");
 512         else
 513                 localcmd("\nsv_hook_gamerestart\n");
 514
 515         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 516         // Otherwise scores could be manipulated during the countdown.
 517         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 518
 519         ReadyRestart_force();
 520
 521         return;
 522 }
 523
 524 // Count the players who are ready and determine whether or not to restart the match
 525 void ReadyCount()
 526 {
 527         entity tmp_player;
 528         float ready_needed_factor, ready_needed_count;
 529         float t_ready = 0, t_players = 0;
 530
 531         FOR_EACH_REALCLIENT(tmp_player)
 532         {
 533                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 534                 {
 535                         ++t_players;
 536                         if(tmp_player.ready) { ++t_ready; }
 537                 }
 538         }
 539
 540         readycount = t_ready;
 541
 542         Nagger_ReadyCounted();
 543
 544         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 545         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 546
 547         if(readycount >= ready_needed_count)
 548         {
 549                 ReadyRestart();
 550         }
 551
 552         return;
 553 }
 554
 555
 556 // ======================================
 557 //  Supporting functions for VoteCommand
 558 // ======================================
 559
 560 float Votecommand_check_assignment(entity caller, float assignment)
 561 {
 562         float from_server = (!caller);
 563
 564         if((assignment == VC_ASGNMNT_BOTH)
 565                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 566                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 567         {
 568                 return true;
 569         }
 570
 571         return false;
 572 }
 573
 574 string VoteCommand_extractcommand(string input, float startpos, float argc)
 575 {
 576         string output;
 577
 578         if((argc - 1) < startpos)
 579                 output = "";
 580         else
 581                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 582
 583         return output;
 584 }
 585
 586 float VoteCommand_checknasty(string vote_command)
 587 {
 588         if((strstrofs(vote_command, ";", 0) >= 0)
 589                 || (strstrofs(vote_command, "\n", 0) >= 0)
 590                 || (strstrofs(vote_command, "\r", 0) >= 0)
 591                 || (strstrofs(vote_command, "$", 0) >= 0))
 592                 return false;
 593
 594         return true;
 595 }
 596
 597 float VoteCommand_checkinlist(string vote_command, string list)
 598 {
 599         string l = strcat(" ", list, " ");
 600
 601         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 602                 return true;
 603
 604         return false;
 605 }
 606
 607 string ValidateMap(string validated_map, entity caller)
 608 {
 609         validated_map = MapInfo_FixName(validated_map);
 610
 611         if (!validated_map)
 612         {
 613                 print_to(caller, "This map is not available on this server.");
 614                 return string_null;
 615         }
 616
 617         if(!autocvar_sv_vote_override_mostrecent && caller)
 618         {
 619                 if(Map_IsRecent(validated_map))
 620                 {
 621                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 622                         return string_null;
 623                 }
 624         }
 625
 626         if(!MapInfo_CheckMap(validated_map))
 627         {
 628                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 629                 return string_null;
 630         }
 631
 632         return validated_map;
 633 }
 634
 635 float VoteCommand_checkargs(float startpos, float argc)
 636 {
 637         float p, q, check, minargs;
 638         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 639         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 640         string charlist, arg;
 641         float checkmate;
 642
 643         if(cmdrestriction == "")
 644                 return true;
 645
 646         ++startpos; // skip command name
 647
 648         // check minimum arg count
 649
 650         // 0 args: argc == startpos
 651         // 1 args: argc == startpos + 1
 652         // ...
 653
 654         minargs = stof(cmdrestriction);
 655         if(argc - startpos < minargs)
 656                 return false;
 657
 658         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 659
 660         for (;;)
 661         {
 662                 // we know that at any time, startpos <= argc - minargs
 663                 // so this means: argc-minargs >= startpos >= argc, thus
 664                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 665                 // have been seen already
 666
 667                 if(startpos >= argc) // all args checked? GOOD
 668                         break;
 669
 670                 if(p < 0) // no more args? FAIL
 671                 {
 672                         // exception: exactly minargs left, this one included
 673                         if(argc - startpos == minargs)
 674                                 break;
 675
 676                         // otherwise fail
 677                         return false;
 678                 }
 679
 680                 // cut to next semicolon
 681                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 682                 if(q < 0)
 683                         charlist = substring(cmdrestriction, p+1, -1);
 684                 else
 685                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 686
 687                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 688                 // charlist = strreplace("^^", ";", charlist);
 689
 690                 if(charlist != "")
 691                 {
 692                         // verify the arg only contains allowed chars
 693                         arg = argv(startpos);
 694                         checkmate = strlen(arg);
 695                         for(check = 0; check < checkmate; ++check)
 696                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 697                                         return false; // not allowed character
 698                         // all characters are allowed. FINE.
 699                 }
 700
 701                 ++startpos;
 702                 --minargs;
 703                 p = q;
 704         }
 705
 706         return true;
 707 }
 708
 709 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 710 {
 711         string first_command;
 712
 713         first_command = argv(startpos);
 714
 715         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 716                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 717                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 718         );*/
 719
 720         if(
 721                 (autocvar_sv_vote_limit > 0)
 722                 &&
 723                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 724         )
 725                 return false;
 726
 727         if (!VoteCommand_checkinlist(first_command, vote_list))
 728                 return false;
 729
 730         if (!VoteCommand_checkargs(startpos, argc))
 731                 return false;
 732
 733         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 734         {
 735                 case "kick":
 736                 case "kickban": // catch all kick/kickban commands
 737                 {
 738                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 739                         float accepted = VerifyClientEntity(victim, true, false);
 740
 741                         if(accepted > 0)
 742                         {
 743                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 744                                 string command_arguments;
 745
 746                                 if(first_command == "kickban")
 747                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 748                                 else
 749                                         command_arguments = reason;
 750
 751                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 752                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 753                         }
 754                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 755
 756                         break;
 757                 }
 758
 759                 case "map":
 760                 case "chmap":
 761                 case "gotomap": // re-direct all map selection commands to gotomap
 762                 {
 763                         vote_command = ValidateMap(argv(startpos + 1), caller);
 764                         if (!vote_command) { return false; }
 765                         vote_parsed_command = strcat("gotomap ", vote_command);
 766                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 767
 768                         break;
 769                 }
 770
 771                 default:
 772                 {
 773                         vote_parsed_command = vote_command;
 774                         vote_parsed_display = strzone(strcat("^1", vote_command));
 775
 776                         break;
 777                 }
 778         }
 779
 780         return true;
 781 }
 782
 783
 784 // =======================
 785 //  Command Sub-Functions
 786 // =======================
 787
 788 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 789 {
 790         switch(request)
 791         {
 792                 case CMD_REQUEST_COMMAND:
 793                 {
 794                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 795                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 796
 797                         else // everything went okay, continue changing vote
 798                         {
 799                                 print_to(caller, "^1You abstained from your vote.");
 800                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 801                                 msg_entity = caller;
 802                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 803                         }
 804
 805                         return;
 806                 }
 807
 808                 default:
 809                 case CMD_REQUEST_USAGE:
 810                 {
 811                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 812                         print_to(caller, "  No arguments required.");
 813                         return;
 814                 }
 815         }
 816 }
 817
 818 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 819 {
 820         switch(request)
 821         {
 822                 case CMD_REQUEST_COMMAND:
 823                 {
 824                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 825                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 826                                 || (autocvar_sv_vote_nospectators == 0));
 827
 828                         float tmp_playercount = 0;
 829                         entity tmp_player;
 830
 831                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 832
 833                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 834                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 835                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 836                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 837                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 838                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 839                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 840                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 841                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 842
 843                         else // everything went okay, continue with calling the vote
 844                         {
 845                                 vote_caller = caller; // remember who called the vote
 846                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 847                                 vote_called = VOTE_NORMAL;
 848                                 vote_called_command = strzone(vote_parsed_command);
 849                                 vote_called_display = strzone(vote_parsed_display);
 850                                 vote_endtime = time + autocvar_sv_vote_timeout;
 851
 852                                 if(caller)
 853                                 {
 854                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 855                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 856                                         msg_entity = caller;
 857                                 }
 858
 859                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 860                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 861
 862                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 863                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 864                                 Nagger_VoteChanged();
 865                                 VoteCount(true); // needed if you are the only one
 866                         }
 867
 868                         return;
 869                 }
 870
 871                 default:
 872                 case CMD_REQUEST_USAGE:
 873                 {
 874                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 875                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 876                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 877                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 878                         return;
 879                 }
 880         }
 881 }
 882
 883 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 884 {
 885         switch(request)
 886         {
 887                 case CMD_REQUEST_COMMAND:
 888                 {
 889                         if(autocvar_sv_vote_master)
 890                         {
 891                                 switch(strtolower(argv(2)))
 892                                 {
 893                                         case "do":
 894                                         {
 895                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 896
 897                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 898                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 899                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 900
 901                                                 else // everything went okay, proceed with command
 902                                                 {
 903                                                         localcmd(strcat(vote_parsed_command, "\n"));
 904                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 905                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 906                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 907                                                 }
 908
 909                                                 return;
 910                                         }
 911
 912                                         case "login":
 913                                         {
 914                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 915                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 916                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 917
 918                                                 else // everything went okay, proceed with giving this player master privilages
 919                                                 {
 920                                                         caller.vote_master = true;
 921                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 922                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 923                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 924                                                 }
 925
 926                                                 return;
 927                                         }
 928
 929                                         default: // calling a vote for master
 930                                         {
 931                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 932                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 933                                                         || (autocvar_sv_vote_nospectators == 0));
 934
 935                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 936                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 937                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 938                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 939
 940                                                 else // everything went okay, continue with creating vote
 941                                                 {
 942                                                         vote_caller = caller;
 943                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 944                                                         vote_called = VOTE_MASTER;
 945                                                         vote_called_command = strzone("XXX");
 946                                                         vote_called_display = strzone("^3master");
 947                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 948
 949                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 950                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 951
 952                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 953                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 954                                                         Nagger_VoteChanged();
 955                                                         VoteCount(true); // needed if you are the only one
 956                                                 }
 957
 958                                                 return;
 959                                         }
 960                                 }
 961                         }
 962                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 963
 964                         return;
 965                 }
 966
 967                 default:
 968                 case CMD_REQUEST_USAGE:
 969                 {
 970                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 971                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 972                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 973                         return;
 974                 }
 975         }
 976 }
 977
 978 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 979 {
 980         switch(request)
 981         {
 982                 case CMD_REQUEST_COMMAND:
 983                 {
 984                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 985                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 986                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 987
 988                         else // everything went okay, continue changing vote
 989                         {
 990                                 print_to(caller, "^1You rejected the vote.");
 991                                 caller.vote_selection = VOTE_SELECT_REJECT;
 992                                 msg_entity = caller;
 993                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 994                         }
 995
 996                         return;
 997                 }
 998
 999                 default:
1000                 case CMD_REQUEST_USAGE:
1001                 {
1002                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1003                         print_to(caller, "  No arguments required.");
1004                         return;
1005                 }
1006         }
1007 }
1008
1009 void VoteCommand_status(float request, entity caller) // BOTH
1010 {
1011         switch(request)
1012         {
1013                 case CMD_REQUEST_COMMAND:
1014                 {
1015                         if(vote_called)
1016                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1017                         else
1018                                 print_to(caller, "^1No vote called.");
1019
1020                         return;
1021                 }
1022
1023                 default:
1024                 case CMD_REQUEST_USAGE:
1025                 {
1026                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1027                         print_to(caller, "  No arguments required.");
1028                         return;
1029                 }
1030         }
1031 }
1032
1033 void VoteCommand_stop(float request, entity caller) // BOTH
1034 {
1035         switch(request)
1036         {
1037                 case CMD_REQUEST_COMMAND:
1038                 {
1039                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1040                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1041                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1042
1043                         return;
1044                 }
1045
1046                 default:
1047                 case CMD_REQUEST_USAGE:
1048                 {
1049                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1050                         print_to(caller, "  No arguments required.");
1051                         return;
1052                 }
1053         }
1054 }
1055
1056 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1057 {
1058         switch(request)
1059         {
1060                 case CMD_REQUEST_COMMAND:
1061                 {
1062                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1063                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1064
1065                         else // everything went okay, continue changing vote
1066                         {
1067                                 print_to(caller, "^1You accepted the vote.");
1068                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1069                                 msg_entity = caller;
1070                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1071                         }
1072
1073                         return;
1074                 }
1075
1076                 default:
1077                 case CMD_REQUEST_USAGE:
1078                 {
1079                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1080                         print_to(caller, "  No arguments required.");
1081                         return;
1082                 }
1083         }
1084 }
1085
1086 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1087 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1088 void VoteCommand_(float request)
1089 {
1090         switch(request)
1091         {
1092                 case CMD_REQUEST_COMMAND:
1093                 {
1094
1095                         return;
1096                 }
1097
1098                 default:
1099                 case CMD_REQUEST_USAGE:
1100                 {
1101                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1102                         print_to(caller, "  No arguments required.");
1103                         return;
1104                 }
1105         }
1106 }
1107 */
1108
1109
1110 // ================================
1111 //  Macro system for vote commands
1112 // ================================
1113
1114 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1115 #define VOTE_COMMANDS(request,caller,arguments,command) \
1116         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1117         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1118         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1119         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1120         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1121         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1122         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1123         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1124         /* nothing */
1125
1126 void VoteCommand_macro_help(entity caller, float argc)
1127 {
1128         string command_origin = GetCommandPrefix(caller);
1129
1130         if(argc == 2 || argv(2) == "help") // help display listing all commands
1131         {
1132                 print_to(caller, "\nVoting commands:\n");
1133                 #define VOTE_COMMAND(name,function,description,assignment) \
1134                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1135
1136                 VOTE_COMMANDS(0, caller, 0, "");
1137                 #undef VOTE_COMMAND
1138
1139                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1140                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1141                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1142         }
1143         else // usage for individual command
1144         {
1145                 #define VOTE_COMMAND(name,function,description,assignment) \
1146                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1147
1148                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1149                 #undef VOTE_COMMAND
1150         }
1151
1152         return;
1153 }
1154
1155 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1156 {
1157         #define VOTE_COMMAND(name,function,description,assignment) \
1158                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1159
1160         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1161         #undef VOTE_COMMAND
1162
1163         return false;
1164 }
1165
1166
1167 // ======================================
1168 //  Main function handling vote commands
1169 // ======================================
1170
1171 void VoteCommand(float request, entity caller, float argc, string vote_command)
1172 {
1173         // Guide for working with argc arguments by example:
1174         // argc:   1    - 2      - 3     - 4
1175         // argv:   0    - 1      - 2     - 3
1176         // cmd     vote - master - login - password
1177
1178         switch(request)
1179         {
1180                 case CMD_REQUEST_COMMAND:
1181                 {
1182                         if(VoteCommand_macro_command(caller, argc, vote_command))
1183                                 return;
1184                 }
1185
1186                 default:
1187                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1188                 case CMD_REQUEST_USAGE:
1189                 {
1190                         VoteCommand_macro_help(caller, argc);
1191                         return;
1192                 }
1193         }
1194 }