qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/command.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/all.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/mapinfo.qh>
  17 #include <common/notifications/all.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/util.qh>
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if (readycount)
  45         {
  46                 nags |= BIT(0);
  47                 if (to.ready == 0) nags |= BIT(1);
  48         }
  49         if (vote_called)
  50         {
  51                 nags |= BIT(2);
  52                 if (to.vote_selection == 0) nags |= BIT(3);
  53         }
  54         if (warmup_stage) nags |= BIT(4);
  55
  56         if (sendflags & BIT(6)) nags |= BIT(6);
  57
  58         if (sendflags & BIT(7)) nags |= BIT(7);
  59
  60         if (!(nags & 4))  // no vote called? send no string
  61                 nags &= ~(BIT(6) | BIT(7));
  62
  63         WriteByte(MSG_ENTITY, nags);
  64
  65         if (nags & BIT(6))
  66         {
  67                 WriteByte(MSG_ENTITY, vote_accept_count);
  68                 WriteByte(MSG_ENTITY, vote_reject_count);
  69                 WriteByte(MSG_ENTITY, vote_needed_overall);
  70                 WriteChar(MSG_ENTITY, to.vote_selection);
  71         }
  72
  73         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  74
  75         if (nags & 1)
  76         {
  77                 for (i = 1; i <= maxclients; i += 8)
  78                 {
  79                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  80                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  81                         WriteByte(MSG_ENTITY, f);
  82                 }
  83         }
  84
  85         return true;
  86 }
  87
  88 void Nagger_Init()
  89 {
  90         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 122
 123         if (vote_called)
 124         {
 125                 strunzone(vote_called_command);
 126                 strunzone(vote_called_display);
 127                 strunzone(vote_caller_name);
 128         }
 129
 130         vote_called = VOTE_NULL;
 131         vote_caller = world;
 132         vote_caller_name = string_null;
 133         vote_endtime = 0;
 134
 135         vote_called_command = string_null;
 136         vote_called_display = string_null;
 137
 138         vote_parsed_command = string_null;
 139         vote_parsed_display = string_null;
 140
 141         Nagger_VoteChanged();
 142 }
 143
 144 void VoteStop(entity stopper)
 145 {
 146         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 147         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 148         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 149         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 150         VoteReset();
 151 }
 152
 153 void VoteAccept()
 154 {
 155         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 156
 157         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 158         else localcmd(strcat(vote_called_command, "\n"));
 159
 160         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 161
 162         VoteReset();
 163         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 164 }
 165
 166 void VoteReject()
 167 {
 168         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 169         VoteReset();
 170         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 171 }
 172
 173 void VoteTimeout()
 174 {
 175         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 176         VoteReset();
 177         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 178 }
 179
 180 void VoteSpam(float notvoters, float mincount, string result)
 181 {
 182         bprint(strcat(
 183                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 184                 strcat("^2:^1", ftos(vote_reject_count)),
 185                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 186                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 187                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 188
 189         if (autocvar_sv_eventlog)
 190         {
 191                 GameLogEcho(strcat(
 192                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 193                         strcat(":", ftos(vote_reject_count)),
 194                         strcat(":", ftos(vote_abstain_count)),
 195                         strcat(":", ftos(notvoters)),
 196                         strcat(":", ftos(mincount))));
 197         }
 198 }
 199
 200 void VoteCount(float first_count)
 201 {
 202         // declarations
 203         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 204
 205         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 206
 207         float vote_player_count = 0, notvoters = 0;
 208         float vote_real_player_count = 0, vote_real_accept_count = 0;
 209         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 210         float vote_needed_of_voted, final_needed_votes;
 211         float vote_factor_overall, vote_factor_of_voted;
 212
 213         Nagger_VoteCountChanged();
 214
 215         // add up all the votes from each connected client
 216         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 217                 ++vote_player_count;
 218                 if (IS_PLAYER(it))   ++vote_real_player_count;
 219                 switch (it.vote_selection)
 220                 {
 221                         case VOTE_SELECT_REJECT:
 222                         { ++vote_reject_count;
 223                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 224                         }
 225                         case VOTE_SELECT_ACCEPT:
 226                         { ++vote_accept_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 228                         }
 229                         case VOTE_SELECT_ABSTAIN:
 230                         { ++vote_abstain_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 232                         }
 233                         default: break;
 234                 }
 235         ));
 236
 237         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 238         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 239         {
 240                 if (vote_caller)   vote_caller.vote_waittime = 0;
 241                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 242                 VoteReset();
 243                 return;
 244         }
 245
 246         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 247         if (!spectators_allowed && (vote_real_player_count > 0))
 248         {
 249                 vote_accept_count = vote_real_accept_count;
 250                 vote_reject_count = vote_real_reject_count;
 251                 vote_abstain_count = vote_real_abstain_count;
 252                 vote_player_count = vote_real_player_count;
 253         }
 254
 255         // people who have no opinion in any way :D
 256         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 257
 258         // determine the goal for the vote to be passed or rejected normally
 259         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 260         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 261
 262         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 263         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 264         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 265
 266         // are there any players at all on the server? it could be an admin vote
 267         if (vote_player_count == 0 && first_count)
 268         {
 269                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 270                 VoteAccept();
 271                 return;
 272         }
 273
 274         // since there ARE players, finally calculate the result of the vote
 275         if (vote_accept_count >= vote_needed_overall)
 276         {
 277                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 278                 VoteAccept();
 279                 return;
 280         }
 281
 282         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 283         {
 284                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 285                 VoteReject();
 286                 return;
 287         }
 288
 289         // there is not enough votes in either direction, now lets just calculate what the voters have said
 290         if (time > vote_endtime)
 291         {
 292                 final_needed_votes = vote_needed_overall;
 293
 294                 if (autocvar_sv_vote_majority_factor_of_voted)
 295                 {
 296                         if (vote_accept_count >= vote_needed_of_voted)
 297                         {
 298                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 299                                 VoteAccept();
 300                                 return;
 301                         }
 302
 303                         if (vote_accept_count + vote_reject_count > 0)
 304                         {
 305                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 306                                 VoteReject();
 307                                 return;
 308                         }
 309
 310                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 311                 }
 312
 313                 // it didn't pass or fail, so not enough votes to even make a decision.
 314                 VoteSpam(notvoters, final_needed_votes, "timeout");
 315                 VoteTimeout();
 316         }
 317 }
 318
 319 void VoteThink()
 320 {
 321         if (vote_endtime > 0)        // a vote was called
 322         {
 323                 if (time > vote_endtime) // time is up
 324                         VoteCount(false);
 325         }
 326 }
 327
 328
 329 // =======================
 330 //  Game logic for warmup
 331 // =======================
 332
 333 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 334 void reset_map(bool dorespawn)
 335 {
 336         SELFPARAM();
 337
 338         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 339
 340         MUTATOR_CALLHOOK(reset_map_global);
 341
 342         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 343                 if (it.reset)
 344                 {
 345                         WITHSELF(it, it.reset(it));
 346                         continue;
 347                 }
 348                 if (it.team_saved) it.team = it.team_saved;
 349                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
 350         });
 351
 352         // Waypoints and assault start come LAST
 353         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 354                 if (it.reset2) WITHSELF(it, it.reset2());
 355         });
 356
 357         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(WITHSELF(it, Unfreeze(it))));
 358
 359         // Moving the player reset code here since the player-reset depends
 360         // on spawnpoint entities which have to be reset first --blub
 361         if (dorespawn)
 362         {
 363                 if (!MUTATOR_CALLHOOK(reset_map_players))
 364                 {
 365                         FOREACH_CLIENT(true, LAMBDA(
 366                                 setself(it);
 367                                 /*
 368                                 only reset players if a restart countdown is active
 369                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 370                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 371                                 sv_ready_restart_after_countdown is not used and countdown is still running
 372                                 */
 373                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 374                                 {
 375                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 376                                         if (IS_PLAYER(self))
 377                                         {
 378                                                 // PlayerScore_Clear(self);
 379                                                 self.killcount = 0;
 380                                                 // stop the player from moving so that he stands still once he gets respawned
 381                                                 self.velocity = '0 0 0';
 382                                                 self.avelocity = '0 0 0';
 383                                                 self.movement = '0 0 0';
 384                                                 PutClientInServer();
 385                                         }
 386                                 }
 387                         ));
 388
 389                         setself(this);
 390                 }
 391         }
 392 }
 393
 394 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 395 void ReadyRestart_think()
 396 {
 397         SELFPARAM();
 398         restart_mapalreadyrestarted = true;
 399         reset_map(true);
 400         Score_ClearAll();
 401         remove(this);
 402 }
 403
 404 // Forces a restart of the game without actually reloading the map // this is a mess...
 405 void ReadyRestart_force()
 406 {
 407         bprint("^1Server is restarting...\n");
 408
 409         VoteReset();
 410
 411         // clear overtime, we have to decrease timelimit to its original value again.
 412         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 413                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 414         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 415
 416         readyrestart_happened = true;
 417         game_starttime = time + RESTART_COUNTDOWN;
 418
 419         // clear player attributes
 420         FOREACH_CLIENT(true, LAMBDA(
 421                 it.alivetime = 0;
 422                 it.killcount = 0;
 423                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 424         ));
 425
 426         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 427
 428         // disable the warmup global for the server
 429         warmup_stage = 0;                // once the game is restarted the game is in match stage
 430
 431         // reset the .ready status of all players (also spectators)
 432         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 433         readycount = 0;
 434         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 435
 436         // lock teams with lockonrestart
 437         if (autocvar_teamplay_lockonrestart && teamplay)
 438         {
 439                 lockteams = true;
 440                 bprint("^1The teams are now locked.\n");
 441         }
 442
 443         // initiate the restart-countdown-announcer entity
 444         if (autocvar_sv_ready_restart_after_countdown)
 445         {
 446                 entity restart_timer = new_pure(restart_timer);
 447                 restart_timer.think = ReadyRestart_think;
 448                 restart_timer.nextthink = game_starttime;
 449         }
 450
 451         // after a restart every players number of allowed timeouts gets reset, too
 452         if (autocvar_sv_timeout)
 453         {
 454                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 455         }
 456     // reset map immediately if this cvar is not set
 457     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 458         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 459 }
 460
 461 void ReadyRestart()
 462 {
 463         // no assault support yet...
 464         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 465         else localcmd("\nsv_hook_gamerestart\n");
 466
 467         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 468         // Otherwise scores could be manipulated during the countdown.
 469         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 470         ReadyRestart_force();
 471 }
 472
 473 // Count the players who are ready and determine whether or not to restart the match
 474 void ReadyCount()
 475 {
 476         float ready_needed_factor, ready_needed_count;
 477         float t_ready = 0, t_players = 0;
 478
 479         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 480                 ++t_players;
 481                 if (it.ready) ++t_ready;
 482         ));
 483
 484         readycount = t_ready;
 485
 486         Nagger_ReadyCounted();
 487
 488         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 489         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 490
 491         if (readycount >= ready_needed_count) ReadyRestart();
 492 }
 493
 494
 495 // ======================================
 496 //  Supporting functions for VoteCommand
 497 // ======================================
 498
 499 float Votecommand_check_assignment(entity caller, float assignment)
 500 {
 501         float from_server = (!caller);
 502
 503         if ((assignment == VC_ASGNMNT_BOTH)
 504             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 505             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 506
 507         return false;
 508 }
 509
 510 string VoteCommand_extractcommand(string input, float startpos, float argc)
 511 {
 512         string output;
 513
 514         if ((argc - 1) < startpos) output = "";
 515         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 516
 517         return output;
 518 }
 519
 520 float VoteCommand_checknasty(string vote_command)
 521 {
 522         if ((strstrofs(vote_command, ";", 0) >= 0)
 523             || (strstrofs(vote_command, "\n", 0) >= 0)
 524             || (strstrofs(vote_command, "\r", 0) >= 0)
 525             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 526
 527         return true;
 528 }
 529
 530 float VoteCommand_checkinlist(string vote_command, string list)
 531 {
 532         string l = strcat(" ", list, " ");
 533
 534         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 535
 536         return false;
 537 }
 538
 539 string ValidateMap(string validated_map, entity caller)
 540 {
 541         validated_map = MapInfo_FixName(validated_map);
 542
 543         if (!validated_map)
 544         {
 545                 print_to(caller, "This map is not available on this server.");
 546                 return string_null;
 547         }
 548
 549         if (!autocvar_sv_vote_override_mostrecent && caller)
 550         {
 551                 if (Map_IsRecent(validated_map))
 552                 {
 553                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 554                         return string_null;
 555                 }
 556         }
 557
 558         if (!MapInfo_CheckMap(validated_map))
 559         {
 560                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 561                 return string_null;
 562         }
 563
 564         return validated_map;
 565 }
 566
 567 float VoteCommand_checkargs(float startpos, float argc)
 568 {
 569         float p, q, check, minargs;
 570         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 571         string cmdrestriction = "";  // No we don't.
 572         string charlist, arg;
 573         float checkmate;
 574
 575         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 576                 cmdrestriction = cvar_string(cvarname);
 577         else
 578                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 579
 580         if (cmdrestriction == "") return true;
 581
 582         ++startpos;  // skip command name
 583
 584         // check minimum arg count
 585
 586         // 0 args: argc == startpos
 587         // 1 args: argc == startpos + 1
 588         // ...
 589
 590         minargs = stof(cmdrestriction);
 591         if (argc - startpos < minargs) return false;
 592
 593         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 594
 595         for ( ; ; )
 596         {
 597                 // we know that at any time, startpos <= argc - minargs
 598                 // so this means: argc-minargs >= startpos >= argc, thus
 599                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 600                 // have been seen already
 601
 602                 if (startpos >= argc) // all args checked? GOOD
 603                         break;
 604
 605                 if (p < 0)            // no more args? FAIL
 606                 {
 607                         // exception: exactly minargs left, this one included
 608                         if (argc - startpos == minargs) break;
 609
 610                         // otherwise fail
 611                         return false;
 612                 }
 613
 614                 // cut to next semicolon
 615                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 616                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 617                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 618
 619                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 620                 // charlist = strreplace("^^", ";", charlist);
 621
 622                 if (charlist != "")
 623                 {
 624                         // verify the arg only contains allowed chars
 625                         arg = argv(startpos);
 626                         checkmate = strlen(arg);
 627                         for (check = 0; check < checkmate; ++check)
 628                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 629                         // not allowed character
 630                         // all characters are allowed. FINE.
 631                 }
 632
 633                 ++startpos;
 634                 --minargs;
 635                 p = q;
 636         }
 637
 638         return true;
 639 }
 640
 641 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 642 {
 643         string first_command;
 644
 645         first_command = argv(startpos);
 646
 647         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 648             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 649             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 650         );*/
 651
 652         if (
 653             (autocvar_sv_vote_limit > 0)
 654             &&
 655             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 656            )   return false;
 657
 658         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 659
 660         if (!VoteCommand_checkargs(startpos, argc)) return false;
 661
 662         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 663         {
 664                 case "kick":
 665                 case "kickban":    // catch all kick/kickban commands
 666                 {
 667                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 668                         float accepted = VerifyClientEntity(victim, true, false);
 669
 670                         if (accepted > 0)
 671                         {
 672                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 673                                 string command_arguments;
 674
 675                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 676                                 else command_arguments = reason;
 677
 678                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 679                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 680                         }
 681                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 682
 683                         break;
 684                 }
 685
 686                 case "map":
 687                 case "chmap":
 688                 case "gotomap":  // re-direct all map selection commands to gotomap
 689                 {
 690                         vote_command = ValidateMap(argv(startpos + 1), caller);
 691                         if (!vote_command)   return false;
 692                         vote_parsed_command = strcat("gotomap ", vote_command);
 693                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 694
 695                         break;
 696                 }
 697
 698                 default:
 699                 {
 700                         vote_parsed_command = vote_command;
 701                         vote_parsed_display = strzone(strcat("^1", vote_command));
 702
 703                         break;
 704                 }
 705         }
 706
 707         return true;
 708 }
 709
 710
 711 // =======================
 712 //  Command Sub-Functions
 713 // =======================
 714
 715 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 716 {
 717         switch (request)
 718         {
 719                 case CMD_REQUEST_COMMAND:
 720                 {
 721                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 722                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 723                         {
 724                                 print_to(caller, "^1You have already voted.");
 725                         }
 726
 727                         else  // everything went okay, continue changing vote
 728                         {
 729                                 print_to(caller, "^1You abstained from your vote.");
 730                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 731                                 msg_entity = caller;
 732                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 733
 734                         return;
 735                 }
 736
 737                 default:
 738                 case CMD_REQUEST_USAGE:
 739                 {
 740                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 741                         print_to(caller, "  No arguments required.");
 742                         return;
 743                 }
 744         }
 745 }
 746
 747 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 748 {
 749         switch (request)
 750         {
 751                 case CMD_REQUEST_COMMAND:
 752                 {
 753                         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 754
 755                         float tmp_playercount = 0;
 756
 757                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 758
 759                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 760                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 761                         {
 762                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 763                         }
 764                         else if (vote_called)
 765                         {
 766                                 print_to(caller, "^1There is already a vote called.");
 767                         }
 768                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 769                         {
 770                                 print_to(caller, "^1Only players can call a vote.");
 771                         }
 772                         else if (caller && !IS_CLIENT(caller))
 773                         {
 774                                 print_to(caller, "^1Only connected clients can vote.");
 775                         }
 776                         else if (timeout_status)
 777                         {
 778                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 779                         }
 780                         else if (caller && (time < caller.vote_waittime))
 781                         {
 782                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 783                         }
 784                         else if (!VoteCommand_checknasty(vote_command))
 785                         {
 786                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 787                         }
 788                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 789                         {
 790                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 791                         }
 792
 793                         else  // everything went okay, continue with calling the vote
 794                         {
 795                                 vote_caller = caller;  // remember who called the vote
 796                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 797                                 vote_called = VOTE_NORMAL;
 798                                 vote_called_command = strzone(vote_parsed_command);
 799                                 vote_called_display = strzone(vote_parsed_display);
 800                                 vote_endtime = time + autocvar_sv_vote_timeout;
 801
 802                                 if (caller)
 803                                 {
 804                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 805                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 806                                         msg_entity = caller;
 807                                 }
 808
 809                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 810                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 811
 812                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 813                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 814                                 Nagger_VoteChanged();
 815                                 VoteCount(true);  // needed if you are the only one
 816                         }
 817
 818                         return;
 819                 }
 820
 821                 default:
 822                 case CMD_REQUEST_USAGE:
 823                 {
 824                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 825                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 826                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 827                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 828                         return;
 829                 }
 830         }
 831 }
 832
 833 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 834 {
 835         switch (request)
 836         {
 837                 case CMD_REQUEST_COMMAND:
 838                 {
 839                         if (autocvar_sv_vote_master)
 840                         {
 841                                 switch (strtolower(argv(2)))
 842                                 {
 843                                         case "do":
 844                                         {
 845                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 846
 847                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 848                                                 else if (!VoteCommand_checknasty(vote_command))
 849                                                 {
 850                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 851                                                 }
 852                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 853                                                 {
 854                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 855                                                 }
 856
 857                                                 else  // everything went okay, proceed with command
 858                                                 {
 859                                                         localcmd(strcat(vote_parsed_command, "\n"));
 860                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 861                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 862                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 863
 864                                                 return;
 865                                         }
 866
 867                                         case "login":
 868                                         {
 869                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 870                                                 else if (caller.vote_master)
 871                                                 {
 872                                                         print_to(caller, "^1You are already logged in as vote master.");
 873                                                 }
 874                                                 else if (autocvar_sv_vote_master_password != argv(3))
 875                                                 {
 876                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 877                                                 }
 878
 879                                                 else  // everything went okay, proceed with giving this player master privilages
 880                                                 {
 881                                                         caller.vote_master = true;
 882                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 883                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 884                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 885
 886                                                 return;
 887                                         }
 888
 889                                         default:  // calling a vote for master
 890                                         {
 891                                                 bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 892
 893                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 894                                                 else if (vote_called)
 895                                                 {
 896                                                         print_to(caller, "^1There is already a vote called.");
 897                                                 }
 898                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 899                                                 {
 900                                                         print_to(caller, "^1Only players can call a vote.");
 901                                                 }
 902                                                 else if (timeout_status)
 903                                                 {
 904                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 905                                                 }
 906
 907                                                 else  // everything went okay, continue with creating vote
 908                                                 {
 909                                                         vote_caller = caller;
 910                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 911                                                         vote_called = VOTE_MASTER;
 912                                                         vote_called_command = strzone("XXX");
 913                                                         vote_called_display = strzone("^3master");
 914                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 915
 916                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 917                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 918
 919                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 920                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 921                                                         Nagger_VoteChanged();
 922                                                         VoteCount(true);  // needed if you are the only one
 923                                                 }
 924
 925                                                 return;
 926                                         }
 927                                 }
 928                         }
 929                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 930
 931                         return;
 932                 }
 933
 934                 default:
 935                 case CMD_REQUEST_USAGE:
 936                 {
 937                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 938                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 939                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 946 {
 947         switch (request)
 948         {
 949                 case CMD_REQUEST_COMMAND:
 950                 {
 951                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 952                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 953                         {
 954                                 print_to(caller, "^1You have already voted.");
 955                         }
 956                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 957                         {
 958                                 VoteStop(caller);
 959                         }
 960
 961                         else  // everything went okay, continue changing vote
 962                         {
 963                                 print_to(caller, "^1You rejected the vote.");
 964                                 caller.vote_selection = VOTE_SELECT_REJECT;
 965                                 msg_entity = caller;
 966                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 967
 968                         return;
 969                 }
 970
 971                 default:
 972                 case CMD_REQUEST_USAGE:
 973                 {
 974                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 975                         print_to(caller, "  No arguments required.");
 976                         return;
 977                 }
 978         }
 979 }
 980
 981 void VoteCommand_status(float request, entity caller)  // BOTH
 982 {
 983         switch (request)
 984         {
 985                 case CMD_REQUEST_COMMAND:
 986                 {
 987                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 988                         else print_to(caller, "^1No vote called.");
 989
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 997                         print_to(caller, "  No arguments required.");
 998                         return;
 999                 }
1000         }
1001 }
1002
1003 void VoteCommand_stop(float request, entity caller)  // BOTH
1004 {
1005         switch (request)
1006         {
1007                 case CMD_REQUEST_COMMAND:
1008                 {
1009                         if (!vote_called)   print_to(caller, "^1No vote called.");
1010                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1011                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1012                         return;
1013                 }
1014
1015                 default:
1016                 case CMD_REQUEST_USAGE:
1017                 {
1018                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1019                         print_to(caller, "  No arguments required.");
1020                         return;
1021                 }
1022         }
1023 }
1024
1025 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1026 {
1027         switch (request)
1028         {
1029                 case CMD_REQUEST_COMMAND:
1030                 {
1031                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1032                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1033                         {
1034                                 print_to(caller, "^1You have already voted.");
1035                         }
1036
1037                         else  // everything went okay, continue changing vote
1038                         {
1039                                 print_to(caller, "^1You accepted the vote.");
1040                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1041                                 msg_entity = caller;
1042                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1043
1044                         return;
1045                 }
1046
1047                 default:
1048                 case CMD_REQUEST_USAGE:
1049                 {
1050                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1051                         print_to(caller, "  No arguments required.");
1052                         return;
1053                 }
1054         }
1055 }
1056
1057 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1058 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1059 void VoteCommand_(float request)
1060 {
1061     switch(request)
1062     {
1063         case CMD_REQUEST_COMMAND:
1064         {
1065
1066             return;
1067         }
1068
1069         default:
1070         case CMD_REQUEST_USAGE:
1071         {
1072             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1073             print_to(caller, "  No arguments required.");
1074             return;
1075         }
1076     }
1077 }
1078 */
1079
1080
1081 // ================================
1082 //  Macro system for vote commands
1083 // ================================
1084
1085 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1086 #define VOTE_COMMANDS(request, caller, arguments, command) \
1087         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1088         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1089         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1090         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1091         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1092         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1093         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1094         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1095         /* nothing */
1096
1097 void VoteCommand_macro_help(entity caller, float argc)
1098 {
1099         string command_origin = GetCommandPrefix(caller);
1100
1101         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1102         {
1103                 print_to(caller, "\nVoting commands:\n");
1104                 #define VOTE_COMMAND(name, function, description, assignment) \
1105                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1106
1107                 VOTE_COMMANDS(0, caller, 0, "");
1108 #undef VOTE_COMMAND
1109
1110                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1111                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1112                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1113         }
1114         else  // usage for individual command
1115         {
1116                 #define VOTE_COMMAND(name, function, description, assignment) \
1117                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1118
1119                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1120 #undef VOTE_COMMAND
1121         }
1122 }
1123
1124 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1125 {
1126         #define VOTE_COMMAND(name, function, description, assignment) \
1127                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1128
1129         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1130 #undef VOTE_COMMAND
1131
1132         return false;
1133 }
1134
1135
1136 // ======================================
1137 //  Main function handling vote commands
1138 // ======================================
1139
1140 void VoteCommand(float request, entity caller, float argc, string vote_command)
1141 {
1142         // Guide for working with argc arguments by example:
1143         // argc:   1    - 2      - 3     - 4
1144         // argv:   0    - 1      - 2     - 3
1145         // cmd     vote - master - login - password
1146
1147         switch (request)
1148         {
1149                 case CMD_REQUEST_COMMAND:
1150                 {
1151                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1152                 }
1153
1154                 default:
1155                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1156                 case CMD_REQUEST_USAGE:
1157                 {
1158                         VoteCommand_macro_help(caller, argc);
1159                         return;
1160                 }
1161         }
1162 }