qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  66                 {
  67                         CS(e).latency_sum += CS(e).ping;
  68                         CS(e).latency_cnt += 1;
  69                         CS(e).latency_time = time;
  70                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         strfree(cvar_changes);
 149         strfree(cvar_purechanges);
 150         cvar_purechanges_count = 0;
 151
 152         h = buf_create();
 153         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 154         n = buf_getsize(h);
 155
 156         adding = true;
 157         pureadding = true;
 158
 159         for(i = 0; i < n; ++i)
 160         {
 161                 k = bufstr_get(h, i);
 162
 163 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 164 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 165 #define BADCVAR(p) if(k == p) continue
 166
 167                 // general excludes and namespaces for server admin used cvars
 168                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 169
 170                 // internal
 171                 BADPREFIX("csqc_");
 172                 BADPREFIX("cvar_check_");
 173                 BADCVAR("gamecfg");
 174                 BADCVAR("g_configversion");
 175                 BADCVAR("halflifebsp");
 176                 BADCVAR("sv_mapformat_is_quake2");
 177                 BADCVAR("sv_mapformat_is_quake3");
 178                 BADPREFIX("sv_world");
 179
 180                 // client
 181                 BADPREFIX("chase_");
 182                 BADPREFIX("cl_");
 183                 BADPREFIX("con_");
 184                 BADPREFIX("scoreboard_");
 185                 BADPREFIX("g_campaign");
 186                 BADPREFIX("g_waypointsprite_");
 187                 BADPREFIX("gl_");
 188                 BADPREFIX("joy");
 189                 BADPREFIX("hud_");
 190                 BADPREFIX("m_");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("snd_");
 197                 BADPREFIX("show");
 198                 BADPREFIX("sensitivity");
 199                 BADPREFIX("userbind");
 200                 BADPREFIX("v_");
 201                 BADPREFIX("vid_");
 202                 BADPREFIX("crosshair");
 203                 BADCVAR("mod_q3bsp_lightmapmergepower");
 204                 BADCVAR("mod_q3bsp_nolightmaps");
 205                 BADCVAR("fov");
 206                 BADCVAR("mastervolume");
 207                 BADCVAR("volume");
 208                 BADCVAR("bgmvolume");
 209                 BADCVAR("in_pitch_min");
 210                 BADCVAR("in_pitch_max");
 211
 212                 // private
 213                 BADCVAR("developer");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("net_address");
 216                 BADCVAR("net_address_ipv6");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("serverconfig");
 220                 BADCVAR("sv_autoscreenshot");
 221                 BADCVAR("sv_heartbeatperiod");
 222                 BADCVAR("sv_vote_master_password");
 223                 BADCVAR("sys_colortranslation");
 224                 BADCVAR("sys_specialcharactertranslation");
 225                 BADCVAR("timeformat");
 226                 BADCVAR("timestamps");
 227                 BADCVAR("g_require_stats");
 228                 BADPREFIX("developer_");
 229                 BADPREFIX("g_ban_");
 230                 BADPREFIX("g_banned_list");
 231                 BADPREFIX("g_require_stats_");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("quit_");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251                 BADCVAR("sv_muteban_list");
 252                 BADCVAR("sv_allow_customplayermodels_idlist");
 253                 BADCVAR("sv_allow_customplayermodels_speciallist");
 254
 255                 // mapinfo
 256                 BADCVAR("fraglimit");
 257                 BADCVAR("g_arena");
 258                 BADCVAR("g_assault");
 259                 BADCVAR("g_ca");
 260                 BADCVAR("g_ca_teams");
 261                 BADCVAR("g_conquest");
 262                 BADCVAR("g_ctf");
 263                 BADCVAR("g_cts");
 264                 BADCVAR("g_dotc");
 265                 BADCVAR("g_dm");
 266                 BADCVAR("g_domination");
 267                 BADCVAR("g_domination_default_teams");
 268                 BADCVAR("g_freezetag");
 269                 BADCVAR("g_freezetag_teams");
 270                 BADCVAR("g_invasion_teams");
 271                 BADCVAR("g_invasion_type");
 272                 BADCVAR("g_jailbreak");
 273                 BADCVAR("g_jailbreak_teams");
 274                 BADCVAR("g_keepaway");
 275                 BADCVAR("g_keyhunt");
 276                 BADCVAR("g_keyhunt_teams");
 277                 BADCVAR("g_lms");
 278                 BADCVAR("g_nexball");
 279                 BADCVAR("g_onslaught");
 280                 BADCVAR("g_race");
 281                 BADCVAR("g_race_laps_limit");
 282                 BADCVAR("g_race_qualifying_timelimit");
 283                 BADCVAR("g_race_qualifying_timelimit_override");
 284                 BADCVAR("g_runematch");
 285                 BADCVAR("g_snafu");
 286                 BADCVAR("g_tdm");
 287                 BADCVAR("g_tdm_teams");
 288                 BADCVAR("g_vip");
 289                 BADCVAR("leadlimit");
 290                 BADCVAR("nextmap");
 291                 BADCVAR("teamplay");
 292                 BADCVAR("timelimit");
 293                 BADCVAR("g_mapinfo_ignore_warnings");
 294
 295                 // long
 296                 BADCVAR("hostname");
 297                 BADCVAR("g_maplist");
 298                 BADCVAR("g_maplist_mostrecent");
 299                 BADCVAR("sv_motd");
 300
 301                 v = cvar_string(k);
 302                 d = cvar_defstring(k);
 303                 if(v == d)
 304                         continue;
 305
 306                 if(adding)
 307                 {
 308                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 309                         if(strlen(cvar_changes) > 16384)
 310                         {
 311                                 cvar_changes = "// too many settings have been changed to show them here\n";
 312                                 adding = 0;
 313                         }
 314                 }
 315
 316                 // now check if the changes are actually gameplay relevant
 317
 318                 // does nothing gameplay relevant
 319                 BADCVAR("captureleadlimit_override");
 320                 BADCVAR("condump_stripcolors");
 321                 BADCVAR("gameversion");
 322                 BADCVAR("g_allow_oldvortexbeam");
 323                 BADCVAR("g_balance_kill_delay");
 324                 BADCVAR("g_buffs_pickup_anyway");
 325                 BADCVAR("g_buffs_randomize");
 326                 BADCVAR("g_campcheck_distance");
 327                 BADCVAR("g_ca_point_leadlimit");
 328                 BADCVAR("g_ca_point_limit");
 329                 BADCVAR("g_ctf_captimerecord_always");
 330                 BADCVAR("g_ctf_flag_glowtrails");
 331                 BADCVAR("g_ctf_flag_pickup_verbosename");
 332                 BADCVAR("g_domination_point_leadlimit");
 333                 BADCVAR("g_forced_respawn");
 334                 BADCVAR("g_freezetag_point_leadlimit");
 335                 BADCVAR("g_freezetag_point_limit");
 336                 BADCVAR("g_hats");
 337                 BADCVAR("g_invasion_point_limit");
 338                 BADCVAR("g_jump_grunt");
 339                 BADCVAR("g_keyhunt_point_leadlimit");
 340                 BADCVAR("g_nexball_goalleadlimit");
 341                 BADCVAR("g_new_toys_use_pickupsound");
 342                 BADCVAR("g_physics_predictall");
 343                 BADCVAR("g_piggyback");
 344                 BADCVAR("g_playerclip_collisions");
 345                 BADCVAR("g_tdm_point_leadlimit");
 346                 BADCVAR("g_tdm_point_limit");
 347                 BADCVAR("leadlimit_and_fraglimit");
 348                 BADCVAR("leadlimit_override");
 349                 BADCVAR("pausable");
 350                 BADCVAR("sv_checkforpacketsduringsleep");
 351                 BADCVAR("sv_damagetext");
 352                 BADCVAR("sv_db_saveasdump");
 353                 BADCVAR("sv_intermission_cdtrack");
 354                 BADCVAR("sv_minigames");
 355                 BADCVAR("sv_namechangetimer");
 356                 BADCVAR("sv_precacheplayermodels");
 357                 BADCVAR("sv_stepheight");
 358                 BADCVAR("sv_timeout");
 359                 BADCVAR("sv_weapons_modeloverride");
 360                 BADPREFIX("crypto_");
 361                 BADPREFIX("gameversion_");
 362                 BADPREFIX("g_chat_");
 363                 BADPREFIX("g_ctf_captimerecord_");
 364                 BADPREFIX("g_maplist_");
 365                 BADPREFIX("g_mod_");
 366                 BADPREFIX("g_respawn_");
 367                 BADPREFIX("net_");
 368                 BADPREFIX("notification_");
 369                 BADPREFIX("prvm_");
 370                 BADPREFIX("skill_");
 371                 BADPREFIX("sv_allow_");
 372                 BADPREFIX("sv_cullentities_");
 373                 BADPREFIX("sv_maxidle_");
 374                 BADPREFIX("sv_minigames_");
 375                 BADPREFIX("sv_radio_");
 376                 BADPREFIX("sv_timeout_");
 377                 BADPREFIX("sv_vote_");
 378                 BADPREFIX("timelimit_");
 379
 380                 // allowed changes to server admins (please sync this to server.cfg)
 381                 // vi commands:
 382                 //   :/"impure"/,$d
 383                 //   :g!,^\/\/[^ /],d
 384                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 385                 //   :%!sort
 386                 // yes, this does contain some redundant stuff, don't really care
 387                 BADCVAR("bot_config_file");
 388                 BADCVAR("bot_number");
 389                 BADCVAR("bot_prefix");
 390                 BADCVAR("bot_suffix");
 391                 BADCVAR("capturelimit_override");
 392                 BADCVAR("fraglimit_override");
 393                 BADCVAR("gametype");
 394                 BADCVAR("g_antilag");
 395                 BADCVAR("g_balance_teams");
 396                 BADCVAR("g_balance_teams_prevent_imbalance");
 397                 BADCVAR("g_balance_teams_scorefactor");
 398                 BADCVAR("g_ban_sync_trusted_servers");
 399                 BADCVAR("g_ban_sync_uri");
 400                 BADCVAR("g_buffs");
 401                 BADCVAR("g_ca_teams_override");
 402                 BADCVAR("g_ctf_ignore_frags");
 403                 BADCVAR("g_ctf_leaderboard");
 404                 BADCVAR("g_domination_point_limit");
 405                 BADCVAR("g_domination_teams_override");
 406                 BADCVAR("g_freezetag_teams_override");
 407                 BADCVAR("g_friendlyfire");
 408                 BADCVAR("g_fullbrightitems");
 409                 BADCVAR("g_fullbrightplayers");
 410                 BADCVAR("g_keyhunt_point_limit");
 411                 BADCVAR("g_keyhunt_teams_override");
 412                 BADCVAR("g_lms_lives_override");
 413                 BADCVAR("g_maplist");
 414                 BADCVAR("g_maxplayers");
 415                 BADCVAR("g_mirrordamage");
 416                 BADCVAR("g_nexball_goallimit");
 417                 BADCVAR("g_norecoil");
 418                 BADCVAR("g_physics_clientselect");
 419                 BADCVAR("g_pinata");
 420                 BADCVAR("g_powerups");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADCVAR("g_start_delay");
 423                 BADCVAR("g_superspectate");
 424                 BADCVAR("g_tdm_teams_override");
 425                 BADCVAR("g_warmup");
 426                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 427                 BADCVAR("hostname");
 428                 BADCVAR("log_file");
 429                 BADCVAR("maxplayers");
 430                 BADCVAR("minplayers");
 431                 BADCVAR("net_address");
 432                 BADCVAR("port");
 433                 BADCVAR("rcon_password");
 434                 BADCVAR("rcon_restricted_commands");
 435                 BADCVAR("rcon_restricted_password");
 436                 BADCVAR("skill");
 437                 BADCVAR("sv_adminnick");
 438                 BADCVAR("sv_autoscreenshot");
 439                 BADCVAR("sv_autotaunt");
 440                 BADCVAR("sv_curl_defaulturl");
 441                 BADCVAR("sv_defaultcharacter");
 442                 BADCVAR("sv_defaultcharacterskin");
 443                 BADCVAR("sv_defaultplayercolors");
 444                 BADCVAR("sv_defaultplayermodel");
 445                 BADCVAR("sv_defaultplayerskin");
 446                 BADCVAR("sv_maxidle");
 447                 BADCVAR("sv_maxrate");
 448                 BADCVAR("sv_motd");
 449                 BADCVAR("sv_public");
 450                 BADCVAR("sv_ready_restart");
 451                 BADCVAR("sv_status_privacy");
 452                 BADCVAR("sv_taunt");
 453                 BADCVAR("sv_vote_call");
 454                 BADCVAR("sv_vote_commands");
 455                 BADCVAR("sv_vote_majority_factor");
 456                 BADCVAR("sv_vote_master");
 457                 BADCVAR("sv_vote_master_commands");
 458                 BADCVAR("sv_vote_master_password");
 459                 BADCVAR("sv_vote_simple_majority_factor");
 460                 BADCVAR("teamplay_mode");
 461                 BADCVAR("timelimit_override");
 462                 BADPREFIX("g_warmup_");
 463                 BADPREFIX("sv_info_");
 464                 BADPREFIX("sv_ready_restart_");
 465
 466                 // mutators that announce themselves properly to the server browser
 467                 BADCVAR("g_instagib");
 468                 BADCVAR("g_new_toys");
 469                 BADCVAR("g_nix");
 470                 BADCVAR("g_grappling_hook");
 471                 BADCVAR("g_jetpack");
 472
 473 #undef BADPRESUFFIX
 474 #undef BADPREFIX
 475 #undef BADCVAR
 476
 477                 if(pureadding)
 478                 {
 479                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 480                         if(strlen(cvar_purechanges) > 16384)
 481                         {
 482                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 483                                 pureadding = 0;
 484                         }
 485                 }
 486                 ++cvar_purechanges_count;
 487                 // WARNING: this variable is used for the server list
 488                 // NEVER dare to skip this code!
 489                 // Hacks to intentionally appearing as "pure server" even though you DO have
 490                 // modified settings may be punished by removal from the server list.
 491                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 492                 // though.
 493         }
 494         buf_del(h);
 495         if(cvar_changes == "")
 496                 cvar_changes = "// this server runs at default server settings\n";
 497         else
 498                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 499         cvar_changes = strzone(cvar_changes);
 500         if(cvar_purechanges == "")
 501                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 502         else
 503                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 504         cvar_purechanges = strzone(cvar_purechanges);
 505 }
 506
 507 void detect_maptype()
 508 {
 509 #if 0
 510         vector o, v;
 511         float i;
 512
 513         for (;;)
 514         {
 515                 o = world.mins;
 516                 o.x += random() * (world.maxs.x - world.mins.x);
 517                 o.y += random() * (world.maxs.y - world.mins.y);
 518                 o.z += random() * (world.maxs.z - world.mins.z);
 519
 520                 tracebox(o, STAT(PL_MIN), STAT(PL_MAX), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 521                 if(trace_fraction == 1)
 522                         continue;
 523
 524                 v = trace_endpos;
 525
 526                 for(i = 0; i < 64; i += 4)
 527                 {
 528                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 529         if(trace_fraction == 1)
 530                 continue;
 531                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos));
 532                 }
 533
 534                 break;
 535         }
 536 #endif
 537 }
 538
 539 entity randomseed;
 540 bool RandomSeed_Send(entity this, entity to, int sf)
 541 {
 542         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 543         WriteShort(MSG_ENTITY, this.cnt);
 544         return true;
 545 }
 546 void RandomSeed_Think(entity this)
 547 {
 548         this.cnt = bound(0, floor(random() * 65536), 65535);
 549         this.nextthink = time + 5;
 550
 551         this.SendFlags |= 1;
 552 }
 553 void RandomSeed_Spawn()
 554 {
 555         randomseed = new_pure(randomseed);
 556         setthink(randomseed, RandomSeed_Think);
 557         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 558
 559         getthink(randomseed)(randomseed); // sets random seed and nextthink
 560 }
 561
 562 spawnfunc(__init_dedicated_server)
 563 {
 564         // handler for _init/_init map (only for dedicated server initialization)
 565
 566         world_initialized = -1; // don't complain
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         delete_fn = remove_unsafely;
 572
 573         entity e = spawn();
 574         setthink(e, GotoFirstMap);
 575         e.nextthink = time; // this is usually 1 at this point
 576
 577         e = new(info_player_deathmatch);  // safeguard against player joining
 578
 579     // assign reflectively to avoid "assignment to world" warning
 580     for (int i = 0, n = numentityfields(); i < n; ++i) {
 581         string k = entityfieldname(i);
 582         if (k == "classname") {
 583             // safeguard against various stuff ;)
 584             putentityfieldstring(i, this, "worldspawn");
 585             break;
 586         }
 587     }
 588
 589         // needs to be done so early because of the constants they create
 590         static_init();
 591         static_init_late();
 592         static_init_precache();
 593
 594         IL_PUSH(g_spawnpoints, e); // just incase
 595
 596         MapInfo_Enumerate();
 597         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 598 }
 599
 600 void __init_dedicated_server_shutdown() {
 601         MapInfo_Shutdown();
 602 }
 603
 604 STATIC_INIT_EARLY(maxclients)
 605 {
 606         maxclients = 0;
 607         for (entity head = nextent(NULL); head; head = nextent(head)) {
 608                 ++maxclients;
 609         }
 610 }
 611
 612 void default_delayedinit(entity this)
 613 {
 614         if(!scores_initialized)
 615                 ScoreRules_generic();
 616 }
 617
 618 void InitGameplayMode()
 619 {
 620         VoteReset();
 621
 622         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 623         get_mi_min_max(1);
 624         // assign reflectively to avoid "assignment to world" warning
 625         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 626             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 627             if (v) {
 628             putentityfieldstring(i, world, sprintf("%v", v));
 629             if (++done == 2) break;
 630         }
 631         }
 632         // currently, NetRadiant's limit is 131072 qu for each side
 633         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 634         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 635         // in case somebody makes extremely large maps
 636         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 637
 638         MapInfo_LoadMapSettings(mapname);
 639         GameRules_teams(false);
 640
 641         if (!cvar_value_issafe(world.fog))
 642         {
 643                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 644                 world.fog = string_null;
 645         }
 646         if(MapInfo_Map_fog != "")
 647                 if(MapInfo_Map_fog == "none")
 648                         world.fog = string_null;
 649                 else
 650                         world.fog = strzone(MapInfo_Map_fog);
 651         clientstuff = strzone(MapInfo_Map_clientstuff);
 652
 653         MapInfo_ClearTemps();
 654
 655         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 656
 657         cache_mutatormsg = strzone("");
 658         cache_lastmutatormsg = strzone("");
 659
 660         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 661 }
 662
 663 void Map_MarkAsRecent(string m);
 664 float world_already_spawned;
 665 void Nagger_Init();
 666 void ClientInit_Spawn();
 667 void WeaponStats_Init();
 668 void WeaponStats_Shutdown();
 669 spawnfunc(worldspawn)
 670 {
 671         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 672
 673     bool wantrestart = false;
 674         {
 675                 if (!server_is_dedicated)
 676                 {
 677                         // force unloading of server pk3 files when starting a listen server
 678                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 679                         // restore csqc_progname too
 680                         string expect = "csprogs.dat";
 681                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 682                         cvar_set_normal("csqc_progname", expect);
 683                 }
 684                 else
 685                 {
 686                         // Try to use versioned csprogs from pk3
 687                         // Only ever use versioned csprogs.dat files on dedicated servers;
 688                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 689                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 690                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 691                         string select = "csprogs.dat";
 692                         if (fexists(pk3csprogs)) select = pk3csprogs;
 693                         if (cvar_string_normal("csqc_progname") != select)
 694                         {
 695                                 cvar_set_normal("csqc_progname", select);
 696                                 wantrestart = true;
 697                         }
 698                         // Check for updates on startup
 699                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 700                         int sentinel = fopen("progs.txt", FILE_READ);
 701                         if (sentinel >= 0)
 702                         {
 703                                 string switchversion = fgets(sentinel);
 704                                 fclose(sentinel);
 705                                 if (switchversion != "" && switchversion != WATERMARK)
 706                                 {
 707                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 708                                         // if it doesn't exist, assume either:
 709                                         //   a) the current program was overwritten
 710                                         //   b) this is a client only update
 711                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 712                                         if (fexists(newprogs))
 713                                         {
 714                                                 cvar_set_normal("sv_progs", newprogs);
 715                                                 wantrestart = true;
 716                                         }
 717                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 718                                         if (fexists(newcsprogs))
 719                                         {
 720                                                 cvar_set_normal("csqc_progname", newcsprogs);
 721                                                 wantrestart = true;
 722                                         }
 723                                 }
 724                         }
 725                 }
 726                 if (wantrestart)
 727                 {
 728                         LOG_INFOF("Restart requested");
 729                         changelevel(mapname);
 730                         // let initialization continue, shutdown depends on it
 731                 }
 732         }
 733
 734         cvar = cvar_normal;
 735         cvar_string = cvar_string_normal;
 736         cvar_set = cvar_set_normal;
 737
 738         if(world_already_spawned)
 739                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 740         world_already_spawned = true;
 741
 742         delete_fn = remove_safely; // during spawning, watch what you remove!
 743
 744         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 745
 746         // needs to be done so early because of the constants they create
 747         static_init();
 748
 749         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 750
 751         TemporaryDB = db_create();
 752
 753         // 0 normal
 754         lightstyle(0, "m");
 755
 756         // 1 FLICKER (first variety)
 757         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 758
 759         // 2 SLOW STRONG PULSE
 760         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 761
 762         // 3 CANDLE (first variety)
 763         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 764
 765         // 4 FAST STROBE
 766         lightstyle(4, "mamamamamama");
 767
 768         // 5 GENTLE PULSE 1
 769         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 770
 771         // 6 FLICKER (second variety)
 772         lightstyle(6, "nmonqnmomnmomomno");
 773
 774         // 7 CANDLE (second variety)
 775         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 776
 777         // 8 CANDLE (third variety)
 778         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 779
 780         // 9 SLOW STROBE (fourth variety)
 781         lightstyle(9, "aaaaaaaazzzzzzzz");
 782
 783         // 10 FLUORESCENT FLICKER
 784         lightstyle(10, "mmamammmmammamamaaamammma");
 785
 786         // 11 SLOW PULSE NOT FADE TO BLACK
 787         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 788
 789         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 790
 791         // 63 testing
 792         lightstyle(63, "a");
 793
 794         if(autocvar_g_campaign)
 795                 CampaignPreInit();
 796
 797         Map_MarkAsRecent(mapname);
 798
 799         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 800
 801         InitGameplayMode();
 802         static_init_late();
 803         static_init_precache();
 804         readlevelcvars();
 805         GrappleHookInit();
 806
 807     GameRules_limit_fallbacks();
 808
 809         if(warmup_limit == 0)
 810                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 811
 812         player_count = 0;
 813         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 814         if(bot_waypoints_for_items == 1)
 815                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 816                         bot_waypoints_for_items = 0;
 817
 818         precache();
 819
 820         WaypointSprite_Init();
 821
 822         GameLogInit(); // prepare everything
 823         // NOTE for matchid:
 824         // changing the logic generating it is okay. But:
 825         // it HAS to stay <= 64 chars
 826         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 827         if(autocvar_sv_eventlog)
 828         {
 829                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 830                 matchid = strzone(s);
 831
 832                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 833                 s = ":gameinfo:mutators:LIST";
 834
 835                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 836                 s = M_ARGV(0, string);
 837
 838                 // initialiation stuff, not good in the mutator system
 839                 if(!autocvar_g_use_ammunition)
 840                         s = strcat(s, ":no_use_ammunition");
 841
 842                 // initialiation stuff, not good in the mutator system
 843                 if(autocvar_g_pickup_items == 0)
 844                         s = strcat(s, ":no_pickup_items");
 845                 if(autocvar_g_pickup_items > 0)
 846                         s = strcat(s, ":pickup_items");
 847
 848                 // initialiation stuff, not good in the mutator system
 849                 if(autocvar_g_weaponarena != "0")
 850                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 851
 852                 // TODO to mutator system
 853                 if(autocvar_g_norecoil)
 854                         s = strcat(s, ":norecoil");
 855
 856                 // TODO to mutator system
 857                 if(autocvar_g_powerups == 0)
 858                         s = strcat(s, ":no_powerups");
 859                 if(autocvar_g_powerups > 0)
 860                         s = strcat(s, ":powerups");
 861
 862                 GameLogEcho(s);
 863                 GameLogEcho(":gameinfo:end");
 864         }
 865         else
 866                 matchid = strzone(ftos(random()));
 867
 868         cvar_set("nextmap", "");
 869
 870         SetDefaultAlpha();
 871
 872         if(autocvar_g_campaign)
 873                 CampaignPostInit();
 874
 875         Ban_LoadBans();
 876
 877         MapInfo_Enumerate();
 878         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 879
 880         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 881         {
 882                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 883                 if(fd != -1)
 884                 {
 885                         string s;
 886                         while((s = fgets(fd)))
 887                         {
 888                                 int l = tokenize_console(s);
 889                                 if(l < 2)
 890                                         continue;
 891                                 if(argv(0) == "cd")
 892                                 {
 893                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 894                                         LOG_INFO("  cdtrack ", argv(2));
 895                                 }
 896                                 else if(argv(0) == "fog")
 897                                 {
 898                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 899                                         LOG_INFO("  \"fog\" \"", s, "\"");
 900                                 }
 901                                 else if(argv(0) == "set")
 902                                 {
 903                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 904                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 905                                 }
 906                                 else if(argv(0) != "//")
 907                                 {
 908                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 909                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 910                                 }
 911                         }
 912                         fclose(fd);
 913                 }
 914         }
 915
 916         WeaponStats_Init();
 917
 918         Nagger_Init();
 919
 920         next_pingtime = time + 5;
 921
 922         detect_maptype();
 923
 924         // set up information replies for clients and server to use
 925         maplist_reply = strzone(getmaplist());
 926         lsmaps_reply = strzone(getlsmaps());
 927         monsterlist_reply = strzone(getmonsterlist());
 928         for(int i = 0; i < 10; ++i)
 929         {
 930                 string s = getrecords(i);
 931                 if (s)
 932                         records_reply[i] = strzone(s);
 933         }
 934         ladder_reply = strzone(getladder());
 935         rankings_reply = strzone(getrankings());
 936
 937         // begin other init
 938         ClientInit_Spawn();
 939         RandomSeed_Spawn();
 940         PingPLReport_Spawn();
 941
 942         CheatInit();
 943
 944         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 945
 946         // fill sv_curl_serverpackages from .serverpackage files
 947         if (autocvar_sv_curl_serverpackages_auto)
 948         {
 949                 string s = "csprogs-" WATERMARK ".txt";
 950                 // remove automatically managed files from the list to prevent duplicates
 951                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 952                 {
 953                         string pkg = argv(i);
 954                         if (startsWith(pkg, "csprogs-")) continue;
 955                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 956                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 957                         s = cons(s, pkg);
 958                 }
 959                 // add automatically managed files to the list
 960                 #define X(match) MACRO_BEGIN { \
 961                         int fd = search_begin(match, true, false); \
 962                         if (fd >= 0) \
 963                         { \
 964                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 965                                 { \
 966                                         s = cons(s, search_getfilename(fd, i)); \
 967                                 } \
 968                                 search_end(fd); \
 969                         } \
 970                 } MACRO_END
 971                 X("*-serverpackage.txt");
 972                 X("*.serverpackage");
 973                 #undef X
 974                 cvar_set("sv_curl_serverpackages", s);
 975         }
 976
 977         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 978         modname = "Xonotic";
 979         // physics/balance/config changes that count as mod
 980         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 981                 modname = cvar_string("g_mod_physics");
 982         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 983                 modname = cvar_string("g_mod_balance");
 984         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 985                 modname = cvar_string("g_mod_config");
 986         // extra mutators that deserve to count as mod
 987         MUTATOR_CALLHOOK(SetModname, modname);
 988         modname = M_ARGV(0, string);
 989
 990         // save it for later
 991         modname = strzone(modname);
 992
 993         WinningConditionHelper(this); // set worldstatus
 994
 995         world_initialized = 1;
 996         __spawnfunc_spawn_all();
 997 }
 998
 999 spawnfunc(light)
