qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "waypointsprites.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/buffs.qh"
  24 #include "../common/constants.qh"
  25 #include "../common/deathtypes.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/all.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/notifications.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/util.qh"
  34 #include "../common/items/all.qh"
  35 #include "../common/weapons/all.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_fraginfo");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_fraginfo_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 float RandomSeed_Send(entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         entity oldself;
 534         oldself = self;
 535         self = randomseed;
 536         self.think(); // sets random seed and nextthink
 537         self = oldself;
 538 }
 539
 540 void spawnfunc___init_dedicated_server(void)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         remove = remove_unsafely;
 550
 551         entity e;
 552         e = spawn();
 553         e.think = GotoFirstMap;
 554         e.nextthink = time; // this is usually 1 at this point
 555
 556         e = spawn();
 557         e.classname = "info_player_deathmatch"; // safeguard against player joining
 558
 559         self.classname = "worldspawn"; // safeguard against various stuff ;)
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 564         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 565
 566         MapInfo_Enumerate();
 567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 568 }
 569
 570 void Map_MarkAsRecent(string m);
 571 float world_already_spawned;
 572 void Nagger_Init();
 573 void Item_ItemsTime_Init();
 574 void ClientInit_Spawn();
 575 void WeaponStats_Init();
 576 void WeaponStats_Shutdown();
 577 void Physics_AddStats();
 578 void spawnfunc_worldspawn (void)
 579 {
 580         float fd, l, j, n;
 581         string s;
 582
 583         cvar = cvar_normal;
 584         cvar_string = cvar_string_normal;
 585         cvar_set = cvar_set_normal;
 586
 587         if(world_already_spawned)
 588                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 589         world_already_spawned = true;
 590
 591         remove = remove_safely; // during spawning, watch what you remove!
 592
 593         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 594
 595         compressShortVector_init();
 596
 597         entity head;
 598         head = nextent(world);
 599         maxclients = 0;
 600         while(head)
 601         {
 602                 ++maxclients;
 603                 head = nextent(head);
 604         }
 605
 606         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 607
 608         // needs to be done so early because of the constants they create
 609         static_init();
 610         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 611         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 612
 613         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 614
 615         TemporaryDB = db_create();
 616
 617         // 0 normal
 618         lightstyle(0, "m");
 619
 620         // 1 FLICKER (first variety)
 621         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 622
 623         // 2 SLOW STRONG PULSE
 624         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 625
 626         // 3 CANDLE (first variety)
 627         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 628
 629         // 4 FAST STROBE
 630         lightstyle(4, "mamamamamama");
 631
 632         // 5 GENTLE PULSE 1
 633         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 634
 635         // 6 FLICKER (second variety)
 636         lightstyle(6, "nmonqnmomnmomomno");
 637
 638         // 7 CANDLE (second variety)
 639         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 640
 641         // 8 CANDLE (third variety)
 642         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 643
 644         // 9 SLOW STROBE (fourth variety)
 645         lightstyle(9, "aaaaaaaazzzzzzzz");
 646
 647         // 10 FLUORESCENT FLICKER
 648         lightstyle(10, "mmamammmmammamamaaamammma");
 649
 650         // 11 SLOW PULSE NOT FADE TO BLACK
 651         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 652
 653         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 654
 655         // 63 testing
 656         lightstyle(63, "a");
 657
 658         if(autocvar_g_campaign)
 659                 CampaignPreInit();
 660
 661         Map_MarkAsRecent(mapname);
 662
 663         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 664
 665         precache_model ("null"); // we need this one before InitGameplayMode
 666         InitGameplayMode();
 667         readlevelcvars();
 668         GrappleHookInit();
 669
 670         player_count = 0;
 671         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 672         if(bot_waypoints_for_items == 1)
 673                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 674                         bot_waypoints_for_items = 0;
 675
 676         precache();
 677
 678         WaypointSprite_Init();
 679
 680         GameLogInit(); // prepare everything
 681         // NOTE for matchid:
 682         // changing the logic generating it is okay. But:
 683         // it HAS to stay <= 64 chars
 684         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 685         if(autocvar_sv_eventlog)
 686         {
 687                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 688                 matchid = strzone(s);
 689
 690                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 691                 s = ":gameinfo:mutators:LIST";
 692
 693                 ret_string = s;
 694                 MUTATOR_CALLHOOK(BuildMutatorsString);
 695                 s = ret_string;
 696
 697                 // simple, probably not good in the mutator system
 698                 if(autocvar_g_grappling_hook)
 699                         s = strcat(s, ":grappling_hook");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(!autocvar_g_use_ammunition)
 703                         s = strcat(s, ":no_use_ammunition");
 704
 705                 // initialiation stuff, not good in the mutator system
 706                 if(autocvar_g_pickup_items == 0)
 707                         s = strcat(s, ":no_pickup_items");
 708                 if(autocvar_g_pickup_items > 0)
 709                         s = strcat(s, ":pickup_items");
 710
 711                 // initialiation stuff, not good in the mutator system
 712                 if(autocvar_g_weaponarena != "0")
 713                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_norecoil)
 717                         s = strcat(s, ":norecoil");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_powerups == 0)
 721                         s = strcat(s, ":no_powerups");
 722                 if(autocvar_g_powerups > 0)
 723                         s = strcat(s, ":powerups");
 724
 725                 GameLogEcho(s);
 726                 GameLogEcho(":gameinfo:end");
 727         }
 728         else
 729                 matchid = strzone(ftos(random()));
 730
 731         cvar_set("nextmap", "");
 732
 733         SetDefaultAlpha();
 734
 735         if(autocvar_g_campaign)
 736                 CampaignPostInit();
 737
 738         Ban_LoadBans();
 739
 740         MapInfo_Enumerate();
 741         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 742
 743         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 744         {
 745                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 746                 if(fd != -1)
 747                 {
 748                         while((s = fgets(fd)))
 749                         {
 750                                 l = tokenize_console(s);
 751                                 if(l < 2)
 752                                         continue;
 753                                 if(argv(0) == "cd")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 756                                         print("  cdtrack ", argv(2), "\n");
 757                                 }
 758                                 else if(argv(0) == "fog")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 761                                         print("  \"fog\" \"", s, "\"\n");
 762                                 }
 763                                 else if(argv(0) == "set")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 767                                 }
 768                                 else if(argv(0) != "//")
 769                                 {
 770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 772                                 }
 773                         }
 774                         fclose(fd);
 775                 }
 776         }
 777
 778         WeaponStats_Init();
 779
 780         WepSet_AddStat();
 781         WepSet_AddStat_InMap();
 782         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 783         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 784         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 785         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 786         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 787         Nagger_Init();
 788
 789         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 790         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 791         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 792         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 793         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 794         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 795         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 796         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 797         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 798         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 799         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 800         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 801         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 802         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 803         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 804
 805         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 806         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 807
 808         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 809
 810         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 811
 812         // items time
 813         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 814         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 815         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 816         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 817         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 818         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 819         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 820         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 821         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 822         addstat(STAT_SUPERWEAPONS_TIME, AS_FLOAT, item_superweapons_time);
 823         Item_ItemsTime_Init();
 824
 825         // freeze attacks
 826         addstat(STAT_FROZEN, AS_INT, frozen);
 827         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 828
 829         // physics
 830         Physics_AddStats();
 831
 832         // new properties
 833         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 834         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 835         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 836         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 837         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 838         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 839         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 840         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 841         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 842         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 843         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 844         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 845         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 846         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 847         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 848         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 849         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 850         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 851         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 852
 853         // secrets
 854         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 855         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 856
 857         // monsters
 858         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 859         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 860
 861         // misc
 862         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 863
 864         next_pingtime = time + 5;
 865
 866         detect_maptype();
 867
 868         // set up information replies for clients and server to use
 869         maplist_reply = strzone(getmaplist());
 870         lsmaps_reply = strzone(getlsmaps());
 871         monsterlist_reply = strzone(getmonsterlist());
 872         for(int i = 0; i < 10; ++i)
 873         {
 874                 s = getrecords(i);
 875                 if (s)
 876                         records_reply[i] = strzone(s);
 877         }
 878         ladder_reply = strzone(getladder());
 879         rankings_reply = strzone(getrankings());
 880
 881         // begin other init
 882         ClientInit_Spawn();
 883         RandomSeed_Spawn();
 884         PingPLReport_Spawn();
 885
 886         CheatInit();
 887
 888         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 889
 890         // fill sv_curl_serverpackages from .serverpackage files
 891         if(autocvar_sv_curl_serverpackages_auto)
 892         {
 893                 s = "";
 894                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 895                 for(int i = 0; i < n; ++i)
 896                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 897                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 898                                 s = strcat(s, " ", argv(i));
 899                 fd = search_begin("*-serverpackage.txt", true, false);
 900                 if(fd >= 0)
 901                 {
 902                         j = search_getsize(fd);
 903                         for(int i = 0; i < j; ++i)
 904                                 s = strcat(s, " ", search_getfilename(fd, i));
 905                         search_end(fd);
 906                 }
 907                 fd = search_begin("*.serverpackage", true, false);
 908                 if(fd >= 0)
 909                 {
 910                         j = search_getsize(fd);
 911                         for(int i = 0; i < j; ++i)
 912                                 s = strcat(s, " ", search_getfilename(fd, i));
 913                         search_end(fd);
 914                 }
 915                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 916         }
 917
 918         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 919         modname = "Xonotic";
 920         // physics/balance/config changes that count as mod
 921         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 922                 modname = cvar_string("g_mod_physics");
 923         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 924                 modname = cvar_string("g_mod_balance");
 925         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 926                 modname = cvar_string("g_mod_config");
 927         // extra mutators that deserve to count as mod
 928         MUTATOR_CALLHOOK(SetModname);
 929
 930         // save it for later
 931         modname = strzone(modname);
 932
 933         WinningConditionHelper(); // set worldstatus
 934
 935         world_initialized = 1;
 936 }
 937
 938 void spawnfunc_light (void)
 939 {
 940         //makestatic (self); // Who the f___ did that?
 941         remove(self);
 942 }
 943
 944 string GetGametype()
 945 {
 946         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 947 }
 948
 949 string GetMapname()
 950 {
 951         return mapname;
 952 }
 953
 954 float Map_Count, Map_Current;
 955 string Map_Current_Name;
 956
 957 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 958 float GetMaplistPosition()
 959 {
 960         float pos, idx;
 961         string map;
 962
 963         map = GetMapname();
 964         idx = autocvar_g_maplist_index;
 965
 966         if(idx >= 0)
 967                 if(idx < Map_Count)
 968                         if(map == argv(idx))
 969                                 return idx;
 970
 971         for(pos = 0; pos < Map_Count; ++pos)
 972                 if(map == argv(pos))
 973                         return pos;
 974
 975         // resume normal maplist rotation if current map is not in g_maplist
 976         return idx;
 977 }
 978
 979 float MapHasRightSize(string map)
 980 {
 981         float fh;
 982         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 983         if(autocvar_g_maplist_check_waypoints)
 984         {
 985                 dprint("checkwp "); dprint(map);
 986                 if(!fexists(strcat("maps/", map, ".waypoints")))
 987                 {
 988                         dprint(": no waypoints\n");
 989                         return false;
 990                 }
 991                 dprint(": has waypoints\n");
 992         }
 993
 994         // open map size restriction file
 995         dprint("opensize "); dprint(map);
 996         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 997         if(fh >= 0)
 998         {
 999                 float mapmin, mapmax;
1000                 dprint(": ok, ");
1001                 mapmin = stof(fgets(fh));
1002                 mapmax = stof(fgets(fh));
1003                 fclose(fh);
1004                 if(player_count < mapmin)
1005                 {
1006                         dprint("not enough\n");
1007                         return false;
1008                 }
1009                 if(player_count > mapmax)
1010                 {
1011                         dprint("too many\n");
1012                         return false;
1013                 }
1014                 dprint("right size\n");
1015                 return true;
1016         }
1017         dprint(": not found\n");
1018         return true;
1019 }
1020
1021 string Map_Filename(float position)
1022 {
1023         return strcat("maps/", argv(position), ".bsp");
1024 }
1025
1026 string strwords(string s, float w)
1027 {
1028         float endpos;
1029         for(endpos = 0; w && endpos >= 0; --w)
1030                 endpos = strstrofs(s, " ", endpos + 1);
1031         if(endpos < 0)
1032                 return s;
1033         else
1034                 return substring(s, 0, endpos);
1035 }
1036
1037 float strhasword(string s, string w)
1038 {
1039         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1040 }
1041
1042 void Map_MarkAsRecent(string m)
1043 {
1044         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1045 }
1046
1047 float Map_IsRecent(string m)
1048 {
1049         return strhasword(autocvar_g_maplist_mostrecent, m);
1050 }
1051
1052 float Map_Check(float position, float pass)
1053 {
1054         string filename;
1055         string map_next;
1056         map_next = argv(position);
1057         if(pass <= 1)
1058         {
1059                 if(Map_IsRecent(map_next))
1060                         return 0;
1061         }
1062         filename = Map_Filename(position);
1063         if(MapInfo_CheckMap(map_next))
1064         {
1065                 if(pass == 2)
1066                         return 1;
1067                 if(MapHasRightSize(map_next))
1068                         return 1;
1069                 return 0;
1070         }
1071         else
1072                 dprint( "Couldn't select '", filename, "'..\n" );
1073
1074         return 0;
1075 }
1076
1077 void Map_Goto_SetStr(string nextmapname)
1078 {
1079         if(getmapname_stored != "")
1080                 strunzone(getmapname_stored);
1081         if(nextmapname == "")
1082                 getmapname_stored = "";
1083         else
1084                 getmapname_stored = strzone(nextmapname);
1085 }
1086
1087 void Map_Goto_SetFloat(float position)
1088 {
1089         cvar_set("g_maplist_index", ftos(position));
1090         Map_Goto_SetStr(argv(position));
1091 }
1092
1093 void Map_Goto(float reinit)
1094 {
1095         MapInfo_LoadMap(getmapname_stored, reinit);
1096 }
1097
1098 // return codes of map selectors:
1099 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1100 //   -2 = permanent failure
1101 float() MaplistMethod_Iterate = // usual method
1102 {
1103         float pass, i;
1104
1105         dprint("Trying MaplistMethod_Iterate\n");
1106
1107         for(pass = 1; pass <= 2; ++pass)
1108         {
1109                 for(i = 1; i < Map_Count; ++i)
1110                 {
1111                         float mapindex;
1112                         mapindex = (i + Map_Current) % Map_Count;
1113                         if(Map_Check(mapindex, pass))
1114                                 return mapindex;
1115                 }
1116         }
1117         return -1;
1118 }
1119
1120 float() MaplistMethod_Repeat = // fallback method
1121 {
1122         dprint("Trying MaplistMethod_Repeat\n");
1123
1124         if(Map_Check(Map_Current, 2))
1125                 return Map_Current;
1126         return -2;
1127 }
1128
1129 float() MaplistMethod_Random = // random map selection
1130 {
1131         float i, imax;
1132
1133         dprint("Trying MaplistMethod_Random\n");
1134
1135         imax = 42;
1136
1137         for(i = 0; i <= imax; ++i)
1138         {
1139                 float mapindex;
1140                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1141                 if(Map_Check(mapindex, 1))
1142                         return mapindex;
1143         }
1144         return -1;
1145 }
1146
1147 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1148 // the exponent sets a bias on the map selection:
1149 // the higher the exponent, the less likely "shortly repeated" same maps are
1150 {
1151         float i, j, imax, insertpos;
1152
1153         dprint("Trying MaplistMethod_Shuffle\n");
1154
1155         imax = 42;
1156
1157         for(i = 0; i <= imax; ++i)
1158         {
1159                 string newlist;
1160
1161                 // now reinsert this at another position
1162                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1163                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1164                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1165                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1166
1167                 // insert the current map there
1168                 newlist = "";
1169                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1170                         newlist = strcat(newlist, " ", argv(j));
1171                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1172                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1173                         newlist = strcat(newlist, " ", argv(j));
1174                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1175                 cvar_set("g_maplist", newlist);
1176                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1177
1178                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1179                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1180                 if(Map_Check(Map_Current, 1))
1181                         return Map_Current;
1182         }
1183         return -1;
1184 }
1185
1186 void Maplist_Init()
1187 {
1188         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1189         float i;
1190         for (i = 0; i < Map_Count; ++i)
1191                 if (Map_Check(i, 2))
1192                         break;
1193         if (i == Map_Count)
1194         {
1195                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1196                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1197                 if(autocvar_g_maplist_shuffle)
1198                         ShuffleMaplist();
1199                 localcmd("\nmenu_cmd sync\n");
1200                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         }
1202         if(Map_Count == 0)
1203                 error("empty maplist, cannot select a new map");
1204         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1205
1206         if(Map_Current_Name)
1207                 strunzone(Map_Current_Name);
1208         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1209         // this may or may not be correct, but who cares, in the worst case a map
1210         // isn't chosen in the first pass that should have been
1211 }
1212
1213 string GetNextMap()
1214 {
1215         float nextMap;
1216
1217         Maplist_Init();
1218         nextMap = -1;
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_shuffle > 0)
1222                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_selectrandom)
1226                         nextMap = MaplistMethod_Random();
1227
1228         if(nextMap == -1)
1229                 nextMap = MaplistMethod_Iterate();
1230
1231         if(nextMap == -1)
1232                 nextMap = MaplistMethod_Repeat();
1233
1234         if(nextMap >= 0)
1235         {
1236                 Map_Goto_SetFloat(nextMap);
1237                 return getmapname_stored;
1238         }
1239
1240         return "";
1241 }
1242
1243 float DoNextMapOverride(float reinit)
1244 {
1245         if(autocvar_g_campaign)
1246         {
1247                 CampaignPostIntermission();
1248                 alreadychangedlevel = true;
1249                 return true;
1250         }
1251         if(autocvar_quit_when_empty)
1252         {
1253                 if(player_count <= currentbots)
1254                 {
1255                         localcmd("quit\n");
1256                         alreadychangedlevel = true;
1257                         return true;
1258                 }
1259         }
1260         if(autocvar_quit_and_redirect != "")
1261         {
1262                 redirection_target = strzone(autocvar_quit_and_redirect);
1263                 alreadychangedlevel = true;
1264                 return true;
1265         }
1266         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1267         {
1268                 localcmd("restart\n");
1269                 alreadychangedlevel = true;
1270                 return true;
1271         }
1272         if(autocvar_nextmap != "")
1273         {
1274                 string m;
1275                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1276                 cvar_set("nextmap",m);
1277
1278                 if(!m || gametypevote)
1279                         return false;
1280                 if(autocvar_sv_vote_gametype)
1281                 {
1282                         Map_Goto_SetStr(m);
1283                         return false;
1284                 }
1285
1286                 if(MapInfo_CheckMap(m))
1287                 {
1288                         Map_Goto_SetStr(m);
1289                         Map_Goto(reinit);
1290                         alreadychangedlevel = true;
1291                         return true;
1292                 }
1293         }
1294         if(!reinit && autocvar_lastlevel)
1295         {
1296                 cvar_settemp_restore();
1297                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1298                 alreadychangedlevel = true;
1299                 return true;
1300         }
1301         return false;
1302 }
1303
1304 void GotoNextMap(float reinit)
1305 {
1306         //string nextmap;
1307         //float n, nummaps;
1308         //string s;
1309         if (alreadychangedlevel)
1310                 return;
1311         alreadychangedlevel = true;
1312
1313         string nextMap;
1314
1315         nextMap = GetNextMap();
1316         if(nextMap == "")
1317                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1318         Map_Goto(reinit);
1319 }
1320
1321
1322 /*
1323 ============
1324 IntermissionThink
1325
1326 When the player presses attack or jump, change to the next level
1327 ============
1328 */
1329 .float autoscreenshot;
1330 void IntermissionThink()
1331 {
1332         FixIntermissionClient(self);
1333
1334         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1335         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1336
1337         if( (server_screenshot || client_screenshot)
1338                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1339         {
1340                 self.autoscreenshot = -1;
1341                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1342                 return;
1343         }
1344
1345         if (time < intermission_exittime)
1346                 return;
1347
1348         if(!mapvote_initialized)
1349                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1350                         return;
1351
1352         MapVote_Start();
1353 }
1354
1355 /*
1356 ============
1357 FindIntermission
1358
1359 Returns the entity to view from
1360 ============
1361 */
1362 /*
1363 entity FindIntermission()
1364 {
1365         local   entity spot;
1366         local   float cyc;
1367
1368 // look for info_intermission first
1369         spot = find (world, classname, "info_intermission");
1370         if (spot)
1371         {       // pick a random one
1372                 cyc = random() * 4;
1373                 while (cyc > 1)
1374                 {
1375                         spot = find (spot, classname, "info_intermission");
1376                         if (!spot)
1377                                 spot = find (spot, classname, "info_intermission");
1378                         cyc = cyc - 1;
1379                 }
1380                 return spot;
1381         }
1382
1383 // then look for the start position
1384         spot = find (world, classname, "info_player_start");
1385         if (spot)
1386                 return spot;
1387
1388 // testinfo_player_start is only found in regioned levels
1389         spot = find (world, classname, "testplayerstart");
1390         if (spot)
1391                 return spot;
1392
1393 // then look for the start position
1394         spot = find (world, classname, "info_player_deathmatch");
1395         if (spot)
1396                 return spot;
1397
1398         //objerror ("FindIntermission: no spot");
1399         return world;
1400 }
1401 */
1402
1403 /*
1404 ===============================================================================
1405
1406 RULES
1407
1408 ===============================================================================
1409 */
1410
1411 void DumpStats(float final)
1412 {
1413         float file;
1414         string s;
1415         float to_console;
1416         float to_eventlog;
1417         float to_file;
1418         float i;
1419
1420         to_console = autocvar_sv_logscores_console;
1421         to_eventlog = autocvar_sv_eventlog;
1422         to_file = autocvar_sv_logscores_file;
1423
1424         if(!final)
1425         {
1426                 to_console = true; // always print printstats replies
1427                 to_eventlog = false; // but never print them to the event log
1428         }
1429
1430         if(to_eventlog)
1431                 if(autocvar_sv_eventlog_console)
1432                         to_console = false; // otherwise we get the output twice
1433
1434         if(final)
1435                 s = ":scores:";
1436         else
1437                 s = ":status:";
1438         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1439
1440         if(to_console)
1441                 print(s, "\n");
1442         if(to_eventlog)
1443                 GameLogEcho(s);
1444
1445         file = -1;
1446         if(to_file)
1447         {
1448                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1449                 if(file == -1)
1450                         to_file = false;
1451                 else
1452                         fputs(file, strcat(s, "\n"));
1453         }
1454
1455         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1456         if(to_console)
1457                 print(s, "\n");
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460         if(to_file)
1461                 fputs(file, strcat(s, "\n"));
1462
1463         FOR_EACH_CLIENT(other)
1464         {
1465                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1466                 {
1467                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1468                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1469                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1470                                 s = strcat(s, ftos(other.team), ":");
1471                         else
1472                                 s = strcat(s, "spectator:");
1473
1474                         if(to_console)
1475                                 print(s, other.netname, "\n");
1476                         if(to_eventlog)
1477                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1478                         if(to_file)
1479                                 fputs(file, strcat(s, other.netname, "\n"));
1480                 }
1481         }
1482
1483         if(teamplay)
1484         {
1485                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1486                 if(to_console)
1487                         print(s, "\n");
1488                 if(to_eventlog)
1489                         GameLogEcho(s);
1490                 if(to_file)
1491                         fputs(file, strcat(s, "\n"));
1492
1493                 for(i = 1; i < 16; ++i)
1494                 {
1495                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1496                         s = strcat(s, ":", ftos(i));
1497                         if(to_console)
1498                                 print(s, "\n");
1499                         if(to_eventlog)
1500                                 GameLogEcho(s);
1501                         if(to_file)
1502                                 fputs(file, strcat(s, "\n"));
1503                 }
1504         }
1505
1506         if(to_console)
1507                 print(":end\n");
1508         if(to_eventlog)
1509                 GameLogEcho(":end");
1510         if(to_file)
1511         {
1512                 fputs(file, ":end\n");
1513                 fclose(file);
1514         }
1515 }
1516
1517 void FixIntermissionClient(entity e)
1518 {
1519         string s;
1520         if(!e.autoscreenshot) // initial call
1521         {
1522                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1523                 e.health = -2342;
1524                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1525                 e.solid = SOLID_NOT;
1526                 e.movetype = MOVETYPE_NONE;
1527                 e.takedamage = DAMAGE_NO;
1528                 if(e.weaponentity)
1529                 {
1530                         e.weaponentity.effects = EF_NODRAW;
1531                         if (e.weaponentity.weaponentity)
1532                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1533                 }
1534                 if(IS_REAL_CLIENT(e))
1535                 {
1536                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1537                         s = autocvar_sv_intermission_cdtrack;
1538                         if(s != "")
1539                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1540                         msg_entity = e;
1541                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1542                 }
1543         }
1544 }
1545
1546 /*
1547 go to the next level for deathmatch
1548 only called if a time or frag limit has expired
1549 */
1550 void NextLevel()
1551 {
1552         gameover = true;
1553
1554         intermission_running = 1;
1555
1556 // enforce a wait time before allowing changelevel
1557         if(player_count > 0)
1558                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1559         else
1560                 intermission_exittime = -1;
1561
1562         /*
1563         WriteByte (MSG_ALL, SVC_CDTRACK);
1564         WriteByte (MSG_ALL, 3);
1565         WriteByte (MSG_ALL, 3);
1566         // done in FixIntermission
1567         */
1568
1569         //pos = FindIntermission ();
1570
1571         VoteReset();
1572
1573         DumpStats(true);
1574
1575         // send statistics
1576         PlayerStats_GameReport(true);
1577         WeaponStats_Shutdown();
1578
1579         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1580
1581         if(autocvar_sv_eventlog)
1582                 GameLogEcho(":gameover");
1583
1584         GameLogClose();
1585
1586         FOR_EACH_PLAYER(other) {
1587                 FixIntermissionClient(other);
1588                 if(other.winning)
1589                         bprint(other.netname, " ^7wins.\n");
1590         }
1591
1592         if(autocvar_g_campaign)
1593                 CampaignPreIntermission();
1594
1595         MUTATOR_CALLHOOK(MatchEnd);
1596
1597         localcmd("\nsv_hook_gameend\n");
1598 }
1599
1600 /*
1601 ============
1602 CheckRules_Player
1603
1604 Exit deathmatch games upon conditions
1605 ============
1606 */
1607 void CheckRules_Player()
1608 {
1609         if (gameover)   // someone else quit the game already
1610                 return;
1611
1612         if(self.deadflag == DEAD_NO)
1613                 self.play_time += frametime;
1614
1615         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1616         //   (div0: and that in CheckRules_World please)
1617 }
1618
1619
1620 float InitiateSuddenDeath()
1621 {
1622         // Check first whether normal overtimes could be added before initiating suddendeath mode
1623         // - for this timelimit_overtime needs to be >0 of course
1624         // - also check the winning condition calculated in the previous frame and only add normal overtime
1625         //   again, if at the point at which timelimit would be extended again, still no winner was found
1626         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1627         {
1628                 return 1; // need to call InitiateOvertime later
1629         }
1630         else
1631         {
1632                 if(!checkrules_suddendeathend)
1633                 {
1634                         if(autocvar_g_campaign)
1635                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1636                         else
1637                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1638                         if(g_race && !g_race_qualifying)
1639                                 race_StartCompleting();
1640                 }
1641                 return 0;
1642         }
1643 }
1644
1645 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1646 {
1647         ++checkrules_overtimesadded;
1648         //add one more overtime by simply extending the timelimit
1649         float tl;
1650         tl = autocvar_timelimit;
1651         tl += autocvar_timelimit_overtime;
1652         cvar_set("timelimit", ftos(tl));
1653
1654         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1655 }
1656
1657 float GetWinningCode(float fraglimitreached, float equality)
1658 {
1659         if(autocvar_g_campaign == 1)
1660                 if(fraglimitreached)
1661                         return WINNING_YES;
1662                 else
1663                         return WINNING_NO;
1664
1665         else
1666                 if(equality)
1667                         if(fraglimitreached)
1668                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1669                         else
1670                                 return WINNING_NEVER;
1671                 else
1672                         if(fraglimitreached)
1673                                 return WINNING_YES;
1674                         else
1675                                 return WINNING_NO;
1676 }
1677
1678 // set the .winning flag for exactly those players with a given field value
1679 void SetWinners(.float field, float value)
1680 {
1681         entity head;
1682         FOR_EACH_PLAYER(head)
1683                 head.winning = (head.(field) == value);
1684 }
1685
1686 // set the .winning flag for those players with a given field value
1687 void AddWinners(.float field, float value)
1688 {
1689         entity head;
1690         FOR_EACH_PLAYER(head)
1691                 if (head.(field) == value)
1692                         head.winning = 1;
1693 }
1694
1695 // clear the .winning flags
1696 void ClearWinners(void)
1697 {
1698         entity head;
1699         FOR_EACH_PLAYER(head)
1700                 head.winning = 0;
1701 }
1702
1703 // Onslaught winning condition:
1704 // game terminates if only one team has a working generator (or none)
1705 float WinningCondition_Onslaught()
1706 {
1707         entity head;
1708         float t1, t2, t3, t4;
1709
1710         WinningConditionHelper(); // set worldstatus
1711
1712         if(warmup_stage)
1713                 return WINNING_NO;
1714
1715         // first check if the game has ended
1716         t1 = t2 = t3 = t4 = 0;
1717         head = find(world, classname, "onslaught_generator");
1718         while (head)
1719         {
1720                 if (head.health > 0)
1721                 {
1722                         if (head.team == NUM_TEAM_1) t1 = 1;
1723                         if (head.team == NUM_TEAM_2) t2 = 1;
1724                         if (head.team == NUM_TEAM_3) t3 = 1;
1725                         if (head.team == NUM_TEAM_4) t4 = 1;
1726                 }
1727                 head = find(head, classname, "onslaught_generator");
1728         }
1729         if (t1 + t2 + t3 + t4 < 2)
1730         {
1731                 // game over, only one team remains (or none)
1732                 ClearWinners();
1733                 if (t1) SetWinners(team, NUM_TEAM_1);
1734                 if (t2) SetWinners(team, NUM_TEAM_2);
1735                 if (t3) SetWinners(team, NUM_TEAM_3);
1736                 if (t4) SetWinners(team, NUM_TEAM_4);
1737                 dprint("Have a winner, ending game.\n");
1738                 return WINNING_YES;
1739         }
1740
1741         // Two or more teams remain
1742         return WINNING_NO;
1743 }
1744
1745 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1746 // they win. Otherwise the defending team wins once the timelimit passes.
1747 void assault_new_round();
1748 float WinningCondition_Assault()
1749 {
1750         float status;
1751
1752         WinningConditionHelper(); // set worldstatus
1753
1754         status = WINNING_NO;
1755         // as the timelimit has not yet passed just assume the defending team will win
1756         if(assault_attacker_team == NUM_TEAM_1)
1757         {
1758                 SetWinners(team, NUM_TEAM_2);
1759         }
1760         else
1761         {
1762                 SetWinners(team, NUM_TEAM_1);
1763         }
1764
1765         entity ent;
1766         ent = find(world, classname, "target_assault_roundend");
1767         if(ent)
1768         {
1769                 if(ent.winning) // round end has been triggered by attacking team
1770                 {
1771                         bprint("ASSAULT: round completed...\n");
1772                         SetWinners(team, assault_attacker_team);
1773
1774                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1775
1776                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1777                         {
1778                                 status = WINNING_YES;
1779                         }
1780                         else
1781                         {
1782                                 entity oldself;
1783                                 oldself = self;
1784                                 self = ent;
1785                                 assault_new_round();
1786                                 self = oldself;
1787                         }
1788                 }
1789         }
1790
1791         return status;
1792 }
1793
1794 // LMS winning condition: game terminates if and only if there's at most one
1795 // one player who's living lives. Top two scores being equal cancels the time
1796 // limit.
1797 float WinningCondition_LMS()
1798 {
1799         entity head, head2;
1800         float have_player;
1801         float have_players;
1802         float l;
1803
1804         have_player = false;
1805         have_players = false;
1806         l = LMS_NewPlayerLives();
1807
1808         head = find(world, classname, "player");
1809         if(head)
1810                 have_player = true;
1811         head2 = find(head, classname, "player");
1812         if(head2)
1813                 have_players = true;
1814
1815         if(have_player)
1816         {
1817                 // we have at least one player
1818                 if(have_players)
1819                 {
1820                         // two or more active players - continue with the game
1821                 }
1822                 else
1823                 {
1824                         // exactly one player?
1825
1826                         ClearWinners();
1827                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1828
1829                         if(l)
1830                         {
1831                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1832                                 return WINNING_NO;
1833                         }
1834                         else
1835                         {
1836                                 // a winner!
1837                                 // and assign him his first place
1838                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1839                                 return WINNING_YES;
1840                         }
1841                 }
1842         }
1843         else
1844         {
1845                 // nobody is playing at all...
1846                 if(l)
1847                 {
1848                         // wait for players...
1849                 }
1850                 else
1851                 {
1852                         // SNAFU (maybe a draw game?)
1853                         ClearWinners();
1854                         dprint("No players, ending game.\n");
1855                         return WINNING_YES;
1856                 }
1857         }
1858
1859         // When we get here, we have at least two players who are actually LIVING,
1860         // now check if the top two players have equal score.
1861         WinningConditionHelper();
1862
1863         ClearWinners();
1864         if(WinningConditionHelper_winner)
1865                 WinningConditionHelper_winner.winning = true;
1866         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1867                 return WINNING_NEVER;
1868
1869         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1870         return WINNING_NO;
1871 }
1872
1873 void ShuffleMaplist()
1874 {
1875         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1876 }
1877
1878 float leaderfrags;
1879 float WinningCondition_Scores(float limit, float leadlimit)
1880 {
1881         float limitreached;
1882
1883         // TODO make everything use THIS winning condition (except LMS)
1884         WinningConditionHelper();
1885
1886         if(teamplay)
1887         {
1888                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1889                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1890                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1891                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1892         }
1893
1894         ClearWinners();
1895         if(WinningConditionHelper_winner)
1896                 WinningConditionHelper_winner.winning = 1;
1897         if(WinningConditionHelper_winnerteam >= 0)
1898                 SetWinners(team, WinningConditionHelper_winnerteam);
1899
1900         if(WinningConditionHelper_lowerisbetter)
1901         {
1902                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1903                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1904                 limit = -limit;
1905         }
1906
1907         if(WinningConditionHelper_zeroisworst)
1908                 leadlimit = 0; // not supported in this mode
1909
1910         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1911         // these modes always score in increments of 1, thus this makes sense
1912         {
1913                 if(leaderfrags != WinningConditionHelper_topscore)
1914                 {
1915                         leaderfrags = WinningConditionHelper_topscore;
1916
1917                         if (limit)
1918                         if (leaderfrags == limit - 1)
1919                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1920                         else if (leaderfrags == limit - 2)
1921                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1922                         else if (leaderfrags == limit - 3)
1923                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1924                 }
1925         }
1926
1927         limitreached = false;
1928         if(limit)
1929                 if(WinningConditionHelper_topscore >= limit)
1930                         limitreached = true;
1931         if(leadlimit)
1932         {
1933                 float leadlimitreached;
1934                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1935                 if(autocvar_leadlimit_and_fraglimit)
1936                         limitreached = (limitreached && leadlimitreached);
1937                 else
1938                         limitreached = (limitreached || leadlimitreached);
1939         }
1940
1941         if(limit)
1942                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1943
1944         return GetWinningCode(
1945                 WinningConditionHelper_topscore && limitreached,
1946                 WinningConditionHelper_equality
1947         );
1948 }
1949
1950 float WinningCondition_Race(float fraglimit)
1951 {
1952         float wc;
1953         entity p;
1954         float n, c;
1955
1956         n = 0;
1957         c = 0;
1958         FOR_EACH_PLAYER(p)
1959         {
1960                 ++n;
1961                 if(p.race_completed)
1962                         ++c;
1963         }
1964         if(n && (n == c))
1965                 return WINNING_YES;
1966         wc = WinningCondition_Scores(fraglimit, 0);
1967
1968         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1969         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1970         // do NOT support equality when the laps are all raced!
1971                 return WINNING_STARTSUDDENDEATHOVERTIME;
1972         else
1973                 return WINNING_NEVER;
1974 }
1975
1976 float WinningCondition_QualifyingThenRace(float limit)
1977 {
1978         float wc;
1979         wc = WinningCondition_Scores(limit, 0);
1980
1981         // NEVER initiate overtime
1982         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1983         {
1984                 return WINNING_YES;
1985         }
1986
1987         return wc;
1988 }
1989
1990 float WinningCondition_RanOutOfSpawns()
1991 {
1992         entity head;
1993
1994         if(have_team_spawns <= 0)
1995                 return WINNING_NO;
1996
1997         if(!autocvar_g_spawn_useallspawns)
1998                 return WINNING_NO;
1999
2000         if(!some_spawn_has_been_used)
2001                 return WINNING_NO;
2002
2003         team1_score = team2_score = team3_score = team4_score = 0;
2004
2005         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2006         {
2007                 if(head.team == NUM_TEAM_1)
2008                         team1_score = 1;
2009                 else if(head.team == NUM_TEAM_2)
2010                         team2_score = 1;
2011                 else if(head.team == NUM_TEAM_3)
2012                         team3_score = 1;
2013                 else if(head.team == NUM_TEAM_4)
2014                         team4_score = 1;
2015         }
2016
2017         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2018         {
2019                 if(head.team == NUM_TEAM_1)
2020                         team1_score = 1;
2021                 else if(head.team == NUM_TEAM_2)
2022                         team2_score = 1;
2023                 else if(head.team == NUM_TEAM_3)
2024                         team3_score = 1;
2025                 else if(head.team == NUM_TEAM_4)
2026                         team4_score = 1;
2027         }
2028
2029         ClearWinners();
2030         if(team1_score + team2_score + team3_score + team4_score == 0)
2031         {
2032                 checkrules_equality = true;
2033                 return WINNING_YES;
2034         }
2035         else if(team1_score + team2_score + team3_score + team4_score == 1)
2036         {
2037                 float t, i;
2038                 if(team1_score)
2039                         t = NUM_TEAM_1;
2040                 else if(team2_score)
2041                         t = NUM_TEAM_2;
2042                 else if(team3_score)
2043                         t = NUM_TEAM_3;
2044                 else // if(team4_score)
2045                         t = NUM_TEAM_4;
2046                 CheckAllowedTeams(world);
2047                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2048                 {
2049                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2050                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2051                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2052                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2053                 }
2054
2055                 AddWinners(team, t);
2056                 return WINNING_YES;
2057         }
2058         else
2059                 return WINNING_NO;
2060 }
2061
2062 /*
2063 ============
2064 CheckRules_World
2065
2066 Exit deathmatch games upon conditions
2067 ============
2068 */
2069 void CheckRules_World()
2070 {
2071         float timelimit;
2072         float fraglimit;
2073         float leadlimit;
2074
2075         VoteThink();
2076         MapVote_Think();
2077
2078         SetDefaultAlpha();
2079
2080         if (gameover)   // someone else quit the game already
2081         {
2082                 if(player_count == 0) // Nobody there? Then let's go to the next map
2083                         MapVote_Start();
2084                         // this will actually check the player count in the next frame
2085                         // again, but this shouldn't hurt
2086                 return;
2087         }
2088
2089         timelimit = autocvar_timelimit * 60;
2090         fraglimit = autocvar_fraglimit;
2091         leadlimit = autocvar_leadlimit;
2092
2093         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2094         {
2095                 if(timelimit > 0)
2096                         timelimit = 0; // timelimit is not made for warmup
2097                 if(fraglimit > 0)
2098                         fraglimit = 0; // no fraglimit for now
2099                 leadlimit = 0; // no leadlimit for now
2100         }
2101
2102         if(timelimit > 0)
2103         {
2104                 timelimit += game_starttime;
2105         }
2106         else if (timelimit < 0)
2107         {
2108                 // endmatch
2109                 NextLevel();
2110                 return;
2111         }
2112
2113         if(g_onslaught)
2114                 timelimit = 0; // ONS has its own overtime rule
2115
2116         float wantovertime;
2117         wantovertime = 0;
2118
2119         if(timelimit > game_starttime)
2120                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2121         else
2122                 game_completion_ratio = 0;
2123
2124         if(checkrules_suddendeathend)
2125         {
2126                 if(!checkrules_suddendeathwarning)
2127                 {
2128                         checkrules_suddendeathwarning = true;
2129                         if(g_race && !g_race_qualifying)
2130                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2131                         else
2132                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2133                 }
2134         }
2135         else
2136         {
2137                 if (timelimit && time >= timelimit)
2138                 {
2139                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2140                         {
2141                                 float totalplayers;
2142                                 float playerswithlaps;
2143                                 float readyplayers;
2144                                 entity head;
2145                                 totalplayers = playerswithlaps = readyplayers = 0;
2146                                 FOR_EACH_PLAYER(head)
2147                                 {
2148                                         ++totalplayers;
2149                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2150                                                 ++playerswithlaps;
2151                                         if(head.ready)
2152                                                 ++readyplayers;
2153                                 }
2154
2155                                 // at least 2 of the players have completed a lap: start the RACE
2156                                 // otherwise, the players should end the qualifying on their own
2157                                 if(readyplayers || playerswithlaps >= 2)
2158                                 {
2159                                         checkrules_suddendeathend = 0;
2160                                         ReadyRestart(); // go to race
2161                                         return;
2162                                 }
2163                                 else
2164                                         wantovertime |= InitiateSuddenDeath();
2165                         }
2166                         else
2167                                 wantovertime |= InitiateSuddenDeath();
2168                 }
2169         }
2170
2171         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2172         {
2173                 NextLevel();
2174                 return;
2175         }
2176
2177         float checkrules_status;
2178         checkrules_status = WinningCondition_RanOutOfSpawns();
2179         if(checkrules_status == WINNING_YES)
2180         {
2181                 bprint("Hey! Someone ran out of spawns!\n");
2182         }
2183         else if(g_race && !g_race_qualifying && timelimit >= 0)
2184         {
2185                 checkrules_status = WinningCondition_Race(fraglimit);
2186                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2187         }
2188         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2189         {
2190                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2191                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2192         }
2193         else if(g_assault)
2194         {
2195                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2196         }
2197         else if(g_lms)
2198         {
2199                 checkrules_status = WinningCondition_LMS();
2200         }
2201         else if (g_onslaught)
2202         {
2203                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2204         }
2205         else
2206         {
2207                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2208                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2209         }
2210
2211         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2212         {
2213                 checkrules_status = WINNING_NEVER;
2214                 checkrules_overtimesadded = -1;
2215                 wantovertime |= InitiateSuddenDeath();
2216         }
2217
2218         if(checkrules_status == WINNING_NEVER)
2219                 // equality cases! Nobody wins if the overtime ends in a draw.
2220                 ClearWinners();
2221
2222         if(wantovertime)
2223         {
2224                 if(checkrules_status == WINNING_NEVER)
2225                         InitiateOvertime();
2226                 else
2227                         checkrules_status = WINNING_YES;
2228         }
2229
2230         if(checkrules_suddendeathend)
2231                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2232                         checkrules_status = WINNING_YES;
2233
2234         if(checkrules_status == WINNING_YES)
2235         {
2236                 //print("WINNING\n");
2237                 NextLevel();
2238         }
2239 }
2240
2241 string GotoMap(string m)
2242 {
2243         m = GameTypeVote_MapInfo_FixName(m);
2244         if (!m)
2245                 return "The map you suggested is not available on this server.";
2246         if (!autocvar_sv_vote_gametype)
2247         if(!MapInfo_CheckMap(m))
2248                 return "The map you suggested does not support the current game mode.";
2249         cvar_set("nextmap", m);
2250         cvar_set("timelimit", "-1");
2251         if(mapvote_initialized || alreadychangedlevel)
2252         {
2253                 if(DoNextMapOverride(0))
2254                         return "Map switch initiated.";
2255                 else
2256                         return "Hm... no. For some reason I like THIS map more.";
2257         }
2258         else
2259                 return "Map switch will happen after scoreboard.";
2260 }
2261
2262
2263 void EndFrame()
2264 {
2265         anticheat_endframe();
2266
2267         float altime;
2268         FOR_EACH_REALCLIENT(self)
2269         {
2270                 entity e = IS_SPEC(self) ? self.enemy : self;
2271                 if(e.typehitsound)
2272                         self.typehit_time = time;
2273                 else if(e.damage_dealt)
2274                 {
2275                         self.hit_time = time;
2276                         self.damage_dealt_total += ceil(e.damage_dealt);
2277                 }
2278         }
2279         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2280         // add 1 frametime because after this, engine SV_Physics
2281         // increases time by a frametime and then networks the frame
2282         // add another frametime because client shows everything with
2283         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2284         // needed!
2285         FOR_EACH_CLIENT(self)
2286         {
2287                 self.typehitsound = false;
2288                 self.damage_dealt = 0;
2289                 antilag_record(self, altime);
2290         }
2291         FOR_EACH_MONSTER(self)
2292                 antilag_record(self, altime);
2293 }
2294
2295
2296 /*
2297  * RedirectionThink:
2298  * returns true if redirecting
2299  */
2300 float redirection_timeout;
2301 float redirection_nextthink;
2302 float RedirectionThink()
2303 {
2304         float clients_found;
2305
2306         if(redirection_target == "")
2307                 return false;
2308
2309         if(!redirection_timeout)
2310         {
2311                 cvar_set("sv_public", "-2");
2312                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2313                 if(redirection_target == "self")
2314                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2315                 else
2316                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2317         }
2318
2319         if(time < redirection_nextthink)
2320                 return true;
2321
2322         redirection_nextthink = time + 1;
2323
2324         clients_found = 0;
2325         FOR_EACH_REALCLIENT(self)
2326         {
2327                 // TODO add timer
2328                 print("Redirecting: sending connect command to ", self.netname, "\n");
2329                 if(redirection_target == "self")
2330                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2331                 else
2332                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2333                 ++clients_found;
2334         }
2335
2336         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2337
2338         if(time > redirection_timeout || clients_found == 0)
2339                 localcmd("\nwait; wait; wait; quit\n");
2340
2341         return true;
2342 }
2343
2344 void TargetMusic_RestoreGame();
2345 void RestoreGame()
2346 {
2347         // Loaded from a save game
2348         // some things then break, so let's work around them...
2349
2350         // Progs DB (capture records)
2351         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2352
2353         // Mapinfo
2354         MapInfo_Shutdown();
2355         MapInfo_Enumerate();
2356         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2357         WeaponStats_Init();
2358
2359         TargetMusic_RestoreGame();
2360 }
2361
2362 void Shutdown()
2363 {
2364         gameover = 2;
2365
2366         if(world_initialized > 0)
2367         {
2368                 world_initialized = 0;
2369                 print("Saving persistent data...\n");
2370                 Ban_SaveBans();
2371
2372                 // playerstats with unfinished match
2373                 PlayerStats_GameReport(false);
2374
2375                 if(!cheatcount_total)
2376                 {
2377                         if(autocvar_sv_db_saveasdump)
2378                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2379                         else
2380                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2381                 }
2382                 if(autocvar_developer)
2383                 {
2384                         if(autocvar_sv_db_saveasdump)
2385                                 db_dump(TemporaryDB, "server-temp.db");
2386                         else
2387                                 db_save(TemporaryDB, "server-temp.db");
2388                 }
2389                 CheatShutdown(); // must be after cheatcount check
2390                 db_close(ServerProgsDB);
2391                 db_close(TemporaryDB);
2392                 print("done!\n");
2393                 // tell the bot system the game is ending now
2394                 bot_endgame();
2395
2396                 WeaponStats_Shutdown();
2397                 MapInfo_Shutdown();
2398         }
2399         else if(world_initialized == 0)
2400         {
2401                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2402         }
2403 }