qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "../common/buffs.qh"
   4
   5 #if defined(CSQC)
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "../common/constants.qh"
   9     #include "../common/stats.qh"
  10     #include "../common/teams.qh"
  11     #include "../common/util.qh"
  12     #include "../common/monsters/sv_monsters.qh"
  13     #include "../common/weapons/weapons.qh"
  14     #include "weapons/weaponstats.qh"
  15     #include "autocvars.qh"
  16     #include "constants.qh"
  17     #include "defs.qh"
  18     #include "../common/notifications.qh"
  19     #include "mutators/mutators_include.qh"
  20     #include "campaign.qh"
  21     #include "../common/mapinfo.qh"
  22     #include "command/common.qh"
  23     #include "command/vote.qh"
  24     #include "command/getreplies.qh"
  25     #include "command/sv_cmd.qh"
  26     #include "anticheat.qh"
  27     #include "cheats.qh"
  28     #include "../common/playerstats.qh"
  29     #include "g_hook.qh"
  30     #include "scores.qh"
  31     #include "mapvoting.qh"
  32     #include "ipban.qh"
  33     #include "race.qh"
  34     #include "antilag.qh"
  35     #include "secret.qh"
  36 #endif
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void GotoNextMap(float reinit);
  97 void ShuffleMaplist();
  98 float(float reinit) DoNextMapOverride;
  99
 100 void SetDefaultAlpha()
 101 {
 102         if(autocvar_g_running_guns)
 103         {
 104                 default_player_alpha = -1;
 105                 default_weapon_alpha = +1;
 106         }
 107         else if(g_cloaked)
 108         {
 109                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 110                 default_weapon_alpha = default_player_alpha;
 111         }
 112         else
 113         {
 114                 default_player_alpha = autocvar_g_player_alpha;
 115                 if(default_player_alpha == 0)
 116                         default_player_alpha = 1;
 117                 default_weapon_alpha = default_player_alpha;
 118         }
 119 }
 120
 121 void GotoFirstMap()
 122 {
 123         float n;
 124         if(autocvar__sv_init)
 125         {
 126                 // cvar_set("_sv_init", "0");
 127                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 128                 // to this "init" map on a dedicated server will cause no permanent
 129                 // harm
 130                 if(autocvar_g_maplist_shuffle)
 131                         ShuffleMaplist();
 132                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 133                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 134
 135                 MapInfo_Enumerate();
 136                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 137
 138                 if(!DoNextMapOverride(1))
 139                         GotoNextMap(1);
 140
 141                 return;
 142         }
 143
 144         if(time < 5)
 145         {
 146                 self.nextthink = time;
 147         }
 148         else
 149         {
 150                 self.nextthink = time + 1;
 151                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 152         }
 153 }
 154
 155 void cvar_changes_init()
 156 {
 157         float h;
 158         string k, v, d;
 159         float n, i, adding, pureadding;
 160
 161         if(cvar_changes)
 162                 strunzone(cvar_changes);
 163         cvar_changes = string_null;
 164         if(cvar_purechanges)
 165                 strunzone(cvar_purechanges);
 166         cvar_purechanges = string_null;
 167         cvar_purechanges_count = 0;
 168
 169         h = buf_create();
 170         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 171         n = buf_getsize(h);
 172
 173         adding = true;
 174         pureadding = true;
 175
 176         for(i = 0; i < n; ++i)
 177         {
 178                 k = bufstr_get(h, i);
 179
 180 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 181 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 182 #define BADCVAR(p) if(k == p) continue
 183
 184                 // general excludes and namespaces for server admin used cvars
 185                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 186
 187                 // internal
 188                 BADPREFIX("csqc_");
 189                 BADPREFIX("cvar_check_");
 190                 BADCVAR("gamecfg");
 191                 BADCVAR("g_configversion");
 192                 BADCVAR("g_maplist_index");
 193                 BADCVAR("halflifebsp");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_leadlimit");
 318                 BADCVAR("g_ctf_captimerecord_always");
 319                 BADCVAR("g_ctf_flag_glowtrails");
 320                 BADCVAR("g_ctf_flag_pickup_verbosename");
 321                 BADCVAR("g_domination_point_leadlimit");
 322                 BADCVAR("g_forced_respawn");
 323                 BADCVAR("g_keyhunt_point_leadlimit");
 324                 BADPREFIX("g_mod_");
 325                 BADCVAR("g_nexball_goalleadlimit");
 326                 BADCVAR("leadlimit_and_fraglimit");
 327                 BADCVAR("leadlimit_override");
 328                 BADCVAR("pausable");
 329                 BADCVAR("sv_allow_fullbright");
 330                 BADCVAR("sv_checkforpacketsduringsleep");
 331                 BADCVAR("sv_fraginfo");
 332                 BADCVAR("sv_timeout");
 333                 BADPREFIX("sv_timeout_");
 334                 BADPREFIX("crypto_");
 335                 BADPREFIX("g_chat_");
 336                 BADPREFIX("g_ctf_captimerecord_");
 337                 BADPREFIX("g_maplist_votable_");
 338                 BADPREFIX("net_");
 339                 BADPREFIX("prvm_");
 340                 BADPREFIX("skill_");
 341                 BADPREFIX("sv_cullentities_");
 342                 BADPREFIX("sv_fraginfo_");
 343                 BADPREFIX("sv_maxidle_");
 344                 BADPREFIX("sv_vote_");
 345                 BADPREFIX("timelimit_");
 346                 BADCVAR("gameversion");
 347                 BADPREFIX("gameversion_");
 348                 BADCVAR("sv_namechangetimer");
 349
 350                 // allowed changes to server admins (please sync this to server.cfg)
 351                 // vi commands:
 352                 //   :/"impure"/,$d
 353                 //   :g!,^\/\/[^ /],d
 354                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 355                 //   :%!sort
 356                 // yes, this does contain some redundant stuff, don't really care
 357                 BADCVAR("bot_config_file");
 358                 BADCVAR("bot_number");
 359                 BADCVAR("bot_prefix");
 360                 BADCVAR("bot_suffix");
 361                 BADCVAR("capturelimit_override");
 362                 BADCVAR("fraglimit_override");
 363                 BADCVAR("gametype");
 364                 BADCVAR("g_antilag");
 365                 BADCVAR("g_balance_teams");
 366                 BADCVAR("g_balance_teams_prevent_imbalance");
 367                 BADCVAR("g_balance_teams_scorefactor");
 368                 BADCVAR("g_ban_sync_trusted_servers");
 369                 BADCVAR("g_ban_sync_uri");
 370                 BADCVAR("g_ca_teams_override");
 371                 BADCVAR("g_ctf_ignore_frags");
 372                 BADCVAR("g_domination_point_limit");
 373                 BADCVAR("g_freezetag_teams_override");
 374                 BADCVAR("g_friendlyfire");
 375                 BADCVAR("g_fullbrightitems");
 376                 BADCVAR("g_fullbrightplayers");
 377                 BADCVAR("g_keyhunt_point_limit");
 378                 BADCVAR("g_keyhunt_teams_override");
 379                 BADCVAR("g_lms_lives_override");
 380                 BADCVAR("g_maplist");
 381                 BADCVAR("g_maplist_check_waypoints");
 382                 BADCVAR("g_maplist_mostrecent_count");
 383                 BADCVAR("g_maplist_shuffle");
 384                 BADCVAR("g_maplist_votable");
 385                 BADCVAR("g_maplist_votable_abstain");
 386                 BADCVAR("g_maplist_votable_nodetail");
 387                 BADCVAR("g_maplist_votable_suggestions");
 388                 BADCVAR("g_maxplayers");
 389                 BADCVAR("g_mirrordamage");
 390                 BADCVAR("g_nexball_goallimit");
 391                 BADCVAR("g_powerups");
 392                 BADCVAR("g_start_delay");
 393                 BADCVAR("g_warmup");
 394                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 395                 BADCVAR("hostname");
 396                 BADCVAR("log_file");
 397                 BADCVAR("maxplayers");
 398                 BADCVAR("minplayers");
 399                 BADCVAR("net_address");
 400                 BADCVAR("port");
 401                 BADCVAR("rcon_password");
 402                 BADCVAR("rcon_restricted_commands");
 403                 BADCVAR("rcon_restricted_password");
 404                 BADCVAR("skill");
 405                 BADCVAR("sv_adminnick");
 406                 BADCVAR("sv_autoscreenshot");
 407                 BADCVAR("sv_autotaunt");
 408                 BADCVAR("sv_curl_defaulturl");
 409                 BADCVAR("sv_defaultcharacter");
 410                 BADCVAR("sv_defaultplayercolors");
 411                 BADCVAR("sv_defaultplayermodel");
 412                 BADCVAR("sv_defaultplayerskin");
 413                 BADCVAR("sv_maxidle");
 414                 BADCVAR("sv_maxrate");
 415                 BADCVAR("sv_motd");
 416                 BADCVAR("sv_public");
 417                 BADCVAR("sv_ready_restart");
 418                 BADCVAR("sv_status_privacy");
 419                 BADCVAR("sv_taunt");
 420                 BADCVAR("sv_vote_call");
 421                 BADCVAR("sv_vote_commands");
 422                 BADCVAR("sv_vote_majority_factor");
 423                 BADCVAR("sv_vote_master");
 424                 BADCVAR("sv_vote_master_commands");
 425                 BADCVAR("sv_vote_master_password");
 426                 BADCVAR("sv_vote_simple_majority_factor");
 427                 BADCVAR("teamplay_mode");
 428                 BADCVAR("timelimit_override");
 429                 BADCVAR("g_spawnshieldtime");
 430                 BADPREFIX("g_warmup_");
 431                 BADPREFIX("sv_ready_restart_");
 432
 433                 // mutators that announce themselves properly to the server browser
 434                 BADCVAR("g_instagib");
 435                 BADCVAR("g_new_toys");
 436                 BADCVAR("g_nix");
 437                 BADCVAR("g_grappling_hook");
 438                 BADCVAR("g_jetpack");
 439
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for (;;)
 480         {
 481                 o = world.mins;
 482                 o.x += random() * (world.maxs.x - world.mins.x);
 483                 o.y += random() * (world.maxs.y - world.mins.y);
 484                 o.z += random() * (world.maxs.z - world.mins.z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return true;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 556         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 557         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 558         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 559         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 560
 561         MapInfo_Enumerate();
 562         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 563 }
 564
 565 void Map_MarkAsRecent(string m);
 566 float world_already_spawned;
 567 void Nagger_Init();
 568 void ClientInit_Spawn();
 569 void WeaponStats_Init();
 570 void WeaponStats_Shutdown();
 571 void spawnfunc_worldspawn (void)
 572 {
 573         float fd, l, i, j, n;
 574         string s;
 575
 576         cvar = cvar_normal;
 577         cvar_string = cvar_string_normal;
 578         cvar_set = cvar_set_normal;
 579
 580         if(world_already_spawned)
 581                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 582         world_already_spawned = true;
 583
 584         remove = remove_safely; // during spawning, watch what you remove!
 585
 586         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 587
 588         compressShortVector_init();
 589
 590         entity head;
 591         head = nextent(world);
 592         maxclients = 0;
 593         while(head)
 594         {
 595                 ++maxclients;
 596                 head = nextent(head);
 597         }
 598
 599         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 600
 601         // needs to be done so early because of the constants they create
 602         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 603         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 604         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 605         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 606         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 607         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 608
 609         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 610
 611         TemporaryDB = db_create();
 612
 613         // 0 normal
 614         lightstyle(0, "m");
 615
 616         // 1 FLICKER (first variety)
 617         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 618
 619         // 2 SLOW STRONG PULSE
 620         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 621
 622         // 3 CANDLE (first variety)
 623         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 624
 625         // 4 FAST STROBE
 626         lightstyle(4, "mamamamamama");
 627
 628         // 5 GENTLE PULSE 1
 629         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 630
 631         // 6 FLICKER (second variety)
 632         lightstyle(6, "nmonqnmomnmomomno");
 633
 634         // 7 CANDLE (second variety)
 635         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 636
 637         // 8 CANDLE (third variety)
 638         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 639
 640         // 9 SLOW STROBE (fourth variety)
 641         lightstyle(9, "aaaaaaaazzzzzzzz");
 642
 643         // 10 FLUORESCENT FLICKER
 644         lightstyle(10, "mmamammmmammamamaaamammma");
 645
 646         // 11 SLOW PULSE NOT FADE TO BLACK
 647         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 648
 649         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 650
 651         // 63 testing
 652         lightstyle(63, "a");
 653
 654         if(autocvar_g_campaign)
 655                 CampaignPreInit();
 656
 657         Map_MarkAsRecent(mapname);
 658
 659         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 660
 661         precache_model ("null"); // we need this one before InitGameplayMode
 662         InitGameplayMode();
 663         readlevelcvars();
 664         GrappleHookInit();
 665
 666         player_count = 0;
 667         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 668         if(bot_waypoints_for_items == 1)
 669                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 670                         bot_waypoints_for_items = 0;
 671
 672         precache();
 673
 674         WaypointSprite_Init();
 675
 676         GameLogInit(); // prepare everything
 677         // NOTE for matchid:
 678         // changing the logic generating it is okay. But:
 679         // it HAS to stay <= 64 chars
 680         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 681         if(autocvar_sv_eventlog)
 682         {
 683                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 684                 matchid = strzone(s);
 685
 686                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 687                 s = ":gameinfo:mutators:LIST";
 688
 689                 ret_string = s;
 690                 MUTATOR_CALLHOOK(BuildMutatorsString);
 691                 s = ret_string;
 692
 693                 // simple, probably not good in the mutator system
 694                 if(autocvar_g_grappling_hook)
 695                         s = strcat(s, ":grappling_hook");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(!autocvar_g_use_ammunition)
 699                         s = strcat(s, ":no_use_ammunition");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_pickup_items == 0)
 703                         s = strcat(s, ":no_pickup_items");
 704                 if(autocvar_g_pickup_items > 0)
 705                         s = strcat(s, ":pickup_items");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(autocvar_g_weaponarena != "0")
 709                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_norecoil)
 713                         s = strcat(s, ":norecoil");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_powerups == 0)
 717                         s = strcat(s, ":no_powerups");
 718                 if(autocvar_g_powerups > 0)
 719                         s = strcat(s, ":powerups");
 720
 721                 GameLogEcho(s);
 722                 GameLogEcho(":gameinfo:end");
 723         }
 724         else
 725                 matchid = strzone(ftos(random()));
 726
 727         cvar_set("nextmap", "");
 728
 729         SetDefaultAlpha();
 730
 731         if(autocvar_g_campaign)
 732                 CampaignPostInit();
 733
 734         Ban_LoadBans();
 735
 736         MapInfo_Enumerate();
 737         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 738
 739         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 740         {
 741                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 742                 if(fd != -1)
 743                 {
 744                         while((s = fgets(fd)))
 745                         {
 746                                 l = tokenize_console(s);
 747                                 if(l < 2)
 748                                         continue;
 749                                 if(argv(0) == "cd")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 752                                         print("  cdtrack ", argv(2), "\n");
 753                                 }
 754                                 else if(argv(0) == "fog")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 757                                         print("  \"fog\" \"", s, "\"\n");
 758                                 }
 759                                 else if(argv(0) == "set")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 763                                 }
 764                                 else if(argv(0) != "//")
 765                                 {
 766                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 767                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 768                                 }
 769                         }
 770                         fclose(fd);
 771                 }
 772         }
 773
 774         WeaponStats_Init();
 775
 776         WepSet_AddStat();
 777         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 778         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 779         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 780         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 781         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 782         Nagger_Init();
 783
 784         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 785         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 786         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 787         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 788         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 789         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 790         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 791         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 792         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 793         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 794         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 795         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 796         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 797         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 798         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 799
 800         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 801         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 802
 803         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 804
 805         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 806
 807         // freeze attacks
 808         addstat(STAT_FROZEN, AS_INT, frozen);
 809         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 810
 811         // g_movementspeed hack
 812         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 813         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 814         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 815         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 816
 817         // secrets
 818         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 819         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 820
 821         // monsters
 822         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 823         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 824
 825         // misc
 826         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 827
 828         next_pingtime = time + 5;
 829
 830         detect_maptype();
 831
 832         // set up information replies for clients and server to use
 833         maplist_reply = strzone(getmaplist());
 834         lsmaps_reply = strzone(getlsmaps());
 835         monsterlist_reply = strzone(getmonsterlist());
 836         for(i = 0; i < 10; ++i)
 837         {
 838                 s = getrecords(i);
 839                 if (s)
 840                         records_reply[i] = strzone(s);
 841         }
 842         ladder_reply = strzone(getladder());
 843         rankings_reply = strzone(getrankings());
 844
 845         // begin other init
 846         ClientInit_Spawn();
 847         RandomSeed_Spawn();
 848         PingPLReport_Spawn();
 849
 850         CheatInit();
 851
 852         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 853
 854         // fill sv_curl_serverpackages from .serverpackage files
 855         if(autocvar_sv_curl_serverpackages_auto)
 856         {
 857                 s = "";
 858                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 859                 for(i = 0; i < n; ++i)
 860                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 861                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 862                                 s = strcat(s, " ", argv(i));
 863                 fd = search_begin("*-serverpackage.txt", true, false);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 fd = search_begin("*.serverpackage", true, false);
 872                 if(fd >= 0)
 873                 {
 874                         j = search_getsize(fd);
 875                         for(i = 0; i < j; ++i)
 876                                 s = strcat(s, " ", search_getfilename(fd, i));
 877                         search_end(fd);
 878                 }
 879                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 880         }
 881
 882         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 883         modname = "Xonotic";
 884         // physics/balance/config changes that count as mod
 885         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 886                 modname = cvar_string("g_mod_physics");
 887         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 888                 modname = cvar_string("g_mod_balance");
 889         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 890                 modname = cvar_string("g_mod_config");
 891         // extra mutators that deserve to count as mod
 892         MUTATOR_CALLHOOK(SetModname);
 893
 894         // save it for later
 895         modname = strzone(modname);
 896
 897         WinningConditionHelper(); // set worldstatus
 898
 899         world_initialized = 1;
 900 }
 901
 902 void spawnfunc_light (void)
 903 {
 904         //makestatic (self); // Who the f___ did that?
 905         remove(self);
 906 }
 907
 908 string GetGametype()
 909 {
 910         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 911 }
 912
 913 string GetMapname()
 914 {
 915         return mapname;
 916 }
 917
 918 float Map_Count, Map_Current;
 919 string Map_Current_Name;
 920
 921 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 922 float GetMaplistPosition()
 923 {
 924         float pos, idx;
 925         string map;
 926
 927         map = GetMapname();
 928         idx = autocvar_g_maplist_index;
 929
 930         if(idx >= 0)
 931                 if(idx < Map_Count)
 932                         if(map == argv(idx))
 933                                 return idx;
 934
 935         for(pos = 0; pos < Map_Count; ++pos)
 936                 if(map == argv(pos))
 937                         return pos;
 938
 939         // resume normal maplist rotation if current map is not in g_maplist
 940         return idx;
 941 }
 942
 943 float MapHasRightSize(string map)
 944 {
 945         float fh;
 946         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 947         if(autocvar_g_maplist_check_waypoints)
 948         {
 949                 dprint("checkwp "); dprint(map);
 950                 if(!fexists(strcat("maps/", map, ".waypoints")))
 951                 {
 952                         dprint(": no waypoints\n");
 953                         return false;
 954                 }
 955                 dprint(": has waypoints\n");
 956         }
 957
 958         // open map size restriction file
 959         dprint("opensize "); dprint(map);
 960         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 961         if(fh >= 0)
 962         {
 963                 float mapmin, mapmax;
 964                 dprint(": ok, ");
 965                 mapmin = stof(fgets(fh));
 966                 mapmax = stof(fgets(fh));
 967                 fclose(fh);
 968                 if(player_count < mapmin)
 969                 {
 970                         dprint("not enough\n");
 971                         return false;
 972                 }
 973                 if(player_count > mapmax)
 974                 {
 975                         dprint("too many\n");
 976                         return false;
 977                 }
 978                 dprint("right size\n");
 979                 return true;
 980         }
 981         dprint(": not found\n");
 982         return true;
 983 }
 984
 985 string Map_Filename(float position)
 986 {
 987         return strcat("maps/", argv(position), ".bsp");
 988 }
 989
 990 string strwords(string s, float w)
 991 {
 992         float endpos;
 993         for(endpos = 0; w && endpos >= 0; --w)
 994                 endpos = strstrofs(s, " ", endpos + 1);
 995         if(endpos < 0)
 996                 return s;
 997         else
 998                 return substring(s, 0, endpos);
 999 }
