qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "waypointsprites.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/buffs.qh"
  24 #include "../common/constants.qh"
  25 #include "../common/deathtypes.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/all.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/notifications.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/util.qh"
  34 #include "../common/items/all.qh"
  35 #include "../common/weapons/all.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_fraginfo");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_fraginfo_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 float RandomSeed_Send(entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         entity oldself;
 534         oldself = self;
 535         self = randomseed;
 536         self.think(); // sets random seed and nextthink
 537         self = oldself;
 538 }
 539
 540 void spawnfunc___init_dedicated_server(void)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         remove = remove_unsafely;
 550
 551         entity e;
 552         e = spawn();
 553         e.think = GotoFirstMap;
 554         e.nextthink = time; // this is usually 1 at this point
 555
 556         e = spawn();
 557         e.classname = "info_player_deathmatch"; // safeguard against player joining
 558
 559         self.classname = "worldspawn"; // safeguard against various stuff ;)
 560
 561         // needs to be done so early because of the constants they create
 562         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 563         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 564         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 565         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 566         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 567         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 568         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 569
 570         MapInfo_Enumerate();
 571         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 572 }
 573
 574 void Map_MarkAsRecent(string m);
 575 float world_already_spawned;
 576 void Nagger_Init();
 577 void ClientInit_Spawn();
 578 void WeaponStats_Init();
 579 void WeaponStats_Shutdown();
 580 void Physics_AddStats();
 581 void spawnfunc_worldspawn (void)
 582 {
 583         float fd, l, j, n;
 584         string s;
 585
 586         cvar = cvar_normal;
 587         cvar_string = cvar_string_normal;
 588         cvar_set = cvar_set_normal;
 589
 590         if(world_already_spawned)
 591                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 592         world_already_spawned = true;
 593
 594         remove = remove_safely; // during spawning, watch what you remove!
 595
 596         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 597
 598         compressShortVector_init();
 599
 600         entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 610
 611         // needs to be done so early because of the constants they create
 612         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 613         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 614         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 615         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 616         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 617         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 618         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 619
 620         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 621
 622         TemporaryDB = db_create();
 623
 624         // 0 normal
 625         lightstyle(0, "m");
 626
 627         // 1 FLICKER (first variety)
 628         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 629
 630         // 2 SLOW STRONG PULSE
 631         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 632
 633         // 3 CANDLE (first variety)
 634         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 635
 636         // 4 FAST STROBE
 637         lightstyle(4, "mamamamamama");
 638
 639         // 5 GENTLE PULSE 1
 640         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 641
 642         // 6 FLICKER (second variety)
 643         lightstyle(6, "nmonqnmomnmomomno");
 644
 645         // 7 CANDLE (second variety)
 646         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 647
 648         // 8 CANDLE (third variety)
 649         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 650
 651         // 9 SLOW STROBE (fourth variety)
 652         lightstyle(9, "aaaaaaaazzzzzzzz");
 653
 654         // 10 FLUORESCENT FLICKER
 655         lightstyle(10, "mmamammmmammamamaaamammma");
 656
 657         // 11 SLOW PULSE NOT FADE TO BLACK
 658         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 659
 660         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 661
 662         // 63 testing
 663         lightstyle(63, "a");
 664
 665         if(autocvar_g_campaign)
 666                 CampaignPreInit();
 667
 668         Map_MarkAsRecent(mapname);
 669
 670         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 671
 672         precache_model ("null"); // we need this one before InitGameplayMode
 673         InitGameplayMode();
 674         readlevelcvars();
 675         GrappleHookInit();
 676
 677         player_count = 0;
 678         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 679         if(bot_waypoints_for_items == 1)
 680                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 681                         bot_waypoints_for_items = 0;
 682
 683         precache();
 684
 685         WaypointSprite_Init();
 686
 687         GameLogInit(); // prepare everything
 688         // NOTE for matchid:
 689         // changing the logic generating it is okay. But:
 690         // it HAS to stay <= 64 chars
 691         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 692         if(autocvar_sv_eventlog)
 693         {
 694                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 695                 matchid = strzone(s);
 696
 697                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 698                 s = ":gameinfo:mutators:LIST";
 699
 700                 ret_string = s;
 701                 MUTATOR_CALLHOOK(BuildMutatorsString);
 702                 s = ret_string;
 703
 704                 // simple, probably not good in the mutator system
 705                 if(autocvar_g_grappling_hook)
 706                         s = strcat(s, ":grappling_hook");
 707
 708                 // initialiation stuff, not good in the mutator system
 709                 if(!autocvar_g_use_ammunition)
 710                         s = strcat(s, ":no_use_ammunition");
 711
 712                 // initialiation stuff, not good in the mutator system
 713                 if(autocvar_g_pickup_items == 0)
 714                         s = strcat(s, ":no_pickup_items");
 715                 if(autocvar_g_pickup_items > 0)
 716                         s = strcat(s, ":pickup_items");
 717
 718                 // initialiation stuff, not good in the mutator system
 719                 if(autocvar_g_weaponarena != "0")
 720                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_norecoil)
 724                         s = strcat(s, ":norecoil");
 725
 726                 // TODO to mutator system
 727                 if(autocvar_g_powerups == 0)
 728                         s = strcat(s, ":no_powerups");
 729                 if(autocvar_g_powerups > 0)
 730                         s = strcat(s, ":powerups");
 731
 732                 GameLogEcho(s);
 733                 GameLogEcho(":gameinfo:end");
 734         }
 735         else
 736                 matchid = strzone(ftos(random()));
 737
 738         cvar_set("nextmap", "");
 739
 740         SetDefaultAlpha();
 741
 742         if(autocvar_g_campaign)
 743                 CampaignPostInit();
 744
 745         Ban_LoadBans();
 746
 747         MapInfo_Enumerate();
 748         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 749
 750         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 751         {
 752                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 753                 if(fd != -1)
 754                 {
 755                         while((s = fgets(fd)))
 756                         {
 757                                 l = tokenize_console(s);
 758                                 if(l < 2)
 759                                         continue;
 760                                 if(argv(0) == "cd")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  cdtrack ", argv(2), "\n");
 764                                 }
 765                                 else if(argv(0) == "fog")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 768                                         print("  \"fog\" \"", s, "\"\n");
 769                                 }
 770                                 else if(argv(0) == "set")
 771                                 {
 772                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 773                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 774                                 }
 775                                 else if(argv(0) != "//")
 776                                 {
 777                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 778                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 779                                 }
 780                         }
 781                         fclose(fd);
 782                 }
 783         }
 784
 785         WeaponStats_Init();
 786
 787         WepSet_AddStat();
 788         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 789         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 790         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 791         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 792         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 793         Nagger_Init();
 794
 795         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 796         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 797         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 798         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 799         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 800         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 801         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 802         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 803         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 804         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 807         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 808         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 809         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 810
 811         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 812         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 813
 814         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 815
 816         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 817
 818         // freeze attacks
 819         addstat(STAT_FROZEN, AS_INT, frozen);
 820         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 821
 822         // physics
 823         Physics_AddStats();
 824
 825         // new properties
 826         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 827         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 828         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 829         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 830         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 831         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 832         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 833         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 834         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 835         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 836         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 837         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 838         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 839         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 840         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 841         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 842         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 843         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 844         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 845
 846         // secrets
 847         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 848         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 849
 850         // monsters
 851         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 852         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 853
 854         // misc
 855         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 856
 857         next_pingtime = time + 5;
 858
 859         detect_maptype();
 860
 861         // set up information replies for clients and server to use
 862         maplist_reply = strzone(getmaplist());
 863         lsmaps_reply = strzone(getlsmaps());
 864         monsterlist_reply = strzone(getmonsterlist());
 865         for(int i = 0; i < 10; ++i)
 866         {
 867                 s = getrecords(i);
 868                 if (s)
 869                         records_reply[i] = strzone(s);
 870         }
 871         ladder_reply = strzone(getladder());
 872         rankings_reply = strzone(getrankings());
 873
 874         // begin other init
 875         ClientInit_Spawn();
 876         RandomSeed_Spawn();
 877         PingPLReport_Spawn();
 878
 879         CheatInit();
 880
 881         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 882
 883         // fill sv_curl_serverpackages from .serverpackage files
 884         if(autocvar_sv_curl_serverpackages_auto)
 885         {
 886                 s = "";
 887                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 888                 for(int i = 0; i < n; ++i)
 889                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 890                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 891                                 s = strcat(s, " ", argv(i));
 892                 fd = search_begin("*-serverpackage.txt", true, false);
 893                 if(fd >= 0)
 894                 {
 895                         j = search_getsize(fd);
 896                         for(int i = 0; i < j; ++i)
 897                                 s = strcat(s, " ", search_getfilename(fd, i));
 898                         search_end(fd);
 899                 }
 900                 fd = search_begin("*.serverpackage", true, false);
 901                 if(fd >= 0)
 902                 {
 903                         j = search_getsize(fd);
 904                         for(int i = 0; i < j; ++i)
 905                                 s = strcat(s, " ", search_getfilename(fd, i));
 906                         search_end(fd);
 907                 }
 908                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 909         }
 910
 911         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 912         modname = "Xonotic";
 913         // physics/balance/config changes that count as mod
 914         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 915                 modname = cvar_string("g_mod_physics");
 916         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 917                 modname = cvar_string("g_mod_balance");
 918         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 919                 modname = cvar_string("g_mod_config");
 920         // extra mutators that deserve to count as mod
 921         MUTATOR_CALLHOOK(SetModname);
 922
 923         // save it for later
 924         modname = strzone(modname);
 925
 926         WinningConditionHelper(); // set worldstatus
 927
 928         world_initialized = 1;
 929 }
 930
 931 void spawnfunc_light (void)
 932 {
 933         //makestatic (self); // Who the f___ did that?
 934         remove(self);
 935 }
 936
 937 string GetGametype()
 938 {
 939         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 940 }
 941
 942 string GetMapname()
 943 {
 944         return mapname;
 945 }
 946
 947 float Map_Count, Map_Current;
 948 string Map_Current_Name;
 949
 950 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 951 float GetMaplistPosition()
 952 {
 953         float pos, idx;
 954         string map;
 955
 956         map = GetMapname();
 957         idx = autocvar_g_maplist_index;
 958
 959         if(idx >= 0)
 960                 if(idx < Map_Count)
 961                         if(map == argv(idx))
 962                                 return idx;
 963
 964         for(pos = 0; pos < Map_Count; ++pos)
 965                 if(map == argv(pos))
 966                         return pos;
 967
 968         // resume normal maplist rotation if current map is not in g_maplist
 969         return idx;
 970 }
 971
 972 float MapHasRightSize(string map)
 973 {
 974         float fh;
 975         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 976         if(autocvar_g_maplist_check_waypoints)
 977         {
 978                 dprint("checkwp "); dprint(map);
 979                 if(!fexists(strcat("maps/", map, ".waypoints")))
 980                 {
 981                         dprint(": no waypoints\n");
 982                         return false;
 983                 }
 984                 dprint(": has waypoints\n");
 985         }
 986
 987         // open map size restriction file
 988         dprint("opensize "); dprint(map);
 989         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 990         if(fh >= 0)
 991         {
 992                 float mapmin, mapmax;
 993                 dprint(": ok, ");
 994                 mapmin = stof(fgets(fh));
 995                 mapmax = stof(fgets(fh));
 996                 fclose(fh);
 997                 if(player_count < mapmin)
 998                 {
 999                         dprint("not enough\n");
1000                         return false;
1001                 }
1002                 if(player_count > mapmax)
1003                 {
1004                         dprint("too many\n");
1005                         return false;
1006                 }
1007                 dprint("right size\n");
1008                 return true;
1009         }
1010         dprint(": not found\n");
1011         return true;
1012 }
1013
1014 string Map_Filename(float position)
1015 {
1016         return strcat("maps/", argv(position), ".bsp");
1017 }
1018
1019 string strwords(string s, float w)
1020 {
1021         float endpos;
1022         for(endpos = 0; w && endpos >= 0; --w)
1023                 endpos = strstrofs(s, " ", endpos + 1);
1024         if(endpos < 0)
1025                 return s;
1026         else
1027                 return substring(s, 0, endpos);
1028 }
1029
1030 float strhasword(string s, string w)
1031 {
1032         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1033 }
1034
1035 void Map_MarkAsRecent(string m)
1036 {
1037         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1038 }
1039
1040 float Map_IsRecent(string m)
1041 {
1042         return strhasword(autocvar_g_maplist_mostrecent, m);
1043 }
1044
1045 float Map_Check(float position, float pass)
1046 {
1047         string filename;
1048         string map_next;
1049         map_next = argv(position);
1050         if(pass <= 1)
1051         {
1052                 if(Map_IsRecent(map_next))
1053                         return 0;
1054         }
1055         filename = Map_Filename(position);
1056         if(MapInfo_CheckMap(map_next))
1057         {
1058                 if(pass == 2)
1059                         return 1;
1060                 if(MapHasRightSize(map_next))
1061                         return 1;
1062                 return 0;
1063         }
1064         else
1065                 dprint( "Couldn't select '", filename, "'..\n" );
1066
1067         return 0;
1068 }
1069
1070 void Map_Goto_SetStr(string nextmapname)
1071 {
1072         if(getmapname_stored != "")
1073                 strunzone(getmapname_stored);
1074         if(nextmapname == "")
1075                 getmapname_stored = "";
1076         else
1077                 getmapname_stored = strzone(nextmapname);
1078 }
1079
1080 void Map_Goto_SetFloat(float position)
1081 {
1082         cvar_set("g_maplist_index", ftos(position));
1083         Map_Goto_SetStr(argv(position));
1084 }
1085
1086 void Map_Goto(float reinit)
1087 {
1088         MapInfo_LoadMap(getmapname_stored, reinit);
1089 }
1090
1091 // return codes of map selectors:
1092 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1093 //   -2 = permanent failure
1094 float() MaplistMethod_Iterate = // usual method
1095 {
1096         float pass, i;
1097
1098         dprint("Trying MaplistMethod_Iterate\n");
1099
1100         for(pass = 1; pass <= 2; ++pass)
1101         {
1102                 for(i = 1; i < Map_Count; ++i)
1103                 {
1104                         float mapindex;
1105                         mapindex = (i + Map_Current) % Map_Count;
1106                         if(Map_Check(mapindex, pass))
1107                                 return mapindex;
1108                 }
1109         }
1110         return -1;
1111 }
1112
1113 float() MaplistMethod_Repeat = // fallback method
1114 {
1115         dprint("Trying MaplistMethod_Repeat\n");
1116
1117         if(Map_Check(Map_Current, 2))
1118                 return Map_Current;
1119         return -2;
1120 }
1121
1122 float() MaplistMethod_Random = // random map selection
1123 {
1124         float i, imax;
1125
1126         dprint("Trying MaplistMethod_Random\n");
1127
1128         imax = 42;
1129
1130         for(i = 0; i <= imax; ++i)
1131         {
1132                 float mapindex;
1133                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1134                 if(Map_Check(mapindex, 1))
1135                         return mapindex;
1136         }
1137         return -1;
1138 }
1139
1140 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1141 // the exponent sets a bias on the map selection:
1142 // the higher the exponent, the less likely "shortly repeated" same maps are
1143 {
1144         float i, j, imax, insertpos;
1145
1146         dprint("Trying MaplistMethod_Shuffle\n");
1147
1148         imax = 42;
1149
1150         for(i = 0; i <= imax; ++i)
1151         {
1152                 string newlist;
1153
1154                 // now reinsert this at another position
1155                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1156                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1157                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1158                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1159
1160                 // insert the current map there
1161                 newlist = "";
1162                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1163                         newlist = strcat(newlist, " ", argv(j));
1164                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1165                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1166                         newlist = strcat(newlist, " ", argv(j));
1167                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1168                 cvar_set("g_maplist", newlist);
1169                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1170
1171                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1172                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1173                 if(Map_Check(Map_Current, 1))
1174                         return Map_Current;
1175         }
1176         return -1;
1177 }
1178
1179 void Maplist_Init()
1180 {
1181         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1182         float i;
1183         for (i = 0; i < Map_Count; ++i)
1184                 if (Map_Check(i, 2))
1185                         break;
1186         if (i == Map_Count)
1187         {
1188                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1189                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1190                 if(autocvar_g_maplist_shuffle)
1191                         ShuffleMaplist();
1192                 localcmd("\nmenu_cmd sync\n");
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194         }
1195         if(Map_Count == 0)
1196                 error("empty maplist, cannot select a new map");
1197         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1198
1199         if(Map_Current_Name)
1200                 strunzone(Map_Current_Name);
1201         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1202         // this may or may not be correct, but who cares, in the worst case a map
1203         // isn't chosen in the first pass that should have been
1204 }
1205
1206 string GetNextMap()
1207 {
1208         float nextMap;
1209
1210         Maplist_Init();
1211         nextMap = -1;
1212
1213         if(nextMap == -1)
1214                 if(autocvar_g_maplist_shuffle > 0)
1215                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1216
1217         if(nextMap == -1)
1218                 if(autocvar_g_maplist_selectrandom)
1219                         nextMap = MaplistMethod_Random();
1220
1221         if(nextMap == -1)
1222                 nextMap = MaplistMethod_Iterate();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Repeat();
1226
1227         if(nextMap >= 0)
1228         {
1229                 Map_Goto_SetFloat(nextMap);
1230                 return getmapname_stored;
1231         }
1232
1233         return "";
1234 }
1235
1236 float DoNextMapOverride(float reinit)
1237 {
1238         if(autocvar_g_campaign)
1239         {
1240                 CampaignPostIntermission();
1241                 alreadychangedlevel = true;
1242                 return true;
1243         }
1244         if(autocvar_quit_when_empty)
1245         {
1246                 if(player_count <= currentbots)
1247                 {
1248                         localcmd("quit\n");
1249                         alreadychangedlevel = true;
1250                         return true;
1251                 }
1252         }
1253         if(autocvar_quit_and_redirect != "")
1254         {
1255                 redirection_target = strzone(autocvar_quit_and_redirect);
1256                 alreadychangedlevel = true;
1257                 return true;
1258         }
1259         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1260         {
1261                 localcmd("restart\n");
1262                 alreadychangedlevel = true;
1263                 return true;
1264         }
1265         if(autocvar_nextmap != "")
1266         {
1267                 string m;
1268                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1269                 cvar_set("nextmap",m);
1270
1271                 if(!m || gametypevote)
1272                         return false;
1273                 if(autocvar_sv_vote_gametype)
1274                 {
1275                         Map_Goto_SetStr(m);
1276                         return false;
1277                 }
1278
1279                 if(MapInfo_CheckMap(m))
1280                 {
1281                         Map_Goto_SetStr(m);
1282                         Map_Goto(reinit);
1283                         alreadychangedlevel = true;
1284                         return true;
1285                 }
1286         }
1287         if(!reinit && autocvar_lastlevel)
1288         {
1289                 cvar_settemp_restore();
1290                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1291                 alreadychangedlevel = true;
1292                 return true;
1293         }
1294         return false;
1295 }
1296
1297 void GotoNextMap(float reinit)
1298 {
1299         //string nextmap;
1300         //float n, nummaps;
1301         //string s;
1302         if (alreadychangedlevel)
1303                 return;
1304         alreadychangedlevel = true;
1305
1306         string nextMap;
1307
1308         nextMap = GetNextMap();
1309         if(nextMap == "")
1310                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1311         Map_Goto(reinit);
1312 }
1313
1314
1315 /*
1316 ============
1317 IntermissionThink
1318
1319 When the player presses attack or jump, change to the next level
1320 ============
1321 */
1322 .float autoscreenshot;
1323 void IntermissionThink()
1324 {
1325         FixIntermissionClient(self);
1326
1327         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1328         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1329
1330         if( (server_screenshot || client_screenshot)
1331                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1332         {
1333                 self.autoscreenshot = -1;
1334                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1335                 return;
1336         }
1337
1338         if (time < intermission_exittime)
1339                 return;
1340
1341         if(!mapvote_initialized)
1342                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1343                         return;
1344
1345         MapVote_Start();
1346 }
1347
1348 /*
1349 ============
1350 FindIntermission
1351
1352 Returns the entity to view from
1353 ============
1354 */
1355 /*
1356 entity FindIntermission()
1357 {
1358         local   entity spot;
1359         local   float cyc;
1360
1361 // look for info_intermission first
1362         spot = find (world, classname, "info_intermission");
1363         if (spot)
1364         {       // pick a random one
1365                 cyc = random() * 4;
1366                 while (cyc > 1)
1367                 {
1368                         spot = find (spot, classname, "info_intermission");
1369                         if (!spot)
1370                                 spot = find (spot, classname, "info_intermission");
1371                         cyc = cyc - 1;
1372                 }
1373                 return spot;
1374         }
1375
1376 // then look for the start position
1377         spot = find (world, classname, "info_player_start");
1378         if (spot)
1379                 return spot;
1380
1381 // testinfo_player_start is only found in regioned levels
1382         spot = find (world, classname, "testplayerstart");
1383         if (spot)
1384                 return spot;
1385
1386 // then look for the start position
1387         spot = find (world, classname, "info_player_deathmatch");
1388         if (spot)
1389                 return spot;
1390
1391         //objerror ("FindIntermission: no spot");
1392         return world;
1393 }
1394 */
1395
1396 /*
1397 ===============================================================================
1398
1399 RULES
1400
1401 ===============================================================================
1402 */
1403
1404 void DumpStats(float final)
1405 {
1406         float file;
1407         string s;
1408         float to_console;
1409         float to_eventlog;
1410         float to_file;
1411         float i;
1412
1413         to_console = autocvar_sv_logscores_console;
1414         to_eventlog = autocvar_sv_eventlog;
1415         to_file = autocvar_sv_logscores_file;
1416
1417         if(!final)
1418         {
1419                 to_console = true; // always print printstats replies
1420                 to_eventlog = false; // but never print them to the event log
1421         }
1422
1423         if(to_eventlog)
1424                 if(autocvar_sv_eventlog_console)
1425                         to_console = false; // otherwise we get the output twice
1426
1427         if(final)
1428                 s = ":scores:";
1429         else
1430                 s = ":status:";
1431         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1432
1433         if(to_console)
1434                 print(s, "\n");
1435         if(to_eventlog)
1436                 GameLogEcho(s);
1437
1438         file = -1;
1439         if(to_file)
1440         {
1441                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1442                 if(file == -1)
1443                         to_file = false;
1444                 else
1445                         fputs(file, strcat(s, "\n"));
1446         }
1447
1448         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1449         if(to_console)
1450                 print(s, "\n");
1451         if(to_eventlog)
1452                 GameLogEcho(s);
1453         if(to_file)
1454                 fputs(file, strcat(s, "\n"));
1455
1456         FOR_EACH_CLIENT(other)
1457         {
1458                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1459                 {
1460                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1461                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1462                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1463                                 s = strcat(s, ftos(other.team), ":");
1464                         else
1465                                 s = strcat(s, "spectator:");
1466
1467                         if(to_console)
1468                                 print(s, other.netname, "\n");
1469                         if(to_eventlog)
1470                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1471                         if(to_file)
1472                                 fputs(file, strcat(s, other.netname, "\n"));
1473                 }
1474         }
1475
1476         if(teamplay)
1477         {
1478                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1479                 if(to_console)
1480                         print(s, "\n");
1481                 if(to_eventlog)
1482                         GameLogEcho(s);
1483                 if(to_file)
1484                         fputs(file, strcat(s, "\n"));
1485
1486                 for(i = 1; i < 16; ++i)
1487                 {
1488                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1489                         s = strcat(s, ":", ftos(i));
1490                         if(to_console)
1491                                 print(s, "\n");
1492                         if(to_eventlog)
1493                                 GameLogEcho(s);
1494                         if(to_file)
1495                                 fputs(file, strcat(s, "\n"));
1496                 }
1497         }
1498
1499         if(to_console)
1500                 print(":end\n");
1501         if(to_eventlog)
1502                 GameLogEcho(":end");
1503         if(to_file)
1504         {
1505                 fputs(file, ":end\n");
1506                 fclose(file);
1507         }
1508 }
1509
1510 void FixIntermissionClient(entity e)
1511 {
1512         string s;
1513         if(!e.autoscreenshot) // initial call
1514         {
1515                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1516                 e.health = -2342;
1517                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1518                 e.solid = SOLID_NOT;
1519                 e.movetype = MOVETYPE_NONE;
1520                 e.takedamage = DAMAGE_NO;
1521                 if(e.weaponentity)
1522                 {
1523                         e.weaponentity.effects = EF_NODRAW;
1524                         if (e.weaponentity.weaponentity)
1525                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1526                 }
1527                 if(IS_REAL_CLIENT(e))
1528                 {
1529                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1530                         s = autocvar_sv_intermission_cdtrack;
1531                         if(s != "")
1532                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1533                         msg_entity = e;
1534                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1535                 }
1536         }
1537 }
1538
1539 /*
1540 go to the next level for deathmatch
1541 only called if a time or frag limit has expired
1542 */
1543 void NextLevel()
1544 {
1545         gameover = true;
1546
1547         intermission_running = 1;
1548
1549 // enforce a wait time before allowing changelevel
1550         if(player_count > 0)
1551                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1552         else
1553                 intermission_exittime = -1;
1554
1555         /*
1556         WriteByte (MSG_ALL, SVC_CDTRACK);
1557         WriteByte (MSG_ALL, 3);
1558         WriteByte (MSG_ALL, 3);
1559         // done in FixIntermission
1560         */
1561
1562         //pos = FindIntermission ();
1563
1564         VoteReset();
1565
1566         DumpStats(true);
1567
1568         // send statistics
1569         PlayerStats_GameReport(true);
1570         WeaponStats_Shutdown();
1571
1572         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1573
1574         if(autocvar_sv_eventlog)
1575                 GameLogEcho(":gameover");
1576
1577         GameLogClose();
1578
1579         FOR_EACH_PLAYER(other) {
1580                 FixIntermissionClient(other);
1581                 if(other.winning)
1582                         bprint(other.netname, " ^7wins.\n");
1583         }
1584
1585         if(autocvar_g_campaign)
1586                 CampaignPreIntermission();
1587
1588         MUTATOR_CALLHOOK(MatchEnd);
1589
1590         localcmd("\nsv_hook_gameend\n");
1591 }
1592
1593 /*
1594 ============
1595 CheckRules_Player
1596
1597 Exit deathmatch games upon conditions
1598 ============
1599 */
1600 void CheckRules_Player()
1601 {
1602         if (gameover)   // someone else quit the game already
1603                 return;
1604
1605         if(self.deadflag == DEAD_NO)
1606                 self.play_time += frametime;
1607
1608         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1609         //   (div0: and that in CheckRules_World please)
1610 }
1611
1612
1613 float InitiateSuddenDeath()
1614 {
1615         // Check first whether normal overtimes could be added before initiating suddendeath mode
1616         // - for this timelimit_overtime needs to be >0 of course
1617         // - also check the winning condition calculated in the previous frame and only add normal overtime
1618         //   again, if at the point at which timelimit would be extended again, still no winner was found
1619         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1620         {
1621                 return 1; // need to call InitiateOvertime later
1622         }
1623         else
1624         {
1625                 if(!checkrules_suddendeathend)
1626                 {
1627                         if(autocvar_g_campaign)
1628                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1629                         else
1630                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1631                         if(g_race && !g_race_qualifying)
1632                                 race_StartCompleting();
1633                 }
1634                 return 0;
1635         }
1636 }
1637
1638 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1639 {
1640         ++checkrules_overtimesadded;
1641         //add one more overtime by simply extending the timelimit
1642         float tl;
1643         tl = autocvar_timelimit;
1644         tl += autocvar_timelimit_overtime;
1645         cvar_set("timelimit", ftos(tl));
1646
1647         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1648 }
1649
1650 float GetWinningCode(float fraglimitreached, float equality)
1651 {
1652         if(autocvar_g_campaign == 1)
1653                 if(fraglimitreached)
1654                         return WINNING_YES;
1655                 else
1656                         return WINNING_NO;
1657
1658         else
1659                 if(equality)
1660                         if(fraglimitreached)
1661                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1662                         else
1663                                 return WINNING_NEVER;
1664                 else
1665                         if(fraglimitreached)
1666                                 return WINNING_YES;
1667                         else
1668                                 return WINNING_NO;
1669 }
1670
1671 // set the .winning flag for exactly those players with a given field value
1672 void SetWinners(.float field, float value)
1673 {
1674         entity head;
1675         FOR_EACH_PLAYER(head)
1676                 head.winning = (head.(field) == value);
1677 }
1678
1679 // set the .winning flag for those players with a given field value
1680 void AddWinners(.float field, float value)
1681 {
1682         entity head;
1683         FOR_EACH_PLAYER(head)
1684                 if (head.(field) == value)
1685                         head.winning = 1;
1686 }
1687
1688 // clear the .winning flags
1689 void ClearWinners(void)
1690 {
1691         entity head;
1692         FOR_EACH_PLAYER(head)
1693                 head.winning = 0;
1694 }
1695
1696 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1697 // they win. Otherwise the defending team wins once the timelimit passes.
1698 void assault_new_round();
1699 float WinningCondition_Assault()
1700 {
1701         float status;
1702
1703         WinningConditionHelper(); // set worldstatus
1704
1705         status = WINNING_NO;
1706         // as the timelimit has not yet passed just assume the defending team will win
1707         if(assault_attacker_team == NUM_TEAM_1)
1708         {
1709                 SetWinners(team, NUM_TEAM_2);
1710         }
1711         else
1712         {
1713                 SetWinners(team, NUM_TEAM_1);
1714         }
1715
1716         entity ent;
1717         ent = find(world, classname, "target_assault_roundend");
1718         if(ent)
1719         {
1720                 if(ent.winning) // round end has been triggered by attacking team
1721                 {
1722                         bprint("ASSAULT: round completed...\n");
1723                         SetWinners(team, assault_attacker_team);
1724
1725                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1726
1727                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1728                         {
1729                                 status = WINNING_YES;
1730                         }
1731                         else
1732                         {
1733                                 entity oldself;
1734                                 oldself = self;
1735                                 self = ent;
1736                                 assault_new_round();
1737                                 self = oldself;
1738                         }
1739                 }
1740         }
1741
1742         return status;
1743 }
1744
1745 // LMS winning condition: game terminates if and only if there's at most one
1746 // one player who's living lives. Top two scores being equal cancels the time
1747 // limit.
1748 float WinningCondition_LMS()
1749 {
1750         entity head, head2;
1751         float have_player;
1752         float have_players;
1753         float l;
1754
1755         have_player = false;
1756         have_players = false;
1757         l = LMS_NewPlayerLives();
1758
1759         head = find(world, classname, "player");
1760         if(head)
1761                 have_player = true;
1762         head2 = find(head, classname, "player");
1763         if(head2)
1764                 have_players = true;
1765
1766         if(have_player)
1767         {
1768                 // we have at least one player
1769                 if(have_players)
1770                 {
1771                         // two or more active players - continue with the game
1772                 }
1773                 else
1774                 {
1775                         // exactly one player?
1776
1777                         ClearWinners();
1778                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1779
1780                         if(l)
1781                         {
1782                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1783                                 return WINNING_NO;
1784                         }
1785                         else
1786                         {
1787                                 // a winner!
1788                                 // and assign him his first place
1789                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1790                                 return WINNING_YES;
1791                         }
1792                 }
1793         }
1794         else
1795         {
1796                 // nobody is playing at all...
1797                 if(l)
1798                 {
1799                         // wait for players...
1800                 }
1801                 else
1802                 {
1803                         // SNAFU (maybe a draw game?)
1804                         ClearWinners();
1805                         dprint("No players, ending game.\n");
1806                         return WINNING_YES;
1807                 }
1808         }
1809
1810         // When we get here, we have at least two players who are actually LIVING,
1811         // now check if the top two players have equal score.
1812         WinningConditionHelper();
1813
1814         ClearWinners();
1815         if(WinningConditionHelper_winner)
1816                 WinningConditionHelper_winner.winning = true;
1817         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1818                 return WINNING_NEVER;
1819
1820         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1821         return WINNING_NO;
1822 }
1823
1824 void ShuffleMaplist()
1825 {
1826         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1827 }
1828
1829 float leaderfrags;
1830 float WinningCondition_Scores(float limit, float leadlimit)
1831 {
1832         float limitreached;
1833
1834         // TODO make everything use THIS winning condition (except LMS)
1835         WinningConditionHelper();
1836
1837         if(teamplay)
1838         {
1839                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1840                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1841                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1842                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1843         }
1844
1845         ClearWinners();
1846         if(WinningConditionHelper_winner)
1847                 WinningConditionHelper_winner.winning = 1;
1848         if(WinningConditionHelper_winnerteam >= 0)
1849                 SetWinners(team, WinningConditionHelper_winnerteam);
1850
1851         if(WinningConditionHelper_lowerisbetter)
1852         {
1853                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1854                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1855                 limit = -limit;
1856         }
1857
1858         if(WinningConditionHelper_zeroisworst)
1859                 leadlimit = 0; // not supported in this mode
1860
1861         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1862         // these modes always score in increments of 1, thus this makes sense
1863         {
1864                 if(leaderfrags != WinningConditionHelper_topscore)
1865                 {
1866                         leaderfrags = WinningConditionHelper_topscore;
1867
1868                         if (limit)
1869                         if (leaderfrags == limit - 1)
1870                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1871                         else if (leaderfrags == limit - 2)
1872                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1873                         else if (leaderfrags == limit - 3)
1874                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1875                 }
1876         }
1877
1878         limitreached = false;
1879         if(limit)
1880                 if(WinningConditionHelper_topscore >= limit)
1881                         limitreached = true;
1882         if(leadlimit)
1883         {
1884                 float leadlimitreached;
1885                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1886                 if(autocvar_leadlimit_and_fraglimit)
1887                         limitreached = (limitreached && leadlimitreached);
1888                 else
1889                         limitreached = (limitreached || leadlimitreached);
1890         }
1891
1892         if(limit)
1893                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1894
1895         return GetWinningCode(
1896                 WinningConditionHelper_topscore && limitreached,
1897                 WinningConditionHelper_equality
1898         );
1899 }
1900
1901 float WinningCondition_Race(float fraglimit)
1902 {
1903         float wc;
1904         entity p;
1905         float n, c;
1906
1907         n = 0;
1908         c = 0;
1909         FOR_EACH_PLAYER(p)
1910         {
1911                 ++n;
1912                 if(p.race_completed)
1913                         ++c;
1914         }
1915         if(n && (n == c))
1916                 return WINNING_YES;
1917         wc = WinningCondition_Scores(fraglimit, 0);
1918
1919         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1920         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1921         // do NOT support equality when the laps are all raced!
1922                 return WINNING_STARTSUDDENDEATHOVERTIME;
1923         else
1924                 return WINNING_NEVER;
1925 }
1926
1927 float WinningCondition_QualifyingThenRace(float limit)
1928 {
1929         float wc;
1930         wc = WinningCondition_Scores(limit, 0);
1931
1932         // NEVER initiate overtime
1933         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1934         {
1935                 return WINNING_YES;
1936         }
1937
1938         return wc;
1939 }
1940
1941 float WinningCondition_RanOutOfSpawns()
1942 {
1943         entity head;
1944
1945         if(have_team_spawns <= 0)
1946                 return WINNING_NO;
1947
1948         if(!autocvar_g_spawn_useallspawns)
1949                 return WINNING_NO;
1950
1951         if(!some_spawn_has_been_used)
1952                 return WINNING_NO;
1953
1954         team1_score = team2_score = team3_score = team4_score = 0;
1955
1956         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1957         {
1958                 if(head.team == NUM_TEAM_1)
1959                         team1_score = 1;
1960                 else if(head.team == NUM_TEAM_2)
1961                         team2_score = 1;
1962                 else if(head.team == NUM_TEAM_3)
1963                         team3_score = 1;
1964                 else if(head.team == NUM_TEAM_4)
1965                         team4_score = 1;
1966         }
1967
1968         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1969         {
1970                 if(head.team == NUM_TEAM_1)
1971                         team1_score = 1;
1972                 else if(head.team == NUM_TEAM_2)
1973                         team2_score = 1;
1974                 else if(head.team == NUM_TEAM_3)
1975                         team3_score = 1;
1976                 else if(head.team == NUM_TEAM_4)
1977                         team4_score = 1;
1978         }
1979
1980         ClearWinners();
1981         if(team1_score + team2_score + team3_score + team4_score == 0)
1982         {
1983                 checkrules_equality = true;
1984                 return WINNING_YES;
1985         }
1986         else if(team1_score + team2_score + team3_score + team4_score == 1)
1987         {
1988                 float t, i;
1989                 if(team1_score)
1990                         t = NUM_TEAM_1;
1991                 else if(team2_score)
1992                         t = NUM_TEAM_2;
1993                 else if(team3_score)
1994                         t = NUM_TEAM_3;
1995                 else // if(team4_score)
1996                         t = NUM_TEAM_4;
1997                 CheckAllowedTeams(world);
1998                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1999                 {
2000                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2001                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2002                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2003                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2004                 }
2005
2006                 AddWinners(team, t);
2007                 return WINNING_YES;
2008         }
2009         else
2010                 return WINNING_NO;
2011 }
2012
2013 /*
2014 ============
2015 CheckRules_World
2016
2017 Exit deathmatch games upon conditions
2018 ============
2019 */
2020 void CheckRules_World()
2021 {
2022         float timelimit;
2023         float fraglimit;
2024         float leadlimit;
2025
2026         VoteThink();
2027         MapVote_Think();
2028
2029         SetDefaultAlpha();
2030
2031         if (gameover)   // someone else quit the game already
2032         {
2033                 if(player_count == 0) // Nobody there? Then let's go to the next map
2034                         MapVote_Start();
2035                         // this will actually check the player count in the next frame
2036                         // again, but this shouldn't hurt
2037                 return;
2038         }
2039
2040         timelimit = autocvar_timelimit * 60;
2041         fraglimit = autocvar_fraglimit;
2042         leadlimit = autocvar_leadlimit;
2043
2044         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2045         {
2046                 if(timelimit > 0)
2047                         timelimit = 0; // timelimit is not made for warmup
2048                 if(fraglimit > 0)
2049                         fraglimit = 0; // no fraglimit for now
2050                 leadlimit = 0; // no leadlimit for now
2051         }
2052
2053         if(timelimit > 0)
2054         {
2055                 timelimit += game_starttime;
2056         }
2057         else if (timelimit < 0)
2058         {
2059                 // endmatch
2060                 NextLevel();
2061                 return;
2062         }
2063
2064         float wantovertime;
2065         wantovertime = 0;
2066
2067         if(timelimit > game_starttime)
2068                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2069         else
2070                 game_completion_ratio = 0;
2071
2072         if(checkrules_suddendeathend)
2073         {
2074                 if(!checkrules_suddendeathwarning)
2075                 {
2076                         checkrules_suddendeathwarning = true;
2077                         if(g_race && !g_race_qualifying)
2078                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2079                         else
2080                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2081                 }
2082         }
2083         else
2084         {
2085                 if (timelimit && time >= timelimit)
2086                 {
2087                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2088                         {
2089                                 float totalplayers;
2090                                 float playerswithlaps;
2091                                 float readyplayers;
2092                                 entity head;
2093                                 totalplayers = playerswithlaps = readyplayers = 0;
2094                                 FOR_EACH_PLAYER(head)
2095                                 {
2096                                         ++totalplayers;
2097                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2098                                                 ++playerswithlaps;
2099                                         if(head.ready)
2100                                                 ++readyplayers;
2101                                 }
2102
2103                                 // at least 2 of the players have completed a lap: start the RACE
2104                                 // otherwise, the players should end the qualifying on their own
2105                                 if(readyplayers || playerswithlaps >= 2)
2106                                 {
2107                                         checkrules_suddendeathend = 0;
2108                                         ReadyRestart(); // go to race
2109                                         return;
2110                                 }
2111                                 else
2112                                         wantovertime |= InitiateSuddenDeath();
2113                         }
2114                         else
2115                                 wantovertime |= InitiateSuddenDeath();
2116                 }
2117         }
2118
2119         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2120         {
2121                 NextLevel();
2122                 return;
2123         }
2124
2125         float checkrules_status;
2126         checkrules_status = WinningCondition_RanOutOfSpawns();
2127         if(checkrules_status == WINNING_YES)
2128         {
2129                 bprint("Hey! Someone ran out of spawns!\n");
2130         }
2131         else if(g_race && !g_race_qualifying && timelimit >= 0)
2132         {
2133                 checkrules_status = WinningCondition_Race(fraglimit);
2134                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2135         }
2136         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2137         {
2138                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2139                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2140         }
2141         else if(g_assault)
2142         {
2143                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2144         }
2145         else if(g_lms)
2146         {
2147                 checkrules_status = WinningCondition_LMS();
2148         }
2149         else
2150         {
2151                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2152                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2153         }
2154
2155         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2156         {
2157                 checkrules_status = WINNING_NEVER;
2158                 checkrules_overtimesadded = -1;
2159                 wantovertime |= InitiateSuddenDeath();
2160         }
2161
2162         if(checkrules_status == WINNING_NEVER)
2163                 // equality cases! Nobody wins if the overtime ends in a draw.
2164                 ClearWinners();
2165
2166         if(wantovertime)
2167         {
2168                 if(checkrules_status == WINNING_NEVER)
2169                         InitiateOvertime();
2170                 else
2171                         checkrules_status = WINNING_YES;
2172         }
2173
2174         if(checkrules_suddendeathend)
2175                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2176                         checkrules_status = WINNING_YES;
2177
2178         if(checkrules_status == WINNING_YES)
2179         {
2180                 //print("WINNING\n");
2181                 NextLevel();
2182         }
2183 }
2184
2185 string GotoMap(string m)
2186 {
2187         m = GameTypeVote_MapInfo_FixName(m);
2188         if (!m)
2189                 return "The map you suggested is not available on this server.";
2190         if (!autocvar_sv_vote_gametype)
2191         if(!MapInfo_CheckMap(m))
2192                 return "The map you suggested does not support the current game mode.";
2193         cvar_set("nextmap", m);
2194         cvar_set("timelimit", "-1");
2195         if(mapvote_initialized || alreadychangedlevel)
2196         {
2197                 if(DoNextMapOverride(0))
2198                         return "Map switch initiated.";
2199                 else
2200                         return "Hm... no. For some reason I like THIS map more.";
2201         }
2202         else
2203                 return "Map switch will happen after scoreboard.";
2204 }
2205
2206
2207 void EndFrame()
2208 {
2209         anticheat_endframe();
2210
2211         float altime;
2212         FOR_EACH_REALCLIENT(self)
2213         {
2214                 entity e = IS_SPEC(self) ? self.enemy : self;
2215                 if(e.typehitsound)
2216                         self.typehit_time = time;
2217                 else if(e.damage_dealt)
2218                 {
2219                         self.hit_time = time;
2220                         self.damage_dealt_total += ceil(e.damage_dealt);
2221                 }
2222         }
2223         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2224         // add 1 frametime because after this, engine SV_Physics
2225         // increases time by a frametime and then networks the frame
2226         // add another frametime because client shows everything with
2227         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2228         // needed!
2229         FOR_EACH_CLIENT(self)
2230         {
2231                 self.typehitsound = false;
2232                 self.damage_dealt = 0;
2233                 antilag_record(self, altime);
2234         }
2235         FOR_EACH_MONSTER(self)
2236                 antilag_record(self, altime);
2237 }
2238
2239
2240 /*
2241  * RedirectionThink:
2242  * returns true if redirecting
2243  */
2244 float redirection_timeout;
2245 float redirection_nextthink;
2246 float RedirectionThink()
2247 {
2248         float clients_found;
2249
2250         if(redirection_target == "")
2251                 return false;
2252
2253         if(!redirection_timeout)
2254         {
2255                 cvar_set("sv_public", "-2");
2256                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2257                 if(redirection_target == "self")
2258                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2259                 else
2260                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2261         }
2262
2263         if(time < redirection_nextthink)
2264                 return true;
2265
2266         redirection_nextthink = time + 1;
2267
2268         clients_found = 0;
2269         FOR_EACH_REALCLIENT(self)
2270         {
2271                 // TODO add timer
2272                 print("Redirecting: sending connect command to ", self.netname, "\n");
2273                 if(redirection_target == "self")
2274                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2275                 else
2276                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2277                 ++clients_found;
2278         }
2279
2280         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2281
2282         if(time > redirection_timeout || clients_found == 0)
2283                 localcmd("\nwait; wait; wait; quit\n");
2284
2285         return true;
2286 }
2287
2288 void TargetMusic_RestoreGame();
2289 void RestoreGame()
2290 {
2291         // Loaded from a save game
2292         // some things then break, so let's work around them...
2293
2294         // Progs DB (capture records)
2295         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2296
2297         // Mapinfo
2298         MapInfo_Shutdown();
2299         MapInfo_Enumerate();
2300         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2301         WeaponStats_Init();
2302
2303         TargetMusic_RestoreGame();
2304 }
2305
2306 void Shutdown()
2307 {
2308         gameover = 2;
2309
2310         if(world_initialized > 0)
2311         {
2312                 world_initialized = 0;
2313                 print("Saving persistent data...\n");
2314                 Ban_SaveBans();
2315
2316                 // playerstats with unfinished match
2317                 PlayerStats_GameReport(false);
2318
2319                 if(!cheatcount_total)
2320                 {
2321                         if(autocvar_sv_db_saveasdump)
2322                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2323                         else
2324                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2325                 }
2326                 if(autocvar_developer)
2327                 {
2328                         if(autocvar_sv_db_saveasdump)
2329                                 db_dump(TemporaryDB, "server-temp.db");
2330                         else
2331                                 db_save(TemporaryDB, "server-temp.db");
2332                 }
2333                 CheatShutdown(); // must be after cheatcount check
2334                 db_close(ServerProgsDB);
2335                 db_close(TemporaryDB);
2336                 print("done!\n");
2337                 // tell the bot system the game is ending now
2338                 bot_endgame();
2339
2340                 WeaponStats_Shutdown();
2341                 MapInfo_Shutdown();
2342         }
2343         else if(world_initialized == 0)
2344         {
2345                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2346         }
2347 }