qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 void GotoFirstMap()
  99 {
 100         float n;
 101         if(autocvar__sv_init)
 102         {
 103                 // cvar_set("_sv_init", "0");
 104                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 105                 // to this "init" map on a dedicated server will cause no permanent
 106                 // harm
 107                 if(autocvar_g_maplist_shuffle)
 108                         ShuffleMaplist();
 109                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 110                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 111
 112                 MapInfo_Enumerate();
 113                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 114
 115                 if(!DoNextMapOverride(1))
 116                         GotoNextMap(1);
 117
 118                 return;
 119         }
 120
 121         if(time < 5)
 122         {
 123                 self.nextthink = time;
 124         }
 125         else
 126         {
 127                 self.nextthink = time + 1;
 128                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 129         }
 130 }
 131
 132 void cvar_changes_init()
 133 {
 134         float h;
 135         string k, v, d;
 136         float n, i, adding, pureadding;
 137
 138         if(cvar_changes)
 139                 strunzone(cvar_changes);
 140         cvar_changes = string_null;
 141         if(cvar_purechanges)
 142                 strunzone(cvar_purechanges);
 143         cvar_purechanges = string_null;
 144         cvar_purechanges_count = 0;
 145
 146         h = buf_create();
 147         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 148         n = buf_getsize(h);
 149
 150         adding = TRUE;
 151         pureadding = TRUE;
 152
 153         for(i = 0; i < n; ++i)
 154         {
 155                 k = bufstr_get(h, i);
 156
 157 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 158 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 159 #define BADCVAR(p) if(k == p) continue
 160
 161                 // general excludes and namespaces for server admin used cvars
 162                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 163
 164                 // internal
 165                 BADPREFIX("csqc_");
 166                 BADPREFIX("cvar_check_");
 167                 BADCVAR("gamecfg");
 168                 BADCVAR("g_configversion");
 169                 BADCVAR("g_maplist_index");
 170                 BADCVAR("halflifebsp");
 171                 BADPREFIX("sv_world");
 172
 173                 // client
 174                 BADPREFIX("chase_");
 175                 BADPREFIX("cl_");
 176                 BADPREFIX("con_");
 177                 BADPREFIX("scoreboard_");
 178                 BADPREFIX("g_campaign");
 179                 BADPREFIX("g_waypointsprite_");
 180                 BADPREFIX("gl_");
 181                 BADPREFIX("joy");
 182                 BADPREFIX("hud_");
 183                 BADPREFIX("m_");
 184                 BADPREFIX("menu_");
 185                 BADPREFIX("net_slist_");
 186                 BADPREFIX("r_");
 187                 BADPREFIX("sbar_");
 188                 BADPREFIX("scr_");
 189                 BADPREFIX("snd_");
 190                 BADPREFIX("show");
 191                 BADPREFIX("sensitivity");
 192                 BADPREFIX("userbind");
 193                 BADPREFIX("v_");
 194                 BADPREFIX("vid_");
 195                 BADPREFIX("crosshair");
 196                 BADCVAR("mod_q3bsp_lightmapmergepower");
 197                 BADCVAR("mod_q3bsp_nolightmaps");
 198                 BADCVAR("fov");
 199                 BADCVAR("mastervolume");
 200                 BADCVAR("volume");
 201                 BADCVAR("bgmvolume");
 202
 203                 // private
 204                 BADCVAR("developer");
 205                 BADCVAR("log_dest_udp");
 206                 BADCVAR("log_file");
 207                 BADCVAR("net_address");
 208                 BADCVAR("net_address_ipv6");
 209                 BADCVAR("port");
 210                 BADCVAR("savedgamecfg");
 211                 BADCVAR("serverconfig");
 212                 BADCVAR("sv_autoscreenshot");
 213                 BADCVAR("sv_heartbeatperiod");
 214                 BADCVAR("sv_vote_master_password");
 215                 BADCVAR("sys_colortranslation");
 216                 BADCVAR("sys_specialcharactertranslation");
 217                 BADCVAR("timeformat");
 218                 BADCVAR("timestamps");
 219                 BADPREFIX("developer_");
 220                 BADPREFIX("g_ban_");
 221                 BADPREFIX("g_banned_list");
 222                 BADPREFIX("g_chat_flood_");
 223                 BADPREFIX("g_ghost_items");
 224                 BADPREFIX("g_playerstats_");
 225                 BADPREFIX("g_respawn_ghosts");
 226                 BADPREFIX("g_voice_flood_");
 227                 BADPREFIX("rcon_");
 228                 BADPREFIX("sv_allowdownloads");
 229                 BADPREFIX("sv_autodemo");
 230                 BADPREFIX("sv_curl_");
 231                 BADPREFIX("sv_eventlog");
 232                 BADPREFIX("sv_logscores_");
 233                 BADPREFIX("sv_master");
 234                 BADPREFIX("sv_weaponstats_");
 235                 BADPREFIX("sv_waypointsprite_");
 236                 BADCVAR("rescan_pending");
 237
 238                 // these can contain player IDs, so better hide
 239                 BADPREFIX("g_forced_team_");
 240
 241                 // mapinfo
 242                 BADCVAR("fraglimit");
 243                 BADCVAR("g_arena");
 244                 BADCVAR("g_assault");
 245                 BADCVAR("g_ca");
 246                 BADCVAR("g_ctf");
 247                 BADCVAR("g_cts");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_domination_default_teams");
 251                 BADCVAR("g_freezetag");
 252                 BADCVAR("g_keepaway");
 253                 BADCVAR("g_keyhunt");
 254                 BADCVAR("g_keyhunt_teams");
 255                 BADCVAR("g_keyhunt_teams");
 256                 BADCVAR("g_lms");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("g_onslaught");
 259                 BADCVAR("g_race");
 260                 BADCVAR("g_race_qualifying_timelimit");
 261                 BADCVAR("g_runematch");
 262                 BADCVAR("g_tdm");
 263                 BADCVAR("g_tdm_teams");
 264                 BADCVAR("leadlimit");
 265                 BADCVAR("nextmap");
 266                 BADCVAR("teamplay");
 267                 BADCVAR("timelimit");
 268
 269                 // long
 270                 BADCVAR("hostname");
 271                 BADCVAR("g_maplist");
 272                 BADCVAR("g_maplist_mostrecent");
 273                 BADCVAR("sv_motd");
 274
 275                 v = cvar_string(k);
 276                 d = cvar_defstring(k);
 277                 if(v == d)
 278                         continue;
 279
 280                 if(adding)
 281                 {
 282                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 283                         if(strlen(cvar_changes) > 16384)
 284                         {
 285                                 cvar_changes = "// too many settings have been changed to show them here\n";
 286                                 adding = 0;
 287                         }
 288                 }
 289
 290                 // now check if the changes are actually gameplay relevant
 291
 292                 // does nothing visible
 293                 BADCVAR("captureleadlimit_override");
 294                 BADCVAR("g_arena_point_leadlimit");
 295                 BADCVAR("g_balance_kill_delay");
 296                 BADCVAR("g_ca_point_leadlimit");
 297                 BADCVAR("g_ctf_captimerecord_always");
 298                 BADCVAR("g_ctf_flag_capture_effects");
 299                 BADCVAR("g_ctf_flag_glowtrails");
 300                 BADCVAR("g_ctf_flag_pickup_effects");
 301                 BADCVAR("g_domination_point_leadlimit");
 302                 BADCVAR("g_forced_respawn");
 303                 BADCVAR("g_keyhunt_point_leadlimit");
 304                 BADPREFIX("g_mod_");
 305                 BADCVAR("g_nexball_goalleadlimit");
 306                 BADCVAR("g_runematch_point_leadlimit");
 307                 BADCVAR("leadlimit_and_fraglimit");
 308                 BADCVAR("leadlimit_override");
 309                 BADCVAR("pausable");
 310                 BADCVAR("sv_allow_fullbright");
 311                 BADCVAR("sv_checkforpacketsduringsleep");
 312                 BADCVAR("sv_fraginfo");
 313                 BADCVAR("sv_timeout");
 314                 BADPREFIX("sv_timeout_");
 315                 BADCVAR("welcome_message_time");
 316                 BADPREFIX("crypto_");
 317                 BADPREFIX("g_chat_");
 318                 BADPREFIX("g_ctf_captimerecord_");
 319                 BADPREFIX("g_maplist_votable_");
 320                 BADPREFIX("net_");
 321                 BADPREFIX("prvm_");
 322                 BADPREFIX("skill_");
 323                 BADPREFIX("sv_cullentities_");
 324                 BADPREFIX("sv_fraginfo_");
 325                 BADPREFIX("sv_maxidle_");
 326                 BADPREFIX("sv_vote_");
 327                 BADPREFIX("timelimit_");
 328                 BADCVAR("gameversion");
 329                 BADPREFIX("gameversion_");
 330                 BADCVAR("sv_namechangetimer");
 331 #ifndef NO_LEGACY_NETWORKING
 332                 BADCVAR("sv_use_csqc_players"); // transition
 333 #endif
 334
 335                 // allowed changes to server admins (please sync this to server.cfg)
 336                 // vi commands:
 337                 //   :/"impure"/,$d
 338                 //   :g!,^\/\/[^ /],d
 339                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 340                 //   :%!sort
 341                 // yes, this does contain some redundant stuff, don't really care
 342                 BADCVAR("bot_config_file");
 343                 BADCVAR("bot_number");
 344                 BADCVAR("bot_prefix");
 345                 BADCVAR("bot_suffix");
 346                 BADCVAR("capturelimit_override");
 347                 BADCVAR("fraglimit_override");
 348                 BADCVAR("gametype");
 349                 BADCVAR("g_antilag");
 350                 BADCVAR("g_balance_teams");
 351                 BADCVAR("g_ban_sync_trusted_servers");
 352                 BADCVAR("g_ban_sync_uri");
 353                 BADCVAR("g_ctf_ignore_frags");
 354                 BADCVAR("g_domination_point_limit");
 355                 BADCVAR("g_friendlyfire");
 356                 BADCVAR("g_fullbrightitems");
 357                 BADCVAR("g_fullbrightplayers");
 358                 BADCVAR("g_keyhunt_point_limit");
 359                 BADCVAR("g_keyhunt_teams_override");
 360                 BADCVAR("g_lms_lives_override");
 361                 BADCVAR("g_maplist");
 362                 BADCVAR("g_maplist_check_waypoints");
 363                 BADCVAR("g_maplist_mostrecent_count");
 364                 BADCVAR("g_maplist_shuffle");
 365                 BADCVAR("g_maplist_votable");
 366                 BADCVAR("g_maplist_votable_abstain");
 367                 BADCVAR("g_maplist_votable_nodetail");
 368                 BADCVAR("g_maplist_votable_suggestions");
 369                 BADCVAR("g_maxplayers");
 370                 BADCVAR("g_mirrordamage");
 371                 BADCVAR("g_nexball_goallimit");
 372                 BADCVAR("g_powerups");
 373                 BADCVAR("g_runematch_point_limit");
 374                 BADCVAR("g_start_delay");
 375                 BADCVAR("g_warmup");
 376                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 377                 BADCVAR("hostname");
 378                 BADCVAR("log_file");
 379                 BADCVAR("maxplayers");
 380                 BADCVAR("minplayers");
 381                 BADCVAR("net_address");
 382                 BADCVAR("port");
 383                 BADCVAR("rcon_password");
 384                 BADCVAR("rcon_restricted_commands");
 385                 BADCVAR("rcon_restricted_password");
 386                 BADCVAR("skill");
 387                 BADCVAR("sv_adminnick");
 388                 BADCVAR("sv_autoscreenshot");
 389                 BADCVAR("sv_autotaunt");
 390                 BADCVAR("sv_curl_defaulturl");
 391                 BADCVAR("sv_defaultcharacter");
 392                 BADCVAR("sv_defaultplayercolors");
 393                 BADCVAR("sv_defaultplayermodel");
 394                 BADCVAR("sv_defaultplayerskin");
 395                 BADCVAR("sv_maxidle");
 396                 BADCVAR("sv_maxrate");
 397                 BADCVAR("sv_motd");
 398                 BADCVAR("sv_public");
 399                 BADCVAR("sv_ready_restart");
 400                 BADCVAR("sv_status_privacy");
 401                 BADCVAR("sv_taunt");
 402                 BADCVAR("sv_vote_call");
 403                 BADCVAR("sv_vote_commands");
 404                 BADCVAR("sv_vote_majority_factor");
 405                 BADCVAR("sv_vote_master");
 406                 BADCVAR("sv_vote_master_commands");
 407                 BADCVAR("sv_vote_master_password");
 408                 BADCVAR("sv_vote_simple_majority_factor");
 409                 BADCVAR("sys_ticrate");
 410                 BADCVAR("teamplay_mode");
 411                 BADCVAR("timelimit_override");
 412                 BADCVAR("g_spawnshieldtime");
 413                 BADPREFIX("g_warmup_");
 414                 BADPREFIX("sv_ready_restart_");
 415
 416                 // mutators that announce themselves properly to the server browser
 417                 BADCVAR("g_minstagib");
 418                 BADCVAR("g_new_toys");
 419                 BADCVAR("g_nix");
 420
 421                 if(autocvar_g_minstagib)
 422                 {
 423                         BADCVAR("g_grappling_hook");
 424                         BADCVAR("g_jetpack");
 425                 }
 426 #undef BADPREFIX
 427 #undef BADCVAR
 428
 429                 if(pureadding)
 430                 {
 431                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 432                         if(strlen(cvar_purechanges) > 16384)
 433                         {
 434                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 435                                 pureadding = 0;
 436                         }
 437                 }
 438                 ++cvar_purechanges_count;
 439                 // WARNING: this variable is used for the server list
 440                 // NEVER dare to skip this code!
 441                 // Hacks to intentionally appearing as "pure server" even though you DO have
 442                 // modified settings may be punished by removal from the server list.
 443                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 444                 // though.
 445         }
 446         buf_del(h);
 447         if(cvar_changes == "")
 448                 cvar_changes = "// this server runs at default server settings\n";
 449         else
 450                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 451         cvar_changes = strzone(cvar_changes);
 452         if(cvar_purechanges == "")
 453                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 454         else
 455                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 456         cvar_purechanges = strzone(cvar_purechanges);
 457 }
 458
 459 void detect_maptype()
 460 {
 461 #if 0
 462         vector o, v;
 463         float i;
 464
 465         for(;;)
 466         {
 467                 o = world.mins;
 468                 o_x += random() * (world.maxs_x - world.mins_x);
 469                 o_y += random() * (world.maxs_y - world.mins_y);
 470                 o_z += random() * (world.maxs_z - world.mins_z);
 471
 472                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 473                 if(trace_fraction == 1)
 474                         continue;
 475
 476                 v = trace_endpos;
 477
 478                 for(i = 0; i < 64; i += 4)
 479                 {
 480                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 481         if(trace_fraction == 1)
 482                 continue;
 483                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 484                 }
 485
 486                 break;
 487         }
 488 #endif
 489 }
 490
 491 entity randomseed;
 492 float RandomSeed_Send(entity to, float sf)
 493 {
 494         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 495         WriteShort(MSG_ENTITY, self.cnt);
 496         return TRUE;
 497 }
 498 void RandomSeed_Think()
 499 {
 500         self.cnt = bound(0, floor(random() * 65536), 65535);
 501         self.nextthink = time + 5;
 502
 503         self.SendFlags |= 1;
 504 }
 505 void RandomSeed_Spawn()
 506 {
 507         randomseed = spawn();
 508         randomseed.think = RandomSeed_Think;
 509         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 510
 511         entity oldself;
 512         oldself = self;
 513         self = randomseed;
 514         self.think(); // sets random seed and nextthink
 515         self = oldself;
 516 }
 517
 518 void spawnfunc___init_dedicated_server(void)
 519 {
 520         // handler for _init/_init map (only for dedicated server initialization)
 521
 522         world_initialized = -1; // don't complain
 523         cvar = cvar_normal;
 524         cvar_string = cvar_string_normal;
 525         cvar_set = cvar_set_normal;
 526
 527         remove = remove_unsafely;
 528
 529         entity e;
 530         e = spawn();
 531         e.think = GotoFirstMap;
 532         e.nextthink = time; // this is usually 1 at this point
 533
 534         e = spawn();
 535         e.classname = "info_player_deathmatch"; // safeguard against player joining
 536
 537         self.classname = "worldspawn"; // safeguard against various stuff ;)
 538
 539         // needs to be done so early because of the constants they create
 540         RegisterWeapons();
 541         RegisterGametypes();
 542
 543         MapInfo_Enumerate();
 544         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 545 }
 546
 547 void Map_MarkAsRecent(string m);
 548 float world_already_spawned;
 549 void RegisterWeapons();
 550 void Nagger_Init();
 551 void ClientInit_Spawn();
 552 void WeaponStats_Init();
 553 void WeaponStats_Shutdown();
 554 void spawnfunc_worldspawn (void)
 555 {
 556         float fd, l, i, j, n;
 557         string s, col;
 558
 559         cvar = cvar_normal;
 560         cvar_string = cvar_string_normal;
 561         cvar_set = cvar_set_normal;
 562
 563         if(world_already_spawned)
 564                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 565         world_already_spawned = TRUE;
 566
 567         remove = remove_safely; // during spawning, watch what you remove!
 568
 569         check_unacceptable_compiler_bugs();
 570
 571         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 572
 573         compressShortVector_init();
 574
 575         allowed_to_spawn = TRUE;
 576
 577         entity head;
 578         head = nextent(world);
 579         maxclients = 0;
 580         while(head)
 581         {
 582                 ++maxclients;
 583                 head = nextent(head);
 584         }
 585
 586         // needs to be done so early because of the constants they create
 587         RegisterWeapons();
 588         RegisterGametypes();
 589
 590         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 591
 592         TemporaryDB = db_create();
 593
 594         // 0 normal
 595         lightstyle(0, "m");
 596
 597         // 1 FLICKER (first variety)
 598         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 599
 600         // 2 SLOW STRONG PULSE
 601         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 602
 603         // 3 CANDLE (first variety)
 604         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 605
 606         // 4 FAST STROBE
 607         lightstyle(4, "mamamamamama");
 608
 609         // 5 GENTLE PULSE 1
 610         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 611
 612         // 6 FLICKER (second variety)
 613         lightstyle(6, "nmonqnmomnmomomno");
 614
 615         // 7 CANDLE (second variety)
 616         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 617
 618         // 8 CANDLE (third variety)
 619         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 620
 621         // 9 SLOW STROBE (fourth variety)
 622         lightstyle(9, "aaaaaaaazzzzzzzz");
 623
 624         // 10 FLUORESCENT FLICKER
 625         lightstyle(10, "mmamammmmammamamaaamammma");
 626
 627         // 11 SLOW PULSE NOT FADE TO BLACK
 628         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 629
 630         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 631
 632         // 63 testing
 633         lightstyle(63, "a");
 634
 635         if(autocvar_g_campaign)
 636                 CampaignPreInit();
 637
 638         Map_MarkAsRecent(mapname);
 639
 640         precache_model ("null"); // we need this one before InitGameplayMode
 641         InitGameplayMode();
 642         readlevelcvars();
 643         GrappleHookInit();
 644         ElectroInit();
 645         LaserInit();
 646
 647         player_count = 0;
 648         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 649         if(bot_waypoints_for_items == 1)
 650                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 651                         bot_waypoints_for_items = 0;
 652
 653         precache();
 654
 655         WaypointSprite_Init();
 656
 657         //if (g_domination)
 658         //      dom_init();
 659
 660         GameLogInit(); // prepare everything
 661         // NOTE for matchid:
 662         // changing the logic generating it is okay. But:
 663         // it HAS to stay <= 64 chars
 664         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 665         if(autocvar_sv_eventlog)
 666         {
 667                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 668                 matchid = strzone(s);
 669
 670                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 671                 s = ":gameinfo:mutators:LIST";
 672
 673                 ret_string = s;
 674                 MUTATOR_CALLHOOK(BuildMutatorsString);
 675                 s = ret_string;
 676
 677                 // simple, probably not good in the mutator system
 678                 if(autocvar_g_grappling_hook)
 679                         s = strcat(s, ":grappling_hook");
 680
 681                 // initialiation stuff, not good in the mutator system
 682                 if(!autocvar_g_use_ammunition)
 683                         s = strcat(s, ":no_use_ammunition");
 684
 685                 // initialiation stuff, not good in the mutator system
 686                 if(autocvar_g_pickup_items == 0)
 687                         s = strcat(s, ":no_pickup_items");
 688                 if(autocvar_g_pickup_items > 0)
 689                         s = strcat(s, ":pickup_items");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(autocvar_g_weaponarena != "0")
 693                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 694
 695                 // TODO to mutator system
 696                 if(autocvar_g_norecoil)
 697                         s = strcat(s, ":norecoil");
 698
 699                 // TODO to mutator system
 700                 if(autocvar_g_midair)
 701                         s = strcat(s, ":midair");
 702
 703                 // TODO to mutator system
 704                 if(autocvar_g_minstagib)
 705                         s = strcat(s, ":minstagib");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_powerups == 0)
 709                         s = strcat(s, ":no_powerups");
 710                 if(autocvar_g_powerups > 0)
 711                         s = strcat(s, ":powerups");
 712
 713                 GameLogEcho(s);
 714                 GameLogEcho(":gameinfo:end");
 715         }
 716         else
 717                 matchid = strzone(ftos(random()));
 718
 719         cvar_set("nextmap", "");
 720
 721         SetDefaultAlpha();
 722
 723         if(autocvar_g_campaign)
 724                 CampaignPostInit();
 725
 726         fteqcc_testbugs();
 727
 728         Ban_LoadBans();
 729
 730         MapInfo_Enumerate();
 731         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 732
 733         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 734         {
 735                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 736                 if(fd != -1)
 737                 {
 738                         while((s = fgets(fd)))
 739                         {
 740                                 l = tokenize_console(s);
 741                                 if(l < 2)
 742                                         continue;
 743                                 if(argv(0) == "cd")
 744                                 {
 745                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 746                                         print("  cdtrack ", argv(2), "\n");
 747                                 }
 748                                 else if(argv(0) == "fog")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 751                                         print("  \"fog\" \"", s, "\"\n");
 752                                 }
 753                                 else if(argv(0) == "set")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 756                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 757                                 }
 758                                 else if(argv(0) != "//")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 762                                 }
 763                         }
 764                         fclose(fd);
 765                 }
 766         }
 767
 768         WeaponStats_Init();
 769
 770         WEPSET_ADDSTAT();
 771         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 772         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 773         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 774         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 775         Nagger_Init();
 776
 777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 779         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 780         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 781         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 782         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 783         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 784         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 785         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 786         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 787         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 788         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 789         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 790
 791         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 792         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 793
 794         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 795
 796         if(g_ca || g_freezetag)
 797         {
 798                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 799                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 800                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 801                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 802         }
 803         if(g_freezetag)
 804         {
 805                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 806                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 807         }
 808
 809         // g_movementspeed hack
 810         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 811         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 812         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 813         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 814
 815         // secrets
 816         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 817         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 818
 819         next_pingtime = time + 5;
 820
 821         detect_maptype();
 822
 823         // set up information replies for clients and server to use
 824         lsmaps_reply = "^7Maps available: ";
 825         lsnewmaps_reply = "^7Maps without a record set: ";
 826         for(i = 0, j = 0; i < MapInfo_count; ++i)
 827         {
 828                 if(MapInfo_Get_ByID(i))
 829                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 830                         {
 831                                 if(mod(i, 2))
 832                                         col = "^2";
 833                                 else
 834                                         col = "^3";
 835
 836                                 ++j;
 837
 838                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 839
 840                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 841                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 842                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 843                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 844                         }
 845         }
 846
 847         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 848         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 849
 850         maplist_reply = "^7Maps in list: ";
 851         n = tokenize_console(autocvar_g_maplist);
 852         for(i = 0, j = 0; i < n; ++i)
 853         {
 854                 if(MapInfo_CheckMap(argv(i)))
 855                 {
 856                         if(mod(j, 2))
 857                                 col = "^2";
 858                         else
 859                                 col = "^3";
 860                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 861                         ++j;
 862                 }
 863         }
 864         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 865         MapInfo_ClearTemps();
 866
 867         for(i = 0; i < 10; ++i)
 868         {
 869                 records_reply[i] = strzone(getrecords(i));
 870         }
 871
 872         ladder_reply = strzone(getladder());
 873
 874         rankings_reply = strzone(getrankings());
 875
 876         // begin other init
 877         ClientInit_Spawn();
 878         RandomSeed_Spawn();
 879         PingPLReport_Spawn();
 880
 881         CheatInit();
 882
 883         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 884
 885         // fill sv_curl_serverpackages from .serverpackage files
 886         if(autocvar_sv_curl_serverpackages_auto)
 887         {
 888                 s = "";
 889                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 890                 for(i = 0; i < n; ++i)
 891                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 892                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 893                                 s = strcat(s, " ", argv(i));
 894                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 895                 if(fd >= 0)
 896                 {
 897                         j = search_getsize(fd);
 898                         for(i = 0; i < j; ++i)
 899                                 s = strcat(s, " ", search_getfilename(fd, i));
 900                         search_end(fd);
 901                 }
 902                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 903                 if(fd >= 0)
 904                 {
 905                         j = search_getsize(fd);
 906                         for(i = 0; i < j; ++i)
 907                                 s = strcat(s, " ", search_getfilename(fd, i));
 908                         search_end(fd);
 909                 }
 910                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 911         }
 912
 913         PlayerStats_Init();
 914
 915         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 916         modname = "Xonotic";
 917         // physics/balance/config changes that count as mod
 918         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 919                 modname = cvar_string("g_mod_physics");
 920         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 921                 modname = cvar_string("g_mod_balance");
 922         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 923                 modname = cvar_string("g_mod_config");
 924         // weird mutators that deserve to count as mod
 925         if(autocvar_g_minstagib)
 926                 modname = "MinstaGib";
 927         // extra mutators that deserve to count as mod
 928         MUTATOR_CALLHOOK(SetModname);
 929         // weird game types that deserve to count as mod
 930         if(g_cts)
 931                 modname = "CTS";
 932         // save it for later
 933         modname = strzone(modname);
 934
 935         WinningConditionHelper(); // set worldstatus
 936
 937         world_initialized = 1;
 938 }
 939
 940 void spawnfunc_light (void)
 941 {
 942         //makestatic (self); // Who the f___ did that?
 943         remove(self);
 944 }
 945
 946 string GetGametype()
 947 {
 948         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 949 }
 950
 951 string getmapname_stored;
 952 string GetMapname()
 953 {
 954         return mapname;
 955 }
 956
 957 float Map_Count, Map_Current;
 958 string Map_Current_Name;
 959
 960 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 961 float GetMaplistPosition()
 962 {
 963         float pos, idx;
 964         string map;
 965
 966         map = GetMapname();
 967         idx = autocvar_g_maplist_index;
 968
 969         if(idx >= 0)
 970                 if(idx < Map_Count)
 971                         if(map == argv(idx))
 972                                 return idx;
 973
 974         for(pos = 0; pos < Map_Count; ++pos)
 975                 if(map == argv(pos))
 976                         return pos;
 977
 978         // resume normal maplist rotation if current map is not in g_maplist
 979         return idx;
 980 }
 981
 982 float MapHasRightSize(string map)
 983 {
 984         float fh;
 985         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 986         if(autocvar_g_maplist_check_waypoints)
 987         {
 988                 dprint("checkwp "); dprint(map);
 989                 if(!fexists(strcat("maps/", map, ".waypoints")))
 990                 {
 991                         dprint(": no waypoints\n");
 992                         return FALSE;
 993                 }
 994                 dprint(": has waypoints\n");
 995         }
 996
 997         // open map size restriction file
 998         dprint("opensize "); dprint(map);
 999         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1000         if(fh >= 0)
1001         {
1002                 float mapmin, mapmax;
1003                 dprint(": ok, ");
1004                 mapmin = stof(fgets(fh));
1005                 mapmax = stof(fgets(fh));
1006                 fclose(fh);
1007                 if(player_count < mapmin)
1008                 {
1009                         dprint("not enough\n");
1010                         return FALSE;
1011                 }
1012                 if(player_count > mapmax)
1013                 {
1014                         dprint("too many\n");
1015                         return FALSE;
1016                 }
1017                 dprint("right size\n");
1018                 return TRUE;
1019         }
1020         dprint(": not found\n");
1021         return TRUE;
1022 }
1023
1024 string Map_Filename(float position)
1025 {
1026         return strcat("maps/", argv(position), ".bsp");
1027 }
1028
1029 string strwords(string s, float w)
1030 {
1031         float endpos;
1032         for(endpos = 0; w && endpos >= 0; --w)
1033                 endpos = strstrofs(s, " ", endpos + 1);
1034         if(endpos < 0)
1035                 return s;
1036         else
1037                 return substring(s, 0, endpos);
1038 }
1039
1040 float strhasword(string s, string w)
1041 {
1042         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1043 }
1044
1045 void Map_MarkAsRecent(string m)
1046 {
1047         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1048 }
1049
1050 float Map_IsRecent(string m)
1051 {
1052         return strhasword(autocvar_g_maplist_mostrecent, m);
1053 }
1054
1055 float Map_Check(float position, float pass)
1056 {
1057         string filename;
1058         string map_next;
1059         map_next = argv(position);
1060         if(pass <= 1)
1061         {
1062                 if(Map_IsRecent(map_next))
1063                         return 0;
1064         }
1065         filename = Map_Filename(position);
1066         if(MapInfo_CheckMap(map_next))
1067         {
1068                 if(pass == 2)
1069                         return 1;
1070                 if(MapHasRightSize(map_next))
1071                         return 1;
1072                 return 0;
1073         }
1074         else
1075                 dprint( "Couldn't select '", filename, "'..\n" );
1076
1077         return 0;
1078 }
1079
1080 void Map_Goto_SetStr(string nextmapname)
1081 {
1082         if(getmapname_stored != "")
1083                 strunzone(getmapname_stored);
1084         if(nextmapname == "")
1085                 getmapname_stored = "";
1086         else
1087                 getmapname_stored = strzone(nextmapname);
1088 }
1089
1090 void Map_Goto_SetFloat(float position)
1091 {
1092         cvar_set("g_maplist_index", ftos(position));
1093         Map_Goto_SetStr(argv(position));
1094 }
1095
1096 void Map_Goto(float reinit)
1097 {
1098         MapInfo_LoadMap(getmapname_stored, reinit);
1099 }
1100
1101 // return codes of map selectors:
1102 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1103 //   -2 = permanent failure
1104 float() MaplistMethod_Iterate = // usual method
1105 {
1106         float pass, i;
1107
1108         for(pass = 1; pass <= 2; ++pass)
1109         {
1110                 for(i = 1; i < Map_Count; ++i)
1111                 {
1112                         float mapindex;
1113                         mapindex = mod(i + Map_Current, Map_Count);
1114                         if(Map_Check(mapindex, pass))
1115                                 return mapindex;
1116                 }
1117         }
1118         return -1;
1119 }
1120
1121 float() MaplistMethod_Repeat = // fallback method
1122 {
1123         if(Map_Check(Map_Current, 2))
1124                 return Map_Current;
1125         return -2;
1126 }
1127
1128 float() MaplistMethod_Random = // random map selection
1129 {
1130         float i, imax;
1131
1132         imax = 42;
1133
1134         for(i = 0; i <= imax; ++i)
1135         {
1136                 float mapindex;
1137                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1138                 if(Map_Check(mapindex, 1))
1139                         return mapindex;
1140         }
1141         return -1;
1142 }
1143
1144 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1145 // the exponent sets a bias on the map selection:
1146 // the higher the exponent, the less likely "shortly repeated" same maps are
1147 {
1148         float i, j, imax, insertpos;
1149
1150         imax = 42;
1151
1152         for(i = 0; i <= imax; ++i)
1153         {
1154                 string newlist;
1155
1156                 // now reinsert this at another position
1157                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1158                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1159                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1160                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1161
1162                 // insert the current map there
1163                 newlist = "";
1164                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1165                         newlist = strcat(newlist, " ", argv(j));
1166                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1167                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1168                         newlist = strcat(newlist, " ", argv(j));
1169                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1170                 cvar_set("g_maplist", newlist);
1171                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1172
1173                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1174                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1175                 if(Map_Check(Map_Current, 1))
1176                         return Map_Current;
1177         }
1178         return -1;
1179 }
1180
1181 void Maplist_Init()
1182 {
1183         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1184         if(Map_Count == 0)
1185         {
1186                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1187                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1188                 if(autocvar_g_maplist_shuffle)
1189                         ShuffleMaplist();
1190                 localcmd("\nmenu_cmd sync\n");
1191                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         }
1193         if(Map_Count == 0)
1194                 error("empty maplist, cannot select a new map");
1195         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1196
1197         if(Map_Current_Name)
1198                 strunzone(Map_Current_Name);
1199         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1200         // this may or may not be correct, but who cares, in the worst case a map
1201         // isn't chosen in the first pass that should have been
1202 }
1203
1204 string GetNextMap()
1205 {
1206         float nextMap;
1207
1208         Maplist_Init();
1209         nextMap = -1;
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_shuffle > 0)
1213                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1214
1215         if(nextMap == -1)
1216                 if(autocvar_g_maplist_selectrandom)
1217                         nextMap = MaplistMethod_Random();
1218
1219         if(nextMap == -1)
1220                 nextMap = MaplistMethod_Iterate();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Repeat();
1224
1225         if(nextMap >= 0)
1226         {
1227                 Map_Goto_SetFloat(nextMap);
1228                 return getmapname_stored;
1229         }
1230
1231         return "";
1232 }
1233
1234 float DoNextMapOverride(float reinit)
1235 {
1236         if(autocvar_g_campaign)
1237         {
1238                 CampaignPostIntermission();
1239                 alreadychangedlevel = TRUE;
1240                 return TRUE;
1241         }
1242         if(autocvar_quit_when_empty)
1243         {
1244                 if(player_count <= currentbots)
1245                 {
1246                         localcmd("quit\n");
1247                         alreadychangedlevel = TRUE;
1248                         return TRUE;
1249                 }
1250         }
1251         if(autocvar_quit_and_redirect != "")
1252         {
1253                 redirection_target = strzone(autocvar_quit_and_redirect);
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1258         {
1259                 localcmd("restart\n");
1260                 alreadychangedlevel = TRUE;
1261                 return TRUE;
1262         }
1263         if(autocvar_nextmap != "")
1264                 if(MapInfo_CheckMap(autocvar_nextmap))
1265                 {
1266                         Map_Goto_SetStr(autocvar_nextmap);
1267                         Map_Goto(reinit);
1268                         alreadychangedlevel = TRUE;
1269                         return TRUE;
1270                 }
1271         if(!reinit && autocvar_lastlevel)
1272         {
1273                 cvar_settemp_restore();
1274                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         return FALSE;
1279 }
1280
1281 void GotoNextMap(float reinit)
1282 {
1283         //string nextmap;
1284         //float n, nummaps;
1285         //string s;
1286         if (alreadychangedlevel)
1287                 return;
1288         alreadychangedlevel = TRUE;
1289
1290         {
1291                 string nextMap;
1292                 float allowReset;
1293
1294                 for(allowReset = 1; allowReset >= 0; --allowReset)
1295                 {
1296                         nextMap = GetNextMap();
1297                         if(nextMap != "")
1298                                 break;
1299
1300                         if(allowReset)
1301                         {
1302                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1303                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1304                                 if(autocvar_g_maplist_shuffle)
1305                                         ShuffleMaplist();
1306                                 localcmd("\nmenu_cmd sync\n");
1307                         }
1308                         else
1309                         {
1310                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1311                         }
1312                 }
1313                 Map_Goto(reinit);
1314         }
1315 }
1316
1317
1318 /*
1319 ============
1320 IntermissionThink
1321
1322 When the player presses attack or jump, change to the next level
1323 ============
1324 */
1325 .float autoscreenshot;
1326 void() MapVote_Start;
1327 void() MapVote_Think;
1328 float mapvote_initialized;
1329 void IntermissionThink()
1330 {
1331         FixIntermissionClient(self);
1332
1333         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1334         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1335
1336         if( (server_screenshot || client_screenshot)
1337                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1338         {
1339                 self.autoscreenshot = -1;
1340                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1341                 return;
1342         }
1343
1344         if (time < intermission_exittime)
1345                 return;
1346
1347         if(!mapvote_initialized)
1348                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1349                         return;
1350
1351         MapVote_Start();
1352 }
1353
1354 /*
1355 ============
1356 FindIntermission
1357
1358 Returns the entity to view from
1359 ============
1360 */
1361 /*
1362 entity FindIntermission()
1363 {
1364         local   entity spot;
1365         local   float cyc;
1366
1367 // look for info_intermission first
1368         spot = find (world, classname, "info_intermission");
1369         if (spot)
1370         {       // pick a random one
1371                 cyc = random() * 4;
1372                 while (cyc > 1)
1373                 {
1374                         spot = find (spot, classname, "info_intermission");
1375                         if (!spot)
1376                                 spot = find (spot, classname, "info_intermission");
1377                         cyc = cyc - 1;
1378                 }
1379                 return spot;
1380         }
1381
1382 // then look for the start position
1383         spot = find (world, classname, "info_player_start");
1384         if (spot)
1385                 return spot;
1386
1387 // testinfo_player_start is only found in regioned levels
1388         spot = find (world, classname, "testplayerstart");
1389         if (spot)
1390                 return spot;
1391
1392 // then look for the start position
1393         spot = find (world, classname, "info_player_deathmatch");
1394         if (spot)
1395                 return spot;
1396
1397         //objerror ("FindIntermission: no spot");
1398         return world;
1399 }
1400 */
1401
1402 /*
1403 ===============================================================================
1404
1405 RULES
1406
1407 ===============================================================================
1408 */
1409
1410 void DumpStats(float final)
1411 {
1412         float file;
1413         string s;
1414         float to_console;
1415         float to_eventlog;
1416         float to_file;
1417         float i;
1418
1419         to_console = autocvar_sv_logscores_console;
1420         to_eventlog = autocvar_sv_eventlog;
1421         to_file = autocvar_sv_logscores_file;
1422
1423         if(!final)
1424         {
1425                 to_console = TRUE; // always print printstats replies
1426                 to_eventlog = FALSE; // but never print them to the event log
1427         }
1428
1429         if(to_eventlog)
1430                 if(autocvar_sv_eventlog_console)
1431                         to_console = FALSE; // otherwise we get the output twice
1432
1433         if(final)
1434                 s = ":scores:";
1435         else
1436                 s = ":status:";
1437         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1438
1439         if(to_console)
1440                 print(s, "\n");
1441         if(to_eventlog)
1442                 GameLogEcho(s);
1443
1444         file = -1;
1445         if(to_file)
1446         {
1447                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1448                 if(file == -1)
1449                         to_file = FALSE;
1450                 else
1451                         fputs(file, strcat(s, "\n"));
1452         }
1453
1454         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1455         if(to_console)
1456                 print(s, "\n");
1457         if(to_eventlog)
1458                 GameLogEcho(s);
1459         if(to_file)
1460                 fputs(file, strcat(s, "\n"));
1461
1462         FOR_EACH_CLIENT(other)
1463         {
1464                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1465                 {
1466                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1467                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1468                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1469                                 s = strcat(s, ftos(other.team), ":");
1470                         else
1471                                 s = strcat(s, "spectator:");
1472
1473                         if(to_console)
1474                                 print(s, other.netname, "\n");
1475                         if(to_eventlog)
1476                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1477                         if(to_file)
1478                                 fputs(file, strcat(s, other.netname, "\n"));
1479                 }
1480         }
1481
1482         if(teamplay)
1483         {
1484                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1485                 if(to_console)
1486                         print(s, "\n");
1487                 if(to_eventlog)
1488                         GameLogEcho(s);
1489                 if(to_file)
1490                         fputs(file, strcat(s, "\n"));
1491
1492                 for(i = 1; i < 16; ++i)
1493                 {
1494                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1495                         s = strcat(s, ":", ftos(i));
1496                         if(to_console)
1497                                 print(s, "\n");
1498                         if(to_eventlog)
1499                                 GameLogEcho(s);
1500                         if(to_file)
1501                                 fputs(file, strcat(s, "\n"));
1502                 }
1503         }
1504
1505         if(to_console)
1506                 print(":end\n");
1507         if(to_eventlog)
1508                 GameLogEcho(":end");
1509         if(to_file)
1510         {
1511                 fputs(file, ":end\n");
1512                 fclose(file);
1513         }
1514 }
1515
1516 void FixIntermissionClient(entity e)
1517 {
1518         string s;
1519         if(!e.autoscreenshot) // initial call
1520         {
1521                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1522                 e.health = -2342;
1523                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1524                 e.solid = SOLID_NOT;
1525                 e.movetype = MOVETYPE_NONE;
1526                 e.takedamage = DAMAGE_NO;
1527                 if(e.weaponentity)
1528                 {
1529                         e.weaponentity.effects = EF_NODRAW;
1530                         if (e.weaponentity.weaponentity)
1531                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1532                 }
1533                 if(clienttype(e) == CLIENTTYPE_REAL)
1534                 {
1535                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1536                         s = autocvar_sv_intermission_cdtrack;
1537                         if(s != "")
1538                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1539                         msg_entity = e;
1540                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1541                 }
1542         }
1543 }
1544
1545 void minstagib_stop_countdown(entity e);
1546 /*
1547 go to the next level for deathmatch
1548 only called if a time or frag limit has expired
1549 */
1550 void NextLevel()
1551 {
1552         gameover = TRUE;
1553
1554         intermission_running = 1;
1555
1556 // enforce a wait time before allowing changelevel
1557         if(player_count > 0)
1558                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1559         else
1560                 intermission_exittime = -1;
1561
1562         /*
1563         WriteByte (MSG_ALL, SVC_CDTRACK);
1564         WriteByte (MSG_ALL, 3);
1565         WriteByte (MSG_ALL, 3);
1566         // done in FixIntermission
1567         */
1568
1569         //pos = FindIntermission ();
1570
1571         VoteReset();
1572
1573         DumpStats(TRUE);
1574
1575         // send statistics
1576         entity e;
1577         PlayerStats_EndMatch(1);
1578         FOR_EACH_CLIENT(e)
1579                 PlayerStats_AddGlobalInfo(e);
1580         PlayerStats_Shutdown();
1581         WeaponStats_Shutdown();
1582
1583         if(autocvar_sv_eventlog)
1584                 GameLogEcho(":gameover");
1585
1586         GameLogClose();
1587
1588         FOR_EACH_PLAYER(other) {
1589                 minstagib_stop_countdown(other);
1590                 FixIntermissionClient(other);
1591                 if(other.winning)
1592                         bprint(other.netname, " ^7wins.\n");
1593         }
1594
1595         if(autocvar_g_campaign)
1596                 CampaignPreIntermission();
1597
1598         localcmd("\nsv_hook_gameend\n");
1599 }
1600
1601 /*
1602 ============
1603 CheckRules_Player
1604
1605 Exit deathmatch games upon conditions
1606 ============
1607 */
1608 void CheckRules_Player()
1609 {
1610         if (gameover)   // someone else quit the game already
1611                 return;
1612
1613         if(self.deadflag == DEAD_NO)
1614                 self.play_time += frametime;
1615
1616         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1617         //   (div0: and that in CheckRules_World please)
1618 }
1619
1620 float checkrules_equality;
1621 float checkrules_suddendeathwarning;
1622 float checkrules_suddendeathend;
1623 float checkrules_overtimesadded; //how many overtimes have been already added
1624
1625 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1626 float WINNING_YES = 1; // winner found
1627 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1628 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1629
1630 float InitiateSuddenDeath()
1631 {
1632         // Check first whether normal overtimes could be added before initiating suddendeath mode
1633         // - for this timelimit_overtime needs to be >0 of course
1634         // - also check the winning condition calculated in the previous frame and only add normal overtime
1635         //   again, if at the point at which timelimit would be extended again, still no winner was found
1636         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1637         {
1638                 return 1; // need to call InitiateOvertime later
1639         }
1640         else
1641         {
1642                 if(!checkrules_suddendeathend)
1643                 {
1644                         if(autocvar_g_campaign)
1645                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1646                         else
1647                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1648                         if(g_race && !g_race_qualifying)
1649                                 race_StartCompleting();
1650                 }
1651                 return 0;
1652         }
1653 }
1654
1655 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1656 {
1657         ++checkrules_overtimesadded;
1658         //add one more overtime by simply extending the timelimit
1659         float tl;
1660         tl = autocvar_timelimit;
1661         tl += autocvar_timelimit_overtime;
1662         cvar_set("timelimit", ftos(tl));
1663         string minutesPlural;
1664         if (autocvar_timelimit_overtime == 1)
1665                 minutesPlural = " ^3minute";
1666         else
1667                 minutesPlural = " ^3minutes";
1668
1669         bcenterprint(
1670                 strcat(
1671                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1672                         ftos(autocvar_timelimit_overtime),
1673                         minutesPlural,
1674                         " to the game!"
1675                 )
1676         );
1677 }
1678
1679 float GetWinningCode(float fraglimitreached, float equality)
1680 {
1681         if(autocvar_g_campaign == 1)
1682                 if(fraglimitreached)
1683                         return WINNING_YES;
1684                 else
1685                         return WINNING_NO;
1686
1687         else
1688                 if(equality)
1689                         if(fraglimitreached)
1690                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1691                         else
1692                                 return WINNING_NEVER;
1693                 else
1694                         if(fraglimitreached)
1695                                 return WINNING_YES;
1696                         else
1697                                 return WINNING_NO;
1698 }
1699
1700 // set the .winning flag for exactly those players with a given field value
1701 void SetWinners(.float field, float value)
1702 {
1703         entity head;
1704         FOR_EACH_PLAYER(head)
1705                 head.winning = (head.field == value);
1706 }
1707
1708 // set the .winning flag for those players with a given field value
1709 void AddWinners(.float field, float value)
1710 {
1711         entity head;
1712         FOR_EACH_PLAYER(head)
1713                 if(head.field == value)
1714                         head.winning = 1;
1715 }
1716
1717 // clear the .winning flags
1718 void ClearWinners(void)
1719 {
1720         entity head;
1721         FOR_EACH_PLAYER(head)
1722                 head.winning = 0;
1723 }
1724
1725 // Onslaught winning condition:
1726 // game terminates if only one team has a working generator (or none)
1727 float WinningCondition_Onslaught()
1728 {
1729         entity head;
1730         float t1, t2, t3, t4;
1731
1732         WinningConditionHelper(); // set worldstatus
1733
1734         if(inWarmupStage)
1735                 return WINNING_NO;
1736
1737         // first check if the game has ended
1738         t1 = t2 = t3 = t4 = 0;
1739         head = find(world, classname, "onslaught_generator");
1740         while (head)
1741         {
1742                 if (head.health > 0)
1743                 {
1744                         if (head.team == COLOR_TEAM1) t1 = 1;
1745                         if (head.team == COLOR_TEAM2) t2 = 1;
1746                         if (head.team == COLOR_TEAM3) t3 = 1;
1747                         if (head.team == COLOR_TEAM4) t4 = 1;
1748                 }
1749                 head = find(head, classname, "onslaught_generator");
1750         }
1751         if (t1 + t2 + t3 + t4 < 2)
1752         {
1753                 // game over, only one team remains (or none)
1754                 ClearWinners();
1755                 if (t1) SetWinners(team, COLOR_TEAM1);
1756                 if (t2) SetWinners(team, COLOR_TEAM2);
1757                 if (t3) SetWinners(team, COLOR_TEAM3);
1758                 if (t4) SetWinners(team, COLOR_TEAM4);
1759                 dprint("Have a winner, ending game.\n");
1760                 return WINNING_YES;
1761         }
1762
1763         // Two or more teams remain
1764         return WINNING_NO;
1765 }
1766
1767 float LMS_NewPlayerLives()
1768 {
1769         float fl;
1770         fl = autocvar_fraglimit;
1771         if(fl == 0)
1772                 fl = 999;
1773
1774         // first player has left the game for dying too much? Nobody else can get in.
1775         if(lms_lowest_lives < 1)
1776                 return 0;
1777
1778         if(!autocvar_g_lms_join_anytime)
1779                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1780                         return 0;
1781
1782         return bound(1, lms_lowest_lives, fl);
1783 }
1784
1785 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1786 // they win. Otherwise the defending team wins once the timelimit passes.
1787 void assault_new_round();
1788 float WinningCondition_Assault()
1789 {
1790         float status;
1791
1792         WinningConditionHelper(); // set worldstatus
1793
1794         status = WINNING_NO;
1795         // as the timelimit has not yet passed just assume the defending team will win
1796         if(assault_attacker_team == COLOR_TEAM1)
1797         {
1798                 SetWinners(team, COLOR_TEAM2);
1799         }
1800         else
1801         {
1802                 SetWinners(team, COLOR_TEAM1);
1803         }
1804
1805         entity ent;
1806         ent = find(world, classname, "target_assault_roundend");
1807         if(ent)
1808         {
1809                 if(ent.winning) // round end has been triggered by attacking team
1810                 {
1811                         bprint("ASSAULT: round completed...\n");
1812                         SetWinners(team, assault_attacker_team);
1813
1814                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1815
1816                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1817                         {
1818                                 status = WINNING_YES;
1819                         }
1820                         else
1821                         {
1822                                 entity oldself;
1823                                 oldself = self;
1824                                 self = ent;
1825                                 assault_new_round();
1826                                 self = oldself;
1827                         }
1828                 }
1829         }
1830
1831         return status;
1832 }
1833
1834 // LMS winning condition: game terminates if and only if there's at most one
1835 // one player who's living lives. Top two scores being equal cancels the time
1836 // limit.
1837 float WinningCondition_LMS()
1838 {
1839         entity head, head2;
1840         float have_player;
1841         float have_players;
1842         float l;
1843
1844         have_player = FALSE;
1845         have_players = FALSE;
1846         l = LMS_NewPlayerLives();
1847
1848         head = find(world, classname, "player");
1849         if(head)
1850                 have_player = TRUE;
1851         head2 = find(head, classname, "player");
1852         if(head2)
1853                 have_players = TRUE;
1854
1855         if(have_player)
1856         {
1857                 // we have at least one player
1858                 if(have_players)
1859                 {
1860                         // two or more active players - continue with the game
1861                 }
1862                 else
1863                 {
1864                         // exactly one player?
1865
1866                         ClearWinners();
1867                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1868
1869                         if(l)
1870                         {
1871                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1872                                 return WINNING_NO;
1873                         }
1874                         else
1875                         {
1876                                 // a winner!
1877                                 // and assign him his first place
1878                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1879                                 return WINNING_YES;
1880                         }
1881                 }
1882         }
1883         else
1884         {
1885                 // nobody is playing at all...
1886                 if(l)
1887                 {
1888                         // wait for players...
1889                 }
1890                 else
1891                 {
1892                         // SNAFU (maybe a draw game?)
1893                         ClearWinners();
1894                         dprint("No players, ending game.\n");
1895                         return WINNING_YES;
1896                 }
1897         }
1898
1899         // When we get here, we have at least two players who are actually LIVING,
1900         // now check if the top two players have equal score.
1901         WinningConditionHelper();
1902
1903         ClearWinners();
1904         if(WinningConditionHelper_winner)
1905                 WinningConditionHelper_winner.winning = TRUE;
1906         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1907                 return WINNING_NEVER;
1908
1909         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1910         return WINNING_NO;
1911 }
1912
1913 void ShuffleMaplist()
1914 {
1915         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1916 }
1917
1918 float leaderfrags;
1919 float WinningCondition_Scores(float limit, float leadlimit)
1920 {
1921         float limitreached;
1922
1923         // TODO make everything use THIS winning condition (except LMS)
1924         WinningConditionHelper();
1925
1926         if(teamplay)
1927         {
1928                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1929                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1930                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1931                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1932         }
1933
1934         ClearWinners();
1935         if(WinningConditionHelper_winner)
1936                 WinningConditionHelper_winner.winning = 1;
1937         if(WinningConditionHelper_winnerteam >= 0)
1938                 SetWinners(team, WinningConditionHelper_winnerteam);
1939
1940         if(WinningConditionHelper_lowerisbetter)
1941         {
1942                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1943                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1944                 limit = -limit;
1945         }
1946
1947         if(WinningConditionHelper_zeroisworst)
1948                 leadlimit = 0; // not supported in this mode
1949
1950         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1951         // these modes always score in increments of 1, thus this makes sense
1952         {
1953                 if(leaderfrags != WinningConditionHelper_topscore)
1954                 {
1955                         leaderfrags = WinningConditionHelper_topscore;
1956
1957                         if (limit)
1958                         if (leaderfrags == limit - 1)
1959                                 Announce("1fragleft");
1960                         else if (leaderfrags == limit - 2)
1961                                 Announce("2fragsleft");
1962                         else if (leaderfrags == limit - 3)
1963                                 Announce("3fragsleft");
1964                 }
1965         }
1966
1967         limitreached = FALSE;
1968         if(limit)
1969                 if(WinningConditionHelper_topscore >= limit)
1970                         limitreached = TRUE;
1971         if(leadlimit)
1972         {
1973                 float leadlimitreached;
1974                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1975                 if(autocvar_leadlimit_and_fraglimit)
1976                         limitreached = (limitreached && leadlimitreached);
1977                 else
1978                         limitreached = (limitreached || leadlimitreached);
1979         }
1980
1981         game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / max(1, limit), 1));
1982
1983         return GetWinningCode(
1984                 WinningConditionHelper_topscore && limitreached,
1985                 WinningConditionHelper_equality
1986         );
1987 }
1988
1989 float WinningCondition_Race(float fraglimit)
1990 {
1991         float wc;
1992         entity p;
1993         float n, c;
1994
1995         n = 0;
1996         c = 0;
1997         FOR_EACH_PLAYER(p)
1998         {
1999                 ++n;
2000                 if(p.race_completed)
2001                         ++c;
2002         }
2003         if(n && (n == c))
2004                 return WINNING_YES;
2005         wc = WinningCondition_Scores(fraglimit, 0);
2006
2007         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2008         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2009         // do NOT support equality when the laps are all raced!
2010                 return WINNING_STARTSUDDENDEATHOVERTIME;
2011         else
2012                 return WINNING_NEVER;
2013         return wc;
2014 }
2015
2016 float WinningCondition_QualifyingThenRace(float limit)
2017 {
2018         float wc;
2019         wc = WinningCondition_Scores(limit, 0);
2020
2021         // NEVER initiate overtime
2022         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2023         {
2024                 return WINNING_YES;
2025         }
2026
2027         return wc;
2028 }
2029
2030 float WinningCondition_RanOutOfSpawns()
2031 {
2032         entity head;
2033
2034         if(have_team_spawns <= 0)
2035                 return WINNING_NO;
2036
2037         if(autocvar_g_spawn_useallspawns <= 0)
2038                 return WINNING_NO;
2039
2040         if(!some_spawn_has_been_used)
2041                 return WINNING_NO;
2042
2043         team1_score = team2_score = team3_score = team4_score = 0;
2044
2045         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2046         {
2047                 if(head.team == COLOR_TEAM1)
2048                         team1_score = 1;
2049                 else if(head.team == COLOR_TEAM2)
2050                         team2_score = 1;
2051                 else if(head.team == COLOR_TEAM3)
2052                         team3_score = 1;
2053                 else if(head.team == COLOR_TEAM4)
2054                         team4_score = 1;
2055         }
2056
2057         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2058         {
2059                 if(head.team == COLOR_TEAM1)
2060                         team1_score = 1;
2061                 else if(head.team == COLOR_TEAM2)
2062                         team2_score = 1;
2063                 else if(head.team == COLOR_TEAM3)
2064                         team3_score = 1;
2065                 else if(head.team == COLOR_TEAM4)
2066                         team4_score = 1;
2067         }
2068
2069         ClearWinners();
2070         if(team1_score + team2_score + team3_score + team4_score == 0)
2071         {
2072                 checkrules_equality = TRUE;
2073                 return WINNING_YES;
2074         }
2075         else if(team1_score + team2_score + team3_score + team4_score == 1)
2076         {
2077                 float t, i;
2078                 if(team1_score)
2079                         t = COLOR_TEAM1;
2080                 else if(team2_score)
2081                         t = COLOR_TEAM2;
2082                 else if(team3_score)
2083                         t = COLOR_TEAM3;
2084                 else // if(team4_score)
2085                         t = COLOR_TEAM4;
2086                 CheckAllowedTeams(world);
2087                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2088                 {
2089                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2090                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2091                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2092                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2093                 }
2094
2095                 AddWinners(team, t);
2096                 return WINNING_YES;
2097         }
2098         else
2099                 return WINNING_NO;
2100 }
2101
2102 /*
2103 ============
2104 CheckRules_World
2105
2106 Exit deathmatch games upon conditions
2107 ============
2108 */
2109 void ReadyRestart();
2110 void CheckRules_World()
2111 {
2112         float timelimit;
2113         float fraglimit;
2114         float leadlimit;
2115
2116         VoteThink();
2117         MapVote_Think();
2118
2119         SetDefaultAlpha();
2120
2121         /*
2122         MapVote_Think should now do that part
2123         if (intermission_running)
2124                 if (time >= intermission_exittime + 60)
2125                 {
2126                         if(!DoNextMapOverride())
2127                                 GotoNextMap();
2128                         return;
2129                 }
2130         */
2131
2132         if (gameover)   // someone else quit the game already
2133         {
2134                 if(player_count == 0) // Nobody there? Then let's go to the next map
2135                         MapVote_Start();
2136                         // this will actually check the player count in the next frame
2137                         // again, but this shouldn't hurt
2138                 return;
2139         }
2140
2141         timelimit = autocvar_timelimit * 60;
2142         fraglimit = autocvar_fraglimit;
2143         leadlimit = autocvar_leadlimit;
2144
2145         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2146         {
2147                 if(timelimit > 0)
2148                         timelimit = 0; // timelimit is not made for warmup
2149                 if(fraglimit > 0)
2150                         fraglimit = 0; // no fraglimit for now
2151                 leadlimit = 0; // no leadlimit for now
2152         }
2153
2154         if(timelimit > 0)
2155         {
2156                 timelimit += game_starttime;
2157         }
2158         else if (timelimit < 0)
2159         {
2160                 // endmatch
2161                 NextLevel();
2162                 return;
2163         }
2164
2165         if(g_onslaught)
2166                 timelimit = 0; // ONS has its own overtime rule
2167
2168         float wantovertime;
2169         wantovertime = 0;
2170
2171         if(timelimit > game_starttime)
2172                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2173         else
2174                 game_completion_ratio = 0;
2175
2176         if(checkrules_suddendeathend)
2177         {
2178                 if(!checkrules_suddendeathwarning)
2179                 {
2180                         checkrules_suddendeathwarning = TRUE;
2181                         if(g_race && !g_race_qualifying)
2182                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2183                         else
2184                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2185                 }
2186         }
2187         else
2188         {
2189                 if (timelimit && time >= timelimit)
2190                 {
2191                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2192                         {
2193                                 float totalplayers;
2194                                 float playerswithlaps;
2195                                 float readyplayers;
2196                                 entity head;
2197                                 totalplayers = playerswithlaps = readyplayers = 0;
2198                                 FOR_EACH_PLAYER(head)
2199                                 {
2200                                         ++totalplayers;
2201                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2202                                                 ++playerswithlaps;
2203                                         if(head.ready)
2204                                                 ++readyplayers;
2205                                 }
2206
2207                                 // at least 2 of the players have completed a lap: start the RACE
2208                                 // otherwise, the players should end the qualifying on their own
2209                                 if(readyplayers || playerswithlaps >= 2)
2210                                 {
2211                                         checkrules_suddendeathend = 0;
2212                                         ReadyRestart(); // go to race
2213                                         return;
2214                                 }
2215                                 else
2216                                         wantovertime |= InitiateSuddenDeath();
2217                         }
2218                         else
2219                                 wantovertime |= InitiateSuddenDeath();
2220                 }
2221         }
2222
2223         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2224         {
2225                 NextLevel();
2226                 return;
2227         }
2228
2229         float checkrules_status;
2230         checkrules_status = WinningCondition_RanOutOfSpawns();
2231         if(checkrules_status == WINNING_YES)
2232         {
2233                 bprint("Hey! Someone ran out of spawns!\n");
2234         }
2235         else if(g_race && !g_race_qualifying && timelimit >= 0)
2236         {
2237                 checkrules_status = WinningCondition_Race(fraglimit);
2238                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2239         }
2240         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2241         {
2242                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2243                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2244         }
2245         else if(g_assault)
2246         {
2247                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2248         }
2249         else if(g_lms)
2250         {
2251                 checkrules_status = WinningCondition_LMS();
2252         }
2253         else if (g_onslaught)
2254         {
2255                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2256         }
2257         else
2258         {
2259                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2260                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2261         }
2262
2263         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2264         {
2265                 checkrules_status = WINNING_NEVER;
2266                 checkrules_overtimesadded = -1;
2267                 wantovertime |= InitiateSuddenDeath();
2268         }
2269
2270         if(checkrules_status == WINNING_NEVER)
2271                 // equality cases! Nobody wins if the overtime ends in a draw.
2272                 ClearWinners();
2273
2274         if(wantovertime)
2275         {
2276                 if(checkrules_status == WINNING_NEVER)
2277                         InitiateOvertime();
2278                 else
2279                         checkrules_status = WINNING_YES;
2280         }
2281
2282         if(checkrules_suddendeathend)
2283                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2284                         checkrules_status = WINNING_YES;
2285
2286         if(checkrules_status == WINNING_YES)
2287         {
2288                 //print("WINNING\n");
2289                 NextLevel();
2290         }
2291 }
2292
2293 float mapvote_nextthink;
2294 float mapvote_initialized;
2295 float mapvote_keeptwotime;
2296 float mapvote_timeout;
2297 string mapvote_message;
2298 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2299 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2300 float mapvote_screenshot_dirs_count;
2301
2302 float mapvote_count;
2303 float mapvote_count_real;
2304 string mapvote_maps[MAPVOTE_COUNT];
2305 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2306 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2307 float mapvote_maps_suggested[MAPVOTE_COUNT];
2308 string mapvote_suggestions[MAPVOTE_COUNT];
2309 float mapvote_suggestion_ptr;
2310 float mapvote_voters;
2311 float mapvote_selections[MAPVOTE_COUNT];
2312 float mapvote_run;
2313 float mapvote_detail;
2314 float mapvote_abstain;
2315 .float mapvote;
2316
2317 void MapVote_ClearAllVotes()
2318 {
2319         FOR_EACH_CLIENT(other)
2320                 other.mapvote = 0;
2321 }
2322
2323 string MapVote_Suggest(string m)
2324 {
2325         float i;
2326         if(m == "")
2327                 return "That's not how to use this command.";
2328         if(!autocvar_g_maplist_votable_suggestions)
2329                 return "Suggestions are not accepted on this server.";
2330         if(mapvote_initialized)
2331                 return "Can't suggest - voting is already in progress!";
2332         m = MapInfo_FixName(m);
2333         if(!m)
2334                 return "The map you suggested is not available on this server.";
2335         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2336                 if(Map_IsRecent(m))
2337                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2338
2339         if(!MapInfo_CheckMap(m))
2340                 return "The map you suggested does not support the current game mode.";
2341         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2342                 if(mapvote_suggestions[i] == m)
2343                         return "This map was already suggested.";
2344         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2345         {
2346                 i = floor(random() * mapvote_suggestion_ptr);
2347         }
2348         else
2349         {
2350                 i = mapvote_suggestion_ptr;
2351                 mapvote_suggestion_ptr += 1;
2352         }
2353         if(mapvote_suggestions[i] != "")
2354                 strunzone(mapvote_suggestions[i]);
2355         mapvote_suggestions[i] = strzone(m);
2356         if(autocvar_sv_eventlog)
2357                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2358         return strcat("Suggestion of ", m, " accepted.");
2359 }
2360
2361 void MapVote_AddVotable(string nextMap, float isSuggestion)
2362 {
2363         float j, i, o;
2364         string pakfile, mapfile;
2365
2366         if(nextMap == "")
2367                 return;
2368         for(j = 0; j < mapvote_count; ++j)
2369                 if(mapvote_maps[j] == nextMap)
2370                         return;
2371         // suggestions might be no longer valid/allowed after gametype switch!
2372         if(isSuggestion)
2373                 if(!MapInfo_CheckMap(nextMap))
2374                         return;
2375         mapvote_maps[mapvote_count] = strzone(nextMap);
2376         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2377
2378         pakfile = string_null;
2379         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2380         {
2381                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2382                 pakfile = whichpack(strcat(mapfile, ".tga"));
2383                 if(pakfile == "")
2384                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2385                 if(pakfile == "")
2386                         pakfile = whichpack(strcat(mapfile, ".png"));
2387                 if(pakfile != "")
2388                         break;
2389         }
2390         if(i >= mapvote_screenshot_dirs_count)
2391                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2392         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2393                 pakfile = substring(pakfile, o, -1);
2394
2395         mapvote_maps_screenshot_dir[mapvote_count] = i;
2396         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2397
2398         mapvote_count += 1;
2399 }
2400
2401 void MapVote_Spawn();
2402 void MapVote_Init()
2403 {
2404         float i;
2405         float nmax, smax;
2406
2407         MapVote_ClearAllVotes();
2408
2409         mapvote_count = 0;
2410         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2411         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2412
2413         if(mapvote_abstain)
2414                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2415         else
2416                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2417         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2418
2419         // we need this for AddVotable, as that cycles through the screenshot dirs
2420         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2421         if(mapvote_screenshot_dirs_count == 0)
2422                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2423         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2424         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2425                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2426
2427         if(mapvote_suggestion_ptr)
2428                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2429                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2430
2431         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2432                 MapVote_AddVotable(GetNextMap(), FALSE);
2433
2434         if(mapvote_count == 0)
2435         {
2436                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2437                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2438                 if(autocvar_g_maplist_shuffle)
2439                         ShuffleMaplist();
2440                 localcmd("\nmenu_cmd sync\n");
2441                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2442                         MapVote_AddVotable(GetNextMap(), FALSE);
2443         }
2444
2445         mapvote_count_real = mapvote_count;
2446         if(mapvote_abstain)
2447                 MapVote_AddVotable("don't care", 0);
2448
2449         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2450
2451         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2452         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2453         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2454                 mapvote_keeptwotime = 0;
2455         mapvote_message = "Choose a map and press its key!";
2456
2457         MapVote_Spawn();
2458 }
2459
2460 void MapVote_SendPicture(float id)
2461 {
2462         msg_entity = self;
2463         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2464         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2465         WriteByte(MSG_ONE, id);
2466         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2467 }
2468
2469 float MapVote_GetMapMask()
2470 {
2471         float mask, i, power;
2472         mask = 0;
2473         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2474                 if(mapvote_maps[i] != "")
2475                         mask |= power;
2476         return mask;
2477 }
2478
2479 entity mapvote_ent;
2480 float MapVote_SendEntity(entity to, float sf)
2481 {
2482         float i;
2483
2484         if(sf & 1)
2485                 sf &~= 2; // if we send 1, we don't need to also send 2
2486
2487         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2488         WriteByte(MSG_ENTITY, sf);
2489
2490         if(sf & 1)
2491         {
2492                 // flag 1 == initialization
2493                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2494                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2495                 WriteString(MSG_ENTITY, "");
2496                 WriteByte(MSG_ENTITY, mapvote_count);
2497                 WriteByte(MSG_ENTITY, mapvote_abstain);
2498                 WriteByte(MSG_ENTITY, mapvote_detail);
2499                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2500                 if(mapvote_count <= 8)
2501                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2502                 else
2503                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2504                 for(i = 0; i < mapvote_count; ++i)
2505                         if(mapvote_maps[i] != "")
2506                         {
2507                                 if(mapvote_abstain && i == mapvote_count - 1)
2508                                 {
2509                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2510                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2511                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2512                                 }
2513                                 else
2514                                 {
2515                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2516                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2517                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2518                                 }
2519                         }
2520         }
2521
2522         if(sf & 2)
2523         {
2524                 // flag 2 == update of mask
2525                 if(mapvote_count <= 8)
2526                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2527                 else
2528                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2529         }
2530
2531         if(sf & 4)
2532         {
2533                 if(mapvote_detail)
2534                         for(i = 0; i < mapvote_count; ++i)
2535                                 if(mapvote_maps[i] != "")
2536                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2537
2538                 WriteByte(MSG_ENTITY, to.mapvote);
2539         }
2540
2541         return TRUE;
2542 }
2543
2544 void MapVote_Spawn()
2545 {
2546         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2547 }
2548
2549 void MapVote_TouchMask()
2550 {
2551         mapvote_ent.SendFlags |= 2;
2552 }
2553
2554 void MapVote_TouchVotes(entity voter)
2555 {
2556         mapvote_ent.SendFlags |= 4;
2557 }
2558
2559 float MapVote_Finished(float mappos)
2560 {
2561         string result;
2562         float i;
2563         float didntvote;
2564
2565         if(autocvar_sv_eventlog)
2566         {
2567                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2568                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2569                 didntvote = mapvote_voters;
2570                 for(i = 0; i < mapvote_count; ++i)
2571                         if(mapvote_maps[i] != "")
2572                         {
2573                                 didntvote -= mapvote_selections[i];
2574                                 if(i != mappos)
2575                                 {
2576                                         result = strcat(result, ":", mapvote_maps[i]);
2577                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2578                                 }
2579                         }
2580                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2581
2582                 GameLogEcho(result);
2583                 if(mapvote_maps_suggested[mappos])
2584                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2585         }
2586
2587         FOR_EACH_REALCLIENT(other)
2588                 FixClientCvars(other);
2589
2590         Map_Goto_SetStr(mapvote_maps[mappos]);
2591         Map_Goto(0);
2592         alreadychangedlevel = TRUE;
2593         return TRUE;
2594 }
2595 void MapVote_CheckRules_1()
2596 {
2597         float i;
2598
2599         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2600         {
2601                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2602                 mapvote_selections[i] = 0;
2603         }
2604
2605         mapvote_voters = 0;
2606         FOR_EACH_REALCLIENT(other)
2607         {
2608                 ++mapvote_voters;
2609                 if(other.mapvote)
2610                 {
2611                         i = other.mapvote - 1;
2612                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2613                         mapvote_selections[i] = mapvote_selections[i] + 1;
2614                 }
2615         }
2616 }
2617
2618 float MapVote_CheckRules_2()
2619 {
2620         float i;
2621         float firstPlace, secondPlace;
2622         float firstPlaceVotes, secondPlaceVotes;
2623         float mapvote_voters_real;
2624         string result;
2625
2626         if(mapvote_count_real == 1)
2627                 return MapVote_Finished(0);
2628
2629         mapvote_voters_real = mapvote_voters;
2630         if(mapvote_abstain)
2631                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2632
2633         RandomSelection_Init();
2634         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2635                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2636         firstPlace = RandomSelection_chosen_float;
2637         firstPlaceVotes = RandomSelection_best_priority;
2638         //dprint("First place: ", ftos(firstPlace), "\n");
2639         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2640
2641         RandomSelection_Init();
2642         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2643                 if(i != firstPlace)
2644                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2645         secondPlace = RandomSelection_chosen_float;
2646         secondPlaceVotes = RandomSelection_best_priority;
2647         //dprint("Second place: ", ftos(secondPlace), "\n");
2648         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2649
2650         if(firstPlace == -1)
2651                 error("No first place in map vote... WTF?");
2652
2653         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2654                 return MapVote_Finished(firstPlace);
2655
2656         if(mapvote_keeptwotime)
2657                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2658                 {
2659                         float didntvote;
2660                         MapVote_TouchMask();
2661                         mapvote_message = "Now decide between the TOP TWO!";
2662                         mapvote_keeptwotime = 0;
2663                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2664                         result = strcat(result, ":", ftos(firstPlaceVotes));
2665                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2666                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2667                         didntvote = mapvote_voters;
2668                         for(i = 0; i < mapvote_count; ++i)
2669                                 if(mapvote_maps[i] != "")
2670                                 {
2671                                         didntvote -= mapvote_selections[i];
2672                                         if(i != firstPlace)
2673                                                 if(i != secondPlace)
2674                                                 {
2675                                                         result = strcat(result, ":", mapvote_maps[i]);
2676                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2677                                                         if(i < mapvote_count_real)
2678                                                         {
2679                                                                 strunzone(mapvote_maps[i]);
2680                                                                 mapvote_maps[i] = "";
2681                                                                 strunzone(mapvote_maps_pakfile[i]);
2682                                                                 mapvote_maps_pakfile[i] = "";
2683                                                         }
2684                                                 }
2685                                 }
2686                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2687                         if(autocvar_sv_eventlog)
2688                                 GameLogEcho(result);
2689                 }
2690
2691         return FALSE;
2692 }
2693 void MapVote_Tick()
2694 {
2695         float keeptwo;
2696         float totalvotes;
2697
2698         keeptwo = mapvote_keeptwotime;
2699         MapVote_CheckRules_1(); // count
2700         if(MapVote_CheckRules_2()) // decide
2701                 return;
2702
2703         totalvotes = 0;
2704         FOR_EACH_REALCLIENT(other)
2705         {
2706                 // hide scoreboard again
2707                 if(other.health != 2342)
2708                 {
2709                         other.health = 2342;
2710                         other.impulse = 0;
2711                         if(clienttype(other) == CLIENTTYPE_REAL)
2712                         {
2713                                 msg_entity = other;
2714                                 WriteByte(MSG_ONE, SVC_FINALE);
2715                                 WriteString(MSG_ONE, "");
2716                         }
2717                 }
2718
2719                 // clear possibly invalid votes
2720                 if(mapvote_maps[other.mapvote - 1] == "")
2721                         other.mapvote = 0;
2722                 // use impulses as new vote
2723                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2724                         if(mapvote_maps[other.impulse - 1] != "")
2725                         {
2726                                 other.mapvote = other.impulse;
2727                                 MapVote_TouchVotes(other);
2728                         }
2729                 other.impulse = 0;
2730
2731                 if(other.mapvote)
2732                         ++totalvotes;
2733         }
2734
2735         MapVote_CheckRules_1(); // just count
2736 }
2737 void MapVote_Start()
2738 {
2739         if(mapvote_run)
2740                 return;
2741
2742         // wait for stats to be sent first
2743         if(!playerstats_waitforme)
2744                 return;
2745
2746         MapInfo_Enumerate();
2747         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2748                 mapvote_run = TRUE;
2749 }
2750 void MapVote_Think()
2751 {
2752         if(!mapvote_run)
2753                 return;
2754
2755         if(alreadychangedlevel)
2756                 return;
2757
2758         if(time < mapvote_nextthink)
2759                 return;
2760         //dprint("tick\n");
2761
2762         mapvote_nextthink = time + 0.5;
2763
2764         if(!mapvote_initialized)
2765         {
2766                 if(autocvar_rescan_pending == 1)
2767                 {
2768                         cvar_set("rescan_pending", "2");
2769                         localcmd("fs_rescan\nrescan_pending 3\n");
2770                         return;
2771                 }
2772                 else if(autocvar_rescan_pending == 2)
2773                 {
2774                         return;
2775                 }
2776                 else if(autocvar_rescan_pending == 3)
2777                 {
2778                         // now build missing mapinfo files
2779                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2780                                 return;
2781
2782                         // we're done, start the timer
2783                         cvar_set("rescan_pending", "0");
2784                 }
2785
2786                 mapvote_initialized = TRUE;
2787                 if(DoNextMapOverride(0))
2788                         return;
2789                 if(!autocvar_g_maplist_votable || player_count <= 0)
2790                 {
2791                         GotoNextMap(0);
2792                         return;
2793                 }
2794                 MapVote_Init();
2795         }
2796
2797         MapVote_Tick();
2798 }
2799
2800 string GotoMap(string m)
2801 {
2802         if(!MapInfo_CheckMap(m))
2803                 return "The map you chose is not available on this server.";
2804         cvar_set("nextmap", m);
2805         cvar_set("timelimit", "-1");
2806         if(mapvote_initialized || alreadychangedlevel)
2807         {
2808                 if(DoNextMapOverride(0))
2809                         return "Map switch initiated.";
2810                 else
2811                         return "Hm... no. For some reason I like THIS map more.";
2812         }
2813         else
2814                 return "Map switch will happen after scoreboard.";
2815 }
2816
2817
2818 void EndFrame()
2819 {
2820         float altime;
2821         FOR_EACH_REALCLIENT(self)
2822         {
2823                 if(self.classname == "spectator")
2824                 {
2825                         if(self.enemy.typehitsound)
2826                                 self.typehit_time = time;
2827                         else if(self.enemy.hitsound)
2828                                 self.hit_time = time;
2829                 }
2830                 else
2831                 {
2832                         if(self.typehitsound)
2833                                 self.typehit_time = time;
2834                         else if(self.hitsound)
2835                                 self.hit_time = time;
2836                 }
2837         }
2838         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2839         // add 1 frametime because after this, engine SV_Physics
2840         // increases time by a frametime and then networks the frame
2841         // add another frametime because client shows everything with
2842         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2843         // needed!
2844         FOR_EACH_CLIENT(self)
2845         {
2846                 self.hitsound = FALSE;
2847                 self.typehitsound = FALSE;
2848                 antilag_record(self, altime);
2849         }
2850 }
2851
2852
2853 /*
2854  * RedirectionThink:
2855  * returns TRUE if redirecting
2856  */
2857 float redirection_timeout;
2858 float redirection_nextthink;
2859 float RedirectionThink()
2860 {
2861         float clients_found;
2862
2863         if(redirection_target == "")
2864                 return FALSE;
2865
2866         if(!redirection_timeout)
2867         {
2868                 cvar_set("sv_public", "-2");
2869                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2870                 if(redirection_target == "self")
2871                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2872                 else
2873                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2874         }
2875
2876         if(time < redirection_nextthink)
2877                 return TRUE;
2878
2879         redirection_nextthink = time + 1;
2880
2881         clients_found = 0;
2882         FOR_EACH_REALCLIENT(self)
2883         {
2884                 // TODO add timer
2885                 print("Redirecting: sending connect command to ", self.netname, "\n");
2886                 if(redirection_target == "self")
2887                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2888                 else
2889                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2890                 ++clients_found;
2891         }
2892
2893         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2894
2895         if(time > redirection_timeout || clients_found == 0)
2896                 localcmd("\nwait; wait; wait; quit\n");
2897
2898         return TRUE;
2899 }
2900
2901 void TargetMusic_RestoreGame();
2902 void RestoreGame()
2903 {
2904         // Loaded from a save game
2905         // some things then break, so let's work around them...
2906
2907         // Progs DB (capture records)
2908         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2909
2910         // Mapinfo
2911         MapInfo_Shutdown();
2912         MapInfo_Enumerate();
2913         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2914         WeaponStats_Init();
2915
2916         TargetMusic_RestoreGame();
2917 }
2918
2919 void Shutdown()
2920 {
2921         entity e;
2922
2923         gameover = 2;
2924
2925         if(world_initialized > 0)
2926         {
2927                 world_initialized = 0;
2928                 print("Saving persistent data...\n");
2929                 Ban_SaveBans();
2930
2931                 PlayerStats_EndMatch(0);
2932                 FOR_EACH_CLIENT(e)
2933                         PlayerStats_AddGlobalInfo(e);
2934                 PlayerStats_Shutdown();
2935
2936                 if(!cheatcount_total)
2937                 {
2938                         if(autocvar_sv_db_saveasdump)
2939                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2940                         else
2941                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2942                 }
2943                 if(autocvar_developer)
2944                 {
2945                         if(autocvar_sv_db_saveasdump)
2946                                 db_dump(TemporaryDB, "server-temp.db");
2947                         else
2948                                 db_save(TemporaryDB, "server-temp.db");
2949                 }
2950                 CheatShutdown(); // must be after cheatcount check
2951                 db_close(ServerProgsDB);
2952                 db_close(TemporaryDB);
2953                 print("done!\n");
2954                 // tell the bot system the game is ending now
2955                 bot_endgame();
2956
2957                 WeaponStats_Shutdown();
2958                 MapInfo_Shutdown();
2959         }
2960         else if(world_initialized == 0)
2961         {
2962                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2963         }
2964 }