1000
1001 float strhasword(string s, string w)
1002 {
1003         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1004 }
1005
1006 void Map_MarkAsRecent(string m)
1007 {
1008         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1009 }
1010
1011 float Map_IsRecent(string m)
1012 {
1013         return strhasword(autocvar_g_maplist_mostrecent, m);
1014 }
1015
1016 float Map_Check(float position, float pass)
1017 {
1018         string filename;
1019         string map_next;
1020         map_next = argv(position);
1021         if(pass <= 1)
1022         {
1023                 if(Map_IsRecent(map_next))
1024                         return 0;
1025         }
1026         filename = Map_Filename(position);
1027         if(MapInfo_CheckMap(map_next))
1028         {
1029                 if(pass == 2)
1030                         return 1;
1031                 if(MapHasRightSize(map_next))
1032                         return 1;
1033                 return 0;
1034         }
1035         else
1036                 dprint( "Couldn't select '", filename, "'..\n" );
1037
1038         return 0;
1039 }
1040
1041 void Map_Goto_SetStr(string nextmapname)
1042 {
1043         if(getmapname_stored != "")
1044                 strunzone(getmapname_stored);
1045         if(nextmapname == "")
1046                 getmapname_stored = "";
1047         else
1048                 getmapname_stored = strzone(nextmapname);
1049 }
1050
1051 void Map_Goto_SetFloat(float position)
1052 {
1053         cvar_set("g_maplist_index", ftos(position));
1054         Map_Goto_SetStr(argv(position));
1055 }
1056
1057 void Map_Goto(float reinit)
1058 {
1059         MapInfo_LoadMap(getmapname_stored, reinit);
1060 }
1061
1062 // return codes of map selectors:
1063 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1064 //   -2 = permanent failure
1065 float() MaplistMethod_Iterate = // usual method
1066 {
1067         float pass, i;
1068
1069         dprint("Trying MaplistMethod_Iterate\n");
1070
1071         for(pass = 1; pass <= 2; ++pass)
1072         {
1073                 for(i = 1; i < Map_Count; ++i)
1074                 {
1075                         float mapindex;
1076                         mapindex = (i + Map_Current) % Map_Count;
1077                         if(Map_Check(mapindex, pass))
1078                                 return mapindex;
1079                 }
1080         }
1081         return -1;
1082 }
1083
1084 float() MaplistMethod_Repeat = // fallback method
1085 {
1086         dprint("Trying MaplistMethod_Repeat\n");
1087
1088         if(Map_Check(Map_Current, 2))
1089                 return Map_Current;
1090         return -2;
1091 }
1092
1093 float() MaplistMethod_Random = // random map selection
1094 {
1095         float i, imax;
1096
1097         dprint("Trying MaplistMethod_Random\n");
1098
1099         imax = 42;
1100
1101         for(i = 0; i <= imax; ++i)
1102         {
1103                 float mapindex;
1104                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1105                 if(Map_Check(mapindex, 1))
1106                         return mapindex;
1107         }
1108         return -1;
1109 }
1110
1111 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1112 // the exponent sets a bias on the map selection:
1113 // the higher the exponent, the less likely "shortly repeated" same maps are
1114 {
1115         float i, j, imax, insertpos;
1116
1117         dprint("Trying MaplistMethod_Shuffle\n");
1118
1119         imax = 42;
1120
1121         for(i = 0; i <= imax; ++i)
1122         {
1123                 string newlist;
1124
1125                 // now reinsert this at another position
1126                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1127                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1128                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1129                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1130
1131                 // insert the current map there
1132                 newlist = "";
1133                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1134                         newlist = strcat(newlist, " ", argv(j));
1135                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1136                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1137                         newlist = strcat(newlist, " ", argv(j));
1138                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1139                 cvar_set("g_maplist", newlist);
1140                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1141
1142                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1143                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1144                 if(Map_Check(Map_Current, 1))
1145                         return Map_Current;
1146         }
1147         return -1;
1148 }
1149
1150 void Maplist_Init()
1151 {
1152         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1153         float i;
1154         for (i = 0; i < Map_Count; ++i)
1155                 if (Map_Check(i, 2))
1156                         break;
1157         if (i == Map_Count)
1158         {
1159                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1160                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1161                 if(autocvar_g_maplist_shuffle)
1162                         ShuffleMaplist();
1163                 localcmd("\nmenu_cmd sync\n");
1164                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1165         }
1166         if(Map_Count == 0)
1167                 error("empty maplist, cannot select a new map");
1168         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1169
1170         if(Map_Current_Name)
1171                 strunzone(Map_Current_Name);
1172         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1173         // this may or may not be correct, but who cares, in the worst case a map
1174         // isn't chosen in the first pass that should have been
1175 }
1176
1177 string GetNextMap()
1178 {
1179         float nextMap;
1180
1181         Maplist_Init();
1182         nextMap = -1;
1183
1184         if(nextMap == -1)
1185                 if(autocvar_g_maplist_shuffle > 0)
1186                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1187
1188         if(nextMap == -1)
1189                 if(autocvar_g_maplist_selectrandom)
1190                         nextMap = MaplistMethod_Random();
1191
1192         if(nextMap == -1)
1193                 nextMap = MaplistMethod_Iterate();
1194
1195         if(nextMap == -1)
1196                 nextMap = MaplistMethod_Repeat();
1197
1198         if(nextMap >= 0)
1199         {
1200                 Map_Goto_SetFloat(nextMap);
1201                 return getmapname_stored;
1202         }
1203
1204         return "";
1205 }
1206
1207 float DoNextMapOverride(float reinit)
1208 {
1209         if(autocvar_g_campaign)
1210         {
1211                 CampaignPostIntermission();
1212                 alreadychangedlevel = true;
1213                 return true;
1214         }
1215         if(autocvar_quit_when_empty)
1216         {
1217                 if(player_count <= currentbots)
1218                 {
1219                         localcmd("quit\n");
1220                         alreadychangedlevel = true;
1221                         return true;
1222                 }
1223         }
1224         if(autocvar_quit_and_redirect != "")
1225         {
1226                 redirection_target = strzone(autocvar_quit_and_redirect);
1227                 alreadychangedlevel = true;
1228                 return true;
1229         }
1230         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1231         {
1232                 localcmd("restart\n");
1233                 alreadychangedlevel = true;
1234                 return true;
1235         }
1236         if(autocvar_nextmap != "")
1237         {
1238                 string m;
1239                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1240                 cvar_set("nextmap",m);
1241
1242                 if(!m || gametypevote)
1243                         return false;
1244                 if(autocvar_sv_vote_gametype)
1245                 {
1246                         Map_Goto_SetStr(m);
1247                         return false;
1248                 }
1249
1250                 if(MapInfo_CheckMap(m))
1251                 {
1252                         Map_Goto_SetStr(m);
1253                         Map_Goto(reinit);
1254                         alreadychangedlevel = true;
1255                         return true;
1256                 }
1257         }
1258         if(!reinit && autocvar_lastlevel)
1259         {
1260                 cvar_settemp_restore();
1261                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1262                 alreadychangedlevel = true;
1263                 return true;
1264         }
1265         return false;
1266 }
1267
1268 void GotoNextMap(float reinit)
1269 {
1270         //string nextmap;
1271         //float n, nummaps;
1272         //string s;
1273         if (alreadychangedlevel)
1274                 return;
1275         alreadychangedlevel = true;
1276
1277         string nextMap;
1278
1279         nextMap = GetNextMap();
1280         if(nextMap == "")
1281                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1282         Map_Goto(reinit);
1283 }
1284
1285
1286 /*
1287 ============
1288 IntermissionThink
1289
1290 When the player presses attack or jump, change to the next level
1291 ============
1292 */
1293 .float autoscreenshot;
1294 void IntermissionThink()
1295 {
1296         FixIntermissionClient(self);
1297
1298         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1299         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1300
1301         if( (server_screenshot || client_screenshot)
1302                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1303         {
1304                 self.autoscreenshot = -1;
1305                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1306                 return;
1307         }
1308
1309         if (time < intermission_exittime)
1310                 return;
1311
1312         if(!mapvote_initialized)
1313                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1314                         return;
1315
1316         MapVote_Start();
1317 }
1318
1319 /*
1320 ============
1321 FindIntermission
1322
1323 Returns the entity to view from
1324 ============
1325 */
1326 /*
1327 entity FindIntermission()
1328 {
1329         local   entity spot;
1330         local   float cyc;
1331
1332 // look for info_intermission first
1333         spot = find (world, classname, "info_intermission");
1334         if (spot)
1335         {       // pick a random one
1336                 cyc = random() * 4;
1337                 while (cyc > 1)
1338                 {
1339                         spot = find (spot, classname, "info_intermission");
1340                         if (!spot)
1341                                 spot = find (spot, classname, "info_intermission");
1342                         cyc = cyc - 1;
1343                 }
1344                 return spot;
1345         }
1346
1347 // then look for the start position
1348         spot = find (world, classname, "info_player_start");
1349         if (spot)
1350                 return spot;
1351
1352 // testinfo_player_start is only found in regioned levels
1353         spot = find (world, classname, "testplayerstart");
1354         if (spot)
1355                 return spot;
1356
1357 // then look for the start position
1358         spot = find (world, classname, "info_player_deathmatch");
1359         if (spot)
1360                 return spot;
1361
1362         //objerror ("FindIntermission: no spot");
1363         return world;
1364 }
1365 */
1366
1367 /*
1368 ===============================================================================
1369
1370 RULES
1371
1372 ===============================================================================
1373 */
1374
1375 void DumpStats(float final)
1376 {
1377         float file;
1378         string s;
1379         float to_console;
1380         float to_eventlog;
1381         float to_file;
1382         float i;
1383
1384         to_console = autocvar_sv_logscores_console;
1385         to_eventlog = autocvar_sv_eventlog;
1386         to_file = autocvar_sv_logscores_file;
1387
1388         if(!final)
1389         {
1390                 to_console = true; // always print printstats replies
1391                 to_eventlog = false; // but never print them to the event log
1392         }
1393
1394         if(to_eventlog)
1395                 if(autocvar_sv_eventlog_console)
1396                         to_console = false; // otherwise we get the output twice
1397
1398         if(final)
1399                 s = ":scores:";
1400         else
1401                 s = ":status:";
1402         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1403
1404         if(to_console)
1405                 print(s, "\n");
1406         if(to_eventlog)
1407                 GameLogEcho(s);
1408
1409         file = -1;
1410         if(to_file)
1411         {
1412                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1413                 if(file == -1)
1414                         to_file = false;
1415                 else
1416                         fputs(file, strcat(s, "\n"));
1417         }
1418
1419         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1420         if(to_console)
1421                 print(s, "\n");
1422         if(to_eventlog)
1423                 GameLogEcho(s);
1424         if(to_file)
1425                 fputs(file, strcat(s, "\n"));
1426
1427         FOR_EACH_CLIENT(other)
1428         {
1429                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1430                 {
1431                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1432                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1433                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1434                                 s = strcat(s, ftos(other.team), ":");
1435                         else
1436                                 s = strcat(s, "spectator:");
1437
1438                         if(to_console)
1439                                 print(s, other.netname, "\n");
1440                         if(to_eventlog)
1441                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1442                         if(to_file)
1443                                 fputs(file, strcat(s, other.netname, "\n"));
1444                 }
1445         }
1446
1447         if(teamplay)
1448         {
1449                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1450                 if(to_console)
1451                         print(s, "\n");
1452                 if(to_eventlog)
1453                         GameLogEcho(s);
1454                 if(to_file)
1455                         fputs(file, strcat(s, "\n"));
1456
1457                 for(i = 1; i < 16; ++i)
1458                 {
1459                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1460                         s = strcat(s, ":", ftos(i));
1461                         if(to_console)
1462                                 print(s, "\n");
1463                         if(to_eventlog)
1464                                 GameLogEcho(s);
1465                         if(to_file)
1466                                 fputs(file, strcat(s, "\n"));
1467                 }
1468         }
1469
1470         if(to_console)
1471                 print(":end\n");
1472         if(to_eventlog)
1473                 GameLogEcho(":end");
1474         if(to_file)
1475         {
1476                 fputs(file, ":end\n");
1477                 fclose(file);
1478         }
1479 }
1480
1481 void FixIntermissionClient(entity e)
1482 {
1483         string s;
1484         if(!e.autoscreenshot) // initial call
1485         {
1486                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1487                 e.health = -2342;
1488                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1489                 e.solid = SOLID_NOT;
1490                 e.movetype = MOVETYPE_NONE;
1491                 e.takedamage = DAMAGE_NO;
1492                 if(e.weaponentity)
1493                 {
1494                         e.weaponentity.effects = EF_NODRAW;
1495                         if (e.weaponentity.weaponentity)
1496                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1497                 }
1498                 if(IS_REAL_CLIENT(e))
1499                 {
1500                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1501                         s = autocvar_sv_intermission_cdtrack;
1502                         if(s != "")
1503                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1504                         msg_entity = e;
1505                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1506                 }
1507         }
1508 }
1509
1510 /*
1511 go to the next level for deathmatch
1512 only called if a time or frag limit has expired
1513 */
1514 void NextLevel()
1515 {
1516         gameover = true;
1517
1518         intermission_running = 1;
1519
1520 // enforce a wait time before allowing changelevel
1521         if(player_count > 0)
1522                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1523         else
1524                 intermission_exittime = -1;
1525
1526         /*
1527         WriteByte (MSG_ALL, SVC_CDTRACK);
1528         WriteByte (MSG_ALL, 3);
1529         WriteByte (MSG_ALL, 3);
1530         // done in FixIntermission
1531         */
1532
1533         //pos = FindIntermission ();
1534
1535         VoteReset();
1536
1537         DumpStats(true);
1538
1539         // send statistics
1540         PlayerStats_GameReport(true);
1541         WeaponStats_Shutdown();
1542
1543         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1544
1545         if(autocvar_sv_eventlog)
1546                 GameLogEcho(":gameover");
1547
1548         GameLogClose();
1549
1550         FOR_EACH_PLAYER(other) {
1551                 FixIntermissionClient(other);
1552                 if(other.winning)
1553                         bprint(other.netname, " ^7wins.\n");
1554         }
1555
1556         if(autocvar_g_campaign)
1557                 CampaignPreIntermission();
1558
1559         MUTATOR_CALLHOOK(MatchEnd);
1560
1561         localcmd("\nsv_hook_gameend\n");
1562 }
1563
1564 /*
1565 ============
1566 CheckRules_Player
1567
1568 Exit deathmatch games upon conditions
1569 ============
1570 */
1571 void CheckRules_Player()
1572 {
1573         if (gameover)   // someone else quit the game already
1574                 return;
1575
1576         if(self.deadflag == DEAD_NO)
1577                 self.play_time += frametime;
1578
1579         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1580         //   (div0: and that in CheckRules_World please)
1581 }
1582
1583
1584 float InitiateSuddenDeath()
1585 {
1586         // Check first whether normal overtimes could be added before initiating suddendeath mode
1587         // - for this timelimit_overtime needs to be >0 of course
1588         // - also check the winning condition calculated in the previous frame and only add normal overtime
1589         //   again, if at the point at which timelimit would be extended again, still no winner was found
1590         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1591         {
1592                 return 1; // need to call InitiateOvertime later
1593         }
1594         else
1595         {
1596                 if(!checkrules_suddendeathend)
1597                 {
1598                         if(autocvar_g_campaign)
1599                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1600                         else
1601                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1602                         if(g_race && !g_race_qualifying)
1603                                 race_StartCompleting();
1604                 }
1605                 return 0;
1606         }
1607 }
1608
1609 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1610 {
1611         ++checkrules_overtimesadded;
1612         //add one more overtime by simply extending the timelimit
1613         float tl;
1614         tl = autocvar_timelimit;
1615         tl += autocvar_timelimit_overtime;
1616         cvar_set("timelimit", ftos(tl));
1617
1618         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1619 }
1620
1621 float GetWinningCode(float fraglimitreached, float equality)
1622 {
1623         if(autocvar_g_campaign == 1)
1624                 if(fraglimitreached)
1625                         return WINNING_YES;
1626                 else
1627                         return WINNING_NO;
1628
1629         else
1630                 if(equality)
1631                         if(fraglimitreached)
1632                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1633                         else
1634                                 return WINNING_NEVER;
1635                 else
1636                         if(fraglimitreached)
1637                                 return WINNING_YES;
1638                         else
1639                                 return WINNING_NO;
1640 }
1641
1642 // set the .winning flag for exactly those players with a given field value
1643 void SetWinners(.float field, float value)
1644 {
1645         entity head;
1646         FOR_EACH_PLAYER(head)
1647                 head.winning = (head.field == value);
1648 }
1649
1650 // set the .winning flag for those players with a given field value
1651 void AddWinners(.float field, float value)
1652 {
1653         entity head;
1654         FOR_EACH_PLAYER(head)
1655                 if(head.field == value)
1656                         head.winning = 1;
1657 }
1658
1659 // clear the .winning flags
1660 void ClearWinners(void)
1661 {
1662         entity head;
1663         FOR_EACH_PLAYER(head)
1664                 head.winning = 0;
1665 }
1666
1667 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1668 // they win. Otherwise the defending team wins once the timelimit passes.
1669 void assault_new_round();
1670 float WinningCondition_Assault()
1671 {
1672         float status;
1673
1674         WinningConditionHelper(); // set worldstatus
1675
1676         status = WINNING_NO;
1677         // as the timelimit has not yet passed just assume the defending team will win
1678         if(assault_attacker_team == NUM_TEAM_1)
1679         {
1680                 SetWinners(team, NUM_TEAM_2);
1681         }
1682         else
1683         {
1684                 SetWinners(team, NUM_TEAM_1);
1685         }
1686
1687         entity ent;
1688         ent = find(world, classname, "target_assault_roundend");
1689         if(ent)
1690         {
1691                 if(ent.winning) // round end has been triggered by attacking team
1692                 {
1693                         bprint("ASSAULT: round completed...\n");
1694                         SetWinners(team, assault_attacker_team);
1695
1696                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1697
1698                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1699                         {
1700                                 status = WINNING_YES;
1701                         }
1702                         else
1703                         {
1704                                 entity oldself;
1705                                 oldself = self;
1706                                 self = ent;
1707                                 assault_new_round();
1708                                 self = oldself;
1709                         }
1710                 }
1711         }
1712
1713         return status;
1714 }
1715
1716 // LMS winning condition: game terminates if and only if there's at most one
1717 // one player who's living lives. Top two scores being equal cancels the time
1718 // limit.
1719 float WinningCondition_LMS()
1720 {
1721         entity head, head2;
1722         float have_player;
1723         float have_players;
1724         float l;
1725
1726         have_player = false;
1727         have_players = false;
1728         l = LMS_NewPlayerLives();
1729
1730         head = find(world, classname, "player");
1731         if(head)
1732                 have_player = true;
1733         head2 = find(head, classname, "player");
1734         if(head2)
1735                 have_players = true;
1736
1737         if(have_player)
1738         {
1739                 // we have at least one player
1740                 if(have_players)
1741                 {
1742                         // two or more active players - continue with the game
1743                 }
1744                 else
1745                 {
1746                         // exactly one player?
1747
1748                         ClearWinners();
1749                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1750
1751                         if(l)
1752                         {
1753                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1754                                 return WINNING_NO;
1755                         }
1756                         else
1757                         {
1758                                 // a winner!
1759                                 // and assign him his first place
1760                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1761                                 return WINNING_YES;
1762                         }
1763                 }
1764         }
1765         else
1766         {
1767                 // nobody is playing at all...
1768                 if(l)
1769                 {
1770                         // wait for players...
1771                 }
1772                 else
1773                 {
1774                         // SNAFU (maybe a draw game?)
1775                         ClearWinners();
1776                         dprint("No players, ending game.\n");
1777                         return WINNING_YES;
1778                 }
1779         }
1780
1781         // When we get here, we have at least two players who are actually LIVING,
1782         // now check if the top two players have equal score.
1783         WinningConditionHelper();
1784
1785         ClearWinners();
1786         if(WinningConditionHelper_winner)
1787                 WinningConditionHelper_winner.winning = true;
1788         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1789                 return WINNING_NEVER;
1790
1791         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1792         return WINNING_NO;
1793 }
1794
1795 void ShuffleMaplist()
1796 {
1797         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1798 }
1799
1800 float leaderfrags;
1801 float WinningCondition_Scores(float limit, float leadlimit)
1802 {
1803         float limitreached;
1804
1805         // TODO make everything use THIS winning condition (except LMS)
1806         WinningConditionHelper();
1807
1808         if(teamplay)
1809         {
1810                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1811                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1812                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1813                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1814         }
1815
1816         ClearWinners();
1817         if(WinningConditionHelper_winner)
1818                 WinningConditionHelper_winner.winning = 1;
1819         if(WinningConditionHelper_winnerteam >= 0)
1820                 SetWinners(team, WinningConditionHelper_winnerteam);
1821
1822         if(WinningConditionHelper_lowerisbetter)
1823         {
1824                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1825                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1826                 limit = -limit;
1827         }
1828
1829         if(WinningConditionHelper_zeroisworst)
1830                 leadlimit = 0; // not supported in this mode
1831
1832         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1833         // these modes always score in increments of 1, thus this makes sense
1834         {
1835                 if(leaderfrags != WinningConditionHelper_topscore)
1836                 {
1837                         leaderfrags = WinningConditionHelper_topscore;
1838
1839                         if (limit)
1840                         if (leaderfrags == limit - 1)
1841                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1842                         else if (leaderfrags == limit - 2)
1843                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1844                         else if (leaderfrags == limit - 3)
1845                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1846                 }
1847         }
1848
1849         limitreached = false;
1850         if(limit)
1851                 if(WinningConditionHelper_topscore >= limit)
1852                         limitreached = true;
1853         if(leadlimit)
1854         {
1855                 float leadlimitreached;
1856                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1857                 if(autocvar_leadlimit_and_fraglimit)
1858                         limitreached = (limitreached && leadlimitreached);
1859                 else
1860                         limitreached = (limitreached || leadlimitreached);
1861         }
1862
1863         if(limit)
1864                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1865
1866         return GetWinningCode(
1867                 WinningConditionHelper_topscore && limitreached,
1868                 WinningConditionHelper_equality
1869         );
1870 }
1871
1872 float WinningCondition_Race(float fraglimit)
1873 {
1874         float wc;
1875         entity p;
1876         float n, c;
1877
1878         n = 0;
1879         c = 0;
1880         FOR_EACH_PLAYER(p)
1881         {
1882                 ++n;
1883                 if(p.race_completed)
1884                         ++c;
1885         }
1886         if(n && (n == c))
1887                 return WINNING_YES;
1888         wc = WinningCondition_Scores(fraglimit, 0);
1889
1890         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1891         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1892         // do NOT support equality when the laps are all raced!
1893                 return WINNING_STARTSUDDENDEATHOVERTIME;
1894         else
1895                 return WINNING_NEVER;
1896 }
1897
1898 float WinningCondition_QualifyingThenRace(float limit)
1899 {
1900         float wc;
1901         wc = WinningCondition_Scores(limit, 0);
1902
1903         // NEVER initiate overtime
1904         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1905         {
1906                 return WINNING_YES;
1907         }
1908
1909         return wc;
1910 }
1911
1912 float WinningCondition_RanOutOfSpawns()
1913 {
1914         entity head;
1915
1916         if(have_team_spawns <= 0)
1917                 return WINNING_NO;
1918
1919         if(autocvar_g_spawn_useallspawns <= 0)
1920                 return WINNING_NO;
1921
1922         if(!some_spawn_has_been_used)
1923                 return WINNING_NO;
1924
1925         team1_score = team2_score = team3_score = team4_score = 0;
1926
1927         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1928         {
1929                 if(head.team == NUM_TEAM_1)
1930                         team1_score = 1;
1931                 else if(head.team == NUM_TEAM_2)
1932                         team2_score = 1;
1933                 else if(head.team == NUM_TEAM_3)
1934                         team3_score = 1;
1935                 else if(head.team == NUM_TEAM_4)
1936                         team4_score = 1;
1937         }
1938
1939         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1940         {
1941                 if(head.team == NUM_TEAM_1)
1942                         team1_score = 1;
1943                 else if(head.team == NUM_TEAM_2)
1944                         team2_score = 1;
1945                 else if(head.team == NUM_TEAM_3)
1946                         team3_score = 1;
1947                 else if(head.team == NUM_TEAM_4)
1948                         team4_score = 1;
1949         }
1950
1951         ClearWinners();
1952         if(team1_score + team2_score + team3_score + team4_score == 0)
1953         {
1954                 checkrules_equality = true;
1955                 return WINNING_YES;
1956         }
1957         else if(team1_score + team2_score + team3_score + team4_score == 1)
1958         {
1959                 float t, i;
1960                 if(team1_score)
1961                         t = NUM_TEAM_1;
1962                 else if(team2_score)
1963                         t = NUM_TEAM_2;
1964                 else if(team3_score)
1965                         t = NUM_TEAM_3;
1966                 else // if(team4_score)
1967                         t = NUM_TEAM_4;
1968                 CheckAllowedTeams(world);
1969                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1970                 {
1971                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1972                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1973                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1974                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1975                 }
1976
1977                 AddWinners(team, t);
1978                 return WINNING_YES;
1979         }
1980         else
1981                 return WINNING_NO;
1982 }
1983
1984 /*
1985 ============
1986 CheckRules_World
1987
1988 Exit deathmatch games upon conditions
1989 ============
1990 */
1991 void ReadyRestart();
1992 void CheckRules_World()
1993 {
1994         float timelimit;
1995         float fraglimit;
1996         float leadlimit;
1997
1998         VoteThink();
1999         MapVote_Think();
2000
2001         SetDefaultAlpha();
2002
2003         if (gameover)   // someone else quit the game already
2004         {
2005                 if(player_count == 0) // Nobody there? Then let's go to the next map
2006                         MapVote_Start();
2007                         // this will actually check the player count in the next frame
2008                         // again, but this shouldn't hurt
2009                 return;
2010         }
2011
2012         timelimit = autocvar_timelimit * 60;
2013         fraglimit = autocvar_fraglimit;
2014         leadlimit = autocvar_leadlimit;
2015
2016         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2017         {
2018                 if(timelimit > 0)
2019                         timelimit = 0; // timelimit is not made for warmup
2020                 if(fraglimit > 0)
2021                         fraglimit = 0; // no fraglimit for now
2022                 leadlimit = 0; // no leadlimit for now
2023         }
2024
2025         if(timelimit > 0)
2026         {
2027                 timelimit += game_starttime;
2028         }
2029         else if (timelimit < 0)
2030         {
2031                 // endmatch
2032                 NextLevel();
2033                 return;
2034         }
2035
2036         float wantovertime;
2037         wantovertime = 0;
2038
2039         if(timelimit > game_starttime)
2040                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2041         else
2042                 game_completion_ratio = 0;
2043
2044         if(checkrules_suddendeathend)
2045         {
2046                 if(!checkrules_suddendeathwarning)
2047                 {
2048                         checkrules_suddendeathwarning = true;
2049                         if(g_race && !g_race_qualifying)
2050                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2051                         else
2052                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2053                 }
2054         }
2055         else
2056         {
2057                 if (timelimit && time >= timelimit)
2058                 {
2059                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2060                         {
2061                                 float totalplayers;
2062                                 float playerswithlaps;
2063                                 float readyplayers;
2064                                 entity head;
2065                                 totalplayers = playerswithlaps = readyplayers = 0;
2066                                 FOR_EACH_PLAYER(head)
2067                                 {
2068                                         ++totalplayers;
2069                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2070                                                 ++playerswithlaps;
2071                                         if(head.ready)
2072                                                 ++readyplayers;
2073                                 }
2074
2075                                 // at least 2 of the players have completed a lap: start the RACE
2076                                 // otherwise, the players should end the qualifying on their own
2077                                 if(readyplayers || playerswithlaps >= 2)
2078                                 {
2079                                         checkrules_suddendeathend = 0;
2080                                         ReadyRestart(); // go to race
2081                                         return;
2082                                 }
2083                                 else
2084                                         wantovertime |= InitiateSuddenDeath();
2085                         }
2086                         else
2087                                 wantovertime |= InitiateSuddenDeath();
2088                 }
2089         }
2090
2091         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2092         {
2093                 NextLevel();
2094                 return;
2095         }
2096
2097         float checkrules_status;
2098         checkrules_status = WinningCondition_RanOutOfSpawns();
2099         if(checkrules_status == WINNING_YES)
2100         {
2101                 bprint("Hey! Someone ran out of spawns!\n");
2102         }
2103         else if(g_race && !g_race_qualifying && timelimit >= 0)
2104         {
2105                 checkrules_status = WinningCondition_Race(fraglimit);
2106                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2107         }
2108         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2109         {
2110                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2111                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2112         }
2113         else if(g_assault)
2114         {
2115                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2116         }
2117         else if(g_lms)
2118         {
2119                 checkrules_status = WinningCondition_LMS();
2120         }
2121         else
2122         {
2123                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2124                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2125         }
2126
2127         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2128         {
2129                 checkrules_status = WINNING_NEVER;
2130                 checkrules_overtimesadded = -1;
2131                 wantovertime |= InitiateSuddenDeath();
2132         }
2133
2134         if(checkrules_status == WINNING_NEVER)
2135                 // equality cases! Nobody wins if the overtime ends in a draw.
2136                 ClearWinners();
2137
2138         if(wantovertime)
2139         {
2140                 if(checkrules_status == WINNING_NEVER)
2141                         InitiateOvertime();
2142                 else
2143                         checkrules_status = WINNING_YES;
2144         }
2145
2146         if(checkrules_suddendeathend)
2147                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2148                         checkrules_status = WINNING_YES;
2149
2150         if(checkrules_status == WINNING_YES)
2151         {
2152                 //print("WINNING\n");
2153                 NextLevel();
2154         }
2155 }
2156
2157 string GotoMap(string m)
2158 {
2159         m = GameTypeVote_MapInfo_FixName(m);
2160         if (!m)
2161                 return "The map you suggested is not available on this server.";
2162         if (!autocvar_sv_vote_gametype)
2163         if(!MapInfo_CheckMap(m))
2164                 return "The map you suggested does not support the current game mode.";
2165         cvar_set("nextmap", m);
2166         cvar_set("timelimit", "-1");
2167         if(mapvote_initialized || alreadychangedlevel)
2168         {
2169                 if(DoNextMapOverride(0))
2170                         return "Map switch initiated.";
2171                 else
2172                         return "Hm... no. For some reason I like THIS map more.";
2173         }
2174         else
2175                 return "Map switch will happen after scoreboard.";
2176 }
2177
2178
2179 void EndFrame()
2180 {
2181         anticheat_endframe();
2182
2183         float altime;
2184         FOR_EACH_REALCLIENT(self)
2185         {
2186                 entity e = IS_SPEC(self) ? self.enemy : self;
2187                 if(e.typehitsound)
2188                         self.typehit_time = time;
2189                 else if(e.damage_dealt)
2190                 {
2191                         self.hit_time = time;
2192                         self.damage_dealt_total += ceil(e.damage_dealt);
2193                 }
2194         }
2195         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2196         // add 1 frametime because after this, engine SV_Physics
2197         // increases time by a frametime and then networks the frame
2198         // add another frametime because client shows everything with
2199         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2200         // needed!
2201         FOR_EACH_CLIENT(self)
2202         {
2203                 self.typehitsound = false;
2204                 self.damage_dealt = 0;
2205                 antilag_record(self, altime);
2206         }
2207         FOR_EACH_MONSTER(self)
2208                 antilag_record(self, altime);
2209 }
2210
2211
2212 /*
2213  * RedirectionThink:
2214  * returns true if redirecting
2215  */
2216 float redirection_timeout;
2217 float redirection_nextthink;
2218 float RedirectionThink()
2219 {
2220         float clients_found;
2221
2222         if(redirection_target == "")
2223                 return false;
2224
2225         if(!redirection_timeout)
2226         {
2227                 cvar_set("sv_public", "-2");
2228                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2229                 if(redirection_target == "self")
2230                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2231                 else
2232                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2233         }
2234
2235         if(time < redirection_nextthink)
2236                 return true;
2237
2238         redirection_nextthink = time + 1;
2239
2240         clients_found = 0;
2241         FOR_EACH_REALCLIENT(self)
2242         {
2243                 // TODO add timer
2244                 print("Redirecting: sending connect command to ", self.netname, "\n");
2245                 if(redirection_target == "self")
2246                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2247                 else
2248                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2249                 ++clients_found;
2250         }
2251
2252         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2253
2254         if(time > redirection_timeout || clients_found == 0)
2255                 localcmd("\nwait; wait; wait; quit\n");
2256
2257         return true;
2258 }
2259
2260 void TargetMusic_RestoreGame();
2261 void RestoreGame()
2262 {
2263         // Loaded from a save game
2264         // some things then break, so let's work around them...
2265
2266         // Progs DB (capture records)
2267         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2268
2269         // Mapinfo
2270         MapInfo_Shutdown();
2271         MapInfo_Enumerate();
2272         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2273         WeaponStats_Init();
2274
2275         TargetMusic_RestoreGame();
2276 }
2277
2278 void Shutdown()
2279 {
2280         gameover = 2;
2281
2282         if(world_initialized > 0)
2283         {
2284                 world_initialized = 0;
2285                 print("Saving persistent data...\n");
2286                 Ban_SaveBans();
2287
2288                 // playerstats with unfinished match
2289                 PlayerStats_GameReport(false);
2290
2291                 if(!cheatcount_total)
2292                 {
2293                         if(autocvar_sv_db_saveasdump)
2294                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2295                         else
2296                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2297                 }
2298                 if(autocvar_developer)
2299                 {
2300                         if(autocvar_sv_db_saveasdump)
2301                                 db_dump(TemporaryDB, "server-temp.db");
2302                         else
2303                                 db_save(TemporaryDB, "server-temp.db");
2304                 }
2305                 CheatShutdown(); // must be after cheatcount check
2306                 db_close(ServerProgsDB);
2307                 db_close(TemporaryDB);
2308                 print("done!\n");
2309                 // tell the bot system the game is ending now
2310                 bot_endgame();
2311
2312                 WeaponStats_Shutdown();
2313                 MapInfo_Shutdown();
2314         }
2315         else if(world_initialized == 0)
2316         {
2317                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2318         }
2319 }