1000 {
1001         //makestatic (this); // Who the f___ did that?
1002         delete(this);
1003 }
1004
1005 string GetGametype()
1006 {
1007         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1008 }
1009
1010 string GetMapname()
1011 {
1012         return mapname;
1013 }
1014
1015 float Map_Count, Map_Current;
1016 string Map_Current_Name;
1017
1018 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1019 float GetMaplistPosition()
1020 {
1021         float pos, idx;
1022         string map;
1023
1024         map = GetMapname();
1025         idx = autocvar_g_maplist_index;
1026
1027         if(idx >= 0)
1028                 if(idx < Map_Count)
1029                         if(map == argv(idx))
1030                                 return idx;
1031
1032         for(pos = 0; pos < Map_Count; ++pos)
1033                 if(map == argv(pos))
1034                         return pos;
1035
1036         // resume normal maplist rotation if current map is not in g_maplist
1037         return idx;
1038 }
1039
1040 bool MapHasRightSize(string map)
1041 {
1042         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1043         if(autocvar_g_maplist_check_waypoints)
1044         {
1045                 string checkwp_msg = strcat("checkwp ", map);
1046                 if(!fexists(strcat("maps/", map, ".waypoints")))
1047                 {
1048                         LOG_TRACE(checkwp_msg, ": no waypoints");
1049                         return false;
1050                 }
1051                 LOG_TRACE(checkwp_msg, ": has waypoints");
1052         }
1053
1054         // open map size restriction file
1055         string opensize_msg = strcat("opensize ", map);
1056         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1057         if(fh >= 0)
1058         {
1059                 opensize_msg = strcat(opensize_msg, ": ok, ");
1060                 int mapmin = stoi(fgets(fh));
1061                 int mapmax = stoi(fgets(fh));
1062                 fclose(fh);
1063                 if(player_count < mapmin)
1064                 {
1065                         LOG_TRACE(opensize_msg, "not enough");
1066                         return false;
1067                 }
1068                 if(mapmax && player_count > mapmax)
1069                 {
1070                         LOG_TRACE(opensize_msg, "too many");
1071                         return false;
1072                 }
1073                 LOG_TRACE(opensize_msg, "right size");
1074                 return true;
1075         }
1076         LOG_TRACE(opensize_msg, ": not found");
1077         return true;
1078 }
1079
1080 string Map_Filename(float position)
1081 {
1082         return strcat("maps/", argv(position), ".bsp");
1083 }
1084
1085 void Map_MarkAsRecent(string m)
1086 {
1087         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1088 }
1089
1090 float Map_IsRecent(string m)
1091 {
1092         return strhasword(autocvar_g_maplist_mostrecent, m);
1093 }
1094
1095 float Map_Check(float position, float pass)
1096 {
1097         string filename;
1098         string map_next;
1099         map_next = argv(position);
1100         if(pass <= 1)
1101         {
1102                 if(Map_IsRecent(map_next))
1103                         return 0;
1104         }
1105         filename = Map_Filename(position);
1106         if(MapInfo_CheckMap(map_next))
1107         {
1108                 if(pass == 2)
1109                         return 1;
1110                 if(MapHasRightSize(map_next))
1111                         return 1;
1112                 return 0;
1113         }
1114         else
1115                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1116
1117         return 0;
1118 }
1119
1120 void Map_Goto_SetStr(string nextmapname)
1121 {
1122         if(getmapname_stored != "")
1123                 strunzone(getmapname_stored);
1124         if(nextmapname == "")
1125                 getmapname_stored = "";
1126         else
1127                 getmapname_stored = strzone(nextmapname);
1128 }
1129
1130 void Map_Goto_SetFloat(float position)
1131 {
1132         cvar_set("g_maplist_index", ftos(position));
1133         Map_Goto_SetStr(argv(position));
1134 }
1135
1136 void Map_Goto(float reinit)
1137 {
1138         MapInfo_LoadMap(getmapname_stored, reinit);
1139 }
1140
1141 // return codes of map selectors:
1142 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1143 //   -2 = permanent failure
1144 float() MaplistMethod_Iterate = // usual method
1145 {
1146         float pass, i;
1147
1148         LOG_TRACE("Trying MaplistMethod_Iterate");
1149
1150         for(pass = 1; pass <= 2; ++pass)
1151         {
1152                 for(i = 1; i < Map_Count; ++i)
1153                 {
1154                         float mapindex;
1155                         mapindex = (i + Map_Current) % Map_Count;
1156                         if(Map_Check(mapindex, pass))
1157                                 return mapindex;
1158                 }
1159         }
1160         return -1;
1161 }
1162
1163 float() MaplistMethod_Repeat = // fallback method
1164 {
1165         LOG_TRACE("Trying MaplistMethod_Repeat");
1166
1167         if(Map_Check(Map_Current, 2))
1168                 return Map_Current;
1169         return -2;
1170 }
1171
1172 float() MaplistMethod_Random = // random map selection
1173 {
1174         float i, imax;
1175
1176         LOG_TRACE("Trying MaplistMethod_Random");
1177
1178         imax = 42;
1179
1180         for(i = 0; i <= imax; ++i)
1181         {
1182                 float mapindex;
1183                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1184                 if(Map_Check(mapindex, 1))
1185                         return mapindex;
1186         }
1187         return -1;
1188 }
1189
1190 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1191 // the exponent sets a bias on the map selection:
1192 // the higher the exponent, the less likely "shortly repeated" same maps are
1193 {
1194         float i, j, imax, insertpos;
1195
1196         LOG_TRACE("Trying MaplistMethod_Shuffle");
1197
1198         imax = 42;
1199
1200         for(i = 0; i <= imax; ++i)
1201         {
1202                 string newlist;
1203
1204                 // now reinsert this at another position
1205                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1206                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1207                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1208                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1209
1210                 // insert the current map there
1211                 newlist = "";
1212                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1213                         newlist = strcat(newlist, " ", argv(j));
1214                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1215                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1216                         newlist = strcat(newlist, " ", argv(j));
1217                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1218                 cvar_set("g_maplist", newlist);
1219                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1220
1221                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1222                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1223                 if(Map_Check(Map_Current, 1))
1224                         return Map_Current;
1225         }
1226         return -1;
1227 }
1228
1229 void Maplist_Init()
1230 {
1231         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1232         float i;
1233         for (i = 0; i < Map_Count; ++i)
1234                 if (Map_Check(i, 2))
1235                         break;
1236         if (i == Map_Count)
1237         {
1238                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1239                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1240                 if(autocvar_g_maplist_shuffle)
1241                         ShuffleMaplist();
1242                 localcmd("\nmenu_cmd sync\n");
1243                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1244         }
1245         if(Map_Count == 0)
1246                 error("empty maplist, cannot select a new map");
1247         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1248
1249         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1250         // this may or may not be correct, but who cares, in the worst case a map
1251         // isn't chosen in the first pass that should have been
1252 }
1253
1254 string GetNextMap()
1255 {
1256         float nextMap;
1257
1258         Maplist_Init();
1259         nextMap = -1;
1260
1261         if(nextMap == -1)
1262                 if(autocvar_g_maplist_shuffle > 0)
1263                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1264
1265         if(nextMap == -1)
1266                 if(autocvar_g_maplist_selectrandom)
1267                         nextMap = MaplistMethod_Random();
1268
1269         if(nextMap == -1)
1270                 nextMap = MaplistMethod_Iterate();
1271
1272         if(nextMap == -1)
1273                 nextMap = MaplistMethod_Repeat();
1274
1275         if(nextMap >= 0)
1276         {
1277                 Map_Goto_SetFloat(nextMap);
1278                 return getmapname_stored;
1279         }
1280
1281         return "";
1282 }
1283
1284 float DoNextMapOverride(float reinit)
1285 {
1286         if(autocvar_g_campaign)
1287         {
1288                 CampaignPostIntermission();
1289                 alreadychangedlevel = true;
1290                 return true;
1291         }
1292         if(autocvar_quit_when_empty)
1293         {
1294                 if(player_count <= currentbots)
1295                 {
1296                         localcmd("quit\n");
1297                         alreadychangedlevel = true;
1298                         return true;
1299                 }
1300         }
1301         if(autocvar_quit_and_redirect != "")
1302         {
1303                 redirection_target = strzone(autocvar_quit_and_redirect);
1304                 alreadychangedlevel = true;
1305                 return true;
1306         }
1307         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1308         {
1309                 localcmd("restart\n");
1310                 alreadychangedlevel = true;
1311                 return true;
1312         }
1313         if(autocvar_nextmap != "")
1314         {
1315                 string m;
1316                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1317                 cvar_set("nextmap",m);
1318
1319                 if(!m || gametypevote)
1320                         return false;
1321                 if(autocvar_sv_vote_gametype)
1322                 {
1323                         Map_Goto_SetStr(m);
1324                         return false;
1325                 }
1326
1327                 if(MapInfo_CheckMap(m))
1328                 {
1329                         Map_Goto_SetStr(m);
1330                         Map_Goto(reinit);
1331                         alreadychangedlevel = true;
1332                         return true;
1333                 }
1334         }
1335         if(!reinit && autocvar_lastlevel)
1336         {
1337                 cvar_settemp_restore();
1338                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1339                 alreadychangedlevel = true;
1340                 return true;
1341         }
1342         return false;
1343 }
1344
1345 void GotoNextMap(float reinit)
1346 {
1347         //string nextmap;
1348         //float n, nummaps;
1349         //string s;
1350         if (alreadychangedlevel)
1351                 return;
1352         alreadychangedlevel = true;
1353
1354         string nextMap;
1355
1356         nextMap = GetNextMap();
1357         if(nextMap == "")
1358                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1359         Map_Goto(reinit);
1360 }
1361
1362
1363 /*
1364 ============
1365 IntermissionThink
1366
1367 When the player presses attack or jump, change to the next level
1368 ============
1369 */
1370 .float autoscreenshot;
1371 void IntermissionThink(entity this)
1372 {
1373         FixIntermissionClient(this);
1374
1375         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1376         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1377
1378         if( (server_screenshot || client_screenshot)
1379                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1380         {
1381                 this.autoscreenshot = -1;
1382                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1383                 return;
1384         }
1385
1386         if (time < intermission_exittime)
1387                 return;
1388
1389         if(!mapvote_initialized)
1390                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1391                         return;
1392
1393         MapVote_Start();
1394 }
1395
1396 /*
1397 ============
1398 FindIntermission
1399
1400 Returns the entity to view from
1401 ============
1402 */
1403 /*
1404 entity FindIntermission()
1405 {
1406         local   entity spot;
1407         local   float cyc;
1408
1409 // look for info_intermission first
1410         spot = find(NULL, classname, "info_intermission");
1411         if (spot)
1412         {       // pick a random one
1413                 cyc = random() * 4;
1414                 while (cyc > 1)
1415                 {
1416                         spot = find(spot, classname, "info_intermission");
1417                         if (!spot)
1418                                 spot = find(spot, classname, "info_intermission");
1419                         cyc = cyc - 1;
1420                 }
1421                 return spot;
1422         }
1423
1424 // then look for the start position
1425         spot = find(NULL, classname, "info_player_start");
1426         if (spot)
1427                 return spot;
1428
1429 // testinfo_player_start is only found in regioned levels
1430         spot = find(NULL, classname, "testplayerstart");
1431         if (spot)
1432                 return spot;
1433
1434 // then look for the start position
1435         spot = find(NULL, classname, "info_player_deathmatch");
1436         if (spot)
1437                 return spot;
1438
1439         //objerror ("FindIntermission: no spot");
1440         return NULL;
1441 }
1442 */
1443
1444 /*
1445 ===============================================================================
1446
1447 RULES
1448
1449 ===============================================================================
1450 */
1451
1452 void DumpStats(float final)
1453 {
1454         float file;
1455         string s;
1456         float to_console;
1457         float to_eventlog;
1458         float to_file;
1459         float i;
1460
1461         to_console = autocvar_sv_logscores_console;
1462         to_eventlog = autocvar_sv_eventlog;
1463         to_file = autocvar_sv_logscores_file;
1464
1465         if(!final)
1466         {
1467                 to_console = true; // always print printstats replies
1468                 to_eventlog = false; // but never print them to the event log
1469         }
1470
1471         if(to_eventlog)
1472                 if(autocvar_sv_eventlog_console)
1473                         to_console = false; // otherwise we get the output twice
1474
1475         if(final)
1476                 s = ":scores:";
1477         else
1478                 s = ":status:";
1479         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1480
1481         if(to_console)
1482                 LOG_INFO(s);
1483         if(to_eventlog)
1484                 GameLogEcho(s);
1485
1486         file = -1;
1487         if(to_file)
1488         {
1489                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1490                 if(file == -1)
1491                         to_file = false;
1492                 else
1493                         fputs(file, strcat(s, "\n"));
1494         }
1495
1496         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1497         if(to_console)
1498                 LOG_INFO(s);
1499         if(to_eventlog)
1500                 GameLogEcho(s);
1501         if(to_file)
1502                 fputs(file, strcat(s, "\n"));
1503
1504         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1505                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1506                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1507                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1508                         s = strcat(s, ftos(it.team), ":");
1509                 else
1510                         s = strcat(s, "spectator:");
1511
1512                 if(to_console)
1513                         LOG_INFO(s, playername(it, false));
1514                 if(to_eventlog)
1515                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1516                 if(to_file)
1517                         fputs(file, strcat(s, playername(it, false), "\n"));
1518         });
1519
1520         if(teamplay)
1521         {
1522                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1523                 if(to_console)
1524                         LOG_INFO(s);
1525                 if(to_eventlog)
1526                         GameLogEcho(s);
1527                 if(to_file)
1528                         fputs(file, strcat(s, "\n"));
1529
1530                 for(i = 1; i < 16; ++i)
1531                 {
1532                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1533                         s = strcat(s, ":", ftos(i));
1534                         if(to_console)
1535                                 LOG_INFO(s);
1536                         if(to_eventlog)
1537                                 GameLogEcho(s);
1538                         if(to_file)
1539                                 fputs(file, strcat(s, "\n"));
1540                 }
1541         }
1542
1543         if(to_console)
1544                 LOG_INFO(":end");
1545         if(to_eventlog)
1546                 GameLogEcho(":end");
1547         if(to_file)
1548         {
1549                 fputs(file, ":end\n");
1550                 fclose(file);
1551         }
1552 }
1553
1554 void FixIntermissionClient(entity e)
1555 {
1556         if(!e.autoscreenshot) // initial call
1557         {
1558                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1559                 e.health = -2342;
1560                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1561                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1562                 {
1563                     .entity weaponentity = weaponentities[slot];
1564                         if(e.(weaponentity))
1565                         {
1566                                 e.(weaponentity).effects = EF_NODRAW;
1567                                 if (e.(weaponentity).weaponchild)
1568                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1569                         }
1570                 }
1571                 if(IS_REAL_CLIENT(e))
1572                 {
1573                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1574                         RandomSelection_Init();
1575                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1576                                 RandomSelection_AddString(it, 1, 1);
1577                         });
1578                         if (RandomSelection_chosen_string != "")
1579                         {
1580                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1581                         }
1582                         msg_entity = e;
1583                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1584                 }
1585         }
1586 }
1587
1588 /*
1589 go to the next level for deathmatch
1590 only called if a time or frag limit has expired
1591 */
1592 void NextLevel()
1593 {
1594         game_stopped = true;
1595         intermission_running = 1; // game over
1596
1597         // enforce a wait time before allowing changelevel
1598         if(player_count > 0)
1599                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1600         else
1601                 intermission_exittime = -1;
1602
1603         /*
1604         WriteByte (MSG_ALL, SVC_CDTRACK);
1605         WriteByte (MSG_ALL, 3);
1606         WriteByte (MSG_ALL, 3);
1607         // done in FixIntermission
1608         */
1609
1610         //pos = FindIntermission ();
1611
1612         VoteReset();
1613
1614         DumpStats(true);
1615
1616         // send statistics
1617         PlayerStats_GameReport(true);
1618         WeaponStats_Shutdown();
1619
1620         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1621
1622         if(autocvar_sv_eventlog)
1623                 GameLogEcho(":gameover");
1624
1625         GameLogClose();
1626
1627         FOREACH_CLIENT(IS_PLAYER(it), {
1628                 FixIntermissionClient(it);
1629                 if(it.winning)
1630                         bprint(playername(it, false), " ^7wins.\n");
1631         });
1632
1633         target_music_kill();
1634
1635         if(autocvar_g_campaign)
1636                 CampaignPreIntermission();
1637
1638         MUTATOR_CALLHOOK(MatchEnd);
1639
1640         localcmd("\nsv_hook_gameend\n");
1641 }
1642
1643
1644 float InitiateSuddenDeath()
1645 {
1646         // Check first whether normal overtimes could be added before initiating suddendeath mode
1647         // - for this timelimit_overtime needs to be >0 of course
1648         // - also check the winning condition calculated in the previous frame and only add normal overtime
1649         //   again, if at the point at which timelimit would be extended again, still no winner was found
1650         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1651         {
1652                 return 1; // need to call InitiateOvertime later
1653         }
1654         else
1655         {
1656                 if(!checkrules_suddendeathend)
1657                 {
1658                         if(autocvar_g_campaign)
1659                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1660                         else
1661                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1662                         if(g_race && !g_race_qualifying)
1663                                 race_StartCompleting();
1664                 }
1665                 return 0;
1666         }
1667 }
1668
1669 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1670 {
1671         ++checkrules_overtimesadded;
1672         //add one more overtime by simply extending the timelimit
1673         float tl;
1674         tl = autocvar_timelimit;
1675         tl += autocvar_timelimit_overtime;
1676         cvar_set("timelimit", ftos(tl));
1677
1678         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1679 }
1680
1681 float GetWinningCode(float fraglimitreached, float equality)
1682 {
1683         if(autocvar_g_campaign == 1)
1684                 if(fraglimitreached)
1685                         return WINNING_YES;
1686                 else
1687                         return WINNING_NO;
1688
1689         else
1690                 if(equality)
1691                         if(fraglimitreached)
1692                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1693                         else
1694                                 return WINNING_NEVER;
1695                 else
1696                         if(fraglimitreached)
1697                                 return WINNING_YES;
1698                         else
1699                                 return WINNING_NO;
1700 }
1701
1702 // set the .winning flag for exactly those players with a given field value
1703 void SetWinners(.float field, float value)
1704 {
1705         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1706 }
1707
1708 // set the .winning flag for those players with a given field value
1709 void AddWinners(.float field, float value)
1710 {
1711         FOREACH_CLIENT(IS_PLAYER(it), {
1712                 if(it.(field) == value)
1713                         it.winning = 1;
1714         });
1715 }
1716
1717 // clear the .winning flags
1718 void ClearWinners()
1719 {
1720         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1721 }
1722
1723 void ShuffleMaplist()
1724 {
1725         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1726 }
1727
1728 float leaderfrags;
1729 float WinningCondition_Scores(float limit, float leadlimit)
1730 {
1731         float limitreached;
1732
1733         // TODO make everything use THIS winning condition (except LMS)
1734         WinningConditionHelper(NULL);
1735
1736         if(teamplay)
1737         {
1738                 for (int i = 1; i < 5; ++i)
1739                 {
1740                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1741                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1742                 }
1743         }
1744
1745         ClearWinners();
1746         if(WinningConditionHelper_winner)
1747                 WinningConditionHelper_winner.winning = 1;
1748         if(WinningConditionHelper_winnerteam >= 0)
1749                 SetWinners(team, WinningConditionHelper_winnerteam);
1750
1751         if(WinningConditionHelper_lowerisbetter)
1752         {
1753                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1754                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1755                 limit = -limit;
1756         }
1757
1758         if(WinningConditionHelper_zeroisworst)
1759                 leadlimit = 0; // not supported in this mode
1760
1761         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1762         // these modes always score in increments of 1, thus this makes sense
1763         {
1764                 if(leaderfrags != WinningConditionHelper_topscore)
1765                 {
1766                         leaderfrags = WinningConditionHelper_topscore;
1767
1768                         if (limit)
1769                         if (leaderfrags == limit - 1)
1770                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1771                         else if (leaderfrags == limit - 2)
1772                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1773                         else if (leaderfrags == limit - 3)
1774                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1775                 }
1776         }
1777
1778         limitreached = false;
1779         if(limit)
1780                 if(WinningConditionHelper_topscore >= limit)
1781                         limitreached = true;
1782         if(leadlimit)
1783         {
1784                 float leadlimitreached;
1785                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1786                 if(autocvar_leadlimit_and_fraglimit)
1787                         limitreached = (limitreached && leadlimitreached);
1788                 else
1789                         limitreached = (limitreached || leadlimitreached);
1790         }
1791
1792         if(limit)
1793                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1794
1795         return GetWinningCode(
1796                 WinningConditionHelper_topscore && limitreached,
1797                 WinningConditionHelper_equality
1798         );
1799 }
1800
1801 float WinningCondition_RanOutOfSpawns()
1802 {
1803         if(have_team_spawns <= 0)
1804                 return WINNING_NO;
1805
1806         if(!autocvar_g_spawn_useallspawns)
1807                 return WINNING_NO;
1808
1809         if(!some_spawn_has_been_used)
1810                 return WINNING_NO;
1811
1812         for (int i = 1; i < 5; ++i)
1813         {
1814                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1815         }
1816
1817         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1818         {
1819                 if (Team_IsValidTeam(it.team))
1820                 {
1821                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1822                 }
1823         });
1824
1825         IL_EACH(g_spawnpoints, true,
1826         {
1827                 if (Team_IsValidTeam(it.team))
1828                 {
1829                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1830                 }
1831         });
1832
1833         ClearWinners();
1834         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1835         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1836         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1837         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1838         if(team1_score + team2_score + team3_score + team4_score == 0)
1839         {
1840                 checkrules_equality = true;
1841                 return WINNING_YES;
1842         }
1843         else if(team1_score + team2_score + team3_score + team4_score == 1)
1844         {
1845                 float t, i;
1846                 if(team1_score)
1847                         t = 1;
1848                 else if(team2_score)
1849                         t = 2;
1850                 else if(team3_score)
1851                         t = 3;
1852                 else // if(team4_score)
1853                         t = 4;
1854                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1855                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1856                 {
1857                         for (int j = 1; j <= NUM_TEAMS; ++j)
1858                         {
1859                                 if (t == j)
1860                                 {
1861                                         continue;
1862                                 }
1863                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1864                                 {
1865                                         continue;
1866                                 }
1867                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1868                         }
1869                 }
1870
1871                 AddWinners(team, t);
1872                 return WINNING_YES;
1873         }
1874         else
1875                 return WINNING_NO;
1876 }
1877
1878 /*
1879 ============
1880 CheckRules_World
1881
1882 Exit deathmatch games upon conditions
1883 ============
1884 */
1885 void CheckRules_World()
1886 {
1887         float timelimit;
1888         float fraglimit;
1889         float leadlimit;
1890
1891         VoteThink();
1892         MapVote_Think();
1893
1894         SetDefaultAlpha();
1895
1896         if (intermission_running) // someone else quit the game already
1897         {
1898                 if(player_count == 0) // Nobody there? Then let's go to the next map
1899                         MapVote_Start();
1900                         // this will actually check the player count in the next frame
1901                         // again, but this shouldn't hurt
1902                 return;
1903         }
1904
1905         timelimit = autocvar_timelimit * 60;
1906         fraglimit = autocvar_fraglimit;
1907         leadlimit = autocvar_leadlimit;
1908
1909         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1910         {
1911                 if(timelimit > 0)
1912                         timelimit = 0; // timelimit is not made for warmup
1913                 if(fraglimit > 0)
1914                         fraglimit = 0; // no fraglimit for now
1915                 leadlimit = 0; // no leadlimit for now
1916         }
1917
1918         if(timelimit > 0)
1919         {
1920                 timelimit += game_starttime;
1921         }
1922         else if (timelimit < 0)
1923         {
1924                 // endmatch
1925                 NextLevel();
1926                 return;
1927         }
1928
1929         float wantovertime;
1930         wantovertime = 0;
1931
1932         if(timelimit > game_starttime)
1933                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1934         else
1935                 game_completion_ratio = 0;
1936
1937         if(checkrules_suddendeathend)
1938         {
1939                 if(!checkrules_suddendeathwarning)
1940                 {
1941                         checkrules_suddendeathwarning = true;
1942                         if(g_race && !g_race_qualifying)
1943                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1944                         else
1945                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1946                 }
1947         }
1948         else
1949         {
1950                 if (timelimit && time >= timelimit)
1951                 {
1952                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1953                         {
1954                                 float totalplayers;
1955                                 float playerswithlaps;
1956                                 float readyplayers;
1957                                 totalplayers = playerswithlaps = readyplayers = 0;
1958                                 FOREACH_CLIENT(IS_PLAYER(it), {
1959                                         ++totalplayers;
1960                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1961                                                 ++playerswithlaps;
1962                                         if(it.ready)
1963                                                 ++readyplayers;
1964                                 });
1965
1966                                 // at least 2 of the players have completed a lap: start the RACE
1967                                 // otherwise, the players should end the qualifying on their own
1968                                 if(readyplayers || playerswithlaps >= 2)
1969                                 {
1970                                         checkrules_suddendeathend = 0;
1971                                         ReadyRestart(); // go to race
1972                                         return;
1973                                 }
1974                                 else
1975                                         wantovertime |= InitiateSuddenDeath();
1976                         }
1977                         else
1978                                 wantovertime |= InitiateSuddenDeath();
1979                 }
1980         }
1981
1982         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1983         {
1984                 NextLevel();
1985                 return;
1986         }
1987
1988         int checkrules_status = WinningCondition_RanOutOfSpawns();
1989         if(checkrules_status == WINNING_YES)
1990                 bprint("Hey! Someone ran out of spawns!\n");
1991         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1992                 checkrules_status = M_ARGV(0, float);
1993         else
1994                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1995
1996         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1997         {
1998                 checkrules_status = WINNING_NEVER;
1999                 checkrules_overtimesadded = -1;
2000                 wantovertime |= InitiateSuddenDeath();
2001         }
2002
2003         if(checkrules_status == WINNING_NEVER)
2004                 // equality cases! Nobody wins if the overtime ends in a draw.
2005                 ClearWinners();
2006
2007         if(wantovertime)
2008         {
2009                 if(checkrules_status == WINNING_NEVER)
2010                         InitiateOvertime();
2011                 else
2012                         checkrules_status = WINNING_YES;
2013         }
2014
2015         if(checkrules_suddendeathend)
2016                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2017                         checkrules_status = WINNING_YES;
2018
2019         if(checkrules_status == WINNING_YES)
2020         {
2021                 //print("WINNING\n");
2022                 NextLevel();
2023         }
2024 }
2025
2026 string GotoMap(string m)
2027 {
2028         m = GameTypeVote_MapInfo_FixName(m);
2029         if (!m)
2030                 return "The map you suggested is not available on this server.";
2031         if (!autocvar_sv_vote_gametype)
2032         if(!MapInfo_CheckMap(m))
2033                 return "The map you suggested does not support the current game mode.";
2034         cvar_set("nextmap", m);
2035         cvar_set("timelimit", "-1");
2036         if(mapvote_initialized || alreadychangedlevel)
2037         {
2038                 if(DoNextMapOverride(0))
2039                         return "Map switch initiated.";
2040                 else
2041                         return "Hm... no. For some reason I like THIS map more.";
2042         }
2043         else
2044                 return "Map switch will happen after scoreboard.";
2045 }
2046
2047 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2048 void RunThink(entity this)
2049 {
2050         // don't let things stay in the past.
2051         // it is possible to start that way by a trigger with a local time.
2052         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2053                 return;
2054
2055         float oldtime = time; // do we need to save this?
2056
2057         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2058         {
2059                 time = max(oldtime, this.nextthink);
2060                 this.nextthink = 0;
2061
2062                 if(getthink(this))
2063                         getthink(this)(this);
2064                 // mods often set nextthink to time to cause a think every frame,
2065                 // we don't want to loop in that case, so exit if the new nextthink is
2066                 // <= the time the qc was told, also exit if it is past the end of the
2067                 // frame
2068                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2069                         break;
2070         }
2071
2072         time = oldtime;
2073 }
2074
2075 bool autocvar_sv_freezenonclients;
2076 bool autocvar_sv_gameplayfix_delayprojectiles;
2077 void Physics_Frame()
2078 {
2079         if(autocvar_sv_freezenonclients)
2080                 return;
2081
2082         FOREACH_ENTITY_FLOAT(pure_data, false,
2083         {
2084                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2085                         continue;
2086
2087                 //set_movetype(it, it.move_movetype);
2088                 // inline the set_movetype function, since this is called a lot
2089                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2090
2091                 if(it.move_movetype == MOVETYPE_NONE)
2092                         continue;
2093
2094                 if(it.move_qcphysics)
2095                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2096
2097                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2098                 {
2099                         // handle thinking here
2100                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2101                                 RunThink(it);
2102                 }
2103         });
2104
2105         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2106                 return;
2107
2108         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2109         {
2110                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2111                         continue;
2112                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2113         });
2114 }
2115
2116 void systems_update();
2117 void EndFrame()
2118 {
2119         anticheat_endframe();
2120
2121         Physics_Frame();
2122
2123         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2124                 entity e = IS_SPEC(it) ? it.enemy : it;
2125                 if (e.typehitsound) {
2126                         STAT(TYPEHIT_TIME, it) = time;
2127                 } else if (e.killsound) {
2128                         STAT(KILL_TIME, it) = time;
2129                 } else if (e.damage_dealt) {
2130                         STAT(HIT_TIME, it) = time;
2131                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2132                 }
2133         });
2134         // add 1 frametime because after this, engine SV_Physics
2135         // increases time by a frametime and then networks the frame
2136         // add another frametime because client shows everything with
2137         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2138         // needed!
2139         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2140         FOREACH_CLIENT(true, {
2141                 it.typehitsound = false;
2142                 it.damage_dealt = 0;
2143                 it.killsound = false;
2144                 antilag_record(it, CS(it), altime);
2145         });
2146         IL_EACH(g_monsters, true,
2147         {
2148                 antilag_record(it, it, altime);
2149         });
2150         IL_EACH(g_projectiles, it.classname == "nade",
2151         {
2152                 antilag_record(it, it, altime);
2153         });
2154         systems_update();
2155         IL_ENDFRAME();
2156 }
2157
2158
2159 /*
2160  * RedirectionThink:
2161  * returns true if redirecting
2162  */
2163 float redirection_timeout;
2164 float redirection_nextthink;
2165 float RedirectionThink()
2166 {
2167         float clients_found;
2168
2169         if(redirection_target == "")
2170                 return false;
2171
2172         if(!redirection_timeout)
2173         {
2174                 cvar_set("sv_public", "-2");
2175                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2176                 if(redirection_target == "self")
2177                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2178                 else
2179                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2180         }
2181
2182         if(time < redirection_nextthink)
2183                 return true;
2184
2185         redirection_nextthink = time + 1;
2186
2187         clients_found = 0;
2188         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2189                 // TODO add timer
2190                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2191                 if(redirection_target == "self")
2192                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2193                 else
2194                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2195                 ++clients_found;
2196         });
2197
2198         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2199
2200         if(time > redirection_timeout || clients_found == 0)
2201                 localcmd("\nwait; wait; wait; quit\n");
2202
2203         return true;
2204 }
2205
2206 void TargetMusic_RestoreGame();
2207 void RestoreGame()
2208 {
2209         // Loaded from a save game
2210         // some things then break, so let's work around them...
2211
2212         // Progs DB (capture records)
2213         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2214
2215         // Mapinfo
2216         MapInfo_Shutdown();
2217         MapInfo_Enumerate();
2218         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2219         WeaponStats_Init();
2220
2221         TargetMusic_RestoreGame();
2222 }
2223
2224 void Shutdown()
2225 {
2226         game_stopped = 2;
2227
2228         if(world_initialized > 0)
2229         {
2230                 world_initialized = 0;
2231                 LOG_TRACE("Saving persistent data...");
2232                 Ban_SaveBans();
2233
2234                 // playerstats with unfinished match
2235                 PlayerStats_GameReport(false);
2236
2237                 if(!cheatcount_total)
2238                 {
2239                         if(autocvar_sv_db_saveasdump)
2240                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2241                         else
2242                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2243                 }
2244                 if(autocvar_developer)
2245                 {
2246                         if(autocvar_sv_db_saveasdump)
2247                                 db_dump(TemporaryDB, "server-temp.db");
2248                         else
2249                                 db_save(TemporaryDB, "server-temp.db");
2250                 }
2251                 CheatShutdown(); // must be after cheatcount check
2252                 db_close(ServerProgsDB);
2253                 db_close(TemporaryDB);
2254                 LOG_TRACE("Saving persistent data... done!");
2255                 // tell the bot system the game is ending now
2256                 bot_endgame();
2257
2258                 WeaponStats_Shutdown();
2259                 MapInfo_Shutdown();
2260         }
2261         else if(world_initialized == 0)
2262         {
2263                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2264         }
2265         else
2266         {
2267                 __init_dedicated_server_shutdown();
2268         }
2269 }