qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 761         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 762         Nagger_Init();
 763
 764         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 765         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 766         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 767         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 768         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 769         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 770         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 771         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 772         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 773         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 774         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 775
 776         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 777         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 778
 779         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 780
 781         // freeze attacks
 782         addstat(STAT_FROZEN, AS_INT, frozen);
 783         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 784
 785         // physics
 786         Physics_AddStats();
 787
 788         // new properties
 789         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 790         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 791         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 792         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 793         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 794         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 795         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 796         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 797         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 798         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 799         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 800         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 801         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 802         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 803         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 804         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 805         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 806         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 807         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 808
 809         // secrets
 810         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 811         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 812
 813         // monsters
 814         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 815         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 816
 817         // misc
 818         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         maplist_reply = strzone(getmaplist());
 826         lsmaps_reply = strzone(getlsmaps());
 827         monsterlist_reply = strzone(getmonsterlist());
 828         for(int i = 0; i < 10; ++i)
 829         {
 830                 s = getrecords(i);
 831                 if (s)
 832                         records_reply[i] = strzone(s);
 833         }
 834         ladder_reply = strzone(getladder());
 835         rankings_reply = strzone(getrankings());
 836
 837         // begin other init
 838         ClientInit_Spawn();
 839         RandomSeed_Spawn();
 840         PingPLReport_Spawn();
 841
 842         CheatInit();
 843
 844         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 845
 846         // fill sv_curl_serverpackages from .serverpackage files
 847         if(autocvar_sv_curl_serverpackages_auto)
 848         {
 849                 s = "";
 850                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 851                 for(int i = 0; i < n; ++i)
 852                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 853                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 854                                 s = strcat(s, " ", argv(i));
 855                 fd = search_begin("*-serverpackage.txt", true, false);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(int i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 fd = search_begin("*.serverpackage", true, false);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(int i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 872         }
 873
 874         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 875         modname = "Xonotic";
 876         // physics/balance/config changes that count as mod
 877         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 878                 modname = cvar_string("g_mod_physics");
 879         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 880                 modname = cvar_string("g_mod_balance");
 881         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 882                 modname = cvar_string("g_mod_config");
 883         // extra mutators that deserve to count as mod
 884         MUTATOR_CALLHOOK(SetModname);
 885
 886         // save it for later
 887         modname = strzone(modname);
 888
 889         WinningConditionHelper(); // set worldstatus
 890
 891         world_initialized = 1;
 892 }
 893
 894 spawnfunc(light)
 895 {
 896         //makestatic (self); // Who the f___ did that?
 897         remove(self);
 898 }
 899
 900 string GetGametype()
 901 {
 902         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 903 }
 904
 905 string GetMapname()
 906 {
 907         return mapname;
 908 }
 909
 910 float Map_Count, Map_Current;
 911 string Map_Current_Name;
 912
 913 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 914 float GetMaplistPosition()
 915 {
 916         float pos, idx;
 917         string map;
 918
 919         map = GetMapname();
 920         idx = autocvar_g_maplist_index;
 921
 922         if(idx >= 0)
 923                 if(idx < Map_Count)
 924                         if(map == argv(idx))
 925                                 return idx;
 926
 927         for(pos = 0; pos < Map_Count; ++pos)
 928                 if(map == argv(pos))
 929                         return pos;
 930
 931         // resume normal maplist rotation if current map is not in g_maplist
 932         return idx;
 933 }
 934
 935 float MapHasRightSize(string map)
 936 {
 937         float fh;
 938         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 939         if(autocvar_g_maplist_check_waypoints)
 940         {
 941                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 942                 if(!fexists(strcat("maps/", map, ".waypoints")))
 943                 {
 944                         LOG_TRACE(": no waypoints\n");
 945                         return false;
 946                 }
 947                 LOG_TRACE(": has waypoints\n");
 948         }
 949
 950         // open map size restriction file
 951         LOG_TRACE("opensize "); LOG_TRACE(map);
 952         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 953         if(fh >= 0)
 954         {
 955                 float mapmin, mapmax;
 956                 LOG_TRACE(": ok, ");
 957                 mapmin = stof(fgets(fh));
 958                 mapmax = stof(fgets(fh));
 959                 fclose(fh);
 960                 if(player_count < mapmin)
 961                 {
 962                         LOG_TRACE("not enough\n");
 963                         return false;
 964                 }
 965                 if(player_count > mapmax)
 966                 {
 967                         LOG_TRACE("too many\n");
 968                         return false;
 969                 }
 970                 LOG_TRACE("right size\n");
 971                 return true;
 972         }
 973         LOG_TRACE(": not found\n");
 974         return true;
 975 }
 976
 977 string Map_Filename(float position)
 978 {
 979         return strcat("maps/", argv(position), ".bsp");
 980 }
 981
 982 void Map_MarkAsRecent(string m)
 983 {
 984         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 985 }
 986
 987 float Map_IsRecent(string m)
 988 {
 989         return strhasword(autocvar_g_maplist_mostrecent, m);
 990 }
 991
 992 float Map_Check(float position, float pass)
 993 {
 994         string filename;
 995         string map_next;
 996         map_next = argv(position);
 997         if(pass <= 1)
 998         {
 999                 if(Map_IsRecent(map_next))
1000                         return 0;
1001         }
1002         filename = Map_Filename(position);
1003         if(MapInfo_CheckMap(map_next))
1004         {
1005                 if(pass == 2)
1006                         return 1;
1007                 if(MapHasRightSize(map_next))
1008                         return 1;
1009                 return 0;
1010         }
1011         else
1012                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1013
1014         return 0;
1015 }
1016
1017 void Map_Goto_SetStr(string nextmapname)
1018 {
1019         if(getmapname_stored != "")
1020                 strunzone(getmapname_stored);
1021         if(nextmapname == "")
1022                 getmapname_stored = "";
1023         else
1024                 getmapname_stored = strzone(nextmapname);
1025 }
1026
1027 void Map_Goto_SetFloat(float position)
1028 {
1029         cvar_set("g_maplist_index", ftos(position));
1030         Map_Goto_SetStr(argv(position));
1031 }
1032
1033 void Map_Goto(float reinit)
1034 {
1035         MapInfo_LoadMap(getmapname_stored, reinit);
1036 }
1037
1038 // return codes of map selectors:
1039 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1040 //   -2 = permanent failure
1041 float() MaplistMethod_Iterate = // usual method
1042 {
1043         float pass, i;
1044
1045         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1046
1047         for(pass = 1; pass <= 2; ++pass)
1048         {
1049                 for(i = 1; i < Map_Count; ++i)
1050                 {
1051                         float mapindex;
1052                         mapindex = (i + Map_Current) % Map_Count;
1053                         if(Map_Check(mapindex, pass))
1054                                 return mapindex;
1055                 }
1056         }
1057         return -1;
1058 }
1059
1060 float() MaplistMethod_Repeat = // fallback method
1061 {
1062         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1063
1064         if(Map_Check(Map_Current, 2))
1065                 return Map_Current;
1066         return -2;
1067 }
1068
1069 float() MaplistMethod_Random = // random map selection
1070 {
1071         float i, imax;
1072
1073         LOG_TRACE("Trying MaplistMethod_Random\n");
1074
1075         imax = 42;
1076
1077         for(i = 0; i <= imax; ++i)
1078         {
1079                 float mapindex;
1080                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1081                 if(Map_Check(mapindex, 1))
1082                         return mapindex;
1083         }
1084         return -1;
1085 }
1086
1087 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1088 // the exponent sets a bias on the map selection:
1089 // the higher the exponent, the less likely "shortly repeated" same maps are
1090 {
1091         float i, j, imax, insertpos;
1092
1093         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1094
1095         imax = 42;
1096
1097         for(i = 0; i <= imax; ++i)
1098         {
1099                 string newlist;
1100
1101                 // now reinsert this at another position
1102                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1103                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1104                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1105                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1106
1107                 // insert the current map there
1108                 newlist = "";
1109                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1110                         newlist = strcat(newlist, " ", argv(j));
1111                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1112                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1113                         newlist = strcat(newlist, " ", argv(j));
1114                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1115                 cvar_set("g_maplist", newlist);
1116                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1117
1118                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1119                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1120                 if(Map_Check(Map_Current, 1))
1121                         return Map_Current;
1122         }
1123         return -1;
1124 }
1125
1126 void Maplist_Init()
1127 {
1128         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1129         float i;
1130         for (i = 0; i < Map_Count; ++i)
1131                 if (Map_Check(i, 2))
1132                         break;
1133         if (i == Map_Count)
1134         {
1135                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1136                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1137                 if(autocvar_g_maplist_shuffle)
1138                         ShuffleMaplist();
1139                 localcmd("\nmenu_cmd sync\n");
1140                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1141         }
1142         if(Map_Count == 0)
1143                 error("empty maplist, cannot select a new map");
1144         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1145
1146         if(Map_Current_Name)
1147                 strunzone(Map_Current_Name);
1148         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1149         // this may or may not be correct, but who cares, in the worst case a map
1150         // isn't chosen in the first pass that should have been
1151 }
1152
1153 string GetNextMap()
1154 {
1155         float nextMap;
1156
1157         Maplist_Init();
1158         nextMap = -1;
1159
1160         if(nextMap == -1)
1161                 if(autocvar_g_maplist_shuffle > 0)
1162                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1163
1164         if(nextMap == -1)
1165                 if(autocvar_g_maplist_selectrandom)
1166                         nextMap = MaplistMethod_Random();
1167
1168         if(nextMap == -1)
1169                 nextMap = MaplistMethod_Iterate();
1170
1171         if(nextMap == -1)
1172                 nextMap = MaplistMethod_Repeat();
1173
1174         if(nextMap >= 0)
1175         {
1176                 Map_Goto_SetFloat(nextMap);
1177                 return getmapname_stored;
1178         }
1179
1180         return "";
1181 }
1182
1183 float DoNextMapOverride(float reinit)
1184 {
1185         if(autocvar_g_campaign)
1186         {
1187                 CampaignPostIntermission();
1188                 alreadychangedlevel = true;
1189                 return true;
1190         }
1191         if(autocvar_quit_when_empty)
1192         {
1193                 if(player_count <= currentbots)
1194                 {
1195                         localcmd("quit\n");
1196                         alreadychangedlevel = true;
1197                         return true;
1198                 }
1199         }
1200         if(autocvar_quit_and_redirect != "")
1201         {
1202                 redirection_target = strzone(autocvar_quit_and_redirect);
1203                 alreadychangedlevel = true;
1204                 return true;
1205         }
1206         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1207         {
1208                 localcmd("restart\n");
1209                 alreadychangedlevel = true;
1210                 return true;
1211         }
1212         if(autocvar_nextmap != "")
1213         {
1214                 string m;
1215                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1216                 cvar_set("nextmap",m);
1217
1218                 if(!m || gametypevote)
1219                         return false;
1220                 if(autocvar_sv_vote_gametype)
1221                 {
1222                         Map_Goto_SetStr(m);
1223                         return false;
1224                 }
1225
1226                 if(MapInfo_CheckMap(m))
1227                 {
1228                         Map_Goto_SetStr(m);
1229                         Map_Goto(reinit);
1230                         alreadychangedlevel = true;
1231                         return true;
1232                 }
1233         }
1234         if(!reinit && autocvar_lastlevel)
1235         {
1236                 cvar_settemp_restore();
1237                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1238                 alreadychangedlevel = true;
1239                 return true;
1240         }
1241         return false;
1242 }
1243
1244 void GotoNextMap(float reinit)
1245 {
1246         //string nextmap;
1247         //float n, nummaps;
1248         //string s;
1249         if (alreadychangedlevel)
1250                 return;
1251         alreadychangedlevel = true;
1252
1253         string nextMap;
1254
1255         nextMap = GetNextMap();
1256         if(nextMap == "")
1257                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1258         Map_Goto(reinit);
1259 }
1260
1261
1262 /*
1263 ============
1264 IntermissionThink
1265
1266 When the player presses attack or jump, change to the next level
1267 ============
1268 */
1269 .float autoscreenshot;
1270 void IntermissionThink()
1271 {SELFPARAM();
1272         FixIntermissionClient(self);
1273
1274         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1275         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1276
1277         if( (server_screenshot || client_screenshot)
1278                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1279         {
1280                 self.autoscreenshot = -1;
1281                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1282                 return;
1283         }
1284
1285         if (time < intermission_exittime)
1286                 return;
1287
1288         if(!mapvote_initialized)
1289                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1290                         return;
1291
1292         MapVote_Start();
1293 }
1294
1295 /*
1296 ============
1297 FindIntermission
1298
1299 Returns the entity to view from
1300 ============
1301 */
1302 /*
1303 entity FindIntermission()
1304 {
1305         local   entity spot;
1306         local   float cyc;
1307
1308 // look for info_intermission first
1309         spot = find (world, classname, "info_intermission");
1310         if (spot)
1311         {       // pick a random one
1312                 cyc = random() * 4;
1313                 while (cyc > 1)
1314                 {
1315                         spot = find (spot, classname, "info_intermission");
1316                         if (!spot)
1317                                 spot = find (spot, classname, "info_intermission");
1318                         cyc = cyc - 1;
1319                 }
1320                 return spot;
1321         }
1322
1323 // then look for the start position
1324         spot = find (world, classname, "info_player_start");
1325         if (spot)
1326                 return spot;
1327
1328 // testinfo_player_start is only found in regioned levels
1329         spot = find (world, classname, "testplayerstart");
1330         if (spot)
1331                 return spot;
1332
1333 // then look for the start position
1334         spot = find (world, classname, "info_player_deathmatch");
1335         if (spot)
1336                 return spot;
1337
1338         //objerror ("FindIntermission: no spot");
1339         return world;
1340 }
1341 */
1342
1343 /*
1344 ===============================================================================
1345
1346 RULES
1347
1348 ===============================================================================
1349 */
1350
1351 void DumpStats(float final)
1352 {
1353         float file;
1354         string s;
1355         float to_console;
1356         float to_eventlog;
1357         float to_file;
1358         float i;
1359
1360         to_console = autocvar_sv_logscores_console;
1361         to_eventlog = autocvar_sv_eventlog;
1362         to_file = autocvar_sv_logscores_file;
1363
1364         if(!final)
1365         {
1366                 to_console = true; // always print printstats replies
1367                 to_eventlog = false; // but never print them to the event log
1368         }
1369
1370         if(to_eventlog)
1371                 if(autocvar_sv_eventlog_console)
1372                         to_console = false; // otherwise we get the output twice
1373
1374         if(final)
1375                 s = ":scores:";
1376         else
1377                 s = ":status:";
1378         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1379
1380         if(to_console)
1381                 LOG_INFO(s, "\n");
1382         if(to_eventlog)
1383                 GameLogEcho(s);
1384
1385         file = -1;
1386         if(to_file)
1387         {
1388                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1389                 if(file == -1)
1390                         to_file = false;
1391                 else
1392                         fputs(file, strcat(s, "\n"));
1393         }
1394
1395         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1396         if(to_console)
1397                 LOG_INFO(s, "\n");
1398         if(to_eventlog)
1399                 GameLogEcho(s);
1400         if(to_file)
1401                 fputs(file, strcat(s, "\n"));
1402
1403         FOR_EACH_CLIENT(other)
1404         {
1405                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1406                 {
1407                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1408                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1409                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1410                                 s = strcat(s, ftos(other.team), ":");
1411                         else
1412                                 s = strcat(s, "spectator:");
1413
1414                         if(to_console)
1415                                 LOG_INFO(s, other.netname, "\n");
1416                         if(to_eventlog)
1417                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1418                         if(to_file)
1419                                 fputs(file, strcat(s, other.netname, "\n"));
1420                 }
1421         }
1422
1423         if(teamplay)
1424         {
1425                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1426                 if(to_console)
1427                         LOG_INFO(s, "\n");
1428                 if(to_eventlog)
1429                         GameLogEcho(s);
1430                 if(to_file)
1431                         fputs(file, strcat(s, "\n"));
1432
1433                 for(i = 1; i < 16; ++i)
1434                 {
1435                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1436                         s = strcat(s, ":", ftos(i));
1437                         if(to_console)
1438                                 LOG_INFO(s, "\n");
1439                         if(to_eventlog)
1440                                 GameLogEcho(s);
1441                         if(to_file)
1442                                 fputs(file, strcat(s, "\n"));
1443                 }
1444         }
1445
1446         if(to_console)
1447                 LOG_INFO(":end\n");
1448         if(to_eventlog)
1449                 GameLogEcho(":end");
1450         if(to_file)
1451         {
1452                 fputs(file, ":end\n");
1453                 fclose(file);
1454         }
1455 }
1456
1457 void FixIntermissionClient(entity e)
1458 {
1459         string s;
1460         if(!e.autoscreenshot) // initial call
1461         {
1462                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1463                 e.health = -2342;
1464                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1465                 e.solid = SOLID_NOT;
1466                 e.movetype = MOVETYPE_NONE;
1467                 e.takedamage = DAMAGE_NO;
1468                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1469                 {
1470                     .entity weaponentity = weaponentities[slot];
1471                         if(e.(weaponentity))
1472                         {
1473                                 e.(weaponentity).effects = EF_NODRAW;
1474                                 if (e.(weaponentity).(weaponentity))
1475                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1476                         }
1477                 }
1478                 if(IS_REAL_CLIENT(e))
1479                 {
1480                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1481                         s = autocvar_sv_intermission_cdtrack;
1482                         if(s != "")
1483                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1484                         msg_entity = e;
1485                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1486                 }
1487         }
1488 }
1489
1490 /*
1491 go to the next level for deathmatch
1492 only called if a time or frag limit has expired
1493 */
1494 void NextLevel()
1495 {
1496         gameover = true;
1497
1498         intermission_running = 1;
1499
1500 // enforce a wait time before allowing changelevel
1501         if(player_count > 0)
1502                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1503         else
1504                 intermission_exittime = -1;
1505
1506         /*
1507         WriteByte (MSG_ALL, SVC_CDTRACK);
1508         WriteByte (MSG_ALL, 3);
1509         WriteByte (MSG_ALL, 3);
1510         // done in FixIntermission
1511         */
1512
1513         //pos = FindIntermission ();
1514
1515         VoteReset();
1516
1517         DumpStats(true);
1518
1519         // send statistics
1520         PlayerStats_GameReport(true);
1521         WeaponStats_Shutdown();
1522
1523         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1524
1525         if(autocvar_sv_eventlog)
1526                 GameLogEcho(":gameover");
1527
1528         GameLogClose();
1529
1530         FOR_EACH_PLAYER(other) {
1531                 FixIntermissionClient(other);
1532                 if(other.winning)
1533                         bprint(other.netname, " ^7wins.\n");
1534         }
1535
1536         entity oldself = self;
1537         target_music_kill();
1538         self = oldself;
1539
1540         if(autocvar_g_campaign)
1541                 CampaignPreIntermission();
1542
1543         MUTATOR_CALLHOOK(MatchEnd);
1544
1545         localcmd("\nsv_hook_gameend\n");
1546 }
1547
1548 /*
1549 ============
1550 CheckRules_Player
1551
1552 Exit deathmatch games upon conditions
1553 ============
1554 */
1555 void CheckRules_Player()
1556 {SELFPARAM();
1557         if (gameover)   // someone else quit the game already
1558                 return;
1559
1560         if(self.deadflag == DEAD_NO)
1561                 self.play_time += frametime;
1562
1563         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1564         //   (div0: and that in CheckRules_World please)
1565 }
1566
1567
1568 float InitiateSuddenDeath()
1569 {
1570         // Check first whether normal overtimes could be added before initiating suddendeath mode
1571         // - for this timelimit_overtime needs to be >0 of course
1572         // - also check the winning condition calculated in the previous frame and only add normal overtime
1573         //   again, if at the point at which timelimit would be extended again, still no winner was found
1574         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1575         {
1576                 return 1; // need to call InitiateOvertime later
1577         }
1578         else
1579         {
1580                 if(!checkrules_suddendeathend)
1581                 {
1582                         if(autocvar_g_campaign)
1583                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1584                         else
1585                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1586                         if(g_race && !g_race_qualifying)
1587                                 race_StartCompleting();
1588                 }
1589                 return 0;
1590         }
1591 }
1592
1593 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1594 {
1595         ++checkrules_overtimesadded;
1596         //add one more overtime by simply extending the timelimit
1597         float tl;
1598         tl = autocvar_timelimit;
1599         tl += autocvar_timelimit_overtime;
1600         cvar_set("timelimit", ftos(tl));
1601
1602         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1603 }
1604
1605 float GetWinningCode(float fraglimitreached, float equality)
1606 {
1607         if(autocvar_g_campaign == 1)
1608                 if(fraglimitreached)
1609                         return WINNING_YES;
1610                 else
1611                         return WINNING_NO;
1612
1613         else
1614                 if(equality)
1615                         if(fraglimitreached)
1616                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1617                         else
1618                                 return WINNING_NEVER;
1619                 else
1620                         if(fraglimitreached)
1621                                 return WINNING_YES;
1622                         else
1623                                 return WINNING_NO;
1624 }
1625
1626 // set the .winning flag for exactly those players with a given field value
1627 void SetWinners(.float field, float value)
1628 {
1629         entity head;
1630         FOR_EACH_PLAYER(head)
1631                 head.winning = (head.(field) == value);
1632 }
1633
1634 // set the .winning flag for those players with a given field value
1635 void AddWinners(.float field, float value)
1636 {
1637         entity head;
1638         FOR_EACH_PLAYER(head)
1639                 if (head.(field) == value)
1640                         head.winning = 1;
1641 }
1642
1643 // clear the .winning flags
1644 void ClearWinners()
1645 {
1646         entity head;
1647         FOR_EACH_PLAYER(head)
1648                 head.winning = 0;
1649 }
1650
1651 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1652 // they win. Otherwise the defending team wins once the timelimit passes.
1653 void assault_new_round();
1654 float WinningCondition_Assault()
1655 {SELFPARAM();
1656         float status;
1657
1658         WinningConditionHelper(); // set worldstatus
1659
1660         status = WINNING_NO;
1661         // as the timelimit has not yet passed just assume the defending team will win
1662         if(assault_attacker_team == NUM_TEAM_1)
1663         {
1664                 SetWinners(team, NUM_TEAM_2);
1665         }
1666         else
1667         {
1668                 SetWinners(team, NUM_TEAM_1);
1669         }
1670
1671         entity ent;
1672         ent = find(world, classname, "target_assault_roundend");
1673         if(ent)
1674         {
1675                 if(ent.winning) // round end has been triggered by attacking team
1676                 {
1677                         bprint("ASSAULT: round completed...\n");
1678                         SetWinners(team, assault_attacker_team);
1679
1680                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1681
1682                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1683                         {
1684                                 status = WINNING_YES;
1685                         }
1686                         else
1687                         {
1688                                 WITH(entity, self, ent, assault_new_round());
1689                         }
1690                 }
1691         }
1692
1693         return status;
1694 }
1695
1696 void ShuffleMaplist()
1697 {
1698         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1699 }
1700
1701 float leaderfrags;
1702 float WinningCondition_Scores(float limit, float leadlimit)
1703 {
1704         float limitreached;
1705
1706         // TODO make everything use THIS winning condition (except LMS)
1707         WinningConditionHelper();
1708
1709         if(teamplay)
1710         {
1711                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1712                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1713                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1714                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1715         }
1716
1717         ClearWinners();
1718         if(WinningConditionHelper_winner)
1719                 WinningConditionHelper_winner.winning = 1;
1720         if(WinningConditionHelper_winnerteam >= 0)
1721                 SetWinners(team, WinningConditionHelper_winnerteam);
1722
1723         if(WinningConditionHelper_lowerisbetter)
1724         {
1725                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1726                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1727                 limit = -limit;
1728         }
1729
1730         if(WinningConditionHelper_zeroisworst)
1731                 leadlimit = 0; // not supported in this mode
1732
1733         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1734         // these modes always score in increments of 1, thus this makes sense
1735         {
1736                 if(leaderfrags != WinningConditionHelper_topscore)
1737                 {
1738                         leaderfrags = WinningConditionHelper_topscore;
1739
1740                         if (limit)
1741                         if (leaderfrags == limit - 1)
1742                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1743                         else if (leaderfrags == limit - 2)
1744                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1745                         else if (leaderfrags == limit - 3)
1746                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1747                 }
1748         }
1749
1750         limitreached = false;
1751         if(limit)
1752                 if(WinningConditionHelper_topscore >= limit)
1753                         limitreached = true;
1754         if(leadlimit)
1755         {
1756                 float leadlimitreached;
1757                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1758                 if(autocvar_leadlimit_and_fraglimit)
1759                         limitreached = (limitreached && leadlimitreached);
1760                 else
1761                         limitreached = (limitreached || leadlimitreached);
1762         }
1763
1764         if(limit)
1765                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1766
1767         return GetWinningCode(
1768                 WinningConditionHelper_topscore && limitreached,
1769                 WinningConditionHelper_equality
1770         );
1771 }
1772
1773 float WinningCondition_Race(float fraglimit)
1774 {
1775         float wc;
1776         entity p;
1777         float n, c;
1778
1779         n = 0;
1780         c = 0;
1781         FOR_EACH_PLAYER(p)
1782         {
1783                 ++n;
1784                 if(p.race_completed)
1785                         ++c;
1786         }
1787         if(n && (n == c))
1788                 return WINNING_YES;
1789         wc = WinningCondition_Scores(fraglimit, 0);
1790
1791         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1792         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1793         // do NOT support equality when the laps are all raced!
1794                 return WINNING_STARTSUDDENDEATHOVERTIME;
1795         else
1796                 return WINNING_NEVER;
1797 }
1798
1799 float WinningCondition_QualifyingThenRace(float limit)
1800 {
1801         float wc;
1802         wc = WinningCondition_Scores(limit, 0);
1803
1804         // NEVER initiate overtime
1805         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1806         {
1807                 return WINNING_YES;
1808         }
1809
1810         return wc;
1811 }
1812
1813 float WinningCondition_RanOutOfSpawns()
1814 {
1815         entity head;
1816
1817         if(have_team_spawns <= 0)
1818                 return WINNING_NO;
1819
1820         if(!autocvar_g_spawn_useallspawns)
1821                 return WINNING_NO;
1822
1823         if(!some_spawn_has_been_used)
1824                 return WINNING_NO;
1825
1826         team1_score = team2_score = team3_score = team4_score = 0;
1827
1828         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1829         {
1830                 if(head.team == NUM_TEAM_1)
1831                         team1_score = 1;
1832                 else if(head.team == NUM_TEAM_2)
1833                         team2_score = 1;
1834                 else if(head.team == NUM_TEAM_3)
1835                         team3_score = 1;
1836                 else if(head.team == NUM_TEAM_4)
1837                         team4_score = 1;
1838         }
1839
1840         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1841         {
1842                 if(head.team == NUM_TEAM_1)
1843                         team1_score = 1;
1844                 else if(head.team == NUM_TEAM_2)
1845                         team2_score = 1;
1846                 else if(head.team == NUM_TEAM_3)
1847                         team3_score = 1;
1848                 else if(head.team == NUM_TEAM_4)
1849                         team4_score = 1;
1850         }
1851
1852         ClearWinners();
1853         if(team1_score + team2_score + team3_score + team4_score == 0)
1854         {
1855                 checkrules_equality = true;
1856                 return WINNING_YES;
1857         }
1858         else if(team1_score + team2_score + team3_score + team4_score == 1)
1859         {
1860                 float t, i;
1861                 if(team1_score)
1862                         t = NUM_TEAM_1;
1863                 else if(team2_score)
1864                         t = NUM_TEAM_2;
1865                 else if(team3_score)
1866                         t = NUM_TEAM_3;
1867                 else // if(team4_score)
1868                         t = NUM_TEAM_4;
1869                 CheckAllowedTeams(world);
1870                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1871                 {
1872                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1873                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1874                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1875                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1876                 }
1877
1878                 AddWinners(team, t);
1879                 return WINNING_YES;
1880         }
1881         else
1882                 return WINNING_NO;
1883 }
1884
1885 /*
1886 ============
1887 CheckRules_World
1888
1889 Exit deathmatch games upon conditions
1890 ============
1891 */
1892 void CheckRules_World()
1893 {
1894         float timelimit;
1895         float fraglimit;
1896         float leadlimit;
1897
1898         VoteThink();
1899         MapVote_Think();
1900
1901         SetDefaultAlpha();
1902
1903         if (gameover)   // someone else quit the game already
1904         {
1905                 if(player_count == 0) // Nobody there? Then let's go to the next map
1906                         MapVote_Start();
1907                         // this will actually check the player count in the next frame
1908                         // again, but this shouldn't hurt
1909                 return;
1910         }
1911
1912         timelimit = autocvar_timelimit * 60;
1913         fraglimit = autocvar_fraglimit;
1914         leadlimit = autocvar_leadlimit;
1915
1916         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1917         {
1918                 if(timelimit > 0)
1919                         timelimit = 0; // timelimit is not made for warmup
1920                 if(fraglimit > 0)
1921                         fraglimit = 0; // no fraglimit for now
1922                 leadlimit = 0; // no leadlimit for now
1923         }
1924
1925         if(timelimit > 0)
1926         {
1927                 timelimit += game_starttime;
1928         }
1929         else if (timelimit < 0)
1930         {
1931                 // endmatch
1932                 NextLevel();
1933                 return;
1934         }
1935
1936         float wantovertime;
1937         wantovertime = 0;
1938
1939         if(timelimit > game_starttime)
1940                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1941         else
1942                 game_completion_ratio = 0;
1943
1944         if(checkrules_suddendeathend)
1945         {
1946                 if(!checkrules_suddendeathwarning)
1947                 {
1948                         checkrules_suddendeathwarning = true;
1949                         if(g_race && !g_race_qualifying)
1950                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1951                         else
1952                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1953                 }
1954         }
1955         else
1956         {
1957                 if (timelimit && time >= timelimit)
1958                 {
1959                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1960                         {
1961                                 float totalplayers;
1962                                 float playerswithlaps;
1963                                 float readyplayers;
1964                                 entity head;
1965                                 totalplayers = playerswithlaps = readyplayers = 0;
1966                                 FOR_EACH_PLAYER(head)
1967                                 {
1968                                         ++totalplayers;
1969                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1970                                                 ++playerswithlaps;
1971                                         if(head.ready)
1972                                                 ++readyplayers;
1973                                 }
1974
1975                                 // at least 2 of the players have completed a lap: start the RACE
1976                                 // otherwise, the players should end the qualifying on their own
1977                                 if(readyplayers || playerswithlaps >= 2)
1978                                 {
1979                                         checkrules_suddendeathend = 0;
1980                                         ReadyRestart(); // go to race
1981                                         return;
1982                                 }
1983                                 else
1984                                         wantovertime |= InitiateSuddenDeath();
1985                         }
1986                         else
1987                                 wantovertime |= InitiateSuddenDeath();
1988                 }
1989         }
1990
1991         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1992         {
1993                 NextLevel();
1994                 return;
1995         }
1996
1997         int checkrules_status = WinningCondition_RanOutOfSpawns();
1998         if(checkrules_status == WINNING_YES)
1999                 bprint("Hey! Someone ran out of spawns!\n");
2000         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2001                 checkrules_status = ret_float;
2002         else
2003                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2004
2005         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2006         {
2007                 checkrules_status = WINNING_NEVER;
2008                 checkrules_overtimesadded = -1;
2009                 wantovertime |= InitiateSuddenDeath();
2010         }
2011
2012         if(checkrules_status == WINNING_NEVER)
2013                 // equality cases! Nobody wins if the overtime ends in a draw.
2014                 ClearWinners();
2015
2016         if(wantovertime)
2017         {
2018                 if(checkrules_status == WINNING_NEVER)
2019                         InitiateOvertime();
2020                 else
2021                         checkrules_status = WINNING_YES;
2022         }
2023
2024         if(checkrules_suddendeathend)
2025                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2026                         checkrules_status = WINNING_YES;
2027
2028         if(checkrules_status == WINNING_YES)
2029         {
2030                 //print("WINNING\n");
2031                 NextLevel();
2032         }
2033 }
2034
2035 string GotoMap(string m)
2036 {
2037         m = GameTypeVote_MapInfo_FixName(m);
2038         if (!m)
2039                 return "The map you suggested is not available on this server.";
2040         if (!autocvar_sv_vote_gametype)
2041         if(!MapInfo_CheckMap(m))
2042                 return "The map you suggested does not support the current game mode.";
2043         cvar_set("nextmap", m);
2044         cvar_set("timelimit", "-1");
2045         if(mapvote_initialized || alreadychangedlevel)
2046         {
2047                 if(DoNextMapOverride(0))
2048                         return "Map switch initiated.";
2049                 else
2050                         return "Hm... no. For some reason I like THIS map more.";
2051         }
2052         else
2053                 return "Map switch will happen after scoreboard.";
2054 }
2055
2056
2057 void EndFrame()
2058 {SELFPARAM();
2059         anticheat_endframe();
2060
2061         float altime;
2062         entity e_;
2063         FOR_EACH_REALCLIENT(e_)
2064         {
2065                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2066                 if(e.typehitsound)
2067                         e_.typehit_time = time;
2068                 else if(e.damage_dealt)
2069                 {
2070                         e_.hit_time = time;
2071                         e_.damage_dealt_total += ceil(e.damage_dealt);
2072                 }
2073         }
2074         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2075         // add 1 frametime because after this, engine SV_Physics
2076         // increases time by a frametime and then networks the frame
2077         // add another frametime because client shows everything with
2078         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2079         // needed!
2080         FOR_EACH_CLIENT(e_)
2081         {
2082                 e_.typehitsound = false;
2083                 e_.damage_dealt = 0;
2084                 setself(e_);
2085                 antilag_record(e_, altime);
2086         }
2087         FOR_EACH_MONSTER(e_)
2088         {
2089                 setself(e_);
2090                 antilag_record(e_, altime);
2091         }
2092 }
2093
2094
2095 /*
2096  * RedirectionThink:
2097  * returns true if redirecting
2098  */
2099 float redirection_timeout;
2100 float redirection_nextthink;
2101 float RedirectionThink()
2102 {SELFPARAM();
2103         float clients_found;
2104
2105         if(redirection_target == "")
2106                 return false;
2107
2108         if(!redirection_timeout)
2109         {
2110                 cvar_set("sv_public", "-2");
2111                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2112                 if(redirection_target == "self")
2113                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2114                 else
2115                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2116         }
2117
2118         if(time < redirection_nextthink)
2119                 return true;
2120
2121         redirection_nextthink = time + 1;
2122
2123         clients_found = 0;
2124         entity e;
2125         FOR_EACH_REALCLIENT(e)
2126         {
2127                 setself(e);
2128                 // TODO add timer
2129                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2130                 if(redirection_target == "self")
2131                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2132                 else
2133                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2134                 ++clients_found;
2135         }
2136
2137         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2138
2139         if(time > redirection_timeout || clients_found == 0)
2140                 localcmd("\nwait; wait; wait; quit\n");
2141
2142         return true;
2143 }
2144
2145 void TargetMusic_RestoreGame();
2146 void RestoreGame()
2147 {
2148         // Loaded from a save game
2149         // some things then break, so let's work around them...
2150
2151         // Progs DB (capture records)
2152         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2153
2154         // Mapinfo
2155         MapInfo_Shutdown();
2156         MapInfo_Enumerate();
2157         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2158         WeaponStats_Init();
2159
2160         TargetMusic_RestoreGame();
2161 }
2162
2163 void Shutdown()
2164 {
2165         gameover = 2;
2166
2167         if(world_initialized > 0)
2168         {
2169                 world_initialized = 0;
2170                 LOG_INFO("Saving persistent data...\n");
2171                 Ban_SaveBans();
2172
2173                 // playerstats with unfinished match
2174                 PlayerStats_GameReport(false);
2175
2176                 if(!cheatcount_total)
2177                 {
2178                         if(autocvar_sv_db_saveasdump)
2179                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2180                         else
2181                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2182                 }
2183                 if(autocvar_developer)
2184                 {
2185                         if(autocvar_sv_db_saveasdump)
2186                                 db_dump(TemporaryDB, "server-temp.db");
2187                         else
2188                                 db_save(TemporaryDB, "server-temp.db");
2189                 }
2190                 CheatShutdown(); // must be after cheatcount check
2191                 db_close(ServerProgsDB);
2192                 db_close(TemporaryDB);
2193                 LOG_INFO("done!\n");
2194                 // tell the bot system the game is ending now
2195                 bot_endgame();
2196
2197                 WeaponStats_Shutdown();
2198                 MapInfo_Shutdown();
2199         }
2200         else if(world_initialized == 0)
2201         {
2202                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2203         }
2204 }