qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist()
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 557         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 558
 559         MapInfo_Enumerate();
 560         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 561 }
 562
 563 void Map_MarkAsRecent(string m);
 564 float world_already_spawned;
 565 void Nagger_Init();
 566 void ClientInit_Spawn();
 567 void WeaponStats_Init();
 568 void WeaponStats_Shutdown();
 569 void spawnfunc_worldspawn (void)
 570 {
 571         float fd, l, i, j, n;
 572         string s, col;
 573
 574         cvar = cvar_normal;
 575         cvar_string = cvar_string_normal;
 576         cvar_set = cvar_set_normal;
 577
 578         if(world_already_spawned)
 579                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 580         world_already_spawned = TRUE;
 581
 582         remove = remove_safely; // during spawning, watch what you remove!
 583
 584         check_unacceptable_compiler_bugs();
 585
 586         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 587
 588         compressShortVector_init();
 589
 590         allowed_to_spawn = TRUE;
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         // needs to be done so early because of the constants they create
 602         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 603         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 604         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 605         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 606
 607         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 608
 609         TemporaryDB = db_create();
 610
 611         // 0 normal
 612         lightstyle(0, "m");
 613
 614         // 1 FLICKER (first variety)
 615         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 616
 617         // 2 SLOW STRONG PULSE
 618         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 619
 620         // 3 CANDLE (first variety)
 621         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 622
 623         // 4 FAST STROBE
 624         lightstyle(4, "mamamamamama");
 625
 626         // 5 GENTLE PULSE 1
 627         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 628
 629         // 6 FLICKER (second variety)
 630         lightstyle(6, "nmonqnmomnmomomno");
 631
 632         // 7 CANDLE (second variety)
 633         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 634
 635         // 8 CANDLE (third variety)
 636         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 637
 638         // 9 SLOW STROBE (fourth variety)
 639         lightstyle(9, "aaaaaaaazzzzzzzz");
 640
 641         // 10 FLUORESCENT FLICKER
 642         lightstyle(10, "mmamammmmammamamaaamammma");
 643
 644         // 11 SLOW PULSE NOT FADE TO BLACK
 645         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 646
 647         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 648
 649         // 63 testing
 650         lightstyle(63, "a");
 651
 652         if(autocvar_g_campaign)
 653                 CampaignPreInit();
 654
 655         Map_MarkAsRecent(mapname);
 656
 657         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 658
 659         precache_model ("null"); // we need this one before InitGameplayMode
 660         InitGameplayMode();
 661         readlevelcvars();
 662         GrappleHookInit();
 663         ElectroInit();
 664         LaserInit();
 665
 666         player_count = 0;
 667         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 668         if(bot_waypoints_for_items == 1)
 669                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 670                         bot_waypoints_for_items = 0;
 671
 672         precache();
 673
 674         WaypointSprite_Init();
 675
 676         //if (g_domination)
 677         //      dom_init();
 678
 679         GameLogInit(); // prepare everything
 680         // NOTE for matchid:
 681         // changing the logic generating it is okay. But:
 682         // it HAS to stay <= 64 chars
 683         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 684         if(autocvar_sv_eventlog)
 685         {
 686                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 687                 matchid = strzone(s);
 688
 689                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 690                 s = ":gameinfo:mutators:LIST";
 691
 692                 ret_string = s;
 693                 MUTATOR_CALLHOOK(BuildMutatorsString);
 694                 s = ret_string;
 695
 696                 // simple, probably not good in the mutator system
 697                 if(autocvar_g_grappling_hook)
 698                         s = strcat(s, ":grappling_hook");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(!autocvar_g_use_ammunition)
 702                         s = strcat(s, ":no_use_ammunition");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_pickup_items == 0)
 706                         s = strcat(s, ":no_pickup_items");
 707                 if(autocvar_g_pickup_items > 0)
 708                         s = strcat(s, ":pickup_items");
 709
 710                 // initialiation stuff, not good in the mutator system
 711                 if(autocvar_g_weaponarena != "0")
 712                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 713
 714                 // TODO to mutator system
 715                 if(autocvar_g_norecoil)
 716                         s = strcat(s, ":norecoil");
 717
 718                 // TODO to mutator system
 719                 if(autocvar_g_midair)
 720                         s = strcat(s, ":midair");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_minstagib)
 724                         s = strcat(s, ":minstagib");
 725
 726                 // TODO to mutator system
 727                 if(autocvar_g_powerups == 0)
 728                         s = strcat(s, ":no_powerups");
 729                 if(autocvar_g_powerups > 0)
 730                         s = strcat(s, ":powerups");
 731
 732                 GameLogEcho(s);
 733                 GameLogEcho(":gameinfo:end");
 734         }
 735         else
 736                 matchid = strzone(ftos(random()));
 737
 738         cvar_set("nextmap", "");
 739
 740         SetDefaultAlpha();
 741
 742         if(autocvar_g_campaign)
 743                 CampaignPostInit();
 744
 745         fteqcc_testbugs();
 746
 747         Ban_LoadBans();
 748
 749         MapInfo_Enumerate();
 750         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 751
 752         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 753         {
 754                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 755                 if(fd != -1)
 756                 {
 757                         while((s = fgets(fd)))
 758                         {
 759                                 l = tokenize_console(s);
 760                                 if(l < 2)
 761                                         continue;
 762                                 if(argv(0) == "cd")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 765                                         print("  cdtrack ", argv(2), "\n");
 766                                 }
 767                                 else if(argv(0) == "fog")
 768                                 {
 769                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 770                                         print("  \"fog\" \"", s, "\"\n");
 771                                 }
 772                                 else if(argv(0) == "set")
 773                                 {
 774                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 775                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 776                                 }
 777                                 else if(argv(0) != "//")
 778                                 {
 779                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 780                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 781                                 }
 782                         }
 783                         fclose(fd);
 784                 }
 785         }
 786
 787         WeaponStats_Init();
 788
 789         WEPSET_ADDSTAT();
 790         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 791         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 792         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 793         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 794         Nagger_Init();
 795
 796         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 797         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 798         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 799         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 800         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 801         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 802         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 803         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 804         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 807         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 808         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 809
 810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 811         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 812
 813         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 814
 815         if(g_ca || g_freezetag)
 816         {
 817                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 818                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 819                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 820                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 821         }
 822         if(g_freezetag)
 823         {
 824                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 825                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 826         }
 827
 828         // g_movementspeed hack
 829         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 830         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 831         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 832         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 833
 834         // secrets
 835         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 836         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 837
 838         // misc
 839         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 840
 841         next_pingtime = time + 5;
 842
 843         detect_maptype();
 844
 845         // set up information replies for clients and server to use
 846         lsmaps_reply = "^7Maps available: ";
 847         lsnewmaps_reply = "^7Maps without a record set: ";
 848         for(i = 0, j = 0; i < MapInfo_count; ++i)
 849         {
 850                 if(MapInfo_Get_ByID(i))
 851                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 852                         {
 853                                 if(mod(i, 2))
 854                                         col = "^2";
 855                                 else
 856                                         col = "^3";
 857
 858                                 ++j;
 859
 860                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 861
 862                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 863                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 864                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 865                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 866                         }
 867         }
 868
 869         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 870         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 871
 872         maplist_reply = "^7Maps in list: ";
 873         n = tokenize_console(autocvar_g_maplist);
 874         for(i = 0, j = 0; i < n; ++i)
 875         {
 876                 if(MapInfo_CheckMap(argv(i)))
 877                 {
 878                         if(mod(j, 2))
 879                                 col = "^2";
 880                         else
 881                                 col = "^3";
 882                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 883                         ++j;
 884                 }
 885         }
 886         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 887         MapInfo_ClearTemps();
 888
 889         for(i = 0; i < 10; ++i)
 890         {
 891                 s = getrecords(i);
 892                 if (s)
 893                         records_reply[i] = strzone(s);
 894         }
 895
 896         ladder_reply = strzone(getladder());
 897
 898         rankings_reply = strzone(getrankings());
 899
 900         // begin other init
 901         ClientInit_Spawn();
 902         RandomSeed_Spawn();
 903         PingPLReport_Spawn();
 904
 905         CheatInit();
 906
 907         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 908
 909         // fill sv_curl_serverpackages from .serverpackage files
 910         if(autocvar_sv_curl_serverpackages_auto)
 911         {
 912                 s = "";
 913                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 914                 for(i = 0; i < n; ++i)
 915                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 916                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 917                                 s = strcat(s, " ", argv(i));
 918                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 919                 if(fd >= 0)
 920                 {
 921                         j = search_getsize(fd);
 922                         for(i = 0; i < j; ++i)
 923                                 s = strcat(s, " ", search_getfilename(fd, i));
 924                         search_end(fd);
 925                 }
 926                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 927                 if(fd >= 0)
 928                 {
 929                         j = search_getsize(fd);
 930                         for(i = 0; i < j; ++i)
 931                                 s = strcat(s, " ", search_getfilename(fd, i));
 932                         search_end(fd);
 933                 }
 934                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 935         }
 936
 937         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 938         modname = "Xonotic";
 939         // physics/balance/config changes that count as mod
 940         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 941                 modname = cvar_string("g_mod_physics");
 942         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 943                 modname = cvar_string("g_mod_balance");
 944         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 945                 modname = cvar_string("g_mod_config");
 946         // weird mutators that deserve to count as mod
 947         if(autocvar_g_minstagib)
 948                 modname = "MinstaGib";
 949         // extra mutators that deserve to count as mod
 950         MUTATOR_CALLHOOK(SetModname);
 951         // weird game types that deserve to count as mod
 952         if(g_cts)
 953                 modname = "CTS";
 954         // save it for later
 955         modname = strzone(modname);
 956
 957         WinningConditionHelper(); // set worldstatus
 958
 959         world_initialized = 1;
 960 }
 961
 962 void spawnfunc_light (void)
 963 {
 964         //makestatic (self); // Who the f___ did that?
 965         remove(self);
 966 }
 967
 968 string GetGametype()
 969 {
 970         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 971 }
 972
 973 string getmapname_stored;
 974 string GetMapname()
 975 {
 976         return mapname;
 977 }
 978
 979 float Map_Count, Map_Current;
 980 string Map_Current_Name;
 981
 982 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 983 float GetMaplistPosition()
 984 {
 985         float pos, idx;
 986         string map;
 987
 988         map = GetMapname();
 989         idx = autocvar_g_maplist_index;
 990
 991         if(idx >= 0)
 992                 if(idx < Map_Count)
 993                         if(map == argv(idx))
 994                                 return idx;
 995
 996         for(pos = 0; pos < Map_Count; ++pos)
 997                 if(map == argv(pos))
 998                         return pos;
 999
1000         // resume normal maplist rotation if current map is not in g_maplist
1001         return idx;
1002 }
1003
1004 float MapHasRightSize(string map)
1005 {
1006         float fh;
1007         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1008         if(autocvar_g_maplist_check_waypoints)
1009         {
1010                 dprint("checkwp "); dprint(map);
1011                 if(!fexists(strcat("maps/", map, ".waypoints")))
1012                 {
1013                         dprint(": no waypoints\n");
1014                         return FALSE;
1015                 }
1016                 dprint(": has waypoints\n");
1017         }
1018
1019         // open map size restriction file
1020         dprint("opensize "); dprint(map);
1021         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1022         if(fh >= 0)
1023         {
1024                 float mapmin, mapmax;
1025                 dprint(": ok, ");
1026                 mapmin = stof(fgets(fh));
1027                 mapmax = stof(fgets(fh));
1028                 fclose(fh);
1029                 if(player_count < mapmin)
1030                 {
1031                         dprint("not enough\n");
1032                         return FALSE;
1033                 }
1034                 if(player_count > mapmax)
1035                 {
1036                         dprint("too many\n");
1037                         return FALSE;
1038                 }
1039                 dprint("right size\n");
1040                 return TRUE;
1041         }
1042         dprint(": not found\n");
1043         return TRUE;
1044 }
1045
1046 string Map_Filename(float position)
1047 {
1048         return strcat("maps/", argv(position), ".bsp");
1049 }
1050
1051 string strwords(string s, float w)
1052 {
1053         float endpos;
1054         for(endpos = 0; w && endpos >= 0; --w)
1055                 endpos = strstrofs(s, " ", endpos + 1);
1056         if(endpos < 0)
1057                 return s;
1058         else
1059                 return substring(s, 0, endpos);
1060 }
1061
1062 float strhasword(string s, string w)
1063 {
1064         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1065 }
1066
1067 void Map_MarkAsRecent(string m)
1068 {
1069         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1070 }
1071
1072 float Map_IsRecent(string m)
1073 {
1074         return strhasword(autocvar_g_maplist_mostrecent, m);
1075 }
1076
1077 float Map_Check(float position, float pass)
1078 {
1079         string filename;
1080         string map_next;
1081         map_next = argv(position);
1082         if(pass <= 1)
1083         {
1084                 if(Map_IsRecent(map_next))
1085                         return 0;
1086         }
1087         filename = Map_Filename(position);
1088         if(MapInfo_CheckMap(map_next))
1089         {
1090                 if(pass == 2)
1091                         return 1;
1092                 if(MapHasRightSize(map_next))
1093                         return 1;
1094                 return 0;
1095         }
1096         else
1097                 dprint( "Couldn't select '", filename, "'..\n" );
1098
1099         return 0;
1100 }
1101
1102 void Map_Goto_SetStr(string nextmapname)
1103 {
1104         if(getmapname_stored != "")
1105                 strunzone(getmapname_stored);
1106         if(nextmapname == "")
1107                 getmapname_stored = "";
1108         else
1109                 getmapname_stored = strzone(nextmapname);
1110 }
1111
1112 void Map_Goto_SetFloat(float position)
1113 {
1114         cvar_set("g_maplist_index", ftos(position));
1115         Map_Goto_SetStr(argv(position));
1116 }
1117
1118 void Map_Goto(float reinit)
1119 {
1120         MapInfo_LoadMap(getmapname_stored, reinit);
1121 }
1122
1123 // return codes of map selectors:
1124 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1125 //   -2 = permanent failure
1126 float() MaplistMethod_Iterate = // usual method
1127 {
1128         float pass, i;
1129
1130         for(pass = 1; pass <= 2; ++pass)
1131         {
1132                 for(i = 1; i < Map_Count; ++i)
1133                 {
1134                         float mapindex;
1135                         mapindex = mod(i + Map_Current, Map_Count);
1136                         if(Map_Check(mapindex, pass))
1137                                 return mapindex;
1138                 }
1139         }
1140         return -1;
1141 }
1142
1143 float() MaplistMethod_Repeat = // fallback method
1144 {
1145         if(Map_Check(Map_Current, 2))
1146                 return Map_Current;
1147         return -2;
1148 }
1149
1150 float() MaplistMethod_Random = // random map selection
1151 {
1152         float i, imax;
1153
1154         imax = 42;
1155
1156         for(i = 0; i <= imax; ++i)
1157         {
1158                 float mapindex;
1159                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1160                 if(Map_Check(mapindex, 1))
1161                         return mapindex;
1162         }
1163         return -1;
1164 }
1165
1166 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1167 // the exponent sets a bias on the map selection:
1168 // the higher the exponent, the less likely "shortly repeated" same maps are
1169 {
1170         float i, j, imax, insertpos;
1171
1172         imax = 42;
1173
1174         for(i = 0; i <= imax; ++i)
1175         {
1176                 string newlist;
1177
1178                 // now reinsert this at another position
1179                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1180                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1181                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1182                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1183
1184                 // insert the current map there
1185                 newlist = "";
1186                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1187                         newlist = strcat(newlist, " ", argv(j));
1188                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1189                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1190                         newlist = strcat(newlist, " ", argv(j));
1191                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1192                 cvar_set("g_maplist", newlist);
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194
1195                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1196                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1197                 if(Map_Check(Map_Current, 1))
1198                         return Map_Current;
1199         }
1200         return -1;
1201 }
1202
1203 void Maplist_Init()
1204 {
1205         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1206         if(Map_Count == 0)
1207         {
1208                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1209                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1210                 if(autocvar_g_maplist_shuffle)
1211                         ShuffleMaplist();
1212                 localcmd("\nmenu_cmd sync\n");
1213                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1214         }
1215         if(Map_Count == 0)
1216                 error("empty maplist, cannot select a new map");
1217         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1218
1219         if(Map_Current_Name)
1220                 strunzone(Map_Current_Name);
1221         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1222         // this may or may not be correct, but who cares, in the worst case a map
1223         // isn't chosen in the first pass that should have been
1224 }
1225
1226 string GetNextMap()
1227 {
1228         float nextMap;
1229
1230         Maplist_Init();
1231         nextMap = -1;
1232
1233         if(nextMap == -1)
1234                 if(autocvar_g_maplist_shuffle > 0)
1235                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1236
1237         if(nextMap == -1)
1238                 if(autocvar_g_maplist_selectrandom)
1239                         nextMap = MaplistMethod_Random();
1240
1241         if(nextMap == -1)
1242                 nextMap = MaplistMethod_Iterate();
1243
1244         if(nextMap == -1)
1245                 nextMap = MaplistMethod_Repeat();
1246
1247         if(nextMap >= 0)
1248         {
1249                 Map_Goto_SetFloat(nextMap);
1250                 return getmapname_stored;
1251         }
1252
1253         return "";
1254 }
1255
1256 float DoNextMapOverride(float reinit)
1257 {
1258         if(autocvar_g_campaign)
1259         {
1260                 CampaignPostIntermission();
1261                 alreadychangedlevel = TRUE;
1262                 return TRUE;
1263         }
1264         if(autocvar_quit_when_empty)
1265         {
1266                 if(player_count <= currentbots)
1267                 {
1268                         localcmd("quit\n");
1269                         alreadychangedlevel = TRUE;
1270                         return TRUE;
1271                 }
1272         }
1273         if(autocvar_quit_and_redirect != "")
1274         {
1275                 redirection_target = strzone(autocvar_quit_and_redirect);
1276                 alreadychangedlevel = TRUE;
1277                 return TRUE;
1278         }
1279         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1280         {
1281                 localcmd("restart\n");
1282                 alreadychangedlevel = TRUE;
1283                 return TRUE;
1284         }
1285         if(autocvar_nextmap != "")
1286                 if(MapInfo_CheckMap(autocvar_nextmap))
1287                 {
1288                         Map_Goto_SetStr(autocvar_nextmap);
1289                         Map_Goto(reinit);
1290                         alreadychangedlevel = TRUE;
1291                         return TRUE;
1292                 }
1293         if(!reinit && autocvar_lastlevel)
1294         {
1295                 cvar_settemp_restore();
1296                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1297                 alreadychangedlevel = TRUE;
1298                 return TRUE;
1299         }
1300         return FALSE;
1301 }
1302
1303 void GotoNextMap(float reinit)
1304 {
1305         //string nextmap;
1306         //float n, nummaps;
1307         //string s;
1308         if (alreadychangedlevel)
1309                 return;
1310         alreadychangedlevel = TRUE;
1311
1312         {
1313                 string nextMap;
1314                 float allowReset;
1315
1316                 for(allowReset = 1; allowReset >= 0; --allowReset)
1317                 {
1318                         nextMap = GetNextMap();
1319                         if(nextMap != "")
1320                                 break;
1321
1322                         if(allowReset)
1323                         {
1324                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1325                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1326                                 if(autocvar_g_maplist_shuffle)
1327                                         ShuffleMaplist();
1328                                 localcmd("\nmenu_cmd sync\n");
1329                         }
1330                         else
1331                         {
1332                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1333                         }
1334                 }
1335                 Map_Goto(reinit);
1336         }
1337 }
1338
1339
1340 /*
1341 ============
1342 IntermissionThink
1343
1344 When the player presses attack or jump, change to the next level
1345 ============
1346 */
1347 .float autoscreenshot;
1348 void() MapVote_Start;
1349 void() MapVote_Think;
1350 float mapvote_initialized;
1351 void IntermissionThink()
1352 {
1353         FixIntermissionClient(self);
1354
1355         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1356         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1357
1358         if( (server_screenshot || client_screenshot)
1359                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1360         {
1361                 self.autoscreenshot = -1;
1362                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1363                 return;
1364         }
1365
1366         if (time < intermission_exittime)
1367                 return;
1368
1369         if(!mapvote_initialized)
1370                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1371                         return;
1372
1373         MapVote_Start();
1374 }
1375
1376 /*
1377 ============
1378 FindIntermission
1379
1380 Returns the entity to view from
1381 ============
1382 */
1383 /*
1384 entity FindIntermission()
1385 {
1386         local   entity spot;
1387         local   float cyc;
1388
1389 // look for info_intermission first
1390         spot = find (world, classname, "info_intermission");
1391         if (spot)
1392         {       // pick a random one
1393                 cyc = random() * 4;
1394                 while (cyc > 1)
1395                 {
1396                         spot = find (spot, classname, "info_intermission");
1397                         if (!spot)
1398                                 spot = find (spot, classname, "info_intermission");
1399                         cyc = cyc - 1;
1400                 }
1401                 return spot;
1402         }
1403
1404 // then look for the start position
1405         spot = find (world, classname, "info_player_start");
1406         if (spot)
1407                 return spot;
1408
1409 // testinfo_player_start is only found in regioned levels
1410         spot = find (world, classname, "testplayerstart");
1411         if (spot)
1412                 return spot;
1413
1414 // then look for the start position
1415         spot = find (world, classname, "info_player_deathmatch");
1416         if (spot)
1417                 return spot;
1418
1419         //objerror ("FindIntermission: no spot");
1420         return world;
1421 }
1422 */
1423
1424 /*
1425 ===============================================================================
1426
1427 RULES
1428
1429 ===============================================================================
1430 */
1431
1432 void DumpStats(float final)
1433 {
1434         float file;
1435         string s;
1436         float to_console;
1437         float to_eventlog;
1438         float to_file;
1439         float i;
1440
1441         to_console = autocvar_sv_logscores_console;
1442         to_eventlog = autocvar_sv_eventlog;
1443         to_file = autocvar_sv_logscores_file;
1444
1445         if(!final)
1446         {
1447                 to_console = TRUE; // always print printstats replies
1448                 to_eventlog = FALSE; // but never print them to the event log
1449         }
1450
1451         if(to_eventlog)
1452                 if(autocvar_sv_eventlog_console)
1453                         to_console = FALSE; // otherwise we get the output twice
1454
1455         if(final)
1456                 s = ":scores:";
1457         else
1458                 s = ":status:";
1459         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1460
1461         if(to_console)
1462                 print(s, "\n");
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465
1466         file = -1;
1467         if(to_file)
1468         {
1469                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1470                 if(file == -1)
1471                         to_file = FALSE;
1472                 else
1473                         fputs(file, strcat(s, "\n"));
1474         }
1475
1476         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1477         if(to_console)
1478                 print(s, "\n");
1479         if(to_eventlog)
1480                 GameLogEcho(s);
1481         if(to_file)
1482                 fputs(file, strcat(s, "\n"));
1483
1484         FOR_EACH_CLIENT(other)
1485         {
1486                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1487                 {
1488                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1489                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1490                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1491                                 s = strcat(s, ftos(other.team), ":");
1492                         else
1493                                 s = strcat(s, "spectator:");
1494
1495                         if(to_console)
1496                                 print(s, other.netname, "\n");
1497                         if(to_eventlog)
1498                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1499                         if(to_file)
1500                                 fputs(file, strcat(s, other.netname, "\n"));
1501                 }
1502         }
1503
1504         if(teamplay)
1505         {
1506                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1507                 if(to_console)
1508                         print(s, "\n");
1509                 if(to_eventlog)
1510                         GameLogEcho(s);
1511                 if(to_file)
1512                         fputs(file, strcat(s, "\n"));
1513
1514                 for(i = 1; i < 16; ++i)
1515                 {
1516                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1517                         s = strcat(s, ":", ftos(i));
1518                         if(to_console)
1519                                 print(s, "\n");
1520                         if(to_eventlog)
1521                                 GameLogEcho(s);
1522                         if(to_file)
1523                                 fputs(file, strcat(s, "\n"));
1524                 }
1525         }
1526
1527         if(to_console)
1528                 print(":end\n");
1529         if(to_eventlog)
1530                 GameLogEcho(":end");
1531         if(to_file)
1532         {
1533                 fputs(file, ":end\n");
1534                 fclose(file);
1535         }
1536 }
1537
1538 void FixIntermissionClient(entity e)
1539 {
1540         string s;
1541         if(!e.autoscreenshot) // initial call
1542         {
1543                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1544                 e.health = -2342;
1545                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1546                 e.solid = SOLID_NOT;
1547                 e.movetype = MOVETYPE_NONE;
1548                 e.takedamage = DAMAGE_NO;
1549                 if(e.weaponentity)
1550                 {
1551                         e.weaponentity.effects = EF_NODRAW;
1552                         if (e.weaponentity.weaponentity)
1553                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1554                 }
1555                 if(clienttype(e) == CLIENTTYPE_REAL)
1556                 {
1557                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1558                         s = autocvar_sv_intermission_cdtrack;
1559                         if(s != "")
1560                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1561                         msg_entity = e;
1562                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1563                 }
1564         }
1565 }
1566
1567 void minstagib_stop_countdown(entity e);
1568 /*
1569 go to the next level for deathmatch
1570 only called if a time or frag limit has expired
1571 */
1572 void NextLevel()
1573 {
1574         gameover = TRUE;
1575
1576         intermission_running = 1;
1577
1578 // enforce a wait time before allowing changelevel
1579         if(player_count > 0)
1580                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1581         else
1582                 intermission_exittime = -1;
1583
1584         /*
1585         WriteByte (MSG_ALL, SVC_CDTRACK);
1586         WriteByte (MSG_ALL, 3);
1587         WriteByte (MSG_ALL, 3);
1588         // done in FixIntermission
1589         */
1590
1591         //pos = FindIntermission ();
1592
1593         VoteReset();
1594
1595         DumpStats(TRUE);
1596
1597         // send statistics
1598         entity e;
1599         PlayerStats_EndMatch(1);
1600         FOR_EACH_CLIENT(e)
1601                 PlayerStats_AddGlobalInfo(e);
1602         PlayerStats_Shutdown();
1603         WeaponStats_Shutdown();
1604
1605         if(autocvar_sv_eventlog)
1606                 GameLogEcho(":gameover");
1607
1608         GameLogClose();
1609
1610         FOR_EACH_PLAYER(other) {
1611                 minstagib_stop_countdown(other);
1612                 FixIntermissionClient(other);
1613                 if(other.winning)
1614                         bprint(other.netname, " ^7wins.\n");
1615         }
1616
1617         if(autocvar_g_campaign)
1618                 CampaignPreIntermission();
1619
1620         localcmd("\nsv_hook_gameend\n");
1621 }
1622
1623 /*
1624 ============
1625 CheckRules_Player
1626
1627 Exit deathmatch games upon conditions
1628 ============
1629 */
1630 void CheckRules_Player()
1631 {
1632         if (gameover)   // someone else quit the game already
1633                 return;
1634
1635         if(self.deadflag == DEAD_NO)
1636                 self.play_time += frametime;
1637
1638         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1639         //   (div0: and that in CheckRules_World please)
1640 }
1641
1642 float checkrules_equality;
1643 float checkrules_suddendeathwarning;
1644 float checkrules_suddendeathend;
1645 float checkrules_overtimesadded; //how many overtimes have been already added
1646
1647 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1648 float WINNING_YES = 1; // winner found
1649 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1650 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1651
1652 float InitiateSuddenDeath()
1653 {
1654         // Check first whether normal overtimes could be added before initiating suddendeath mode
1655         // - for this timelimit_overtime needs to be >0 of course
1656         // - also check the winning condition calculated in the previous frame and only add normal overtime
1657         //   again, if at the point at which timelimit would be extended again, still no winner was found
1658         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1659         {
1660                 return 1; // need to call InitiateOvertime later
1661         }
1662         else
1663         {
1664                 if(!checkrules_suddendeathend)
1665                 {
1666                         if(autocvar_g_campaign)
1667                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1668                         else
1669                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1670                         if(g_race && !g_race_qualifying)
1671                                 race_StartCompleting();
1672                 }
1673                 return 0;
1674         }
1675 }
1676
1677 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1678 {
1679         ++checkrules_overtimesadded;
1680         //add one more overtime by simply extending the timelimit
1681         float tl;
1682         tl = autocvar_timelimit;
1683         tl += autocvar_timelimit_overtime;
1684         cvar_set("timelimit", ftos(tl));
1685         string minutesPlural;
1686         if (autocvar_timelimit_overtime == 1)
1687                 minutesPlural = " ^3minute";
1688         else
1689                 minutesPlural = " ^3minutes";
1690
1691         bcenterprint(
1692                 strcat(
1693                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1694                         ftos(autocvar_timelimit_overtime),
1695                         minutesPlural,
1696                         " to the game!"
1697                 )
1698         );
1699 }
1700
1701 float GetWinningCode(float fraglimitreached, float equality)
1702 {
1703         if(autocvar_g_campaign == 1)
1704                 if(fraglimitreached)
1705                         return WINNING_YES;
1706                 else
1707                         return WINNING_NO;
1708
1709         else
1710                 if(equality)
1711                         if(fraglimitreached)
1712                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1713                         else
1714                                 return WINNING_NEVER;
1715                 else
1716                         if(fraglimitreached)
1717                                 return WINNING_YES;
1718                         else
1719                                 return WINNING_NO;
1720 }
1721
1722 // set the .winning flag for exactly those players with a given field value
1723 void SetWinners(.float field, float value)
1724 {
1725         entity head;
1726         FOR_EACH_PLAYER(head)
1727                 head.winning = (head.field == value);
1728 }
1729
1730 // set the .winning flag for those players with a given field value
1731 void AddWinners(.float field, float value)
1732 {
1733         entity head;
1734         FOR_EACH_PLAYER(head)
1735                 if(head.field == value)
1736                         head.winning = 1;
1737 }
1738
1739 // clear the .winning flags
1740 void ClearWinners(void)
1741 {
1742         entity head;
1743         FOR_EACH_PLAYER(head)
1744                 head.winning = 0;
1745 }
1746
1747 // Onslaught winning condition:
1748 // game terminates if only one team has a working generator (or none)
1749 float WinningCondition_Onslaught()
1750 {
1751         entity head;
1752         float t1, t2, t3, t4;
1753
1754         WinningConditionHelper(); // set worldstatus
1755
1756         if(inWarmupStage)
1757                 return WINNING_NO;
1758
1759         // first check if the game has ended
1760         t1 = t2 = t3 = t4 = 0;
1761         head = find(world, classname, "onslaught_generator");
1762         while (head)
1763         {
1764                 if (head.health > 0)
1765                 {
1766                         if (head.team == FL_TEAM_1) t1 = 1;
1767                         if (head.team == FL_TEAM_2) t2 = 1;
1768                         if (head.team == FL_TEAM_3) t3 = 1;
1769                         if (head.team == FL_TEAM_4) t4 = 1;
1770                 }
1771                 head = find(head, classname, "onslaught_generator");
1772         }
1773         if (t1 + t2 + t3 + t4 < 2)
1774         {
1775                 // game over, only one team remains (or none)
1776                 ClearWinners();
1777                 if (t1) SetWinners(team, FL_TEAM_1);
1778                 if (t2) SetWinners(team, FL_TEAM_2);
1779                 if (t3) SetWinners(team, FL_TEAM_3);
1780                 if (t4) SetWinners(team, FL_TEAM_4);
1781                 dprint("Have a winner, ending game.\n");
1782                 return WINNING_YES;
1783         }
1784
1785         // Two or more teams remain
1786         return WINNING_NO;
1787 }
1788
1789 float LMS_NewPlayerLives()
1790 {
1791         float fl;
1792         fl = autocvar_fraglimit;
1793         if(fl == 0)
1794                 fl = 999;
1795
1796         // first player has left the game for dying too much? Nobody else can get in.
1797         if(lms_lowest_lives < 1)
1798                 return 0;
1799
1800         if(!autocvar_g_lms_join_anytime)
1801                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1802                         return 0;
1803
1804         return bound(1, lms_lowest_lives, fl);
1805 }
1806
1807 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1808 // they win. Otherwise the defending team wins once the timelimit passes.
1809 void assault_new_round();
1810 float WinningCondition_Assault()
1811 {
1812         float status;
1813
1814         WinningConditionHelper(); // set worldstatus
1815
1816         status = WINNING_NO;
1817         // as the timelimit has not yet passed just assume the defending team will win
1818         if(assault_attacker_team == FL_TEAM_1)
1819         {
1820                 SetWinners(team, FL_TEAM_2);
1821         }
1822         else
1823         {
1824                 SetWinners(team, FL_TEAM_1);
1825         }
1826
1827         entity ent;
1828         ent = find(world, classname, "target_assault_roundend");
1829         if(ent)
1830         {
1831                 if(ent.winning) // round end has been triggered by attacking team
1832                 {
1833                         bprint("ASSAULT: round completed...\n");
1834                         SetWinners(team, assault_attacker_team);
1835
1836                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1837
1838                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1839                         {
1840                                 status = WINNING_YES;
1841                         }
1842                         else
1843                         {
1844                                 entity oldself;
1845                                 oldself = self;
1846                                 self = ent;
1847                                 assault_new_round();
1848                                 self = oldself;
1849                         }
1850                 }
1851         }
1852
1853         return status;
1854 }
1855
1856 // LMS winning condition: game terminates if and only if there's at most one
1857 // one player who's living lives. Top two scores being equal cancels the time
1858 // limit.
1859 float WinningCondition_LMS()
1860 {
1861         entity head, head2;
1862         float have_player;
1863         float have_players;
1864         float l;
1865
1866         have_player = FALSE;
1867         have_players = FALSE;
1868         l = LMS_NewPlayerLives();
1869
1870         head = find(world, classname, "player");
1871         if(head)
1872                 have_player = TRUE;
1873         head2 = find(head, classname, "player");
1874         if(head2)
1875                 have_players = TRUE;
1876
1877         if(have_player)
1878         {
1879                 // we have at least one player
1880                 if(have_players)
1881                 {
1882                         // two or more active players - continue with the game
1883                 }
1884                 else
1885                 {
1886                         // exactly one player?
1887
1888                         ClearWinners();
1889                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1890
1891                         if(l)
1892                         {
1893                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1894                                 return WINNING_NO;
1895                         }
1896                         else
1897                         {
1898                                 // a winner!
1899                                 // and assign him his first place
1900                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1901                                 return WINNING_YES;
1902                         }
1903                 }
1904         }
1905         else
1906         {
1907                 // nobody is playing at all...
1908                 if(l)
1909                 {
1910                         // wait for players...
1911                 }
1912                 else
1913                 {
1914                         // SNAFU (maybe a draw game?)
1915                         ClearWinners();
1916                         dprint("No players, ending game.\n");
1917                         return WINNING_YES;
1918                 }
1919         }
1920
1921         // When we get here, we have at least two players who are actually LIVING,
1922         // now check if the top two players have equal score.
1923         WinningConditionHelper();
1924
1925         ClearWinners();
1926         if(WinningConditionHelper_winner)
1927                 WinningConditionHelper_winner.winning = TRUE;
1928         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1929                 return WINNING_NEVER;
1930
1931         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1932         return WINNING_NO;
1933 }
1934
1935 void ShuffleMaplist()
1936 {
1937         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1938 }
1939
1940 float leaderfrags;
1941 float WinningCondition_Scores(float limit, float leadlimit)
1942 {
1943         float limitreached;
1944
1945         // TODO make everything use THIS winning condition (except LMS)
1946         WinningConditionHelper();
1947
1948         if(teamplay)
1949         {
1950                 team1_score = TeamScore_GetCompareValue(FL_TEAM_1);
1951                 team2_score = TeamScore_GetCompareValue(FL_TEAM_2);
1952                 team3_score = TeamScore_GetCompareValue(FL_TEAM_3);
1953                 team4_score = TeamScore_GetCompareValue(FL_TEAM_4);
1954         }
1955
1956         ClearWinners();
1957         if(WinningConditionHelper_winner)
1958                 WinningConditionHelper_winner.winning = 1;
1959         if(WinningConditionHelper_winnerteam >= 0)
1960                 SetWinners(team, WinningConditionHelper_winnerteam);
1961
1962         if(WinningConditionHelper_lowerisbetter)
1963         {
1964                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1965                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1966                 limit = -limit;
1967         }
1968
1969         if(WinningConditionHelper_zeroisworst)
1970                 leadlimit = 0; // not supported in this mode
1971
1972         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1973         // these modes always score in increments of 1, thus this makes sense
1974         {
1975                 if(leaderfrags != WinningConditionHelper_topscore)
1976                 {
1977                         leaderfrags = WinningConditionHelper_topscore;
1978
1979                         if (limit)
1980                         if (leaderfrags == limit - 1)
1981                                 Announce("1fragleft");
1982                         else if (leaderfrags == limit - 2)
1983                                 Announce("2fragsleft");
1984                         else if (leaderfrags == limit - 3)
1985                                 Announce("3fragsleft");
1986                 }
1987         }
1988
1989         limitreached = FALSE;
1990         if(limit)
1991                 if(WinningConditionHelper_topscore >= limit)
1992                         limitreached = TRUE;
1993         if(leadlimit)
1994         {
1995                 float leadlimitreached;
1996                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1997                 if(autocvar_leadlimit_and_fraglimit)
1998                         limitreached = (limitreached && leadlimitreached);
1999                 else
2000                         limitreached = (limitreached || leadlimitreached);
2001         }
2002
2003         if(limit)
2004                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2005
2006         return GetWinningCode(
2007                 WinningConditionHelper_topscore && limitreached,
2008                 WinningConditionHelper_equality
2009         );
2010 }
2011
2012 float WinningCondition_Race(float fraglimit)
2013 {
2014         float wc;
2015         entity p;
2016         float n, c;
2017
2018         n = 0;
2019         c = 0;
2020         FOR_EACH_PLAYER(p)
2021         {
2022                 ++n;
2023                 if(p.race_completed)
2024                         ++c;
2025         }
2026         if(n && (n == c))
2027                 return WINNING_YES;
2028         wc = WinningCondition_Scores(fraglimit, 0);
2029
2030         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2031         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2032         // do NOT support equality when the laps are all raced!
2033                 return WINNING_STARTSUDDENDEATHOVERTIME;
2034         else
2035                 return WINNING_NEVER;
2036         return wc;
2037 }
2038
2039 float WinningCondition_QualifyingThenRace(float limit)
2040 {
2041         float wc;
2042         wc = WinningCondition_Scores(limit, 0);
2043
2044         // NEVER initiate overtime
2045         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2046         {
2047                 return WINNING_YES;
2048         }
2049
2050         return wc;
2051 }
2052
2053 float WinningCondition_RanOutOfSpawns()
2054 {
2055         entity head;
2056
2057         if(have_team_spawns <= 0)
2058                 return WINNING_NO;
2059
2060         if(autocvar_g_spawn_useallspawns <= 0)
2061                 return WINNING_NO;
2062
2063         if(!some_spawn_has_been_used)
2064                 return WINNING_NO;
2065
2066         team1_score = team2_score = team3_score = team4_score = 0;
2067
2068         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2069         {
2070                 if(head.team == FL_TEAM_1)
2071                         team1_score = 1;
2072                 else if(head.team == FL_TEAM_2)
2073                         team2_score = 1;
2074                 else if(head.team == FL_TEAM_3)
2075                         team3_score = 1;
2076                 else if(head.team == FL_TEAM_4)
2077                         team4_score = 1;
2078         }
2079
2080         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2081         {
2082                 if(head.team == FL_TEAM_1)
2083                         team1_score = 1;
2084                 else if(head.team == FL_TEAM_2)
2085                         team2_score = 1;
2086                 else if(head.team == FL_TEAM_3)
2087                         team3_score = 1;
2088                 else if(head.team == FL_TEAM_4)
2089                         team4_score = 1;
2090         }
2091
2092         ClearWinners();
2093         if(team1_score + team2_score + team3_score + team4_score == 0)
2094         {
2095                 checkrules_equality = TRUE;
2096                 return WINNING_YES;
2097         }
2098         else if(team1_score + team2_score + team3_score + team4_score == 1)
2099         {
2100                 float t, i;
2101                 if(team1_score)
2102                         t = FL_TEAM_1;
2103                 else if(team2_score)
2104                         t = FL_TEAM_2;
2105                 else if(team3_score)
2106                         t = FL_TEAM_3;
2107                 else // if(team4_score)
2108                         t = FL_TEAM_4;
2109                 CheckAllowedTeams(world);
2110                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2111                 {
2112                         if(t != FL_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(FL_TEAM_1, i, -1000);
2113                         if(t != FL_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(FL_TEAM_2, i, -1000);
2114                         if(t != FL_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(FL_TEAM_3, i, -1000);
2115                         if(t != FL_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(FL_TEAM_4, i, -1000);
2116                 }
2117
2118                 AddWinners(team, t);
2119                 return WINNING_YES;
2120         }
2121         else
2122                 return WINNING_NO;
2123 }
2124
2125 /*
2126 ============
2127 CheckRules_World
2128
2129 Exit deathmatch games upon conditions
2130 ============
2131 */
2132 void ReadyRestart();
2133 void CheckRules_World()
2134 {
2135         float timelimit;
2136         float fraglimit;
2137         float leadlimit;
2138
2139         VoteThink();
2140         MapVote_Think();
2141
2142         SetDefaultAlpha();
2143
2144         /*
2145         MapVote_Think should now do that part
2146         if (intermission_running)
2147                 if (time >= intermission_exittime + 60)
2148                 {
2149                         if(!DoNextMapOverride())
2150                                 GotoNextMap();
2151                         return;
2152                 }
2153         */
2154
2155         if (gameover)   // someone else quit the game already
2156         {
2157                 if(player_count == 0) // Nobody there? Then let's go to the next map
2158                         MapVote_Start();
2159                         // this will actually check the player count in the next frame
2160                         // again, but this shouldn't hurt
2161                 return;
2162         }
2163
2164         timelimit = autocvar_timelimit * 60;
2165         fraglimit = autocvar_fraglimit;
2166         leadlimit = autocvar_leadlimit;
2167
2168         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2169         {
2170                 if(timelimit > 0)
2171                         timelimit = 0; // timelimit is not made for warmup
2172                 if(fraglimit > 0)
2173                         fraglimit = 0; // no fraglimit for now
2174                 leadlimit = 0; // no leadlimit for now
2175         }
2176
2177         if(timelimit > 0)
2178         {
2179                 timelimit += game_starttime;
2180         }
2181         else if (timelimit < 0)
2182         {
2183                 // endmatch
2184                 NextLevel();
2185                 return;
2186         }
2187
2188         if(g_onslaught)
2189                 timelimit = 0; // ONS has its own overtime rule
2190
2191         float wantovertime;
2192         wantovertime = 0;
2193
2194         if(timelimit > game_starttime)
2195                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2196         else
2197                 game_completion_ratio = 0;
2198
2199         if(checkrules_suddendeathend)
2200         {
2201                 if(!checkrules_suddendeathwarning)
2202                 {
2203                         checkrules_suddendeathwarning = TRUE;
2204                         if(g_race && !g_race_qualifying)
2205                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2206                         else
2207                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2208                 }
2209         }
2210         else
2211         {
2212                 if (timelimit && time >= timelimit)
2213                 {
2214                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2215                         {
2216                                 float totalplayers;
2217                                 float playerswithlaps;
2218                                 float readyplayers;
2219                                 entity head;
2220                                 totalplayers = playerswithlaps = readyplayers = 0;
2221                                 FOR_EACH_PLAYER(head)
2222                                 {
2223                                         ++totalplayers;
2224                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2225                                                 ++playerswithlaps;
2226                                         if(head.ready)
2227                                                 ++readyplayers;
2228                                 }
2229
2230                                 // at least 2 of the players have completed a lap: start the RACE
2231                                 // otherwise, the players should end the qualifying on their own
2232                                 if(readyplayers || playerswithlaps >= 2)
2233                                 {
2234                                         checkrules_suddendeathend = 0;
2235                                         ReadyRestart(); // go to race
2236                                         return;
2237                                 }
2238                                 else
2239                                         wantovertime |= InitiateSuddenDeath();
2240                         }
2241                         else
2242                                 wantovertime |= InitiateSuddenDeath();
2243                 }
2244         }
2245
2246         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2247         {
2248                 NextLevel();
2249                 return;
2250         }
2251
2252         float checkrules_status;
2253         checkrules_status = WinningCondition_RanOutOfSpawns();
2254         if(checkrules_status == WINNING_YES)
2255         {
2256                 bprint("Hey! Someone ran out of spawns!\n");
2257         }
2258         else if(g_race && !g_race_qualifying && timelimit >= 0)
2259         {
2260                 checkrules_status = WinningCondition_Race(fraglimit);
2261                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2262         }
2263         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2264         {
2265                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2266                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2267         }
2268         else if(g_assault)
2269         {
2270                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2271         }
2272         else if(g_lms)
2273         {
2274                 checkrules_status = WinningCondition_LMS();
2275         }
2276         else if (g_onslaught)
2277         {
2278                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2279         }
2280         else
2281         {
2282                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2283                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2284         }
2285
2286         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2287         {
2288                 checkrules_status = WINNING_NEVER;
2289                 checkrules_overtimesadded = -1;
2290                 wantovertime |= InitiateSuddenDeath();
2291         }
2292
2293         if(checkrules_status == WINNING_NEVER)
2294                 // equality cases! Nobody wins if the overtime ends in a draw.
2295                 ClearWinners();
2296
2297         if(wantovertime)
2298         {
2299                 if(checkrules_status == WINNING_NEVER)
2300                         InitiateOvertime();
2301                 else
2302                         checkrules_status = WINNING_YES;
2303         }
2304
2305         if(checkrules_suddendeathend)
2306                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2307                         checkrules_status = WINNING_YES;
2308
2309         if(checkrules_status == WINNING_YES)
2310         {
2311                 //print("WINNING\n");
2312                 NextLevel();
2313         }
2314 }
2315
2316 float mapvote_nextthink;
2317 float mapvote_initialized;
2318 float mapvote_keeptwotime;
2319 float mapvote_timeout;
2320 string mapvote_message;
2321 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2322 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2323 float mapvote_screenshot_dirs_count;
2324
2325 float mapvote_count;
2326 float mapvote_count_real;
2327 string mapvote_maps[MAPVOTE_COUNT];
2328 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2329 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2330 float mapvote_maps_suggested[MAPVOTE_COUNT];
2331 string mapvote_suggestions[MAPVOTE_COUNT];
2332 float mapvote_suggestion_ptr;
2333 float mapvote_voters;
2334 float mapvote_selections[MAPVOTE_COUNT];
2335 float mapvote_run;
2336 float mapvote_detail;
2337 float mapvote_abstain;
2338 .float mapvote;
2339
2340 void MapVote_ClearAllVotes()
2341 {
2342         FOR_EACH_CLIENT(other)
2343                 other.mapvote = 0;
2344 }
2345
2346 string MapVote_Suggest(string m)
2347 {
2348         float i;
2349         if(m == "")
2350                 return "That's not how to use this command.";
2351         if(!autocvar_g_maplist_votable_suggestions)
2352                 return "Suggestions are not accepted on this server.";
2353         if(mapvote_initialized)
2354                 return "Can't suggest - voting is already in progress!";
2355         m = MapInfo_FixName(m);
2356         if(!m)
2357                 return "The map you suggested is not available on this server.";
2358         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2359                 if(Map_IsRecent(m))
2360                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2361
2362         if(!MapInfo_CheckMap(m))
2363                 return "The map you suggested does not support the current game mode.";
2364         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2365                 if(mapvote_suggestions[i] == m)
2366                         return "This map was already suggested.";
2367         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2368         {
2369                 i = floor(random() * mapvote_suggestion_ptr);
2370         }
2371         else
2372         {
2373                 i = mapvote_suggestion_ptr;
2374                 mapvote_suggestion_ptr += 1;
2375         }
2376         if(mapvote_suggestions[i] != "")
2377                 strunzone(mapvote_suggestions[i]);
2378         mapvote_suggestions[i] = strzone(m);
2379         if(autocvar_sv_eventlog)
2380                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2381         return strcat("Suggestion of ", m, " accepted.");
2382 }
2383
2384 void MapVote_AddVotable(string nextMap, float isSuggestion)
2385 {
2386         float j, i, o;
2387         string pakfile, mapfile;
2388
2389         if(nextMap == "")
2390                 return;
2391         for(j = 0; j < mapvote_count; ++j)
2392                 if(mapvote_maps[j] == nextMap)
2393                         return;
2394         // suggestions might be no longer valid/allowed after gametype switch!
2395         if(isSuggestion)
2396                 if(!MapInfo_CheckMap(nextMap))
2397                         return;
2398         mapvote_maps[mapvote_count] = strzone(nextMap);
2399         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2400
2401         pakfile = string_null;
2402         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2403         {
2404                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2405                 pakfile = whichpack(strcat(mapfile, ".tga"));
2406                 if(pakfile == "")
2407                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2408                 if(pakfile == "")
2409                         pakfile = whichpack(strcat(mapfile, ".png"));
2410                 if(pakfile != "")
2411                         break;
2412         }
2413         if(i >= mapvote_screenshot_dirs_count)
2414                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2415         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2416                 pakfile = substring(pakfile, o, -1);
2417
2418         mapvote_maps_screenshot_dir[mapvote_count] = i;
2419         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2420
2421         mapvote_count += 1;
2422 }
2423
2424 void MapVote_Spawn();
2425 void MapVote_Init()
2426 {
2427         float i;
2428         float nmax, smax;
2429
2430         MapVote_ClearAllVotes();
2431
2432         mapvote_count = 0;
2433         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2434         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2435
2436         if(mapvote_abstain)
2437                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2438         else
2439                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2440         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2441
2442         // we need this for AddVotable, as that cycles through the screenshot dirs
2443         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2444         if(mapvote_screenshot_dirs_count == 0)
2445                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2446         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2447         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2448                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2449
2450         if(mapvote_suggestion_ptr)
2451                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2452                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2453
2454         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2455                 MapVote_AddVotable(GetNextMap(), FALSE);
2456
2457         if(mapvote_count == 0)
2458         {
2459                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2460                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2461                 if(autocvar_g_maplist_shuffle)
2462                         ShuffleMaplist();
2463                 localcmd("\nmenu_cmd sync\n");
2464                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2465                         MapVote_AddVotable(GetNextMap(), FALSE);
2466         }
2467
2468         mapvote_count_real = mapvote_count;
2469         if(mapvote_abstain)
2470                 MapVote_AddVotable("don't care", 0);
2471
2472         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2473
2474         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2475         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2476         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2477                 mapvote_keeptwotime = 0;
2478         mapvote_message = "Choose a map and press its key!";
2479
2480         MapVote_Spawn();
2481 }
2482
2483 void MapVote_SendPicture(float id)
2484 {
2485         msg_entity = self;
2486         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2487         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2488         WriteByte(MSG_ONE, id);
2489         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2490 }
2491
2492 float MapVote_GetMapMask()
2493 {
2494         float mask, i, power;
2495         mask = 0;
2496         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2497                 if(mapvote_maps[i] != "")
2498                         mask |= power;
2499         return mask;
2500 }
2501
2502 entity mapvote_ent;
2503 float MapVote_SendEntity(entity to, float sf)
2504 {
2505         float i;
2506
2507         if(sf & 1)
2508                 sf &~= 2; // if we send 1, we don't need to also send 2
2509
2510         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2511         WriteByte(MSG_ENTITY, sf);
2512
2513         if(sf & 1)
2514         {
2515                 // flag 1 == initialization
2516                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2517                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2518                 WriteString(MSG_ENTITY, "");
2519                 WriteByte(MSG_ENTITY, mapvote_count);
2520                 WriteByte(MSG_ENTITY, mapvote_abstain);
2521                 WriteByte(MSG_ENTITY, mapvote_detail);
2522                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2523                 if(mapvote_count <= 8)
2524                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2525                 else
2526                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2527                 for(i = 0; i < mapvote_count; ++i)
2528                         if(mapvote_maps[i] != "")
2529                         {
2530                                 if(mapvote_abstain && i == mapvote_count - 1)
2531                                 {
2532                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2533                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2534                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2535                                 }
2536                                 else
2537                                 {
2538                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2539                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2540                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2541                                 }
2542                         }
2543         }
2544
2545         if(sf & 2)
2546         {
2547                 // flag 2 == update of mask
2548                 if(mapvote_count <= 8)
2549                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2550                 else
2551                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2552         }
2553
2554         if(sf & 4)
2555         {
2556                 if(mapvote_detail)
2557                         for(i = 0; i < mapvote_count; ++i)
2558                                 if(mapvote_maps[i] != "")
2559                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2560
2561                 WriteByte(MSG_ENTITY, to.mapvote);
2562         }
2563
2564         return TRUE;
2565 }
2566
2567 void MapVote_Spawn()
2568 {
2569         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2570 }
2571
2572 void MapVote_TouchMask()
2573 {
2574         mapvote_ent.SendFlags |= 2;
2575 }
2576
2577 void MapVote_TouchVotes(entity voter)
2578 {
2579         mapvote_ent.SendFlags |= 4;
2580 }
2581
2582 float MapVote_Finished(float mappos)
2583 {
2584         string result;
2585         float i;
2586         float didntvote;
2587
2588         if(autocvar_sv_eventlog)
2589         {
2590                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2591                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2592                 didntvote = mapvote_voters;
2593                 for(i = 0; i < mapvote_count; ++i)
2594                         if(mapvote_maps[i] != "")
2595                         {
2596                                 didntvote -= mapvote_selections[i];
2597                                 if(i != mappos)
2598                                 {
2599                                         result = strcat(result, ":", mapvote_maps[i]);
2600                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2601                                 }
2602                         }
2603                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2604
2605                 GameLogEcho(result);
2606                 if(mapvote_maps_suggested[mappos])
2607                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2608         }
2609
2610         FOR_EACH_REALCLIENT(other)
2611                 FixClientCvars(other);
2612
2613         Map_Goto_SetStr(mapvote_maps[mappos]);
2614         Map_Goto(0);
2615         alreadychangedlevel = TRUE;
2616         return TRUE;
2617 }
2618 void MapVote_CheckRules_1()
2619 {
2620         float i;
2621
2622         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2623         {
2624                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2625                 mapvote_selections[i] = 0;
2626         }
2627
2628         mapvote_voters = 0;
2629         FOR_EACH_REALCLIENT(other)
2630         {
2631                 ++mapvote_voters;
2632                 if(other.mapvote)
2633                 {
2634                         i = other.mapvote - 1;
2635                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2636                         mapvote_selections[i] = mapvote_selections[i] + 1;
2637                 }
2638         }
2639 }
2640
2641 float MapVote_CheckRules_2()
2642 {
2643         float i;
2644         float firstPlace, secondPlace;
2645         float firstPlaceVotes, secondPlaceVotes;
2646         float mapvote_voters_real;
2647         string result;
2648
2649         if(mapvote_count_real == 1)
2650                 return MapVote_Finished(0);
2651
2652         mapvote_voters_real = mapvote_voters;
2653         if(mapvote_abstain)
2654                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2655
2656         RandomSelection_Init();
2657         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2658                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2659         firstPlace = RandomSelection_chosen_float;
2660         firstPlaceVotes = RandomSelection_best_priority;
2661         //dprint("First place: ", ftos(firstPlace), "\n");
2662         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2663
2664         RandomSelection_Init();
2665         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2666                 if(i != firstPlace)
2667                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2668         secondPlace = RandomSelection_chosen_float;
2669         secondPlaceVotes = RandomSelection_best_priority;
2670         //dprint("Second place: ", ftos(secondPlace), "\n");
2671         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2672
2673         if(firstPlace == -1)
2674                 error("No first place in map vote... WTF?");
2675
2676         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2677                 return MapVote_Finished(firstPlace);
2678
2679         if(mapvote_keeptwotime)
2680                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2681                 {
2682                         float didntvote;
2683                         MapVote_TouchMask();
2684                         mapvote_message = "Now decide between the TOP TWO!";
2685                         mapvote_keeptwotime = 0;
2686                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2687                         result = strcat(result, ":", ftos(firstPlaceVotes));
2688                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2689                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2690                         didntvote = mapvote_voters;
2691                         for(i = 0; i < mapvote_count; ++i)
2692                                 if(mapvote_maps[i] != "")
2693                                 {
2694                                         didntvote -= mapvote_selections[i];
2695                                         if(i != firstPlace)
2696                                                 if(i != secondPlace)
2697                                                 {
2698                                                         result = strcat(result, ":", mapvote_maps[i]);
2699                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2700                                                         if(i < mapvote_count_real)
2701                                                         {
2702                                                                 strunzone(mapvote_maps[i]);
2703                                                                 mapvote_maps[i] = "";
2704                                                                 strunzone(mapvote_maps_pakfile[i]);
2705                                                                 mapvote_maps_pakfile[i] = "";
2706                                                         }
2707                                                 }
2708                                 }
2709                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2710                         if(autocvar_sv_eventlog)
2711                                 GameLogEcho(result);
2712                 }
2713
2714         return FALSE;
2715 }
2716 void MapVote_Tick()
2717 {
2718         float keeptwo;
2719         float totalvotes;
2720
2721         keeptwo = mapvote_keeptwotime;
2722         MapVote_CheckRules_1(); // count
2723         if(MapVote_CheckRules_2()) // decide
2724                 return;
2725
2726         totalvotes = 0;
2727         FOR_EACH_REALCLIENT(other)
2728         {
2729                 // hide scoreboard again
2730                 if(other.health != 2342)
2731                 {
2732                         other.health = 2342;
2733                         other.impulse = 0;
2734                         if(clienttype(other) == CLIENTTYPE_REAL)
2735                         {
2736                                 msg_entity = other;
2737                                 WriteByte(MSG_ONE, SVC_FINALE);
2738                                 WriteString(MSG_ONE, "");
2739                         }
2740                 }
2741
2742                 // clear possibly invalid votes
2743                 if(mapvote_maps[other.mapvote - 1] == "")
2744                         other.mapvote = 0;
2745                 // use impulses as new vote
2746                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2747                         if(mapvote_maps[other.impulse - 1] != "")
2748                         {
2749                                 other.mapvote = other.impulse;
2750                                 MapVote_TouchVotes(other);
2751                         }
2752                 other.impulse = 0;
2753
2754                 if(other.mapvote)
2755                         ++totalvotes;
2756         }
2757
2758         MapVote_CheckRules_1(); // just count
2759 }
2760 void MapVote_Start()
2761 {
2762         if(mapvote_run)
2763                 return;
2764
2765         // wait for stats to be sent first
2766         if(!playerstats_waitforme)
2767                 return;
2768
2769         MapInfo_Enumerate();
2770         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2771                 mapvote_run = TRUE;
2772 }
2773 void MapVote_Think()
2774 {
2775         if(!mapvote_run)
2776                 return;
2777
2778         if(alreadychangedlevel)
2779                 return;
2780
2781         if(time < mapvote_nextthink)
2782                 return;
2783         //dprint("tick\n");
2784
2785         mapvote_nextthink = time + 0.5;
2786
2787         if(!mapvote_initialized)
2788         {
2789                 if(autocvar_rescan_pending == 1)
2790                 {
2791                         cvar_set("rescan_pending", "2");
2792                         localcmd("fs_rescan\nrescan_pending 3\n");
2793                         return;
2794                 }
2795                 else if(autocvar_rescan_pending == 2)
2796                 {
2797                         return;
2798                 }
2799                 else if(autocvar_rescan_pending == 3)
2800                 {
2801                         // now build missing mapinfo files
2802                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2803                                 return;
2804
2805                         // we're done, start the timer
2806                         cvar_set("rescan_pending", "0");
2807                 }
2808
2809                 mapvote_initialized = TRUE;
2810                 if(DoNextMapOverride(0))
2811                         return;
2812                 if(!autocvar_g_maplist_votable || player_count <= 0)
2813                 {
2814                         GotoNextMap(0);
2815                         return;
2816                 }
2817                 MapVote_Init();
2818         }
2819
2820         MapVote_Tick();
2821 }
2822
2823 string GotoMap(string m)
2824 {
2825         if(!MapInfo_CheckMap(m))
2826                 return "The map you chose is not available on this server.";
2827         cvar_set("nextmap", m);
2828         cvar_set("timelimit", "-1");
2829         if(mapvote_initialized || alreadychangedlevel)
2830         {
2831                 if(DoNextMapOverride(0))
2832                         return "Map switch initiated.";
2833                 else
2834                         return "Hm... no. For some reason I like THIS map more.";
2835         }
2836         else
2837                 return "Map switch will happen after scoreboard.";
2838 }
2839
2840
2841 void EndFrame()
2842 {
2843         float altime;
2844         FOR_EACH_REALCLIENT(self)
2845         {
2846                 if(self.classname == "spectator")
2847                 {
2848                         if(self.enemy.typehitsound)
2849                                 self.typehit_time = time;
2850                         else if(self.enemy.hitsound)
2851                                 self.hit_time = time;
2852                 }
2853                 else
2854                 {
2855                         if(self.typehitsound)
2856                                 self.typehit_time = time;
2857                         else if(self.hitsound)
2858                                 self.hit_time = time;
2859                 }
2860         }
2861         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2862         // add 1 frametime because after this, engine SV_Physics
2863         // increases time by a frametime and then networks the frame
2864         // add another frametime because client shows everything with
2865         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2866         // needed!
2867         FOR_EACH_CLIENT(self)
2868         {
2869                 self.hitsound = FALSE;
2870                 self.typehitsound = FALSE;
2871                 antilag_record(self, altime);
2872         }
2873 }
2874
2875
2876 /*
2877  * RedirectionThink:
2878  * returns TRUE if redirecting
2879  */
2880 float redirection_timeout;
2881 float redirection_nextthink;
2882 float RedirectionThink()
2883 {
2884         float clients_found;
2885
2886         if(redirection_target == "")
2887                 return FALSE;
2888
2889         if(!redirection_timeout)
2890         {
2891                 cvar_set("sv_public", "-2");
2892                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2893                 if(redirection_target == "self")
2894                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2895                 else
2896                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2897         }
2898
2899         if(time < redirection_nextthink)
2900                 return TRUE;
2901
2902         redirection_nextthink = time + 1;
2903
2904         clients_found = 0;
2905         FOR_EACH_REALCLIENT(self)
2906         {
2907                 // TODO add timer
2908                 print("Redirecting: sending connect command to ", self.netname, "\n");
2909                 if(redirection_target == "self")
2910                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2911                 else
2912                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2913                 ++clients_found;
2914         }
2915
2916         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2917
2918         if(time > redirection_timeout || clients_found == 0)
2919                 localcmd("\nwait; wait; wait; quit\n");
2920
2921         return TRUE;
2922 }
2923
2924 void TargetMusic_RestoreGame();
2925 void RestoreGame()
2926 {
2927         // Loaded from a save game
2928         // some things then break, so let's work around them...
2929
2930         // Progs DB (capture records)
2931         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2932
2933         // Mapinfo
2934         MapInfo_Shutdown();
2935         MapInfo_Enumerate();
2936         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2937         WeaponStats_Init();
2938
2939         TargetMusic_RestoreGame();
2940 }
2941
2942 void Shutdown()
2943 {
2944         entity e;
2945
2946         gameover = 2;
2947
2948         if(world_initialized > 0)
2949         {
2950                 world_initialized = 0;
2951                 print("Saving persistent data...\n");
2952                 Ban_SaveBans();
2953
2954                 PlayerStats_EndMatch(0);
2955                 FOR_EACH_CLIENT(e)
2956                         PlayerStats_AddGlobalInfo(e);
2957                 PlayerStats_Shutdown();
2958
2959                 if(!cheatcount_total)
2960                 {
2961                         if(autocvar_sv_db_saveasdump)
2962                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2963                         else
2964                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2965                 }
2966                 if(autocvar_developer)
2967                 {
2968                         if(autocvar_sv_db_saveasdump)
2969                                 db_dump(TemporaryDB, "server-temp.db");
2970                         else
2971                                 db_save(TemporaryDB, "server-temp.db");
2972                 }
2973                 CheatShutdown(); // must be after cheatcount check
2974                 db_close(ServerProgsDB);
2975                 db_close(TemporaryDB);
2976                 print("done!\n");
2977                 // tell the bot system the game is ending now
2978                 bot_endgame();
2979
2980                 WeaponStats_Shutdown();
2981                 MapInfo_Shutdown();
2982         }
2983         else if(world_initialized == 0)
2984         {
2985                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2986         }
2987 }