qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/_mod.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/_mod.qh"
  36 #include <common/weapons/_all.qh>
  37 #include "../common/state.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think(entity this)
  45 {
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         this.nextthink = time + delta;
  53
  54         e = edict_num(this.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, this.cnt);
  59                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  60                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, this.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         this.cnt = (this.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new_pure(pingplreport);
  85         setthink(pingplreport, PingPLReport_Think);
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap(entity this)
 108 {
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 this.nextthink = time;
 133         }
 134         else
 135         {
 136                 this.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_voice_flood_");
 236                 BADPREFIX("log_file");
 237                 BADPREFIX("rcon_");
 238                 BADPREFIX("sv_allowdownloads");
 239                 BADPREFIX("sv_autodemo");
 240                 BADPREFIX("sv_curl_");
 241                 BADPREFIX("sv_eventlog");
 242                 BADPREFIX("sv_logscores_");
 243                 BADPREFIX("sv_master");
 244                 BADPREFIX("sv_weaponstats_");
 245                 BADPREFIX("sv_waypointsprite_");
 246                 BADCVAR("rescan_pending");
 247
 248                 // these can contain player IDs, so better hide
 249                 BADPREFIX("g_forced_team_");
 250
 251                 // mapinfo
 252                 BADCVAR("fraglimit");
 253                 BADCVAR("g_assault");
 254                 BADCVAR("g_ca");
 255                 BADCVAR("g_ca_teams");
 256                 BADCVAR("g_ctf");
 257                 BADCVAR("g_cts");
 258                 BADCVAR("g_dm");
 259                 BADCVAR("g_domination");
 260                 BADCVAR("g_domination_default_teams");
 261                 BADCVAR("g_freezetag");
 262                 BADCVAR("g_freezetag_teams");
 263                 BADCVAR("g_invasion_teams");
 264                 BADCVAR("g_keepaway");
 265                 BADCVAR("g_keyhunt");
 266                 BADCVAR("g_keyhunt_teams");
 267                 BADCVAR("g_lms");
 268                 BADCVAR("g_nexball");
 269                 BADCVAR("g_onslaught");
 270                 BADCVAR("g_race");
 271                 BADCVAR("g_race_laps_limit");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_race_qualifying_timelimit_override");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing gameplay relevant
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("gameversion");
 307                 BADCVAR("g_allow_oldvortexbeam");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_campcheck_distance");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ca_point_limit");
 312                 BADCVAR("g_ctf_captimerecord_always");
 313                 BADCVAR("g_ctf_flag_glowtrails");
 314                 BADCVAR("g_ctf_flag_pickup_verbosename");
 315                 BADCVAR("g_domination_point_leadlimit");
 316                 BADCVAR("g_forced_respawn");
 317                 BADCVAR("g_freezetag_point_leadlimit");
 318                 BADCVAR("g_freezetag_point_limit");
 319                 BADCVAR("g_hats");
 320                 BADCVAR("g_invasion_point_limit");
 321                 BADCVAR("g_keyhunt_point_leadlimit");
 322                 BADCVAR("g_nexball_goalleadlimit");
 323                 BADCVAR("g_tdm_point_leadlimit");
 324                 BADCVAR("g_tdm_point_limit");
 325                 BADCVAR("leadlimit_and_fraglimit");
 326                 BADCVAR("leadlimit_override");
 327                 BADCVAR("pausable");
 328                 BADCVAR("sv_allow_fullbright");
 329                 BADCVAR("sv_checkforpacketsduringsleep");
 330                 BADCVAR("sv_intermission_cdtrack");
 331                 BADCVAR("sv_minigames");
 332                 BADCVAR("sv_namechangetimer");
 333                 BADCVAR("sv_precacheplayermodels");
 334                 BADCVAR("sv_timeout");
 335                 BADPREFIX("crypto_");
 336                 BADPREFIX("gameversion_");
 337                 BADPREFIX("g_chat_");
 338                 BADPREFIX("g_ctf_captimerecord_");
 339                 BADPREFIX("g_maplist_votable_");
 340                 BADPREFIX("g_mod_");
 341                 BADPREFIX("g_respawn_");
 342                 BADPREFIX("net_");
 343                 BADPREFIX("prvm_");
 344                 BADPREFIX("skill_");
 345                 BADPREFIX("sv_cullentities_");
 346                 BADPREFIX("sv_maxidle_");
 347                 BADPREFIX("sv_minigames_");
 348                 BADPREFIX("sv_timeout_");
 349                 BADPREFIX("sv_vote_");
 350                 BADPREFIX("timelimit_");
 351
 352                 // allowed changes to server admins (please sync this to server.cfg)
 353                 // vi commands:
 354                 //   :/"impure"/,$d
 355                 //   :g!,^\/\/[^ /],d
 356                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 357                 //   :%!sort
 358                 // yes, this does contain some redundant stuff, don't really care
 359                 BADCVAR("bot_config_file");
 360                 BADCVAR("bot_number");
 361                 BADCVAR("bot_prefix");
 362                 BADCVAR("bot_suffix");
 363                 BADCVAR("capturelimit_override");
 364                 BADCVAR("fraglimit_override");
 365                 BADCVAR("gametype");
 366                 BADCVAR("g_antilag");
 367                 BADCVAR("g_balance_teams");
 368                 BADCVAR("g_balance_teams_prevent_imbalance");
 369                 BADCVAR("g_balance_teams_scorefactor");
 370                 BADCVAR("g_ban_sync_trusted_servers");
 371                 BADCVAR("g_ban_sync_uri");
 372                 BADCVAR("g_ca_teams_override");
 373                 BADCVAR("g_ctf_ignore_frags");
 374                 BADCVAR("g_domination_point_limit");
 375                 BADCVAR("g_domination_teams_override");
 376                 BADCVAR("g_freezetag_teams_override");
 377                 BADCVAR("g_friendlyfire");
 378                 BADCVAR("g_fullbrightitems");
 379                 BADCVAR("g_fullbrightplayers");
 380                 BADCVAR("g_keyhunt_point_limit");
 381                 BADCVAR("g_keyhunt_teams_override");
 382                 BADCVAR("g_lms_lives_override");
 383                 BADCVAR("g_maplist");
 384                 BADCVAR("g_maplist_check_waypoints");
 385                 BADCVAR("g_maplist_mostrecent_count");
 386                 BADCVAR("g_maplist_shuffle");
 387                 BADCVAR("g_maplist_votable");
 388                 BADCVAR("g_maplist_votable_abstain");
 389                 BADCVAR("g_maplist_votable_nodetail");
 390                 BADCVAR("g_maplist_votable_suggestions");
 391                 BADCVAR("g_maxplayers");
 392                 BADCVAR("g_mirrordamage");
 393                 BADCVAR("g_nexball_goallimit");
 394                 BADCVAR("g_powerups");
 395                 BADCVAR("g_spawnshieldtime");
 396                 BADCVAR("g_start_delay");
 397                 BADCVAR("g_superspectate");
 398                 BADCVAR("g_tdm_teams_override");
 399                 BADCVAR("g_warmup");
 400                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 401                 BADCVAR("hostname");
 402                 BADCVAR("log_file");
 403                 BADCVAR("maxplayers");
 404                 BADCVAR("minplayers");
 405                 BADCVAR("net_address");
 406                 BADCVAR("port");
 407                 BADCVAR("rcon_password");
 408                 BADCVAR("rcon_restricted_commands");
 409                 BADCVAR("rcon_restricted_password");
 410                 BADCVAR("skill");
 411                 BADCVAR("sv_adminnick");
 412                 BADCVAR("sv_autoscreenshot");
 413                 BADCVAR("sv_autotaunt");
 414                 BADCVAR("sv_curl_defaulturl");
 415                 BADCVAR("sv_defaultcharacter");
 416                 BADCVAR("sv_defaultcharacterskin");
 417                 BADCVAR("sv_defaultplayercolors");
 418                 BADCVAR("sv_defaultplayermodel");
 419                 BADCVAR("sv_defaultplayerskin");
 420                 BADCVAR("sv_maxidle");
 421                 BADCVAR("sv_maxrate");
 422                 BADCVAR("sv_motd");
 423                 BADCVAR("sv_public");
 424                 BADCVAR("sv_ready_restart");
 425                 BADCVAR("sv_status_privacy");
 426                 BADCVAR("sv_taunt");
 427                 BADCVAR("sv_vote_call");
 428                 BADCVAR("sv_vote_commands");
 429                 BADCVAR("sv_vote_majority_factor");
 430                 BADCVAR("sv_vote_master");
 431                 BADCVAR("sv_vote_master_commands");
 432                 BADCVAR("sv_vote_master_password");
 433                 BADCVAR("sv_vote_simple_majority_factor");
 434                 BADCVAR("teamplay_mode");
 435                 BADCVAR("timelimit_override");
 436                 BADPREFIX("g_warmup_");
 437                 BADPREFIX("sv_ready_restart_");
 438
 439                 // mutators that announce themselves properly to the server browser
 440                 BADCVAR("g_instagib");
 441                 BADCVAR("g_new_toys");
 442                 BADCVAR("g_nix");
 443                 BADCVAR("g_grappling_hook");
 444                 BADCVAR("g_jetpack");
 445
 446 #undef BADPREFIX
 447 #undef BADCVAR
 448
 449                 if(pureadding)
 450                 {
 451                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 452                         if(strlen(cvar_purechanges) > 16384)
 453                         {
 454                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 455                                 pureadding = 0;
 456                         }
 457                 }
 458                 ++cvar_purechanges_count;
 459                 // WARNING: this variable is used for the server list
 460                 // NEVER dare to skip this code!
 461                 // Hacks to intentionally appearing as "pure server" even though you DO have
 462                 // modified settings may be punished by removal from the server list.
 463                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 464                 // though.
 465         }
 466         buf_del(h);
 467         if(cvar_changes == "")
 468                 cvar_changes = "// this server runs at default server settings\n";
 469         else
 470                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 471         cvar_changes = strzone(cvar_changes);
 472         if(cvar_purechanges == "")
 473                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 474         else
 475                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 476         cvar_purechanges = strzone(cvar_purechanges);
 477 }
 478
 479 void detect_maptype()
 480 {
 481 #if 0
 482         vector o, v;
 483         float i;
 484
 485         for (;;)
 486         {
 487                 o = world.mins;
 488                 o.x += random() * (world.maxs.x - world.mins.x);
 489                 o.y += random() * (world.maxs.y - world.mins.y);
 490                 o.z += random() * (world.maxs.z - world.mins.z);
 491
 492                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 493                 if(trace_fraction == 1)
 494                         continue;
 495
 496                 v = trace_endpos;
 497
 498                 for(i = 0; i < 64; i += 4)
 499                 {
 500                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 501         if(trace_fraction == 1)
 502                 continue;
 503                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 504                 }
 505
 506                 break;
 507         }
 508 #endif
 509 }
 510
 511 entity randomseed;
 512 bool RandomSeed_Send(entity this, entity to, int sf)
 513 {
 514         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 515         WriteShort(MSG_ENTITY, this.cnt);
 516         return true;
 517 }
 518 void RandomSeed_Think(entity this)
 519 {
 520         this.cnt = bound(0, floor(random() * 65536), 65535);
 521         this.nextthink = time + 5;
 522
 523         this.SendFlags |= 1;
 524 }
 525 void RandomSeed_Spawn()
 526 {
 527         randomseed = new_pure(randomseed);
 528         setthink(randomseed, RandomSeed_Think);
 529         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 530
 531         getthink(randomseed)(randomseed); // sets random seed and nextthink
 532 }
 533
 534 spawnfunc(__init_dedicated_server)
 535 {
 536         // handler for _init/_init map (only for dedicated server initialization)
 537
 538         world_initialized = -1; // don't complain
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         delete_fn = remove_unsafely;
 544
 545         entity e = spawn();
 546         setthink(e, GotoFirstMap);
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = new(info_player_deathmatch);  // safeguard against player joining
 550
 551         this.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         static_init();
 555         static_init_late();
 556         static_init_precache();
 557
 558         IL_PUSH(g_spawnpoints, e); // just incase
 559
 560         MapInfo_Enumerate();
 561         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 562 }
 563
 564 void __init_dedicated_server_shutdown() {
 565         MapInfo_Shutdown();
 566 }
 567
 568 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 569 {
 570         if(!autocvar_g_campaign)
 571         {
 572                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 573                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 574                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 575                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 576         }
 577         limits_are_set = true;
 578 }
 579
 580 void Map_MarkAsRecent(string m);
 581 float world_already_spawned;
 582 void Nagger_Init();
 583 void ClientInit_Spawn();
 584 void WeaponStats_Init();
 585 void WeaponStats_Shutdown();
 586 spawnfunc(worldspawn)
 587 {
 588         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 589
 590     bool wantrestart = false;
 591         {
 592                 if (!server_is_dedicated)
 593                 {
 594                         // force unloading of server pk3 files when starting a listen server
 595                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 596                         // restore csqc_progname too
 597                         string expect = "csprogs.dat";
 598                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 599                         cvar_set_normal("csqc_progname", expect);
 600                 }
 601                 else
 602                 {
 603                         // Try to use versioned csprogs from pk3
 604                         // Only ever use versioned csprogs.dat files on dedicated servers;
 605                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 606                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 607                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 608                         string select = "csprogs.dat";
 609                         if (fexists(pk3csprogs)) select = pk3csprogs;
 610                         if (cvar_string_normal("csqc_progname") != select)
 611                         {
 612                                 cvar_set_normal("csqc_progname", select);
 613                                 wantrestart = true;
 614                         }
 615                         // Check for updates on startup
 616                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 617                         int sentinel = fopen("progs.txt", FILE_READ);
 618                         if (sentinel >= 0)
 619                         {
 620                                 string switchversion = fgets(sentinel);
 621                                 fclose(sentinel);
 622                                 if (switchversion != "" && switchversion != WATERMARK)
 623                                 {
 624                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 625                                         // if it doesn't exist, assume either:
 626                                         //   a) the current program was overwritten
 627                                         //   b) this is a client only update
 628                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 629                                         if (fexists(newprogs))
 630                                         {
 631                                                 cvar_set_normal("sv_progs", newprogs);
 632                                                 wantrestart = true;
 633                                         }
 634                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 635                                         if (fexists(newcsprogs))
 636                                         {
 637                                                 cvar_set_normal("csqc_progname", newcsprogs);
 638                                                 wantrestart = true;
 639                                         }
 640                                 }
 641                         }
 642                 }
 643                 if (wantrestart)
 644                 {
 645                         LOG_INFOF("Restart requested\n");
 646                         changelevel(mapname);
 647                         // let initialization continue, shutdown depends on it
 648                 }
 649         }
 650
 651         cvar = cvar_normal;
 652         cvar_string = cvar_string_normal;
 653         cvar_set = cvar_set_normal;
 654
 655         if(world_already_spawned)
 656                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 657         world_already_spawned = true;
 658
 659         delete_fn = remove_safely; // during spawning, watch what you remove!
 660
 661         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 662
 663         maxclients = 0;
 664         for (entity head = nextent(NULL); head; head = nextent(head))
 665         {
 666                 ++maxclients;
 667         }
 668
 669         // needs to be done so early because of the constants they create
 670         static_init();
 671
 672         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 673
 674         TemporaryDB = db_create();
 675
 676         // 0 normal
 677         lightstyle(0, "m");
 678
 679         // 1 FLICKER (first variety)
 680         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 681
 682         // 2 SLOW STRONG PULSE
 683         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 684
 685         // 3 CANDLE (first variety)
 686         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 687
 688         // 4 FAST STROBE
 689         lightstyle(4, "mamamamamama");
 690
 691         // 5 GENTLE PULSE 1
 692         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 693
 694         // 6 FLICKER (second variety)
 695         lightstyle(6, "nmonqnmomnmomomno");
 696
 697         // 7 CANDLE (second variety)
 698         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 699
 700         // 8 CANDLE (third variety)
 701         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 702
 703         // 9 SLOW STROBE (fourth variety)
 704         lightstyle(9, "aaaaaaaazzzzzzzz");
 705
 706         // 10 FLUORESCENT FLICKER
 707         lightstyle(10, "mmamammmmammamamaaamammma");
 708
 709         // 11 SLOW PULSE NOT FADE TO BLACK
 710         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 711
 712         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 713
 714         // 63 testing
 715         lightstyle(63, "a");
 716
 717         if(autocvar_g_campaign)
 718                 CampaignPreInit();
 719
 720         Map_MarkAsRecent(mapname);
 721
 722         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 723
 724         InitGameplayMode();
 725         static_init_late();
 726         static_init_precache();
 727         readlevelcvars();
 728         GrappleHookInit();
 729
 730         if(!limits_are_set)
 731                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 732
 733         if(warmup_limit == 0)
 734                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 735
 736         player_count = 0;
 737         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 738         if(bot_waypoints_for_items == 1)
 739                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 740                         bot_waypoints_for_items = 0;
 741
 742         precache();
 743
 744         WaypointSprite_Init();
 745
 746         GameLogInit(); // prepare everything
 747         // NOTE for matchid:
 748         // changing the logic generating it is okay. But:
 749         // it HAS to stay <= 64 chars
 750         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 751         if(autocvar_sv_eventlog)
 752         {
 753                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 754                 matchid = strzone(s);
 755
 756                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 757                 s = ":gameinfo:mutators:LIST";
 758
 759                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 760                 s = M_ARGV(0, string);
 761
 762                 // initialiation stuff, not good in the mutator system
 763                 if(!autocvar_g_use_ammunition)
 764                         s = strcat(s, ":no_use_ammunition");
 765
 766                 // initialiation stuff, not good in the mutator system
 767                 if(autocvar_g_pickup_items == 0)
 768                         s = strcat(s, ":no_pickup_items");
 769                 if(autocvar_g_pickup_items > 0)
 770                         s = strcat(s, ":pickup_items");
 771
 772                 // initialiation stuff, not good in the mutator system
 773                 if(autocvar_g_weaponarena != "0")
 774                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 775
 776                 // TODO to mutator system
 777                 if(autocvar_g_norecoil)
 778                         s = strcat(s, ":norecoil");
 779
 780                 // TODO to mutator system
 781                 if(autocvar_g_powerups == 0)
 782                         s = strcat(s, ":no_powerups");
 783                 if(autocvar_g_powerups > 0)
 784                         s = strcat(s, ":powerups");
 785
 786                 GameLogEcho(s);
 787                 GameLogEcho(":gameinfo:end");
 788         }
 789         else
 790                 matchid = strzone(ftos(random()));
 791
 792         cvar_set("nextmap", "");
 793
 794         SetDefaultAlpha();
 795
 796         if(autocvar_g_campaign)
 797                 CampaignPostInit();
 798
 799         Ban_LoadBans();
 800
 801         MapInfo_Enumerate();
 802         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 803
 804         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 805         {
 806                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 807                 if(fd != -1)
 808                 {
 809                         string s;
 810                         while((s = fgets(fd)))
 811                         {
 812                                 int l = tokenize_console(s);
 813                                 if(l < 2)
 814                                         continue;
 815                                 if(argv(0) == "cd")
 816                                 {
 817                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 818                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 819                                 }
 820                                 else if(argv(0) == "fog")
 821                                 {
 822                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 823                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 824                                 }
 825                                 else if(argv(0) == "set")
 826                                 {
 827                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 828                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 829                                 }
 830                                 else if(argv(0) != "//")
 831                                 {
 832                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 833                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 834                                 }
 835                         }
 836                         fclose(fd);
 837                 }
 838         }
 839
 840         WeaponStats_Init();
 841
 842         Nagger_Init();
 843
 844         next_pingtime = time + 5;
 845
 846         detect_maptype();
 847
 848         // set up information replies for clients and server to use
 849         maplist_reply = strzone(getmaplist());
 850         lsmaps_reply = strzone(getlsmaps());
 851         monsterlist_reply = strzone(getmonsterlist());
 852         for(int i = 0; i < 10; ++i)
 853         {
 854                 string s = getrecords(i);
 855                 if (s)
 856                         records_reply[i] = strzone(s);
 857         }
 858         ladder_reply = strzone(getladder());
 859         rankings_reply = strzone(getrankings());
 860
 861         // begin other init
 862         ClientInit_Spawn();
 863         RandomSeed_Spawn();
 864         PingPLReport_Spawn();
 865
 866         CheatInit();
 867
 868         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 869
 870         // fill sv_curl_serverpackages from .serverpackage files
 871         if (autocvar_sv_curl_serverpackages_auto)
 872         {
 873                 string s = "csprogs-" WATERMARK ".txt";
 874                 // remove automatically managed files from the list to prevent duplicates
 875                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 876                 {
 877                         string pkg = argv(i);
 878                         if (startsWith(pkg, "csprogs-")) continue;
 879                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 880                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 881                         s = cons(s, pkg);
 882                 }
 883                 // add automatically managed files to the list
 884                 #define X(match) MACRO_BEGIN { \
 885                         int fd = search_begin(match, true, false); \
 886                         if (fd >= 0) \
 887                         { \
 888                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 889                                 { \
 890                                         s = cons(s, search_getfilename(fd, i)); \
 891                                 } \
 892                                 search_end(fd); \
 893                         } \
 894                 } MACRO_END
 895                 X("*-serverpackage.txt");
 896                 X("*.serverpackage");
 897                 #undef X
 898                 cvar_set("sv_curl_serverpackages", s);
 899         }
 900
 901         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 902         modname = "Xonotic";
 903         // physics/balance/config changes that count as mod
 904         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 905                 modname = cvar_string("g_mod_physics");
 906         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 907                 modname = cvar_string("g_mod_balance");
 908         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 909                 modname = cvar_string("g_mod_config");
 910         // extra mutators that deserve to count as mod
 911         MUTATOR_CALLHOOK(SetModname);
 912
 913         // save it for later
 914         modname = strzone(modname);
 915
 916         WinningConditionHelper(this); // set worldstatus
 917
 918         world_initialized = 1;
 919 }
 920
 921 spawnfunc(light)
 922 {
 923         //makestatic (this); // Who the f___ did that?
 924         delete(this);
 925 }
 926
 927 string GetGametype()
 928 {
 929         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 930 }
 931
 932 string GetMapname()
 933 {
 934         return mapname;
 935 }
 936
 937 float Map_Count, Map_Current;
 938 string Map_Current_Name;
 939
 940 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 941 float GetMaplistPosition()
 942 {
 943         float pos, idx;
 944         string map;
 945
 946         map = GetMapname();
 947         idx = autocvar_g_maplist_index;
 948
 949         if(idx >= 0)
 950                 if(idx < Map_Count)
 951                         if(map == argv(idx))
 952                                 return idx;
 953
 954         for(pos = 0; pos < Map_Count; ++pos)
 955                 if(map == argv(pos))
 956                         return pos;
 957
 958         // resume normal maplist rotation if current map is not in g_maplist
 959         return idx;
 960 }
 961
 962 float MapHasRightSize(string map)
 963 {
 964         float fh;
 965         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 966         if(autocvar_g_maplist_check_waypoints)
 967         {
 968                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 969                 if(!fexists(strcat("maps/", map, ".waypoints")))
 970                 {
 971                         LOG_TRACE(": no waypoints");
 972                         return false;
 973                 }
 974                 LOG_TRACE(": has waypoints");
 975         }
 976
 977         // open map size restriction file
 978         LOG_TRACE("opensize "); LOG_TRACE(map);
 979         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 980         if(fh >= 0)
 981         {
 982                 float mapmin, mapmax;
 983                 LOG_TRACE(": ok, ");
 984                 mapmin = stof(fgets(fh));
 985                 mapmax = stof(fgets(fh));
 986                 fclose(fh);
 987                 if(player_count < mapmin)
 988                 {
 989                         LOG_TRACE("not enough");
 990                         return false;
 991                 }
 992                 if(player_count > mapmax)
 993                 {
 994                         LOG_TRACE("too many");
 995                         return false;
 996                 }
 997                 LOG_TRACE("right size");
 998                 return true;
 999         }
1000         LOG_TRACE(": not found");
1001         return true;
1002 }
1003
1004 string Map_Filename(float position)
1005 {
1006         return strcat("maps/", argv(position), ".bsp");
1007 }
1008
1009 void Map_MarkAsRecent(string m)
1010 {
1011         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1012 }
1013
1014 float Map_IsRecent(string m)
1015 {
1016         return strhasword(autocvar_g_maplist_mostrecent, m);
1017 }
1018
1019 float Map_Check(float position, float pass)
1020 {
1021         string filename;
1022         string map_next;
1023         map_next = argv(position);
1024         if(pass <= 1)
1025         {
1026                 if(Map_IsRecent(map_next))
1027                         return 0;
1028         }
1029         filename = Map_Filename(position);
1030         if(MapInfo_CheckMap(map_next))
1031         {
1032                 if(pass == 2)
1033                         return 1;
1034                 if(MapHasRightSize(map_next))
1035                         return 1;
1036                 return 0;
1037         }
1038         else
1039                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1040
1041         return 0;
1042 }
1043
1044 void Map_Goto_SetStr(string nextmapname)
1045 {
1046         if(getmapname_stored != "")
1047                 strunzone(getmapname_stored);
1048         if(nextmapname == "")
1049                 getmapname_stored = "";
1050         else
1051                 getmapname_stored = strzone(nextmapname);
1052 }
1053
1054 void Map_Goto_SetFloat(float position)
1055 {
1056         cvar_set("g_maplist_index", ftos(position));
1057         Map_Goto_SetStr(argv(position));
1058 }
1059
1060 void Map_Goto(float reinit)
1061 {
1062         MapInfo_LoadMap(getmapname_stored, reinit);
1063 }
1064
1065 // return codes of map selectors:
1066 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1067 //   -2 = permanent failure
1068 float() MaplistMethod_Iterate = // usual method
1069 {
1070         float pass, i;
1071
1072         LOG_TRACE("Trying MaplistMethod_Iterate");
1073
1074         for(pass = 1; pass <= 2; ++pass)
1075         {
1076                 for(i = 1; i < Map_Count; ++i)
1077                 {
1078                         float mapindex;
1079                         mapindex = (i + Map_Current) % Map_Count;
1080                         if(Map_Check(mapindex, pass))
1081                                 return mapindex;
1082                 }
1083         }
1084         return -1;
1085 }
1086
1087 float() MaplistMethod_Repeat = // fallback method
1088 {
1089         LOG_TRACE("Trying MaplistMethod_Repeat");
1090
1091         if(Map_Check(Map_Current, 2))
1092                 return Map_Current;
1093         return -2;
1094 }
1095
1096 float() MaplistMethod_Random = // random map selection
1097 {
1098         float i, imax;
1099
1100         LOG_TRACE("Trying MaplistMethod_Random");
1101
1102         imax = 42;
1103
1104         for(i = 0; i <= imax; ++i)
1105         {
1106                 float mapindex;
1107                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1108                 if(Map_Check(mapindex, 1))
1109                         return mapindex;
1110         }
1111         return -1;
1112 }
1113
1114 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1115 // the exponent sets a bias on the map selection:
1116 // the higher the exponent, the less likely "shortly repeated" same maps are
1117 {
1118         float i, j, imax, insertpos;
1119
1120         LOG_TRACE("Trying MaplistMethod_Shuffle");
1121
1122         imax = 42;
1123
1124         for(i = 0; i <= imax; ++i)
1125         {
1126                 string newlist;
1127
1128                 // now reinsert this at another position
1129                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1130                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1131                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1132                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1133
1134                 // insert the current map there
1135                 newlist = "";
1136                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1137                         newlist = strcat(newlist, " ", argv(j));
1138                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1139                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1140                         newlist = strcat(newlist, " ", argv(j));
1141                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1142                 cvar_set("g_maplist", newlist);
1143                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1144
1145                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1146                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1147                 if(Map_Check(Map_Current, 1))
1148                         return Map_Current;
1149         }
1150         return -1;
1151 }
1152
1153 void Maplist_Init()
1154 {
1155         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1156         float i;
1157         for (i = 0; i < Map_Count; ++i)
1158                 if (Map_Check(i, 2))
1159                         break;
1160         if (i == Map_Count)
1161         {
1162                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1163                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1164                 if(autocvar_g_maplist_shuffle)
1165                         ShuffleMaplist();
1166                 localcmd("\nmenu_cmd sync\n");
1167                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168         }
1169         if(Map_Count == 0)
1170                 error("empty maplist, cannot select a new map");
1171         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1172
1173         if(Map_Current_Name)
1174                 strunzone(Map_Current_Name);
1175         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1176         // this may or may not be correct, but who cares, in the worst case a map
1177         // isn't chosen in the first pass that should have been
1178 }
1179
1180 string GetNextMap()
1181 {
1182         float nextMap;
1183
1184         Maplist_Init();
1185         nextMap = -1;
1186
1187         if(nextMap == -1)
1188                 if(autocvar_g_maplist_shuffle > 0)
1189                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1190
1191         if(nextMap == -1)
1192                 if(autocvar_g_maplist_selectrandom)
1193                         nextMap = MaplistMethod_Random();
1194
1195         if(nextMap == -1)
1196                 nextMap = MaplistMethod_Iterate();
1197
1198         if(nextMap == -1)
1199                 nextMap = MaplistMethod_Repeat();
1200
1201         if(nextMap >= 0)
1202         {
1203                 Map_Goto_SetFloat(nextMap);
1204                 return getmapname_stored;
1205         }
1206
1207         return "";
1208 }
1209
1210 float DoNextMapOverride(float reinit)
1211 {
1212         if(autocvar_g_campaign)
1213         {
1214                 CampaignPostIntermission();
1215                 alreadychangedlevel = true;
1216                 return true;
1217         }
1218         if(autocvar_quit_when_empty)
1219         {
1220                 if(player_count <= currentbots)
1221                 {
1222                         localcmd("quit\n");
1223                         alreadychangedlevel = true;
1224                         return true;
1225                 }
1226         }
1227         if(autocvar_quit_and_redirect != "")
1228         {
1229                 redirection_target = strzone(autocvar_quit_and_redirect);
1230                 alreadychangedlevel = true;
1231                 return true;
1232         }
1233         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1234         {
1235                 localcmd("restart\n");
1236                 alreadychangedlevel = true;
1237                 return true;
1238         }
1239         if(autocvar_nextmap != "")
1240         {
1241                 string m;
1242                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1243                 cvar_set("nextmap",m);
1244
1245                 if(!m || gametypevote)
1246                         return false;
1247                 if(autocvar_sv_vote_gametype)
1248                 {
1249                         Map_Goto_SetStr(m);
1250                         return false;
1251                 }
1252
1253                 if(MapInfo_CheckMap(m))
1254                 {
1255                         Map_Goto_SetStr(m);
1256                         Map_Goto(reinit);
1257                         alreadychangedlevel = true;
1258                         return true;
1259                 }
1260         }
1261         if(!reinit && autocvar_lastlevel)
1262         {
1263                 cvar_settemp_restore();
1264                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1265                 alreadychangedlevel = true;
1266                 return true;
1267         }
1268         return false;
1269 }
1270
1271 void GotoNextMap(float reinit)
1272 {
1273         //string nextmap;
1274         //float n, nummaps;
1275         //string s;
1276         if (alreadychangedlevel)
1277                 return;
1278         alreadychangedlevel = true;
1279
1280         string nextMap;
1281
1282         nextMap = GetNextMap();
1283         if(nextMap == "")
1284                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1285         Map_Goto(reinit);
1286 }
1287
1288
1289 /*
1290 ============
1291 IntermissionThink
1292
1293 When the player presses attack or jump, change to the next level
1294 ============
1295 */
1296 .float autoscreenshot;
1297 void IntermissionThink(entity this)
1298 {
1299         FixIntermissionClient(this);
1300         CSQCMODEL_AUTOUPDATE(this); // PlayerPostThink returns before calling this during intermission, so run it here
1301
1302         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1303         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1304
1305         if( (server_screenshot || client_screenshot)
1306                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1307         {
1308                 this.autoscreenshot = -1;
1309                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1310                 return;
1311         }
1312
1313         if (time < intermission_exittime)
1314                 return;
1315
1316         if(!mapvote_initialized)
1317                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1318                         return;
1319
1320         MapVote_Start();
1321 }
1322
1323 /*
1324 ============
1325 FindIntermission
1326
1327 Returns the entity to view from
1328 ============
1329 */
1330 /*
1331 entity FindIntermission()
1332 {
1333         local   entity spot;
1334         local   float cyc;
1335
1336 // look for info_intermission first
1337         spot = find(NULL, classname, "info_intermission");
1338         if (spot)
1339         {       // pick a random one
1340                 cyc = random() * 4;
1341                 while (cyc > 1)
1342                 {
1343                         spot = find(spot, classname, "info_intermission");
1344                         if (!spot)
1345                                 spot = find(spot, classname, "info_intermission");
1346                         cyc = cyc - 1;
1347                 }
1348                 return spot;
1349         }
1350
1351 // then look for the start position
1352         spot = find(NULL, classname, "info_player_start");
1353         if (spot)
1354                 return spot;
1355
1356 // testinfo_player_start is only found in regioned levels
1357         spot = find(NULL, classname, "testplayerstart");
1358         if (spot)
1359                 return spot;
1360
1361 // then look for the start position
1362         spot = find(NULL, classname, "info_player_deathmatch");
1363         if (spot)
1364                 return spot;
1365
1366         //objerror ("FindIntermission: no spot");
1367         return NULL;
1368 }
1369 */
1370
1371 /*
1372 ===============================================================================
1373
1374 RULES
1375
1376 ===============================================================================
1377 */
1378
1379 void DumpStats(float final)
1380 {
1381         float file;
1382         string s;
1383         float to_console;
1384         float to_eventlog;
1385         float to_file;
1386         float i;
1387
1388         to_console = autocvar_sv_logscores_console;
1389         to_eventlog = autocvar_sv_eventlog;
1390         to_file = autocvar_sv_logscores_file;
1391
1392         if(!final)
1393         {
1394                 to_console = true; // always print printstats replies
1395                 to_eventlog = false; // but never print them to the event log
1396         }
1397
1398         if(to_eventlog)
1399                 if(autocvar_sv_eventlog_console)
1400                         to_console = false; // otherwise we get the output twice
1401
1402         if(final)
1403                 s = ":scores:";
1404         else
1405                 s = ":status:";
1406         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1407
1408         if(to_console)
1409                 LOG_INFO(s, "\n");
1410         if(to_eventlog)
1411                 GameLogEcho(s);
1412
1413         file = -1;
1414         if(to_file)
1415         {
1416                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1417                 if(file == -1)
1418                         to_file = false;
1419                 else
1420                         fputs(file, strcat(s, "\n"));
1421         }
1422
1423         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1424         if(to_console)
1425                 LOG_INFO(s, "\n");
1426         if(to_eventlog)
1427                 GameLogEcho(s);
1428         if(to_file)
1429                 fputs(file, strcat(s, "\n"));
1430
1431         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1432                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1433                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1434                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1435                         s = strcat(s, ftos(it.team), ":");
1436                 else
1437                         s = strcat(s, "spectator:");
1438
1439                 if(to_console)
1440                         LOG_INFO(s, it.netname, "\n");
1441                 if(to_eventlog)
1442                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1443                 if(to_file)
1444                         fputs(file, strcat(s, it.netname, "\n"));
1445         ));
1446
1447         if(teamplay)
1448         {
1449                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1450                 if(to_console)
1451                         LOG_INFO(s, "\n");
1452                 if(to_eventlog)
1453                         GameLogEcho(s);
1454                 if(to_file)
1455                         fputs(file, strcat(s, "\n"));
1456
1457                 for(i = 1; i < 16; ++i)
1458                 {
1459                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1460                         s = strcat(s, ":", ftos(i));
1461                         if(to_console)
1462                                 LOG_INFO(s, "\n");
1463                         if(to_eventlog)
1464                                 GameLogEcho(s);
1465                         if(to_file)
1466                                 fputs(file, strcat(s, "\n"));
1467                 }
1468         }
1469
1470         if(to_console)
1471                 LOG_INFO(":end\n");
1472         if(to_eventlog)
1473                 GameLogEcho(":end");
1474         if(to_file)
1475         {
1476                 fputs(file, ":end\n");
1477                 fclose(file);
1478         }
1479 }
1480
1481 void FixIntermissionClient(entity e)
1482 {
1483         if(!e.autoscreenshot) // initial call
1484         {
1485                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1486                 e.health = -2342;
1487                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1488                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1489                 {
1490                     .entity weaponentity = weaponentities[slot];
1491                         if(e.(weaponentity))
1492                         {
1493                                 e.(weaponentity).effects = EF_NODRAW;
1494                                 if (e.(weaponentity).weaponchild)
1495                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1496                         }
1497                 }
1498                 if(IS_REAL_CLIENT(e))
1499                 {
1500                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1501                         RandomSelection_Init();
1502                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1503                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1504                         ));
1505                         if (RandomSelection_chosen_string != "")
1506                         {
1507                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1508                         }
1509                         msg_entity = e;
1510                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1511                 }
1512         }
1513 }
1514
1515 /*
1516 go to the next level for deathmatch
1517 only called if a time or frag limit has expired
1518 */
1519 void NextLevel()
1520 {
1521         gameover = true;
1522
1523         intermission_running = 1;
1524
1525         // enforce a wait time before allowing changelevel
1526         if(player_count > 0)
1527                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1528         else
1529                 intermission_exittime = -1;
1530
1531         /*
1532         WriteByte (MSG_ALL, SVC_CDTRACK);
1533         WriteByte (MSG_ALL, 3);
1534         WriteByte (MSG_ALL, 3);
1535         // done in FixIntermission
1536         */
1537
1538         //pos = FindIntermission ();
1539
1540         VoteReset();
1541
1542         DumpStats(true);
1543
1544         // send statistics
1545         PlayerStats_GameReport(true);
1546         WeaponStats_Shutdown();
1547
1548         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1549
1550         if(autocvar_sv_eventlog)
1551                 GameLogEcho(":gameover");
1552
1553         GameLogClose();
1554
1555         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1556                 FixIntermissionClient(it);
1557                 if(it.winning)
1558                         bprint(it.netname, " ^7wins.\n");
1559         ));
1560
1561         target_music_kill();
1562
1563         if(autocvar_g_campaign)
1564                 CampaignPreIntermission();
1565
1566         MUTATOR_CALLHOOK(MatchEnd);
1567
1568         localcmd("\nsv_hook_gameend\n");
1569 }
1570
1571 /*
1572 ============
1573 CheckRules_Player
1574
1575 Exit deathmatch games upon conditions
1576 ============
1577 */
1578 void CheckRules_Player(entity this)
1579 {
1580         if (gameover)   // someone else quit the game already
1581                 return;
1582
1583         if(!IS_DEAD(this))
1584                 this.play_time += frametime;
1585
1586         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1587         //   (div0: and that in CheckRules_World please)
1588 }
1589
1590
1591 float InitiateSuddenDeath()
1592 {
1593         // Check first whether normal overtimes could be added before initiating suddendeath mode
1594         // - for this timelimit_overtime needs to be >0 of course
1595         // - also check the winning condition calculated in the previous frame and only add normal overtime
1596         //   again, if at the point at which timelimit would be extended again, still no winner was found
1597         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1598         {
1599                 return 1; // need to call InitiateOvertime later
1600         }
1601         else
1602         {
1603                 if(!checkrules_suddendeathend)
1604                 {
1605                         if(autocvar_g_campaign)
1606                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1607                         else
1608                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1609                         if(g_race && !g_race_qualifying)
1610                                 race_StartCompleting();
1611                 }
1612                 return 0;
1613         }
1614 }
1615
1616 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1617 {
1618         ++checkrules_overtimesadded;
1619         //add one more overtime by simply extending the timelimit
1620         float tl;
1621         tl = autocvar_timelimit;
1622         tl += autocvar_timelimit_overtime;
1623         cvar_set("timelimit", ftos(tl));
1624
1625         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1626 }
1627
1628 float GetWinningCode(float fraglimitreached, float equality)
1629 {
1630         if(autocvar_g_campaign == 1)
1631                 if(fraglimitreached)
1632                         return WINNING_YES;
1633                 else
1634                         return WINNING_NO;
1635
1636         else
1637                 if(equality)
1638                         if(fraglimitreached)
1639                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1640                         else
1641                                 return WINNING_NEVER;
1642                 else
1643                         if(fraglimitreached)
1644                                 return WINNING_YES;
1645                         else
1646                                 return WINNING_NO;
1647 }
1648
1649 // set the .winning flag for exactly those players with a given field value
1650 void SetWinners(.float field, float value)
1651 {
1652         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1653 }
1654
1655 // set the .winning flag for those players with a given field value
1656 void AddWinners(.float field, float value)
1657 {
1658         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1659                 if(it.(field) == value)
1660                         it.winning = 1;
1661         ));
1662 }
1663
1664 // clear the .winning flags
1665 void ClearWinners()
1666 {
1667         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1668 }
1669
1670 void ShuffleMaplist()
1671 {
1672         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1673 }
1674
1675 float leaderfrags;
1676 float WinningCondition_Scores(float limit, float leadlimit)
1677 {
1678         float limitreached;
1679
1680         // TODO make everything use THIS winning condition (except LMS)
1681         WinningConditionHelper(NULL);
1682
1683         if(teamplay)
1684         {
1685                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1686                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1687                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1688                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1689         }
1690
1691         ClearWinners();
1692         if(WinningConditionHelper_winner)
1693                 WinningConditionHelper_winner.winning = 1;
1694         if(WinningConditionHelper_winnerteam >= 0)
1695                 SetWinners(team, WinningConditionHelper_winnerteam);
1696
1697         if(WinningConditionHelper_lowerisbetter)
1698         {
1699                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1700                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1701                 limit = -limit;
1702         }
1703
1704         if(WinningConditionHelper_zeroisworst)
1705                 leadlimit = 0; // not supported in this mode
1706
1707         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1708         // these modes always score in increments of 1, thus this makes sense
1709         {
1710                 if(leaderfrags != WinningConditionHelper_topscore)
1711                 {
1712                         leaderfrags = WinningConditionHelper_topscore;
1713
1714                         if (limit)
1715                         if (leaderfrags == limit - 1)
1716                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1717                         else if (leaderfrags == limit - 2)
1718                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1719                         else if (leaderfrags == limit - 3)
1720                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1721                 }
1722         }
1723
1724         limitreached = false;
1725         if(limit)
1726                 if(WinningConditionHelper_topscore >= limit)
1727                         limitreached = true;
1728         if(leadlimit)
1729         {
1730                 float leadlimitreached;
1731                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1732                 if(autocvar_leadlimit_and_fraglimit)
1733                         limitreached = (limitreached && leadlimitreached);
1734                 else
1735                         limitreached = (limitreached || leadlimitreached);
1736         }
1737
1738         if(limit)
1739                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1740
1741         return GetWinningCode(
1742                 WinningConditionHelper_topscore && limitreached,
1743                 WinningConditionHelper_equality
1744         );
1745 }
1746
1747 float WinningCondition_RanOutOfSpawns()
1748 {
1749         if(have_team_spawns <= 0)
1750                 return WINNING_NO;
1751
1752         if(!autocvar_g_spawn_useallspawns)
1753                 return WINNING_NO;
1754
1755         if(!some_spawn_has_been_used)
1756                 return WINNING_NO;
1757
1758         team1_score = team2_score = team3_score = team4_score = 0;
1759
1760         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1761                 switch(it.team)
1762                 {
1763                         case NUM_TEAM_1: team1_score = 1; break;
1764                         case NUM_TEAM_2: team2_score = 1; break;
1765                         case NUM_TEAM_3: team3_score = 1; break;
1766                         case NUM_TEAM_4: team4_score = 1; break;
1767                 }
1768         ));
1769
1770         IL_EACH(g_spawnpoints, true,
1771         {
1772                 switch(it.team)
1773                 {
1774                         case NUM_TEAM_1: team1_score = 1; break;
1775                         case NUM_TEAM_2: team2_score = 1; break;
1776                         case NUM_TEAM_3: team3_score = 1; break;
1777                         case NUM_TEAM_4: team4_score = 1; break;
1778                 }
1779         });
1780
1781         ClearWinners();
1782         if(team1_score + team2_score + team3_score + team4_score == 0)
1783         {
1784                 checkrules_equality = true;
1785                 return WINNING_YES;
1786         }
1787         else if(team1_score + team2_score + team3_score + team4_score == 1)
1788         {
1789                 float t, i;
1790                 if(team1_score)
1791                         t = NUM_TEAM_1;
1792                 else if(team2_score)
1793                         t = NUM_TEAM_2;
1794                 else if(team3_score)
1795                         t = NUM_TEAM_3;
1796                 else // if(team4_score)
1797                         t = NUM_TEAM_4;
1798                 CheckAllowedTeams(NULL);
1799                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1800                 {
1801                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1802                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1803                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1804                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1805                 }
1806
1807                 AddWinners(team, t);
1808                 return WINNING_YES;
1809         }
1810         else
1811                 return WINNING_NO;
1812 }
1813
1814 /*
1815 ============
1816 CheckRules_World
1817
1818 Exit deathmatch games upon conditions
1819 ============
1820 */
1821 void CheckRules_World()
1822 {
1823         float timelimit;
1824         float fraglimit;
1825         float leadlimit;
1826
1827         VoteThink();
1828         MapVote_Think();
1829
1830         SetDefaultAlpha();
1831
1832         if (intermission_running) // someone else quit the game already
1833         {
1834                 if(player_count == 0) // Nobody there? Then let's go to the next map
1835                         MapVote_Start();
1836                         // this will actually check the player count in the next frame
1837                         // again, but this shouldn't hurt
1838                 return;
1839         }
1840
1841         timelimit = autocvar_timelimit * 60;
1842         fraglimit = autocvar_fraglimit;
1843         leadlimit = autocvar_leadlimit;
1844
1845         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1846         {
1847                 if(timelimit > 0)
1848                         timelimit = 0; // timelimit is not made for warmup
1849                 if(fraglimit > 0)
1850                         fraglimit = 0; // no fraglimit for now
1851                 leadlimit = 0; // no leadlimit for now
1852         }
1853
1854         if(timelimit > 0)
1855         {
1856                 timelimit += game_starttime;
1857         }
1858         else if (timelimit < 0)
1859         {
1860                 // endmatch
1861                 NextLevel();
1862                 return;
1863         }
1864
1865         float wantovertime;
1866         wantovertime = 0;
1867
1868         if(timelimit > game_starttime)
1869                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1870         else
1871                 game_completion_ratio = 0;
1872
1873         if(checkrules_suddendeathend)
1874         {
1875                 if(!checkrules_suddendeathwarning)
1876                 {
1877                         checkrules_suddendeathwarning = true;
1878                         if(g_race && !g_race_qualifying)
1879                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1880                         else
1881                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1882                 }
1883         }
1884         else
1885         {
1886                 if (timelimit && time >= timelimit)
1887                 {
1888                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1889                         {
1890                                 float totalplayers;
1891                                 float playerswithlaps;
1892                                 float readyplayers;
1893                                 totalplayers = playerswithlaps = readyplayers = 0;
1894                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1895                                         ++totalplayers;
1896                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1897                                                 ++playerswithlaps;
1898                                         if(it.ready)
1899                                                 ++readyplayers;
1900                                 ));
1901
1902                                 // at least 2 of the players have completed a lap: start the RACE
1903                                 // otherwise, the players should end the qualifying on their own
1904                                 if(readyplayers || playerswithlaps >= 2)
1905                                 {
1906                                         checkrules_suddendeathend = 0;
1907                                         ReadyRestart(); // go to race
1908                                         return;
1909                                 }
1910                                 else
1911                                         wantovertime |= InitiateSuddenDeath();
1912                         }
1913                         else
1914                                 wantovertime |= InitiateSuddenDeath();
1915                 }
1916         }
1917
1918         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1919         {
1920                 NextLevel();
1921                 return;
1922         }
1923
1924         int checkrules_status = WinningCondition_RanOutOfSpawns();
1925         if(checkrules_status == WINNING_YES)
1926                 bprint("Hey! Someone ran out of spawns!\n");
1927         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1928                 checkrules_status = M_ARGV(0, float);
1929         else
1930                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1931
1932         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1933         {
1934                 checkrules_status = WINNING_NEVER;
1935                 checkrules_overtimesadded = -1;
1936                 wantovertime |= InitiateSuddenDeath();
1937         }
1938
1939         if(checkrules_status == WINNING_NEVER)
1940                 // equality cases! Nobody wins if the overtime ends in a draw.
1941                 ClearWinners();
1942
1943         if(wantovertime)
1944         {
1945                 if(checkrules_status == WINNING_NEVER)
1946                         InitiateOvertime();
1947                 else
1948                         checkrules_status = WINNING_YES;
1949         }
1950
1951         if(checkrules_suddendeathend)
1952                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1953                         checkrules_status = WINNING_YES;
1954
1955         if(checkrules_status == WINNING_YES)
1956         {
1957                 //print("WINNING\n");
1958                 NextLevel();
1959         }
1960 }
1961
1962 string GotoMap(string m)
1963 {
1964         m = GameTypeVote_MapInfo_FixName(m);
1965         if (!m)
1966                 return "The map you suggested is not available on this server.";
1967         if (!autocvar_sv_vote_gametype)
1968         if(!MapInfo_CheckMap(m))
1969                 return "The map you suggested does not support the current game mode.";
1970         cvar_set("nextmap", m);
1971         cvar_set("timelimit", "-1");
1972         if(mapvote_initialized || alreadychangedlevel)
1973         {
1974                 if(DoNextMapOverride(0))
1975                         return "Map switch initiated.";
1976                 else
1977                         return "Hm... no. For some reason I like THIS map more.";
1978         }
1979         else
1980                 return "Map switch will happen after scoreboard.";
1981 }
1982
1983 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1984 void RunThink(entity this)
1985 {
1986         // don't let things stay in the past.
1987         // it is possible to start that way by a trigger with a local time.
1988         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1989                 return;
1990
1991         float oldtime = time; // do we need to save this?
1992
1993         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1994         {
1995                 time = max(oldtime, this.nextthink);
1996                 this.nextthink = 0;
1997
1998                 if(getthink(this))
1999                         getthink(this)(this);
2000                 // mods often set nextthink to time to cause a think every frame,
2001                 // we don't want to loop in that case, so exit if the new nextthink is
2002                 // <= the time the qc was told, also exit if it is past the end of the
2003                 // frame
2004                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2005                         break;
2006         }
2007
2008         time = oldtime;
2009 }
2010
2011 bool autocvar_sv_freezenonclients;
2012 bool autocvar_sv_gameplayfix_delayprojectiles;
2013 void Physics_Frame()
2014 {
2015         if(autocvar_sv_freezenonclients)
2016                 return;
2017
2018         FOREACH_ENTITY_FLOAT(pure_data, false,
2019         {
2020                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2021                         continue;
2022
2023                 set_movetype(it, it.move_movetype);
2024
2025                 if(it.move_movetype == MOVETYPE_NONE)
2026                         continue;
2027
2028                 if(it.move_qcphysics)
2029                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2030
2031                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2032                 {
2033                         // handle thinking here
2034                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2035                                 RunThink(it);
2036                 }
2037         });
2038
2039         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2040                 return;
2041
2042         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2043         {
2044                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2045                         continue;
2046                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2047         });
2048 }
2049
2050 void systems_update();
2051 void EndFrame()
2052 {
2053         anticheat_endframe();
2054
2055         Physics_Frame();
2056
2057         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2058                 entity e = IS_SPEC(it) ? it.enemy : it;
2059                 if (e.typehitsound) {
2060                         it.typehit_time = time;
2061                 } else if (e.damage_dealt) {
2062                         it.hit_time = time;
2063                         it.damage_dealt_total += ceil(e.damage_dealt);
2064                 }
2065         });
2066         // add 1 frametime because after this, engine SV_Physics
2067         // increases time by a frametime and then networks the frame
2068         // add another frametime because client shows everything with
2069         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2070         // needed!
2071         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2072         FOREACH_CLIENT(true, {
2073                 it.typehitsound = false;
2074                 it.damage_dealt = 0;
2075                 antilag_record(it, CS(it), altime);
2076         });
2077         IL_EACH(g_monsters, true,
2078         {
2079                 antilag_record(it, it, altime);
2080         });
2081         FOREACH_CLIENT(PS(it), {
2082                 PlayerState s = PS(it);
2083                 s.ps_push(s, it);
2084         });
2085         systems_update();
2086         IL_ENDFRAME();
2087 }
2088
2089
2090 /*
2091  * RedirectionThink:
2092  * returns true if redirecting
2093  */
2094 float redirection_timeout;
2095 float redirection_nextthink;
2096 float RedirectionThink()
2097 {
2098         float clients_found;
2099
2100         if(redirection_target == "")
2101                 return false;
2102
2103         if(!redirection_timeout)
2104         {
2105                 cvar_set("sv_public", "-2");
2106                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2107                 if(redirection_target == "self")
2108                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2109                 else
2110                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2111         }
2112
2113         if(time < redirection_nextthink)
2114                 return true;
2115
2116         redirection_nextthink = time + 1;
2117
2118         clients_found = 0;
2119         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2120                 // TODO add timer
2121                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2122                 if(redirection_target == "self")
2123                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2124                 else
2125                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2126                 ++clients_found;
2127         ));
2128
2129         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2130
2131         if(time > redirection_timeout || clients_found == 0)
2132                 localcmd("\nwait; wait; wait; quit\n");
2133
2134         return true;
2135 }
2136
2137 void TargetMusic_RestoreGame();
2138 void RestoreGame()
2139 {
2140         // Loaded from a save game
2141         // some things then break, so let's work around them...
2142
2143         // Progs DB (capture records)
2144         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2145
2146         // Mapinfo
2147         MapInfo_Shutdown();
2148         MapInfo_Enumerate();
2149         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2150         WeaponStats_Init();
2151
2152         TargetMusic_RestoreGame();
2153 }
2154
2155 void Shutdown()
2156 {
2157         gameover = 2;
2158
2159         if(world_initialized > 0)
2160         {
2161                 world_initialized = 0;
2162                 LOG_TRACE("Saving persistent data...");
2163                 Ban_SaveBans();
2164
2165                 // playerstats with unfinished match
2166                 PlayerStats_GameReport(false);
2167
2168                 if(!cheatcount_total)
2169                 {
2170                         if(autocvar_sv_db_saveasdump)
2171                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2172                         else
2173                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2174                 }
2175                 if(autocvar_developer)
2176                 {
2177                         if(autocvar_sv_db_saveasdump)
2178                                 db_dump(TemporaryDB, "server-temp.db");
2179                         else
2180                                 db_save(TemporaryDB, "server-temp.db");
2181                 }
2182                 CheatShutdown(); // must be after cheatcount check
2183                 db_close(ServerProgsDB);
2184                 db_close(TemporaryDB);
2185                 LOG_TRACE("Saving persistent data... done!");
2186                 // tell the bot system the game is ending now
2187                 bot_endgame();
2188
2189                 WeaponStats_Shutdown();
2190                 MapInfo_Shutdown();
2191         }
2192         else if(world_initialized == 0)
2193         {
2194                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2195         }
2196         else
2197         {
2198                 __init_dedicated_server_shutdown();
2199         }
2200 }