qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/_mod.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/_mod.qh"
  36 #include <common/weapons/_all.qh>
  37 #include "../common/state.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think(entity this)
  45 {
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         this.nextthink = time + delta;
  53
  54         e = edict_num(this.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, this.cnt);
  59                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  60                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, this.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         this.cnt = (this.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new_pure(pingplreport);
  85         setthink(pingplreport, PingPLReport_Think);
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250
 251                 // mapinfo
 252                 BADCVAR("fraglimit");
 253                 BADCVAR("g_assault");
 254                 BADCVAR("g_ca");
 255                 BADCVAR("g_ca_teams");
 256                 BADCVAR("g_ctf");
 257                 BADCVAR("g_cts");
 258                 BADCVAR("g_dm");
 259                 BADCVAR("g_domination");
 260                 BADCVAR("g_domination_default_teams");
 261                 BADCVAR("g_freezetag");
 262                 BADCVAR("g_freezetag_teams");
 263                 BADCVAR("g_invasion_teams");
 264                 BADCVAR("g_keepaway");
 265                 BADCVAR("g_keyhunt");
 266                 BADCVAR("g_keyhunt_teams");
 267                 BADCVAR("g_lms");
 268                 BADCVAR("g_nexball");
 269                 BADCVAR("g_onslaught");
 270                 BADCVAR("g_race");
 271                 BADCVAR("g_race_laps_limit");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_race_qualifying_timelimit_override");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing gameplay relevant
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("gameversion");
 307                 BADCVAR("g_allow_oldvortexbeam");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_campcheck_distance");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ca_point_limit");
 312                 BADCVAR("g_ctf_captimerecord_always");
 313                 BADCVAR("g_ctf_flag_glowtrails");
 314                 BADCVAR("g_ctf_flag_pickup_verbosename");
 315                 BADCVAR("g_domination_point_leadlimit");
 316                 BADCVAR("g_forced_respawn");
 317                 BADCVAR("g_freezetag_point_leadlimit");
 318                 BADCVAR("g_freezetag_point_limit");
 319                 BADCVAR("g_hats");
 320                 BADCVAR("g_invasion_point_limit");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADCVAR("g_nexball_goalleadlimit");
 323                 BADCVAR("g_new_toys_use_pickupsound");
 324                 BADCVAR("g_physics_predictall");
 325                 BADCVAR("g_tdm_point_leadlimit");
 326                 BADCVAR("g_tdm_point_limit");
 327                 BADCVAR("leadlimit_and_fraglimit");
 328                 BADCVAR("leadlimit_override");
 329                 BADCVAR("pausable");
 330                 BADCVAR("sv_checkforpacketsduringsleep");
 331                 BADCVAR("sv_intermission_cdtrack");
 332                 BADCVAR("sv_minigames");
 333                 BADCVAR("sv_namechangetimer");
 334                 BADCVAR("sv_precacheplayermodels");
 335                 BADCVAR("sv_timeout");
 336                 BADPREFIX("crypto_");
 337                 BADPREFIX("gameversion_");
 338                 BADPREFIX("g_chat_");
 339                 BADPREFIX("g_ctf_captimerecord_");
 340                 BADPREFIX("g_maplist_votable_");
 341                 BADPREFIX("g_mod_");
 342                 BADPREFIX("g_respawn_");
 343                 BADPREFIX("net_");
 344                 BADPREFIX("prvm_");
 345                 BADPREFIX("skill_");
 346                 BADPREFIX("sv_allow_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_maxidle_");
 349                 BADPREFIX("sv_minigames_");
 350                 BADPREFIX("sv_radio_");
 351                 BADPREFIX("sv_timeout_");
 352                 BADPREFIX("sv_vote_");
 353                 BADPREFIX("timelimit_");
 354
 355                 // allowed changes to server admins (please sync this to server.cfg)
 356                 // vi commands:
 357                 //   :/"impure"/,$d
 358                 //   :g!,^\/\/[^ /],d
 359                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 360                 //   :%!sort
 361                 // yes, this does contain some redundant stuff, don't really care
 362                 BADCVAR("bot_config_file");
 363                 BADCVAR("bot_number");
 364                 BADCVAR("bot_prefix");
 365                 BADCVAR("bot_suffix");
 366                 BADCVAR("capturelimit_override");
 367                 BADCVAR("fraglimit_override");
 368                 BADCVAR("gametype");
 369                 BADCVAR("g_antilag");
 370                 BADCVAR("g_balance_teams");
 371                 BADCVAR("g_balance_teams_prevent_imbalance");
 372                 BADCVAR("g_balance_teams_scorefactor");
 373                 BADCVAR("g_ban_sync_trusted_servers");
 374                 BADCVAR("g_ban_sync_uri");
 375                 BADCVAR("g_buffs");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_spawnshieldtime");
 400                 BADCVAR("g_start_delay");
 401                 BADCVAR("g_superspectate");
 402                 BADCVAR("g_tdm_teams_override");
 403                 BADCVAR("g_warmup");
 404                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 405                 BADCVAR("hostname");
 406                 BADCVAR("log_file");
 407                 BADCVAR("maxplayers");
 408                 BADCVAR("minplayers");
 409                 BADCVAR("net_address");
 410                 BADCVAR("port");
 411                 BADCVAR("rcon_password");
 412                 BADCVAR("rcon_restricted_commands");
 413                 BADCVAR("rcon_restricted_password");
 414                 BADCVAR("skill");
 415                 BADCVAR("sv_adminnick");
 416                 BADCVAR("sv_autoscreenshot");
 417                 BADCVAR("sv_autotaunt");
 418                 BADCVAR("sv_curl_defaulturl");
 419                 BADCVAR("sv_defaultcharacter");
 420                 BADCVAR("sv_defaultcharacterskin");
 421                 BADCVAR("sv_defaultplayercolors");
 422                 BADCVAR("sv_defaultplayermodel");
 423                 BADCVAR("sv_defaultplayerskin");
 424                 BADCVAR("sv_maxidle");
 425                 BADCVAR("sv_maxrate");
 426                 BADCVAR("sv_motd");
 427                 BADCVAR("sv_public");
 428                 BADCVAR("sv_ready_restart");
 429                 BADCVAR("sv_status_privacy");
 430                 BADCVAR("sv_taunt");
 431                 BADCVAR("sv_vote_call");
 432                 BADCVAR("sv_vote_commands");
 433                 BADCVAR("sv_vote_majority_factor");
 434                 BADCVAR("sv_vote_master");
 435                 BADCVAR("sv_vote_master_commands");
 436                 BADCVAR("sv_vote_master_password");
 437                 BADCVAR("sv_vote_simple_majority_factor");
 438                 BADCVAR("teamplay_mode");
 439                 BADCVAR("timelimit_override");
 440                 BADPREFIX("g_warmup_");
 441                 BADPREFIX("sv_ready_restart_");
 442
 443                 // mutators that announce themselves properly to the server browser
 444                 BADCVAR("g_instagib");
 445                 BADCVAR("g_new_toys");
 446                 BADCVAR("g_nix");
 447                 BADCVAR("g_grappling_hook");
 448                 BADCVAR("g_jetpack");
 449
 450 #undef BADPRESUFFIX
 451 #undef BADPREFIX
 452 #undef BADCVAR
 453
 454                 if(pureadding)
 455                 {
 456                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 457                         if(strlen(cvar_purechanges) > 16384)
 458                         {
 459                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 460                                 pureadding = 0;
 461                         }
 462                 }
 463                 ++cvar_purechanges_count;
 464                 // WARNING: this variable is used for the server list
 465                 // NEVER dare to skip this code!
 466                 // Hacks to intentionally appearing as "pure server" even though you DO have
 467                 // modified settings may be punished by removal from the server list.
 468                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 469                 // though.
 470         }
 471         buf_del(h);
 472         if(cvar_changes == "")
 473                 cvar_changes = "// this server runs at default server settings\n";
 474         else
 475                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 476         cvar_changes = strzone(cvar_changes);
 477         if(cvar_purechanges == "")
 478                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 479         else
 480                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 481         cvar_purechanges = strzone(cvar_purechanges);
 482 }
 483
 484 void detect_maptype()
 485 {
 486 #if 0
 487         vector o, v;
 488         float i;
 489
 490         for (;;)
 491         {
 492                 o = world.mins;
 493                 o.x += random() * (world.maxs.x - world.mins.x);
 494                 o.y += random() * (world.maxs.y - world.mins.y);
 495                 o.z += random() * (world.maxs.z - world.mins.z);
 496
 497                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 498                 if(trace_fraction == 1)
 499                         continue;
 500
 501                 v = trace_endpos;
 502
 503                 for(i = 0; i < 64; i += 4)
 504                 {
 505                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 506         if(trace_fraction == 1)
 507                 continue;
 508                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 509                 }
 510
 511                 break;
 512         }
 513 #endif
 514 }
 515
 516 entity randomseed;
 517 bool RandomSeed_Send(entity this, entity to, int sf)
 518 {
 519         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 520         WriteShort(MSG_ENTITY, this.cnt);
 521         return true;
 522 }
 523 void RandomSeed_Think(entity this)
 524 {
 525         this.cnt = bound(0, floor(random() * 65536), 65535);
 526         this.nextthink = time + 5;
 527
 528         this.SendFlags |= 1;
 529 }
 530 void RandomSeed_Spawn()
 531 {
 532         randomseed = new_pure(randomseed);
 533         setthink(randomseed, RandomSeed_Think);
 534         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 535
 536         getthink(randomseed)(randomseed); // sets random seed and nextthink
 537 }
 538
 539 spawnfunc(__init_dedicated_server)
 540 {
 541         // handler for _init/_init map (only for dedicated server initialization)
 542
 543         world_initialized = -1; // don't complain
 544         cvar = cvar_normal;
 545         cvar_string = cvar_string_normal;
 546         cvar_set = cvar_set_normal;
 547
 548         delete_fn = remove_unsafely;
 549
 550         entity e = spawn();
 551         setthink(e, GotoFirstMap);
 552         e.nextthink = time; // this is usually 1 at this point
 553
 554         e = new(info_player_deathmatch);  // safeguard against player joining
 555
 556         this.classname = "worldspawn"; // safeguard against various stuff ;)
 557
 558         // needs to be done so early because of the constants they create
 559         static_init();
 560         static_init_late();
 561         static_init_precache();
 562
 563         IL_PUSH(g_spawnpoints, e); // just incase
 564
 565         MapInfo_Enumerate();
 566         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 567 }
 568
 569 void __init_dedicated_server_shutdown() {
 570         MapInfo_Shutdown();
 571 }
 572
 573 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 574 {
 575         if(!autocvar_g_campaign)
 576         {
 577                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 578                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 579                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 580                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 581         }
 582         limits_are_set = true;
 583 }
 584
 585 void Map_MarkAsRecent(string m);
 586 float world_already_spawned;
 587 void Nagger_Init();
 588 void ClientInit_Spawn();
 589 void WeaponStats_Init();
 590 void WeaponStats_Shutdown();
 591 spawnfunc(worldspawn)
 592 {
 593         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 594
 595     bool wantrestart = false;
 596         {
 597                 if (!server_is_dedicated)
 598                 {
 599                         // force unloading of server pk3 files when starting a listen server
 600                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 601                         // restore csqc_progname too
 602                         string expect = "csprogs.dat";
 603                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 604                         cvar_set_normal("csqc_progname", expect);
 605                 }
 606                 else
 607                 {
 608                         // Try to use versioned csprogs from pk3
 609                         // Only ever use versioned csprogs.dat files on dedicated servers;
 610                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 611                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 612                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 613                         string select = "csprogs.dat";
 614                         if (fexists(pk3csprogs)) select = pk3csprogs;
 615                         if (cvar_string_normal("csqc_progname") != select)
 616                         {
 617                                 cvar_set_normal("csqc_progname", select);
 618                                 wantrestart = true;
 619                         }
 620                         // Check for updates on startup
 621                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 622                         int sentinel = fopen("progs.txt", FILE_READ);
 623                         if (sentinel >= 0)
 624                         {
 625                                 string switchversion = fgets(sentinel);
 626                                 fclose(sentinel);
 627                                 if (switchversion != "" && switchversion != WATERMARK)
 628                                 {
 629                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 630                                         // if it doesn't exist, assume either:
 631                                         //   a) the current program was overwritten
 632                                         //   b) this is a client only update
 633                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 634                                         if (fexists(newprogs))
 635                                         {
 636                                                 cvar_set_normal("sv_progs", newprogs);
 637                                                 wantrestart = true;
 638                                         }
 639                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 640                                         if (fexists(newcsprogs))
 641                                         {
 642                                                 cvar_set_normal("csqc_progname", newcsprogs);
 643                                                 wantrestart = true;
 644                                         }
 645                                 }
 646                         }
 647                 }
 648                 if (wantrestart)
 649                 {
 650                         LOG_INFOF("Restart requested\n");
 651                         changelevel(mapname);
 652                         // let initialization continue, shutdown depends on it
 653                 }
 654         }
 655
 656         cvar = cvar_normal;
 657         cvar_string = cvar_string_normal;
 658         cvar_set = cvar_set_normal;
 659
 660         if(world_already_spawned)
 661                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 662         world_already_spawned = true;
 663
 664         delete_fn = remove_safely; // during spawning, watch what you remove!
 665
 666         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 667
 668         maxclients = 0;
 669         for (entity head = nextent(NULL); head; head = nextent(head))
 670         {
 671                 ++maxclients;
 672         }
 673
 674         // needs to be done so early because of the constants they create
 675         static_init();
 676
 677         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 678
 679         TemporaryDB = db_create();
 680
 681         // 0 normal
 682         lightstyle(0, "m");
 683
 684         // 1 FLICKER (first variety)
 685         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 686
 687         // 2 SLOW STRONG PULSE
 688         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 689
 690         // 3 CANDLE (first variety)
 691         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 692
 693         // 4 FAST STROBE
 694         lightstyle(4, "mamamamamama");
 695
 696         // 5 GENTLE PULSE 1
 697         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 698
 699         // 6 FLICKER (second variety)
 700         lightstyle(6, "nmonqnmomnmomomno");
 701
 702         // 7 CANDLE (second variety)
 703         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 704
 705         // 8 CANDLE (third variety)
 706         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 707
 708         // 9 SLOW STROBE (fourth variety)
 709         lightstyle(9, "aaaaaaaazzzzzzzz");
 710
 711         // 10 FLUORESCENT FLICKER
 712         lightstyle(10, "mmamammmmammamamaaamammma");
 713
 714         // 11 SLOW PULSE NOT FADE TO BLACK
 715         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 716
 717         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 718
 719         // 63 testing
 720         lightstyle(63, "a");
 721
 722         if(autocvar_g_campaign)
 723                 CampaignPreInit();
 724
 725         Map_MarkAsRecent(mapname);
 726
 727         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 728
 729         InitGameplayMode();
 730         static_init_late();
 731         static_init_precache();
 732         readlevelcvars();
 733         GrappleHookInit();
 734
 735         if(!limits_are_set)
 736                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 737
 738         if(warmup_limit == 0)
 739                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 740
 741         player_count = 0;
 742         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 743         if(bot_waypoints_for_items == 1)
 744                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 745                         bot_waypoints_for_items = 0;
 746
 747         precache();
 748
 749         WaypointSprite_Init();
 750
 751         GameLogInit(); // prepare everything
 752         // NOTE for matchid:
 753         // changing the logic generating it is okay. But:
 754         // it HAS to stay <= 64 chars
 755         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 756         if(autocvar_sv_eventlog)
 757         {
 758                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 759                 matchid = strzone(s);
 760
 761                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 762                 s = ":gameinfo:mutators:LIST";
 763
 764                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 765                 s = M_ARGV(0, string);
 766
 767                 // initialiation stuff, not good in the mutator system
 768                 if(!autocvar_g_use_ammunition)
 769                         s = strcat(s, ":no_use_ammunition");
 770
 771                 // initialiation stuff, not good in the mutator system
 772                 if(autocvar_g_pickup_items == 0)
 773                         s = strcat(s, ":no_pickup_items");
 774                 if(autocvar_g_pickup_items > 0)
 775                         s = strcat(s, ":pickup_items");
 776
 777                 // initialiation stuff, not good in the mutator system
 778                 if(autocvar_g_weaponarena != "0")
 779                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 780
 781                 // TODO to mutator system
 782                 if(autocvar_g_norecoil)
 783                         s = strcat(s, ":norecoil");
 784
 785                 // TODO to mutator system
 786                 if(autocvar_g_powerups == 0)
 787                         s = strcat(s, ":no_powerups");
 788                 if(autocvar_g_powerups > 0)
 789                         s = strcat(s, ":powerups");
 790
 791                 GameLogEcho(s);
 792                 GameLogEcho(":gameinfo:end");
 793         }
 794         else
 795                 matchid = strzone(ftos(random()));
 796
 797         cvar_set("nextmap", "");
 798
 799         SetDefaultAlpha();
 800
 801         if(autocvar_g_campaign)
 802                 CampaignPostInit();
 803
 804         Ban_LoadBans();
 805
 806         MapInfo_Enumerate();
 807         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 808
 809         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 810         {
 811                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 812                 if(fd != -1)
 813                 {
 814                         string s;
 815                         while((s = fgets(fd)))
 816                         {
 817                                 int l = tokenize_console(s);
 818                                 if(l < 2)
 819                                         continue;
 820                                 if(argv(0) == "cd")
 821                                 {
 822                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 823                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 824                                 }
 825                                 else if(argv(0) == "fog")
 826                                 {
 827                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 828                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 829                                 }
 830                                 else if(argv(0) == "set")
 831                                 {
 832                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 833                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 834                                 }
 835                                 else if(argv(0) != "//")
 836                                 {
 837                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 838                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 839                                 }
 840                         }
 841                         fclose(fd);
 842                 }
 843         }
 844
 845         WeaponStats_Init();
 846
 847         Nagger_Init();
 848
 849         next_pingtime = time + 5;
 850
 851         detect_maptype();
 852
 853         // set up information replies for clients and server to use
 854         maplist_reply = strzone(getmaplist());
 855         lsmaps_reply = strzone(getlsmaps());
 856         monsterlist_reply = strzone(getmonsterlist());
 857         for(int i = 0; i < 10; ++i)
 858         {
 859                 string s = getrecords(i);
 860                 if (s)
 861                         records_reply[i] = strzone(s);
 862         }
 863         ladder_reply = strzone(getladder());
 864         rankings_reply = strzone(getrankings());
 865
 866         // begin other init
 867         ClientInit_Spawn();
 868         RandomSeed_Spawn();
 869         PingPLReport_Spawn();
 870
 871         CheatInit();
 872
 873         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 874
 875         // fill sv_curl_serverpackages from .serverpackage files
 876         if (autocvar_sv_curl_serverpackages_auto)
 877         {
 878                 string s = "csprogs-" WATERMARK ".txt";
 879                 // remove automatically managed files from the list to prevent duplicates
 880                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 881                 {
 882                         string pkg = argv(i);
 883                         if (startsWith(pkg, "csprogs-")) continue;
 884                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 885                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 886                         s = cons(s, pkg);
 887                 }
 888                 // add automatically managed files to the list
 889                 #define X(match) MACRO_BEGIN { \
 890                         int fd = search_begin(match, true, false); \
 891                         if (fd >= 0) \
 892                         { \
 893                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 894                                 { \
 895                                         s = cons(s, search_getfilename(fd, i)); \
 896                                 } \
 897                                 search_end(fd); \
 898                         } \
 899                 } MACRO_END
 900                 X("*-serverpackage.txt");
 901                 X("*.serverpackage");
 902                 #undef X
 903                 cvar_set("sv_curl_serverpackages", s);
 904         }
 905
 906         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 907         modname = "Xonotic";
 908         // physics/balance/config changes that count as mod
 909         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 910                 modname = cvar_string("g_mod_physics");
 911         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 912                 modname = cvar_string("g_mod_balance");
 913         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 914                 modname = cvar_string("g_mod_config");
 915         // extra mutators that deserve to count as mod
 916         MUTATOR_CALLHOOK(SetModname);
 917
 918         // save it for later
 919         modname = strzone(modname);
 920
 921         WinningConditionHelper(this); // set worldstatus
 922
 923         world_initialized = 1;
 924 }
 925
 926 spawnfunc(light)
 927 {
 928         //makestatic (this); // Who the f___ did that?
 929         delete(this);
 930 }
 931
 932 string GetGametype()
 933 {
 934         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 935 }
 936
 937 string GetMapname()
 938 {
 939         return mapname;
 940 }
 941
 942 float Map_Count, Map_Current;
 943 string Map_Current_Name;
 944
 945 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 946 float GetMaplistPosition()
 947 {
 948         float pos, idx;
 949         string map;
 950
 951         map = GetMapname();
 952         idx = autocvar_g_maplist_index;
 953
 954         if(idx >= 0)
 955                 if(idx < Map_Count)
 956                         if(map == argv(idx))
 957                                 return idx;
 958
 959         for(pos = 0; pos < Map_Count; ++pos)
 960                 if(map == argv(pos))
 961                         return pos;
 962
 963         // resume normal maplist rotation if current map is not in g_maplist
 964         return idx;
 965 }
 966
 967 float MapHasRightSize(string map)
 968 {
 969         float fh;
 970         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 971         if(autocvar_g_maplist_check_waypoints)
 972         {
 973                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 974                 if(!fexists(strcat("maps/", map, ".waypoints")))
 975                 {
 976                         LOG_TRACE(": no waypoints");
 977                         return false;
 978                 }
 979                 LOG_TRACE(": has waypoints");
 980         }
 981
 982         // open map size restriction file
 983         LOG_TRACE("opensize "); LOG_TRACE(map);
 984         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 985         if(fh >= 0)
 986         {
 987                 float mapmin, mapmax;
 988                 LOG_TRACE(": ok, ");
 989                 mapmin = stof(fgets(fh));
 990                 mapmax = stof(fgets(fh));
 991                 fclose(fh);
 992                 if(player_count < mapmin)
 993                 {
 994                         LOG_TRACE("not enough");
 995                         return false;
 996                 }
 997                 if(player_count > mapmax)
 998                 {
 999                         LOG_TRACE("too many");
1000                         return false;
1001                 }
1002                 LOG_TRACE("right size");
1003                 return true;
1004         }
1005         LOG_TRACE(": not found");
1006         return true;
1007 }
1008
1009 string Map_Filename(float position)
1010 {
1011         return strcat("maps/", argv(position), ".bsp");
1012 }
1013
1014 void Map_MarkAsRecent(string m)
1015 {
1016         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1017 }
1018
1019 float Map_IsRecent(string m)
1020 {
1021         return strhasword(autocvar_g_maplist_mostrecent, m);
1022 }
1023
1024 float Map_Check(float position, float pass)
1025 {
1026         string filename;
1027         string map_next;
1028         map_next = argv(position);
1029         if(pass <= 1)
1030         {
1031                 if(Map_IsRecent(map_next))
1032                         return 0;
1033         }
1034         filename = Map_Filename(position);
1035         if(MapInfo_CheckMap(map_next))
1036         {
1037                 if(pass == 2)
1038                         return 1;
1039                 if(MapHasRightSize(map_next))
1040                         return 1;
1041                 return 0;
1042         }
1043         else
1044                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1045
1046         return 0;
1047 }
1048
1049 void Map_Goto_SetStr(string nextmapname)
1050 {
1051         if(getmapname_stored != "")
1052                 strunzone(getmapname_stored);
1053         if(nextmapname == "")
1054                 getmapname_stored = "";
1055         else
1056                 getmapname_stored = strzone(nextmapname);
1057 }
1058
1059 void Map_Goto_SetFloat(float position)
1060 {
1061         cvar_set("g_maplist_index", ftos(position));
1062         Map_Goto_SetStr(argv(position));
1063 }
1064
1065 void Map_Goto(float reinit)
1066 {
1067         MapInfo_LoadMap(getmapname_stored, reinit);
1068 }
1069
1070 // return codes of map selectors:
1071 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1072 //   -2 = permanent failure
1073 float() MaplistMethod_Iterate = // usual method
1074 {
1075         float pass, i;
1076
1077         LOG_TRACE("Trying MaplistMethod_Iterate");
1078
1079         for(pass = 1; pass <= 2; ++pass)
1080         {
1081                 for(i = 1; i < Map_Count; ++i)
1082                 {
1083                         float mapindex;
1084                         mapindex = (i + Map_Current) % Map_Count;
1085                         if(Map_Check(mapindex, pass))
1086                                 return mapindex;
1087                 }
1088         }
1089         return -1;
1090 }
1091
1092 float() MaplistMethod_Repeat = // fallback method
1093 {
1094         LOG_TRACE("Trying MaplistMethod_Repeat");
1095
1096         if(Map_Check(Map_Current, 2))
1097                 return Map_Current;
1098         return -2;
1099 }
1100
1101 float() MaplistMethod_Random = // random map selection
1102 {
1103         float i, imax;
1104
1105         LOG_TRACE("Trying MaplistMethod_Random");
1106
1107         imax = 42;
1108
1109         for(i = 0; i <= imax; ++i)
1110         {
1111                 float mapindex;
1112                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1113                 if(Map_Check(mapindex, 1))
1114                         return mapindex;
1115         }
1116         return -1;
1117 }
1118
1119 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1120 // the exponent sets a bias on the map selection:
1121 // the higher the exponent, the less likely "shortly repeated" same maps are
1122 {
1123         float i, j, imax, insertpos;
1124
1125         LOG_TRACE("Trying MaplistMethod_Shuffle");
1126
1127         imax = 42;
1128
1129         for(i = 0; i <= imax; ++i)
1130         {
1131                 string newlist;
1132
1133                 // now reinsert this at another position
1134                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1135                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1136                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1137                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1138
1139                 // insert the current map there
1140                 newlist = "";
1141                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1142                         newlist = strcat(newlist, " ", argv(j));
1143                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1144                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1145                         newlist = strcat(newlist, " ", argv(j));
1146                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1147                 cvar_set("g_maplist", newlist);
1148                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1149
1150                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1151                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1152                 if(Map_Check(Map_Current, 1))
1153                         return Map_Current;
1154         }
1155         return -1;
1156 }
1157
1158 void Maplist_Init()
1159 {
1160         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1161         float i;
1162         for (i = 0; i < Map_Count; ++i)
1163                 if (Map_Check(i, 2))
1164                         break;
1165         if (i == Map_Count)
1166         {
1167                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1168                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1169                 if(autocvar_g_maplist_shuffle)
1170                         ShuffleMaplist();
1171                 localcmd("\nmenu_cmd sync\n");
1172                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1173         }
1174         if(Map_Count == 0)
1175                 error("empty maplist, cannot select a new map");
1176         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1177
1178         if(Map_Current_Name)
1179                 strunzone(Map_Current_Name);
1180         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1181         // this may or may not be correct, but who cares, in the worst case a map
1182         // isn't chosen in the first pass that should have been
1183 }
1184
1185 string GetNextMap()
1186 {
1187         float nextMap;
1188
1189         Maplist_Init();
1190         nextMap = -1;
1191
1192         if(nextMap == -1)
1193                 if(autocvar_g_maplist_shuffle > 0)
1194                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1195
1196         if(nextMap == -1)
1197                 if(autocvar_g_maplist_selectrandom)
1198                         nextMap = MaplistMethod_Random();
1199
1200         if(nextMap == -1)
1201                 nextMap = MaplistMethod_Iterate();
1202
1203         if(nextMap == -1)
1204                 nextMap = MaplistMethod_Repeat();
1205
1206         if(nextMap >= 0)
1207         {
1208                 Map_Goto_SetFloat(nextMap);
1209                 return getmapname_stored;
1210         }
1211
1212         return "";
1213 }
1214
1215 float DoNextMapOverride(float reinit)
1216 {
1217         if(autocvar_g_campaign)
1218         {
1219                 CampaignPostIntermission();
1220                 alreadychangedlevel = true;
1221                 return true;
1222         }
1223         if(autocvar_quit_when_empty)
1224         {
1225                 if(player_count <= currentbots)
1226                 {
1227                         localcmd("quit\n");
1228                         alreadychangedlevel = true;
1229                         return true;
1230                 }
1231         }
1232         if(autocvar_quit_and_redirect != "")
1233         {
1234                 redirection_target = strzone(autocvar_quit_and_redirect);
1235                 alreadychangedlevel = true;
1236                 return true;
1237         }
1238         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1239         {
1240                 localcmd("restart\n");
1241                 alreadychangedlevel = true;
1242                 return true;
1243         }
1244         if(autocvar_nextmap != "")
1245         {
1246                 string m;
1247                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1248                 cvar_set("nextmap",m);
1249
1250                 if(!m || gametypevote)
1251                         return false;
1252                 if(autocvar_sv_vote_gametype)
1253                 {
1254                         Map_Goto_SetStr(m);
1255                         return false;
1256                 }
1257
1258                 if(MapInfo_CheckMap(m))
1259                 {
1260                         Map_Goto_SetStr(m);
1261                         Map_Goto(reinit);
1262                         alreadychangedlevel = true;
1263                         return true;
1264                 }
1265         }
1266         if(!reinit && autocvar_lastlevel)
1267         {
1268                 cvar_settemp_restore();
1269                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1270                 alreadychangedlevel = true;
1271                 return true;
1272         }
1273         return false;
1274 }
1275
1276 void GotoNextMap(float reinit)
1277 {
1278         //string nextmap;
1279         //float n, nummaps;
1280         //string s;
1281         if (alreadychangedlevel)
1282                 return;
1283         alreadychangedlevel = true;
1284
1285         string nextMap;
1286
1287         nextMap = GetNextMap();
1288         if(nextMap == "")
1289                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1290         Map_Goto(reinit);
1291 }
1292
1293
1294 /*
1295 ============
1296 IntermissionThink
1297
1298 When the player presses attack or jump, change to the next level
1299 ============
1300 */
1301 .float autoscreenshot;
1302 void IntermissionThink(entity this)
1303 {
1304         FixIntermissionClient(this);
1305         CSQCMODEL_AUTOUPDATE(this); // PlayerPostThink returns before calling this during intermission, so run it here
1306
1307         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1308         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1309
1310         if( (server_screenshot || client_screenshot)
1311                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1312         {
1313                 this.autoscreenshot = -1;
1314                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1315                 return;
1316         }
1317
1318         if (time < intermission_exittime)
1319                 return;
1320
1321         if(!mapvote_initialized)
1322                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1323                         return;
1324
1325         MapVote_Start();
1326 }
1327
1328 /*
1329 ============
1330 FindIntermission
1331
1332 Returns the entity to view from
1333 ============
1334 */
1335 /*
1336 entity FindIntermission()
1337 {
1338         local   entity spot;
1339         local   float cyc;
1340
1341 // look for info_intermission first
1342         spot = find(NULL, classname, "info_intermission");
1343         if (spot)
1344         {       // pick a random one
1345                 cyc = random() * 4;
1346                 while (cyc > 1)
1347                 {
1348                         spot = find(spot, classname, "info_intermission");
1349                         if (!spot)
1350                                 spot = find(spot, classname, "info_intermission");
1351                         cyc = cyc - 1;
1352                 }
1353                 return spot;
1354         }
1355
1356 // then look for the start position
1357         spot = find(NULL, classname, "info_player_start");
1358         if (spot)
1359                 return spot;
1360
1361 // testinfo_player_start is only found in regioned levels
1362         spot = find(NULL, classname, "testplayerstart");
1363         if (spot)
1364                 return spot;
1365
1366 // then look for the start position
1367         spot = find(NULL, classname, "info_player_deathmatch");
1368         if (spot)
1369                 return spot;
1370
1371         //objerror ("FindIntermission: no spot");
1372         return NULL;
1373 }
1374 */
1375
1376 /*
1377 ===============================================================================
1378
1379 RULES
1380
1381 ===============================================================================
1382 */
1383
1384 void DumpStats(float final)
1385 {
1386         float file;
1387         string s;
1388         float to_console;
1389         float to_eventlog;
1390         float to_file;
1391         float i;
1392
1393         to_console = autocvar_sv_logscores_console;
1394         to_eventlog = autocvar_sv_eventlog;
1395         to_file = autocvar_sv_logscores_file;
1396
1397         if(!final)
1398         {
1399                 to_console = true; // always print printstats replies
1400                 to_eventlog = false; // but never print them to the event log
1401         }
1402
1403         if(to_eventlog)
1404                 if(autocvar_sv_eventlog_console)
1405                         to_console = false; // otherwise we get the output twice
1406
1407         if(final)
1408                 s = ":scores:";
1409         else
1410                 s = ":status:";
1411         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1412
1413         if(to_console)
1414                 LOG_INFO(s, "\n");
1415         if(to_eventlog)
1416                 GameLogEcho(s);
1417
1418         file = -1;
1419         if(to_file)
1420         {
1421                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1422                 if(file == -1)
1423                         to_file = false;
1424                 else
1425                         fputs(file, strcat(s, "\n"));
1426         }
1427
1428         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1429         if(to_console)
1430                 LOG_INFO(s, "\n");
1431         if(to_eventlog)
1432                 GameLogEcho(s);
1433         if(to_file)
1434                 fputs(file, strcat(s, "\n"));
1435
1436         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1437                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1438                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1439                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1440                         s = strcat(s, ftos(it.team), ":");
1441                 else
1442                         s = strcat(s, "spectator:");
1443
1444                 if(to_console)
1445                         LOG_INFO(s, it.netname, "\n");
1446                 if(to_eventlog)
1447                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1448                 if(to_file)
1449                         fputs(file, strcat(s, it.netname, "\n"));
1450         ));
1451
1452         if(teamplay)
1453         {
1454                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1455                 if(to_console)
1456                         LOG_INFO(s, "\n");
1457                 if(to_eventlog)
1458                         GameLogEcho(s);
1459                 if(to_file)
1460                         fputs(file, strcat(s, "\n"));
1461
1462                 for(i = 1; i < 16; ++i)
1463                 {
1464                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1465                         s = strcat(s, ":", ftos(i));
1466                         if(to_console)
1467                                 LOG_INFO(s, "\n");
1468                         if(to_eventlog)
1469                                 GameLogEcho(s);
1470                         if(to_file)
1471                                 fputs(file, strcat(s, "\n"));
1472                 }
1473         }
1474
1475         if(to_console)
1476                 LOG_INFO(":end\n");
1477         if(to_eventlog)
1478                 GameLogEcho(":end");
1479         if(to_file)
1480         {
1481                 fputs(file, ":end\n");
1482                 fclose(file);
1483         }
1484 }
1485
1486 void FixIntermissionClient(entity e)
1487 {
1488         if(!e.autoscreenshot) // initial call
1489         {
1490                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1491                 e.health = -2342;
1492                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1493                 e.solid = SOLID_NOT;
1494                 set_movetype(e, MOVETYPE_NONE);
1495                 e.takedamage = DAMAGE_NO;
1496                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1497                 {
1498                     .entity weaponentity = weaponentities[slot];
1499                         if(e.(weaponentity))
1500                         {
1501                                 e.(weaponentity).effects = EF_NODRAW;
1502                                 if (e.(weaponentity).weaponchild)
1503                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1504                         }
1505                 }
1506                 if(IS_REAL_CLIENT(e))
1507                 {
1508                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1509                         RandomSelection_Init();
1510                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1511                                 RandomSelection_AddString(it, 1, 1);
1512                         ));
1513                         if (RandomSelection_chosen_string != "")
1514                         {
1515                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1516                         }
1517                         msg_entity = e;
1518                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1519                 }
1520         }
1521 }
1522
1523 /*
1524 go to the next level for deathmatch
1525 only called if a time or frag limit has expired
1526 */
1527 void NextLevel()
1528 {
1529         gameover = true;
1530
1531         intermission_running = 1;
1532
1533 // enforce a wait time before allowing changelevel
1534         if(player_count > 0)
1535                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1536         else
1537                 intermission_exittime = -1;
1538
1539         /*
1540         WriteByte (MSG_ALL, SVC_CDTRACK);
1541         WriteByte (MSG_ALL, 3);
1542         WriteByte (MSG_ALL, 3);
1543         // done in FixIntermission
1544         */
1545
1546         //pos = FindIntermission ();
1547
1548         VoteReset();
1549
1550         DumpStats(true);
1551
1552         // send statistics
1553         PlayerStats_GameReport(true);
1554         WeaponStats_Shutdown();
1555
1556         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1557
1558         if(autocvar_sv_eventlog)
1559                 GameLogEcho(":gameover");
1560
1561         GameLogClose();
1562
1563         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1564                 FixIntermissionClient(it);
1565                 if(it.winning)
1566                         bprint(it.netname, " ^7wins.\n");
1567         ));
1568
1569         target_music_kill();
1570
1571         if(autocvar_g_campaign)
1572                 CampaignPreIntermission();
1573
1574         MUTATOR_CALLHOOK(MatchEnd);
1575
1576         localcmd("\nsv_hook_gameend\n");
1577 }
1578
1579 /*
1580 ============
1581 CheckRules_Player
1582
1583 Exit deathmatch games upon conditions
1584 ============
1585 */
1586 void CheckRules_Player(entity this)
1587 {
1588         if (gameover)   // someone else quit the game already
1589                 return;
1590
1591         if(!IS_DEAD(this))
1592                 this.play_time += frametime;
1593
1594         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1595         //   (div0: and that in CheckRules_World please)
1596 }
1597
1598
1599 float InitiateSuddenDeath()
1600 {
1601         // Check first whether normal overtimes could be added before initiating suddendeath mode
1602         // - for this timelimit_overtime needs to be >0 of course
1603         // - also check the winning condition calculated in the previous frame and only add normal overtime
1604         //   again, if at the point at which timelimit would be extended again, still no winner was found
1605         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1606         {
1607                 return 1; // need to call InitiateOvertime later
1608         }
1609         else
1610         {
1611                 if(!checkrules_suddendeathend)
1612                 {
1613                         if(autocvar_g_campaign)
1614                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1615                         else
1616                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1617                         if(g_race && !g_race_qualifying)
1618                                 race_StartCompleting();
1619                 }
1620                 return 0;
1621         }
1622 }
1623
1624 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1625 {
1626         ++checkrules_overtimesadded;
1627         //add one more overtime by simply extending the timelimit
1628         float tl;
1629         tl = autocvar_timelimit;
1630         tl += autocvar_timelimit_overtime;
1631         cvar_set("timelimit", ftos(tl));
1632
1633         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1634 }
1635
1636 float GetWinningCode(float fraglimitreached, float equality)
1637 {
1638         if(autocvar_g_campaign == 1)
1639                 if(fraglimitreached)
1640                         return WINNING_YES;
1641                 else
1642                         return WINNING_NO;
1643
1644         else
1645                 if(equality)
1646                         if(fraglimitreached)
1647                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1648                         else
1649                                 return WINNING_NEVER;
1650                 else
1651                         if(fraglimitreached)
1652                                 return WINNING_YES;
1653                         else
1654                                 return WINNING_NO;
1655 }
1656
1657 // set the .winning flag for exactly those players with a given field value
1658 void SetWinners(.float field, float value)
1659 {
1660         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1661 }
1662
1663 // set the .winning flag for those players with a given field value
1664 void AddWinners(.float field, float value)
1665 {
1666         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1667                 if(it.(field) == value)
1668                         it.winning = 1;
1669         ));
1670 }
1671
1672 // clear the .winning flags
1673 void ClearWinners()
1674 {
1675         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1676 }
1677
1678 void ShuffleMaplist()
1679 {
1680         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1681 }
1682
1683 float leaderfrags;
1684 float WinningCondition_Scores(float limit, float leadlimit)
1685 {
1686         float limitreached;
1687
1688         // TODO make everything use THIS winning condition (except LMS)
1689         WinningConditionHelper(NULL);
1690
1691         if(teamplay)
1692         {
1693                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1694                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1695                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1696                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1697         }
1698
1699         ClearWinners();
1700         if(WinningConditionHelper_winner)
1701                 WinningConditionHelper_winner.winning = 1;
1702         if(WinningConditionHelper_winnerteam >= 0)
1703                 SetWinners(team, WinningConditionHelper_winnerteam);
1704
1705         if(WinningConditionHelper_lowerisbetter)
1706         {
1707                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1708                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1709                 limit = -limit;
1710         }
1711
1712         if(WinningConditionHelper_zeroisworst)
1713                 leadlimit = 0; // not supported in this mode
1714
1715         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1716         // these modes always score in increments of 1, thus this makes sense
1717         {
1718                 if(leaderfrags != WinningConditionHelper_topscore)
1719                 {
1720                         leaderfrags = WinningConditionHelper_topscore;
1721
1722                         if (limit)
1723                         if (leaderfrags == limit - 1)
1724                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1725                         else if (leaderfrags == limit - 2)
1726                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1727                         else if (leaderfrags == limit - 3)
1728                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1729                 }
1730         }
1731
1732         limitreached = false;
1733         if(limit)
1734                 if(WinningConditionHelper_topscore >= limit)
1735                         limitreached = true;
1736         if(leadlimit)
1737         {
1738                 float leadlimitreached;
1739                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1740                 if(autocvar_leadlimit_and_fraglimit)
1741                         limitreached = (limitreached && leadlimitreached);
1742                 else
1743                         limitreached = (limitreached || leadlimitreached);
1744         }
1745
1746         if(limit)
1747                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1748
1749         return GetWinningCode(
1750                 WinningConditionHelper_topscore && limitreached,
1751                 WinningConditionHelper_equality
1752         );
1753 }
1754
1755 float WinningCondition_RanOutOfSpawns()
1756 {
1757         if(have_team_spawns <= 0)
1758                 return WINNING_NO;
1759
1760         if(!autocvar_g_spawn_useallspawns)
1761                 return WINNING_NO;
1762
1763         if(!some_spawn_has_been_used)
1764                 return WINNING_NO;
1765
1766         team1_score = team2_score = team3_score = team4_score = 0;
1767
1768         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1769                 switch(it.team)
1770                 {
1771                         case NUM_TEAM_1: team1_score = 1; break;
1772                         case NUM_TEAM_2: team2_score = 1; break;
1773                         case NUM_TEAM_3: team3_score = 1; break;
1774                         case NUM_TEAM_4: team4_score = 1; break;
1775                 }
1776         ));
1777
1778         IL_EACH(g_spawnpoints, true,
1779         {
1780                 switch(it.team)
1781                 {
1782                         case NUM_TEAM_1: team1_score = 1; break;
1783                         case NUM_TEAM_2: team2_score = 1; break;
1784                         case NUM_TEAM_3: team3_score = 1; break;
1785                         case NUM_TEAM_4: team4_score = 1; break;
1786                 }
1787         });
1788
1789         ClearWinners();
1790         if(team1_score + team2_score + team3_score + team4_score == 0)
1791         {
1792                 checkrules_equality = true;
1793                 return WINNING_YES;
1794         }
1795         else if(team1_score + team2_score + team3_score + team4_score == 1)
1796         {
1797                 float t, i;
1798                 if(team1_score)
1799                         t = NUM_TEAM_1;
1800                 else if(team2_score)
1801                         t = NUM_TEAM_2;
1802                 else if(team3_score)
1803                         t = NUM_TEAM_3;
1804                 else // if(team4_score)
1805                         t = NUM_TEAM_4;
1806                 CheckAllowedTeams(NULL);
1807                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1808                 {
1809                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1810                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1811                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1812                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1813                 }
1814
1815                 AddWinners(team, t);
1816                 return WINNING_YES;
1817         }
1818         else
1819                 return WINNING_NO;
1820 }
1821
1822 /*
1823 ============
1824 CheckRules_World
1825
1826 Exit deathmatch games upon conditions
1827 ============
1828 */
1829 void CheckRules_World()
1830 {
1831         float timelimit;
1832         float fraglimit;
1833         float leadlimit;
1834
1835         VoteThink();
1836         MapVote_Think();
1837
1838         SetDefaultAlpha();
1839
1840         if (gameover)   // someone else quit the game already
1841         {
1842                 if(player_count == 0) // Nobody there? Then let's go to the next map
1843                         MapVote_Start();
1844                         // this will actually check the player count in the next frame
1845                         // again, but this shouldn't hurt
1846                 return;
1847         }
1848
1849         timelimit = autocvar_timelimit * 60;
1850         fraglimit = autocvar_fraglimit;
1851         leadlimit = autocvar_leadlimit;
1852
1853         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1854         {
1855                 if(timelimit > 0)
1856                         timelimit = 0; // timelimit is not made for warmup
1857                 if(fraglimit > 0)
1858                         fraglimit = 0; // no fraglimit for now
1859                 leadlimit = 0; // no leadlimit for now
1860         }
1861
1862         if(timelimit > 0)
1863         {
1864                 timelimit += game_starttime;
1865         }
1866         else if (timelimit < 0)
1867         {
1868                 // endmatch
1869                 NextLevel();
1870                 return;
1871         }
1872
1873         float wantovertime;
1874         wantovertime = 0;
1875
1876         if(timelimit > game_starttime)
1877                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1878         else
1879                 game_completion_ratio = 0;
1880
1881         if(checkrules_suddendeathend)
1882         {
1883                 if(!checkrules_suddendeathwarning)
1884                 {
1885                         checkrules_suddendeathwarning = true;
1886                         if(g_race && !g_race_qualifying)
1887                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1888                         else
1889                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1890                 }
1891         }
1892         else
1893         {
1894                 if (timelimit && time >= timelimit)
1895                 {
1896                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1897                         {
1898                                 float totalplayers;
1899                                 float playerswithlaps;
1900                                 float readyplayers;
1901                                 totalplayers = playerswithlaps = readyplayers = 0;
1902                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1903                                         ++totalplayers;
1904                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1905                                                 ++playerswithlaps;
1906                                         if(it.ready)
1907                                                 ++readyplayers;
1908                                 ));
1909
1910                                 // at least 2 of the players have completed a lap: start the RACE
1911                                 // otherwise, the players should end the qualifying on their own
1912                                 if(readyplayers || playerswithlaps >= 2)
1913                                 {
1914                                         checkrules_suddendeathend = 0;
1915                                         ReadyRestart(); // go to race
1916                                         return;
1917                                 }
1918                                 else
1919                                         wantovertime |= InitiateSuddenDeath();
1920                         }
1921                         else
1922                                 wantovertime |= InitiateSuddenDeath();
1923                 }
1924         }
1925
1926         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1927         {
1928                 NextLevel();
1929                 return;
1930         }
1931
1932         int checkrules_status = WinningCondition_RanOutOfSpawns();
1933         if(checkrules_status == WINNING_YES)
1934                 bprint("Hey! Someone ran out of spawns!\n");
1935         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1936                 checkrules_status = M_ARGV(0, float);
1937         else
1938                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1939
1940         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1941         {
1942                 checkrules_status = WINNING_NEVER;
1943                 checkrules_overtimesadded = -1;
1944                 wantovertime |= InitiateSuddenDeath();
1945         }
1946
1947         if(checkrules_status == WINNING_NEVER)
1948                 // equality cases! Nobody wins if the overtime ends in a draw.
1949                 ClearWinners();
1950
1951         if(wantovertime)
1952         {
1953                 if(checkrules_status == WINNING_NEVER)
1954                         InitiateOvertime();
1955                 else
1956                         checkrules_status = WINNING_YES;
1957         }
1958
1959         if(checkrules_suddendeathend)
1960                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1961                         checkrules_status = WINNING_YES;
1962
1963         if(checkrules_status == WINNING_YES)
1964         {
1965                 //print("WINNING\n");
1966                 NextLevel();
1967         }
1968 }
1969
1970 string GotoMap(string m)
1971 {
1972         m = GameTypeVote_MapInfo_FixName(m);
1973         if (!m)
1974                 return "The map you suggested is not available on this server.";
1975         if (!autocvar_sv_vote_gametype)
1976         if(!MapInfo_CheckMap(m))
1977                 return "The map you suggested does not support the current game mode.";
1978         cvar_set("nextmap", m);
1979         cvar_set("timelimit", "-1");
1980         if(mapvote_initialized || alreadychangedlevel)
1981         {
1982                 if(DoNextMapOverride(0))
1983                         return "Map switch initiated.";
1984                 else
1985                         return "Hm... no. For some reason I like THIS map more.";
1986         }
1987         else
1988                 return "Map switch will happen after scoreboard.";
1989 }
1990
1991 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1992 void RunThink(entity this)
1993 {
1994         // don't let things stay in the past.
1995         // it is possible to start that way by a trigger with a local time.
1996         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1997                 return;
1998
1999         float oldtime = time; // do we need to save this?
2000
2001         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2002         {
2003                 time = max(oldtime, this.nextthink);
2004                 this.nextthink = 0;
2005
2006                 if(getthink(this))
2007                         getthink(this)(this);
2008                 // mods often set nextthink to time to cause a think every frame,
2009                 // we don't want to loop in that case, so exit if the new nextthink is
2010                 // <= the time the qc was told, also exit if it is past the end of the
2011                 // frame
2012                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2013                         break;
2014         }
2015
2016         time = oldtime;
2017 }
2018
2019 bool autocvar_sv_freezenonclients;
2020 bool autocvar_sv_gameplayfix_delayprojectiles;
2021 void Physics_Frame()
2022 {
2023         if(autocvar_sv_freezenonclients)
2024                 return;
2025
2026         FOREACH_ENTITY_FLOAT(pure_data, false,
2027         {
2028                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2029                         continue;
2030
2031                 set_movetype(it, it.move_movetype);
2032
2033                 if(it.move_movetype == MOVETYPE_NONE)
2034                         continue;
2035
2036                 if(it.move_qcphysics)
2037                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2038
2039                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2040                 {
2041                         // handle thinking here
2042                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2043                                 RunThink(it);
2044                 }
2045         });
2046
2047         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2048                 return;
2049
2050         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2051         {
2052                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2053                         continue;
2054                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2055         });
2056 }
2057
2058 void systems_update();
2059 void EndFrame()
2060 {
2061         anticheat_endframe();
2062
2063         Physics_Frame();
2064
2065         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2066                 entity e = IS_SPEC(it) ? it.enemy : it;
2067                 if (e.typehitsound) {
2068                         it.typehit_time = time;
2069                 } else if (e.damage_dealt) {
2070                         it.hit_time = time;
2071                         it.damage_dealt_total += ceil(e.damage_dealt);
2072                 }
2073         });
2074         // add 1 frametime because after this, engine SV_Physics
2075         // increases time by a frametime and then networks the frame
2076         // add another frametime because client shows everything with
2077         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2078         // needed!
2079         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2080         FOREACH_CLIENT(true, {
2081                 it.typehitsound = false;
2082                 it.damage_dealt = 0;
2083                 antilag_record(it, CS(it), altime);
2084         });
2085         IL_EACH(g_monsters, true,
2086         {
2087                 antilag_record(it, it, altime);
2088         });
2089         FOREACH_CLIENT(PS(it), {
2090                 PlayerState s = PS(it);
2091                 s.ps_push(s, it);
2092         });
2093         systems_update();
2094         IL_ENDFRAME();
2095 }
2096
2097
2098 /*
2099  * RedirectionThink:
2100  * returns true if redirecting
2101  */
2102 float redirection_timeout;
2103 float redirection_nextthink;
2104 float RedirectionThink()
2105 {
2106         float clients_found;
2107
2108         if(redirection_target == "")
2109                 return false;
2110
2111         if(!redirection_timeout)
2112         {
2113                 cvar_set("sv_public", "-2");
2114                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2115                 if(redirection_target == "self")
2116                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2117                 else
2118                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2119         }
2120
2121         if(time < redirection_nextthink)
2122                 return true;
2123
2124         redirection_nextthink = time + 1;
2125
2126         clients_found = 0;
2127         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2128                 // TODO add timer
2129                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2130                 if(redirection_target == "self")
2131                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2132                 else
2133                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2134                 ++clients_found;
2135         ));
2136
2137         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2138
2139         if(time > redirection_timeout || clients_found == 0)
2140                 localcmd("\nwait; wait; wait; quit\n");
2141
2142         return true;
2143 }
2144
2145 void TargetMusic_RestoreGame();
2146 void RestoreGame()
2147 {
2148         // Loaded from a save game
2149         // some things then break, so let's work around them...
2150
2151         // Progs DB (capture records)
2152         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2153
2154         // Mapinfo
2155         MapInfo_Shutdown();
2156         MapInfo_Enumerate();
2157         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2158         WeaponStats_Init();
2159
2160         TargetMusic_RestoreGame();
2161 }
2162
2163 void Shutdown()
2164 {
2165         gameover = 2;
2166
2167         if(world_initialized > 0)
2168         {
2169                 world_initialized = 0;
2170                 LOG_TRACE("Saving persistent data...");
2171                 Ban_SaveBans();
2172
2173                 // playerstats with unfinished match
2174                 PlayerStats_GameReport(false);
2175
2176                 if(!cheatcount_total)
2177                 {
2178                         if(autocvar_sv_db_saveasdump)
2179                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                         else
2181                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2182                 }
2183                 if(autocvar_developer)
2184                 {
2185                         if(autocvar_sv_db_saveasdump)
2186                                 db_dump(TemporaryDB, "server-temp.db");
2187                         else
2188                                 db_save(TemporaryDB, "server-temp.db");
2189                 }
2190                 CheatShutdown(); // must be after cheatcount check
2191                 db_close(ServerProgsDB);
2192                 db_close(TemporaryDB);
2193                 LOG_TRACE("Saving persistent data... done!");
2194                 // tell the bot system the game is ending now
2195                 bot_endgame();
2196
2197                 WeaponStats_Shutdown();
2198                 MapInfo_Shutdown();
2199         }
2200         else if(world_initialized == 0)
2201         {
2202                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2203         }
2204         else
2205         {
2206                 __init_dedicated_server_shutdown();
2207         }
2208 }