qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void GotoFirstMap()
  85 {
  86         float n;
  87         if(autocvar__sv_init)
  88         {
  89                 // cvar_set("_sv_init", "0");
  90                 // we do NOT set this to 0 any more, so someone "accidentally" changing
  91                 // to this "init" map on a dedicated server will cause no permanent
  92                 // harm
  93                 if(autocvar_g_maplist_shuffle)
  94                         ShuffleMaplist();
  95                 n = tokenizebyseparator(autocvar_g_maplist, " ");
  96                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
  97
  98                 MapInfo_Enumerate();
  99                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 100
 101                 if(!DoNextMapOverride(1))
 102                         GotoNextMap(1);
 103
 104                 return;
 105         }
 106
 107         if(time < 5)
 108         {
 109                 self.nextthink = time;
 110         }
 111         else
 112         {
 113                 self.nextthink = time + 1;
 114                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 115         }
 116 }
 117
 118 void cvar_changes_init()
 119 {
 120         float h;
 121         string k, v, d;
 122         float n, i, adding, pureadding;
 123
 124         if(cvar_changes)
 125                 strunzone(cvar_changes);
 126         cvar_changes = string_null;
 127         if(cvar_purechanges)
 128                 strunzone(cvar_purechanges);
 129         cvar_purechanges = string_null;
 130         cvar_purechanges_count = 0;
 131
 132         h = buf_create();
 133         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 134         n = buf_getsize(h);
 135
 136         adding = TRUE;
 137         pureadding = TRUE;
 138
 139         for(i = 0; i < n; ++i)
 140         {
 141                 k = bufstr_get(h, i);
 142
 143 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 144 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 145 #define BADCVAR(p) if(k == p) continue
 146
 147                 // general excludes and namespaces for server admin used cvars
 148                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 149
 150                 // internal
 151                 BADPREFIX("csqc_");
 152                 BADPREFIX("cvar_check_");
 153                 BADCVAR("gamecfg");
 154                 BADCVAR("g_configversion");
 155                 BADCVAR("g_maplist_index");
 156                 BADCVAR("halflifebsp");
 157                 BADPREFIX("sv_world");
 158
 159                 // client
 160                 BADPREFIX("chase_");
 161                 BADPREFIX("cl_");
 162                 BADPREFIX("con_");
 163                 BADPREFIX("scoreboard_");
 164                 BADPREFIX("g_campaign");
 165                 BADPREFIX("g_waypointsprite_");
 166                 BADPREFIX("gl_");
 167                 BADPREFIX("joy");
 168                 BADPREFIX("hud_");
 169                 BADPREFIX("m_");
 170                 BADPREFIX("menu_");
 171                 BADPREFIX("net_slist_");
 172                 BADPREFIX("r_");
 173                 BADPREFIX("sbar_");
 174                 BADPREFIX("scr_");
 175                 BADPREFIX("snd_");
 176                 BADPREFIX("show");
 177                 BADPREFIX("sensitivity");
 178                 BADPREFIX("userbind");
 179                 BADPREFIX("v_");
 180                 BADPREFIX("vid_");
 181                 BADPREFIX("crosshair");
 182                 BADCVAR("mod_q3bsp_lightmapmergepower");
 183                 BADCVAR("mod_q3bsp_nolightmaps");
 184                 BADCVAR("fov");
 185                 BADCVAR("mastervolume");
 186                 BADCVAR("volume");
 187                 BADCVAR("bgmvolume");
 188
 189                 // private
 190                 BADCVAR("developer");
 191                 BADCVAR("log_dest_udp");
 192                 BADCVAR("net_address");
 193                 BADCVAR("net_address_ipv6");
 194                 BADCVAR("port");
 195                 BADCVAR("savedgamecfg");
 196                 BADCVAR("serverconfig");
 197                 BADCVAR("sv_autoscreenshot");
 198                 BADCVAR("sv_heartbeatperiod");
 199                 BADCVAR("sv_vote_master_password");
 200                 BADCVAR("sys_colortranslation");
 201                 BADCVAR("sys_specialcharactertranslation");
 202                 BADCVAR("timeformat");
 203                 BADCVAR("timestamps");
 204                 BADPREFIX("developer_");
 205                 BADPREFIX("g_ban_");
 206                 BADPREFIX("g_banned_list");
 207                 BADPREFIX("g_chat_flood_");
 208                 BADPREFIX("g_ghost_items");
 209                 BADPREFIX("g_playerstats_");
 210                 BADPREFIX("g_respawn_ghosts");
 211                 BADPREFIX("g_voice_flood_");
 212                 BADPREFIX("log_file");
 213                 BADPREFIX("rcon_");
 214                 BADPREFIX("sv_allowdownloads");
 215                 BADPREFIX("sv_autodemo");
 216                 BADPREFIX("sv_curl_");
 217                 BADPREFIX("sv_eventlog");
 218                 BADPREFIX("sv_logscores_");
 219                 BADPREFIX("sv_master");
 220                 BADPREFIX("sv_weaponstats_");
 221                 BADPREFIX("sv_waypointsprite_");
 222                 BADCVAR("rescan_pending");
 223
 224                 // these can contain player IDs, so better hide
 225                 BADPREFIX("g_forced_team_");
 226
 227                 // mapinfo
 228                 BADCVAR("fraglimit");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ca");
 231                 BADCVAR("g_ca_teams");
 232                 BADCVAR("g_ctf");
 233                 BADCVAR("g_cts");
 234                 BADCVAR("g_dm");
 235                 BADCVAR("g_domination");
 236                 BADCVAR("g_domination_default_teams");
 237                 BADCVAR("g_freezetag");
 238                 BADCVAR("g_freezetag_teams");
 239                 BADCVAR("g_keepaway");
 240                 BADCVAR("g_keyhunt");
 241                 BADCVAR("g_keyhunt_teams");
 242                 BADCVAR("g_lms");
 243                 BADCVAR("g_nexball");
 244                 BADCVAR("g_onslaught");
 245                 BADCVAR("g_race");
 246                 BADCVAR("g_race_qualifying_timelimit");
 247                 BADCVAR("g_tdm");
 248                 BADCVAR("g_tdm_teams");
 249                 BADCVAR("leadlimit");
 250                 BADCVAR("nextmap");
 251                 BADCVAR("teamplay");
 252                 BADCVAR("timelimit");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259
 260                 v = cvar_string(k);
 261                 d = cvar_defstring(k);
 262                 if(v == d)
 263                         continue;
 264
 265                 if(adding)
 266                 {
 267                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 268                         if(strlen(cvar_changes) > 16384)
 269                         {
 270                                 cvar_changes = "// too many settings have been changed to show them here\n";
 271                                 adding = 0;
 272                         }
 273                 }
 274
 275                 // now check if the changes are actually gameplay relevant
 276
 277                 // does nothing visible
 278                 BADCVAR("captureleadlimit_override");
 279                 BADCVAR("g_balance_kill_delay");
 280                 BADCVAR("g_ca_point_leadlimit");
 281                 BADCVAR("g_ctf_captimerecord_always");
 282                 BADCVAR("g_ctf_flag_glowtrails");
 283                 BADCVAR("g_ctf_flag_pickup_verbosename");
 284                 BADCVAR("g_domination_point_leadlimit");
 285                 BADCVAR("g_forced_respawn");
 286                 BADCVAR("g_keyhunt_point_leadlimit");
 287                 BADPREFIX("g_mod_");
 288                 BADCVAR("g_nexball_goalleadlimit");
 289                 BADCVAR("leadlimit_and_fraglimit");
 290                 BADCVAR("leadlimit_override");
 291                 BADCVAR("pausable");
 292                 BADCVAR("sv_allow_fullbright");
 293                 BADCVAR("sv_checkforpacketsduringsleep");
 294                 BADCVAR("sv_fraginfo");
 295                 BADCVAR("sv_timeout");
 296                 BADPREFIX("sv_timeout_");
 297                 BADPREFIX("crypto_");
 298                 BADPREFIX("g_chat_");
 299                 BADPREFIX("g_ctf_captimerecord_");
 300                 BADPREFIX("g_maplist_votable_");
 301                 BADPREFIX("net_");
 302                 BADPREFIX("prvm_");
 303                 BADPREFIX("skill_");
 304                 BADPREFIX("sv_cullentities_");
 305                 BADPREFIX("sv_fraginfo_");
 306                 BADPREFIX("sv_maxidle_");
 307                 BADPREFIX("sv_vote_");
 308                 BADPREFIX("timelimit_");
 309                 BADCVAR("gameversion");
 310                 BADPREFIX("gameversion_");
 311                 BADCVAR("sv_namechangetimer");
 312
 313                 // allowed changes to server admins (please sync this to server.cfg)
 314                 // vi commands:
 315                 //   :/"impure"/,$d
 316                 //   :g!,^\/\/[^ /],d
 317                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 318                 //   :%!sort
 319                 // yes, this does contain some redundant stuff, don't really care
 320                 BADCVAR("bot_config_file");
 321                 BADCVAR("bot_number");
 322                 BADCVAR("bot_prefix");
 323                 BADCVAR("bot_suffix");
 324                 BADCVAR("capturelimit_override");
 325                 BADCVAR("fraglimit_override");
 326                 BADCVAR("gametype");
 327                 BADCVAR("g_antilag");
 328                 BADCVAR("g_balance_teams");
 329                 BADCVAR("g_balance_teams_prevent_imbalance");
 330                 BADCVAR("g_balance_teams_scorefactor");
 331                 BADCVAR("g_ban_sync_trusted_servers");
 332                 BADCVAR("g_ban_sync_uri");
 333                 BADCVAR("g_ca_teams_override");
 334                 BADCVAR("g_ctf_ignore_frags");
 335                 BADCVAR("g_domination_point_limit");
 336                 BADCVAR("g_freezetag_teams_override");
 337                 BADCVAR("g_friendlyfire");
 338                 BADCVAR("g_fullbrightitems");
 339                 BADCVAR("g_fullbrightplayers");
 340                 BADCVAR("g_keyhunt_point_limit");
 341                 BADCVAR("g_keyhunt_teams_override");
 342                 BADCVAR("g_lms_lives_override");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_check_waypoints");
 345                 BADCVAR("g_maplist_mostrecent_count");
 346                 BADCVAR("g_maplist_shuffle");
 347                 BADCVAR("g_maplist_votable");
 348                 BADCVAR("g_maplist_votable_abstain");
 349                 BADCVAR("g_maplist_votable_nodetail");
 350                 BADCVAR("g_maplist_votable_suggestions");
 351                 BADCVAR("g_maxplayers");
 352                 BADCVAR("g_mirrordamage");
 353                 BADCVAR("g_nexball_goallimit");
 354                 BADCVAR("g_powerups");
 355                 BADCVAR("g_start_delay");
 356                 BADCVAR("g_warmup");
 357                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 358                 BADCVAR("hostname");
 359                 BADCVAR("log_file");
 360                 BADCVAR("maxplayers");
 361                 BADCVAR("minplayers");
 362                 BADCVAR("net_address");
 363                 BADCVAR("port");
 364                 BADCVAR("rcon_password");
 365                 BADCVAR("rcon_restricted_commands");
 366                 BADCVAR("rcon_restricted_password");
 367                 BADCVAR("skill");
 368                 BADCVAR("sv_adminnick");
 369                 BADCVAR("sv_autoscreenshot");
 370                 BADCVAR("sv_autotaunt");
 371                 BADCVAR("sv_curl_defaulturl");
 372                 BADCVAR("sv_defaultcharacter");
 373                 BADCVAR("sv_defaultplayercolors");
 374                 BADCVAR("sv_defaultplayermodel");
 375                 BADCVAR("sv_defaultplayerskin");
 376                 BADCVAR("sv_maxidle");
 377                 BADCVAR("sv_maxrate");
 378                 BADCVAR("sv_motd");
 379                 BADCVAR("sv_public");
 380                 BADCVAR("sv_ready_restart");
 381                 BADCVAR("sv_status_privacy");
 382                 BADCVAR("sv_taunt");
 383                 BADCVAR("sv_vote_call");
 384                 BADCVAR("sv_vote_commands");
 385                 BADCVAR("sv_vote_majority_factor");
 386                 BADCVAR("sv_vote_master");
 387                 BADCVAR("sv_vote_master_commands");
 388                 BADCVAR("sv_vote_master_password");
 389                 BADCVAR("sv_vote_simple_majority_factor");
 390                 BADCVAR("teamplay_mode");
 391                 BADCVAR("timelimit_override");
 392                 BADCVAR("g_spawnshieldtime");
 393                 BADPREFIX("g_warmup_");
 394                 BADPREFIX("sv_ready_restart_");
 395
 396                 // mutators that announce themselves properly to the server browser
 397                 BADCVAR("g_instagib");
 398                 BADCVAR("g_new_toys");
 399                 BADCVAR("g_nix");
 400                 BADCVAR("g_grappling_hook");
 401                 BADCVAR("g_jetpack");
 402
 403 #undef BADPREFIX
 404 #undef BADCVAR
 405
 406                 if(pureadding)
 407                 {
 408                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 409                         if(strlen(cvar_purechanges) > 16384)
 410                         {
 411                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 412                                 pureadding = 0;
 413                         }
 414                 }
 415                 ++cvar_purechanges_count;
 416                 // WARNING: this variable is used for the server list
 417                 // NEVER dare to skip this code!
 418                 // Hacks to intentionally appearing as "pure server" even though you DO have
 419                 // modified settings may be punished by removal from the server list.
 420                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 421                 // though.
 422         }
 423         buf_del(h);
 424         if(cvar_changes == "")
 425                 cvar_changes = "// this server runs at default server settings\n";
 426         else
 427                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 428         cvar_changes = strzone(cvar_changes);
 429         if(cvar_purechanges == "")
 430                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 431         else
 432                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 433         cvar_purechanges = strzone(cvar_purechanges);
 434 }
 435
 436 void detect_maptype()
 437 {
 438 #if 0
 439         vector o, v;
 440         float i;
 441
 442         for(;;)
 443         {
 444                 o = world.mins;
 445                 o_x += random() * (world.maxs_x - world.mins_x);
 446                 o_y += random() * (world.maxs_y - world.mins_y);
 447                 o_z += random() * (world.maxs_z - world.mins_z);
 448
 449                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 450                 if(trace_fraction == 1)
 451                         continue;
 452
 453                 v = trace_endpos;
 454
 455                 for(i = 0; i < 64; i += 4)
 456                 {
 457                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 458         if(trace_fraction == 1)
 459                 continue;
 460                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 461                 }
 462
 463                 break;
 464         }
 465 #endif
 466 }
 467
 468 entity randomseed;
 469 float RandomSeed_Send(entity to, float sf)
 470 {
 471         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 472         WriteShort(MSG_ENTITY, self.cnt);
 473         return TRUE;
 474 }
 475 void RandomSeed_Think()
 476 {
 477         self.cnt = bound(0, floor(random() * 65536), 65535);
 478         self.nextthink = time + 5;
 479
 480         self.SendFlags |= 1;
 481 }
 482 void RandomSeed_Spawn()
 483 {
 484         randomseed = spawn();
 485         randomseed.think = RandomSeed_Think;
 486         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 487
 488         entity oldself;
 489         oldself = self;
 490         self = randomseed;
 491         self.think(); // sets random seed and nextthink
 492         self = oldself;
 493 }
 494
 495 void spawnfunc___init_dedicated_server(void)
 496 {
 497         // handler for _init/_init map (only for dedicated server initialization)
 498
 499         world_initialized = -1; // don't complain
 500         cvar = cvar_normal;
 501         cvar_string = cvar_string_normal;
 502         cvar_set = cvar_set_normal;
 503
 504         remove = remove_unsafely;
 505
 506         entity e;
 507         e = spawn();
 508         e.think = GotoFirstMap;
 509         e.nextthink = time; // this is usually 1 at this point
 510
 511         e = spawn();
 512         e.classname = "info_player_deathmatch"; // safeguard against player joining
 513
 514         self.classname = "worldspawn"; // safeguard against various stuff ;)
 515
 516         // needs to be done so early because of the constants they create
 517         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 518         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 519         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 520         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 521         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 522         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 523
 524         MapInfo_Enumerate();
 525         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 526 }
 527
 528 void Map_MarkAsRecent(string m);
 529 float world_already_spawned;
 530 void Nagger_Init();
 531 void ClientInit_Spawn();
 532 void WeaponStats_Init();
 533 void WeaponStats_Shutdown();
 534 void Physics_AddStats();
 535 void spawnfunc_worldspawn (void)
 536 {
 537         float fd, l, i, j, n;
 538         string s;
 539
 540         cvar = cvar_normal;
 541         cvar_string = cvar_string_normal;
 542         cvar_set = cvar_set_normal;
 543
 544         if(world_already_spawned)
 545                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 546         world_already_spawned = TRUE;
 547
 548         remove = remove_safely; // during spawning, watch what you remove!
 549
 550         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 551
 552         compressShortVector_init();
 553
 554         entity head;
 555         head = nextent(world);
 556         maxclients = 0;
 557         while(head)
 558         {
 559                 ++maxclients;
 560                 head = nextent(head);
 561         }
 562
 563         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 564
 565         // needs to be done so early because of the constants they create
 566         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 567         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 568         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 569         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 570         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 571         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 572
 573         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 574
 575         TemporaryDB = db_create();
 576
 577         // 0 normal
 578         lightstyle(0, "m");
 579
 580         // 1 FLICKER (first variety)
 581         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 582
 583         // 2 SLOW STRONG PULSE
 584         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 585
 586         // 3 CANDLE (first variety)
 587         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 588
 589         // 4 FAST STROBE
 590         lightstyle(4, "mamamamamama");
 591
 592         // 5 GENTLE PULSE 1
 593         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 594
 595         // 6 FLICKER (second variety)
 596         lightstyle(6, "nmonqnmomnmomomno");
 597
 598         // 7 CANDLE (second variety)
 599         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 600
 601         // 8 CANDLE (third variety)
 602         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 603
 604         // 9 SLOW STROBE (fourth variety)
 605         lightstyle(9, "aaaaaaaazzzzzzzz");
 606
 607         // 10 FLUORESCENT FLICKER
 608         lightstyle(10, "mmamammmmammamamaaamammma");
 609
 610         // 11 SLOW PULSE NOT FADE TO BLACK
 611         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 612
 613         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 614
 615         // 63 testing
 616         lightstyle(63, "a");
 617
 618         if(autocvar_g_campaign)
 619                 CampaignPreInit();
 620
 621         Map_MarkAsRecent(mapname);
 622
 623         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 624
 625         precache_model ("null"); // we need this one before InitGameplayMode
 626         InitGameplayMode();
 627         readlevelcvars();
 628         GrappleHookInit();
 629
 630         player_count = 0;
 631         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 632         if(bot_waypoints_for_items == 1)
 633                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 634                         bot_waypoints_for_items = 0;
 635
 636         precache();
 637
 638         WaypointSprite_Init();
 639
 640         GameLogInit(); // prepare everything
 641         // NOTE for matchid:
 642         // changing the logic generating it is okay. But:
 643         // it HAS to stay <= 64 chars
 644         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 645         if(autocvar_sv_eventlog)
 646         {
 647                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 648                 matchid = strzone(s);
 649
 650                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 651                 s = ":gameinfo:mutators:LIST";
 652
 653                 ret_string = s;
 654                 MUTATOR_CALLHOOK(BuildMutatorsString);
 655                 s = ret_string;
 656
 657                 // simple, probably not good in the mutator system
 658                 if(autocvar_g_grappling_hook)
 659                         s = strcat(s, ":grappling_hook");
 660
 661                 // initialiation stuff, not good in the mutator system
 662                 if(!autocvar_g_use_ammunition)
 663                         s = strcat(s, ":no_use_ammunition");
 664
 665                 // initialiation stuff, not good in the mutator system
 666                 if(autocvar_g_pickup_items == 0)
 667                         s = strcat(s, ":no_pickup_items");
 668                 if(autocvar_g_pickup_items > 0)
 669                         s = strcat(s, ":pickup_items");
 670
 671                 // initialiation stuff, not good in the mutator system
 672                 if(autocvar_g_weaponarena != "0")
 673                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 674
 675                 // TODO to mutator system
 676                 if(autocvar_g_norecoil)
 677                         s = strcat(s, ":norecoil");
 678
 679                 // TODO to mutator system
 680                 if(autocvar_g_powerups == 0)
 681                         s = strcat(s, ":no_powerups");
 682                 if(autocvar_g_powerups > 0)
 683                         s = strcat(s, ":powerups");
 684
 685                 GameLogEcho(s);
 686                 GameLogEcho(":gameinfo:end");
 687         }
 688         else
 689                 matchid = strzone(ftos(random()));
 690
 691         cvar_set("nextmap", "");
 692
 693         SetDefaultAlpha();
 694
 695         if(autocvar_g_campaign)
 696                 CampaignPostInit();
 697
 698         Ban_LoadBans();
 699
 700         MapInfo_Enumerate();
 701         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 702
 703         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 704         {
 705                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 706                 if(fd != -1)
 707                 {
 708                         while((s = fgets(fd)))
 709                         {
 710                                 l = tokenize_console(s);
 711                                 if(l < 2)
 712                                         continue;
 713                                 if(argv(0) == "cd")
 714                                 {
 715                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 716                                         print("  cdtrack ", argv(2), "\n");
 717                                 }
 718                                 else if(argv(0) == "fog")
 719                                 {
 720                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 721                                         print("  \"fog\" \"", s, "\"\n");
 722                                 }
 723                                 else if(argv(0) == "set")
 724                                 {
 725                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 726                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 727                                 }
 728                                 else if(argv(0) != "//")
 729                                 {
 730                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 731                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 732                                 }
 733                         }
 734                         fclose(fd);
 735                 }
 736         }
 737
 738         WeaponStats_Init();
 739
 740         WepSet_AddStat();
 741         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 742         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 743         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 744         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 745         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 746         Nagger_Init();
 747
 748         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 749         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 750         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 751         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 752         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 753         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 754         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 755         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 756         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 757         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 758         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 759         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 760         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 761         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 762
 763         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 764         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 765
 766         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 767
 768         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 769
 770         // freeze attacks
 771         addstat(STAT_FROZEN, AS_INT, frozen);
 772         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 773
 774         // physics
 775         Physics_AddStats();
 776
 777         // secrets
 778         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 779         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 780
 781         // monsters
 782         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 783         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 784
 785         // misc
 786         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 787
 788         next_pingtime = time + 5;
 789
 790         detect_maptype();
 791
 792         // set up information replies for clients and server to use
 793         maplist_reply = strzone(getmaplist());
 794         lsmaps_reply = strzone(getlsmaps());
 795         monsterlist_reply = strzone(getmonsterlist());
 796         for(i = 0; i < 10; ++i)
 797         {
 798                 s = getrecords(i);
 799                 if (s)
 800                         records_reply[i] = strzone(s);
 801         }
 802         ladder_reply = strzone(getladder());
 803         rankings_reply = strzone(getrankings());
 804
 805         // begin other init
 806         ClientInit_Spawn();
 807         RandomSeed_Spawn();
 808         PingPLReport_Spawn();
 809
 810         CheatInit();
 811
 812         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 813
 814         // fill sv_curl_serverpackages from .serverpackage files
 815         if(autocvar_sv_curl_serverpackages_auto)
 816         {
 817                 s = "";
 818                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 819                 for(i = 0; i < n; ++i)
 820                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 821                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 822                                 s = strcat(s, " ", argv(i));
 823                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 824                 if(fd >= 0)
 825                 {
 826                         j = search_getsize(fd);
 827                         for(i = 0; i < j; ++i)
 828                                 s = strcat(s, " ", search_getfilename(fd, i));
 829                         search_end(fd);
 830                 }
 831                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 832                 if(fd >= 0)
 833                 {
 834                         j = search_getsize(fd);
 835                         for(i = 0; i < j; ++i)
 836                                 s = strcat(s, " ", search_getfilename(fd, i));
 837                         search_end(fd);
 838                 }
 839                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 840         }
 841
 842         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 843         modname = "Xonotic";
 844         // physics/balance/config changes that count as mod
 845         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 846                 modname = cvar_string("g_mod_physics");
 847         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 848                 modname = cvar_string("g_mod_balance");
 849         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 850                 modname = cvar_string("g_mod_config");
 851         // extra mutators that deserve to count as mod
 852         MUTATOR_CALLHOOK(SetModname);
 853
 854         // save it for later
 855         modname = strzone(modname);
 856
 857         WinningConditionHelper(); // set worldstatus
 858
 859         world_initialized = 1;
 860 }
 861
 862 void spawnfunc_light (void)
 863 {
 864         //makestatic (self); // Who the f___ did that?
 865         remove(self);
 866 }
 867
 868 string GetGametype()
 869 {
 870         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 871 }
 872
 873 string GetMapname()
 874 {
 875         return mapname;
 876 }
 877
 878 float Map_Count, Map_Current;
 879 string Map_Current_Name;
 880
 881 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 882 float GetMaplistPosition()
 883 {
 884         float pos, idx;
 885         string map;
 886
 887         map = GetMapname();
 888         idx = autocvar_g_maplist_index;
 889
 890         if(idx >= 0)
 891                 if(idx < Map_Count)
 892                         if(map == argv(idx))
 893                                 return idx;
 894
 895         for(pos = 0; pos < Map_Count; ++pos)
 896                 if(map == argv(pos))
 897                         return pos;
 898
 899         // resume normal maplist rotation if current map is not in g_maplist
 900         return idx;
 901 }
 902
 903 float MapHasRightSize(string map)
 904 {
 905         float fh;
 906         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 907         if(autocvar_g_maplist_check_waypoints)
 908         {
 909                 dprint("checkwp "); dprint(map);
 910                 if(!fexists(strcat("maps/", map, ".waypoints")))
 911                 {
 912                         dprint(": no waypoints\n");
 913                         return FALSE;
 914                 }
 915                 dprint(": has waypoints\n");
 916         }
 917
 918         // open map size restriction file
 919         dprint("opensize "); dprint(map);
 920         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 921         if(fh >= 0)
 922         {
 923                 float mapmin, mapmax;
 924                 dprint(": ok, ");
 925                 mapmin = stof(fgets(fh));
 926                 mapmax = stof(fgets(fh));
 927                 fclose(fh);
 928                 if(player_count < mapmin)
 929                 {
 930                         dprint("not enough\n");
 931                         return FALSE;
 932                 }
 933                 if(player_count > mapmax)
 934                 {
 935                         dprint("too many\n");
 936                         return FALSE;
 937                 }
 938                 dprint("right size\n");
 939                 return TRUE;
 940         }
 941         dprint(": not found\n");
 942         return TRUE;
 943 }
 944
 945 string Map_Filename(float position)
 946 {
 947         return strcat("maps/", argv(position), ".bsp");
 948 }
 949
 950 string strwords(string s, float w)
 951 {
 952         float endpos;
 953         for(endpos = 0; w && endpos >= 0; --w)
 954                 endpos = strstrofs(s, " ", endpos + 1);
 955         if(endpos < 0)
 956                 return s;
 957         else
 958                 return substring(s, 0, endpos);
 959 }
 960
 961 float strhasword(string s, string w)
 962 {
 963         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 964 }
 965
 966 void Map_MarkAsRecent(string m)
 967 {
 968         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 969 }
 970
 971 float Map_IsRecent(string m)
 972 {
 973         return strhasword(autocvar_g_maplist_mostrecent, m);
 974 }
 975
 976 float Map_Check(float position, float pass)
 977 {
 978         string filename;
 979         string map_next;
 980         map_next = argv(position);
 981         if(pass <= 1)
 982         {
 983                 if(Map_IsRecent(map_next))
 984                         return 0;
 985         }
 986         filename = Map_Filename(position);
 987         if(MapInfo_CheckMap(map_next))
 988         {
 989                 if(pass == 2)
 990                         return 1;
 991                 if(MapHasRightSize(map_next))
 992                         return 1;
 993                 return 0;
 994         }
 995         else
 996                 dprint( "Couldn't select '", filename, "'..\n" );
 997
 998         return 0;
 999 }
1000
1001 void Map_Goto_SetStr(string nextmapname)
1002 {
1003         if(getmapname_stored != "")
1004                 strunzone(getmapname_stored);
1005         if(nextmapname == "")
1006                 getmapname_stored = "";
1007         else
1008                 getmapname_stored = strzone(nextmapname);
1009 }
1010
1011 void Map_Goto_SetFloat(float position)
1012 {
1013         cvar_set("g_maplist_index", ftos(position));
1014         Map_Goto_SetStr(argv(position));
1015 }
1016
1017 void Map_Goto(float reinit)
1018 {
1019         MapInfo_LoadMap(getmapname_stored, reinit);
1020 }
1021
1022 // return codes of map selectors:
1023 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1024 //   -2 = permanent failure
1025 float() MaplistMethod_Iterate = // usual method
1026 {
1027         float pass, i;
1028
1029         dprint("Trying MaplistMethod_Iterate\n");
1030
1031         for(pass = 1; pass <= 2; ++pass)
1032         {
1033                 for(i = 1; i < Map_Count; ++i)
1034                 {
1035                         float mapindex;
1036                         mapindex = mod(i + Map_Current, Map_Count);
1037                         if(Map_Check(mapindex, pass))
1038                                 return mapindex;
1039                 }
1040         }
1041         return -1;
1042 }
1043
1044 float() MaplistMethod_Repeat = // fallback method
1045 {
1046         dprint("Trying MaplistMethod_Repeat\n");
1047
1048         if(Map_Check(Map_Current, 2))
1049                 return Map_Current;
1050         return -2;
1051 }
1052
1053 float() MaplistMethod_Random = // random map selection
1054 {
1055         float i, imax;
1056
1057         dprint("Trying MaplistMethod_Random\n");
1058
1059         imax = 42;
1060
1061         for(i = 0; i <= imax; ++i)
1062         {
1063                 float mapindex;
1064                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1065                 if(Map_Check(mapindex, 1))
1066                         return mapindex;
1067         }
1068         return -1;
1069 }
1070
1071 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1072 // the exponent sets a bias on the map selection:
1073 // the higher the exponent, the less likely "shortly repeated" same maps are
1074 {
1075         float i, j, imax, insertpos;
1076
1077         dprint("Trying MaplistMethod_Shuffle\n");
1078
1079         imax = 42;
1080
1081         for(i = 0; i <= imax; ++i)
1082         {
1083                 string newlist;
1084
1085                 // now reinsert this at another position
1086                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1087                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1088                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1089                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1090
1091                 // insert the current map there
1092                 newlist = "";
1093                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1094                         newlist = strcat(newlist, " ", argv(j));
1095                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1096                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1097                         newlist = strcat(newlist, " ", argv(j));
1098                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1099                 cvar_set("g_maplist", newlist);
1100                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1101
1102                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1103                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1104                 if(Map_Check(Map_Current, 1))
1105                         return Map_Current;
1106         }
1107         return -1;
1108 }
1109
1110 void Maplist_Init()
1111 {
1112         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1113         float i;
1114         for (i = 0; i < Map_Count; ++i)
1115                 if (Map_Check(i, 2))
1116                         break;
1117         if (i == Map_Count)
1118         {
1119                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1120                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1121                 if(autocvar_g_maplist_shuffle)
1122                         ShuffleMaplist();
1123                 localcmd("\nmenu_cmd sync\n");
1124                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1125         }
1126         if(Map_Count == 0)
1127                 error("empty maplist, cannot select a new map");
1128         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1129
1130         if(Map_Current_Name)
1131                 strunzone(Map_Current_Name);
1132         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1133         // this may or may not be correct, but who cares, in the worst case a map
1134         // isn't chosen in the first pass that should have been
1135 }
1136
1137 string GetNextMap()
1138 {
1139         float nextMap;
1140
1141         Maplist_Init();
1142         nextMap = -1;
1143
1144         if(nextMap == -1)
1145                 if(autocvar_g_maplist_shuffle > 0)
1146                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1147
1148         if(nextMap == -1)
1149                 if(autocvar_g_maplist_selectrandom)
1150                         nextMap = MaplistMethod_Random();
1151
1152         if(nextMap == -1)
1153                 nextMap = MaplistMethod_Iterate();
1154
1155         if(nextMap == -1)
1156                 nextMap = MaplistMethod_Repeat();
1157
1158         if(nextMap >= 0)
1159         {
1160                 Map_Goto_SetFloat(nextMap);
1161                 return getmapname_stored;
1162         }
1163
1164         return "";
1165 }
1166
1167 float DoNextMapOverride(float reinit)
1168 {
1169         if(autocvar_g_campaign)
1170         {
1171                 CampaignPostIntermission();
1172                 alreadychangedlevel = TRUE;
1173                 return TRUE;
1174         }
1175         if(autocvar_quit_when_empty)
1176         {
1177                 if(player_count <= currentbots)
1178                 {
1179                         localcmd("quit\n");
1180                         alreadychangedlevel = TRUE;
1181                         return TRUE;
1182                 }
1183         }
1184         if(autocvar_quit_and_redirect != "")
1185         {
1186                 redirection_target = strzone(autocvar_quit_and_redirect);
1187                 alreadychangedlevel = TRUE;
1188                 return TRUE;
1189         }
1190         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1191         {
1192                 localcmd("restart\n");
1193                 alreadychangedlevel = TRUE;
1194                 return TRUE;
1195         }
1196         if(autocvar_nextmap != "")
1197         {
1198                 string m;
1199                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1200                 cvar_set("nextmap",m);
1201
1202                 if(!m || gametypevote)
1203                         return FALSE;
1204                 if(autocvar_sv_vote_gametype)
1205                 {
1206                         Map_Goto_SetStr(m);
1207                         return FALSE;
1208                 }
1209
1210                 if(MapInfo_CheckMap(m))
1211                 {
1212                         Map_Goto_SetStr(m);
1213                         Map_Goto(reinit);
1214                         alreadychangedlevel = TRUE;
1215                         return TRUE;
1216                 }
1217         }
1218         if(!reinit && autocvar_lastlevel)
1219         {
1220                 cvar_settemp_restore();
1221                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1222                 alreadychangedlevel = TRUE;
1223                 return TRUE;
1224         }
1225         return FALSE;
1226 }
1227
1228 void GotoNextMap(float reinit)
1229 {
1230         //string nextmap;
1231         //float n, nummaps;
1232         //string s;
1233         if (alreadychangedlevel)
1234                 return;
1235         alreadychangedlevel = TRUE;
1236
1237         string nextMap;
1238
1239         nextMap = GetNextMap();
1240         if(nextMap == "")
1241                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1242         Map_Goto(reinit);
1243 }
1244
1245
1246 /*
1247 ============
1248 IntermissionThink
1249
1250 When the player presses attack or jump, change to the next level
1251 ============
1252 */
1253 .float autoscreenshot;
1254 void IntermissionThink()
1255 {
1256         FixIntermissionClient(self);
1257
1258         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1259         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1260
1261         if( (server_screenshot || client_screenshot)
1262                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1263         {
1264                 self.autoscreenshot = -1;
1265                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1266                 return;
1267         }
1268
1269         if (time < intermission_exittime)
1270                 return;
1271
1272         if(!mapvote_initialized)
1273                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1274                         return;
1275
1276         MapVote_Start();
1277 }
1278
1279 /*
1280 ============
1281 FindIntermission
1282
1283 Returns the entity to view from
1284 ============
1285 */
1286 /*
1287 entity FindIntermission()
1288 {
1289         local   entity spot;
1290         local   float cyc;
1291
1292 // look for info_intermission first
1293         spot = find (world, classname, "info_intermission");
1294         if (spot)
1295         {       // pick a random one
1296                 cyc = random() * 4;
1297                 while (cyc > 1)
1298                 {
1299                         spot = find (spot, classname, "info_intermission");
1300                         if (!spot)
1301                                 spot = find (spot, classname, "info_intermission");
1302                         cyc = cyc - 1;
1303                 }
1304                 return spot;
1305         }
1306
1307 // then look for the start position
1308         spot = find (world, classname, "info_player_start");
1309         if (spot)
1310                 return spot;
1311
1312 // testinfo_player_start is only found in regioned levels
1313         spot = find (world, classname, "testplayerstart");
1314         if (spot)
1315                 return spot;
1316
1317 // then look for the start position
1318         spot = find (world, classname, "info_player_deathmatch");
1319         if (spot)
1320                 return spot;
1321
1322         //objerror ("FindIntermission: no spot");
1323         return world;
1324 }
1325 */
1326
1327 /*
1328 ===============================================================================
1329
1330 RULES
1331
1332 ===============================================================================
1333 */
1334
1335 void DumpStats(float final)
1336 {
1337         float file;
1338         string s;
1339         float to_console;
1340         float to_eventlog;
1341         float to_file;
1342         float i;
1343
1344         to_console = autocvar_sv_logscores_console;
1345         to_eventlog = autocvar_sv_eventlog;
1346         to_file = autocvar_sv_logscores_file;
1347
1348         if(!final)
1349         {
1350                 to_console = TRUE; // always print printstats replies
1351                 to_eventlog = FALSE; // but never print them to the event log
1352         }
1353
1354         if(to_eventlog)
1355                 if(autocvar_sv_eventlog_console)
1356                         to_console = FALSE; // otherwise we get the output twice
1357
1358         if(final)
1359                 s = ":scores:";
1360         else
1361                 s = ":status:";
1362         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1363
1364         if(to_console)
1365                 print(s, "\n");
1366         if(to_eventlog)
1367                 GameLogEcho(s);
1368
1369         file = -1;
1370         if(to_file)
1371         {
1372                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1373                 if(file == -1)
1374                         to_file = FALSE;
1375                 else
1376                         fputs(file, strcat(s, "\n"));
1377         }
1378
1379         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1380         if(to_console)
1381                 print(s, "\n");
1382         if(to_eventlog)
1383                 GameLogEcho(s);
1384         if(to_file)
1385                 fputs(file, strcat(s, "\n"));
1386
1387         FOR_EACH_CLIENT(other)
1388         {
1389                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1390                 {
1391                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1392                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1393                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1394                                 s = strcat(s, ftos(other.team), ":");
1395                         else
1396                                 s = strcat(s, "spectator:");
1397
1398                         if(to_console)
1399                                 print(s, other.netname, "\n");
1400                         if(to_eventlog)
1401                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1402                         if(to_file)
1403                                 fputs(file, strcat(s, other.netname, "\n"));
1404                 }
1405         }
1406
1407         if(teamplay)
1408         {
1409                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1410                 if(to_console)
1411                         print(s, "\n");
1412                 if(to_eventlog)
1413                         GameLogEcho(s);
1414                 if(to_file)
1415                         fputs(file, strcat(s, "\n"));
1416
1417                 for(i = 1; i < 16; ++i)
1418                 {
1419                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1420                         s = strcat(s, ":", ftos(i));
1421                         if(to_console)
1422                                 print(s, "\n");
1423                         if(to_eventlog)
1424                                 GameLogEcho(s);
1425                         if(to_file)
1426                                 fputs(file, strcat(s, "\n"));
1427                 }
1428         }
1429
1430         if(to_console)
1431                 print(":end\n");
1432         if(to_eventlog)
1433                 GameLogEcho(":end");
1434         if(to_file)
1435         {
1436                 fputs(file, ":end\n");
1437                 fclose(file);
1438         }
1439 }
1440
1441 void FixIntermissionClient(entity e)
1442 {
1443         string s;
1444         if(!e.autoscreenshot) // initial call
1445         {
1446                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1447                 e.health = -2342;
1448                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1449                 e.solid = SOLID_NOT;
1450                 e.movetype = MOVETYPE_NONE;
1451                 e.takedamage = DAMAGE_NO;
1452                 if(e.weaponentity)
1453                 {
1454                         e.weaponentity.effects = EF_NODRAW;
1455                         if (e.weaponentity.weaponentity)
1456                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1457                 }
1458                 if(IS_REAL_CLIENT(e))
1459                 {
1460                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1461                         s = autocvar_sv_intermission_cdtrack;
1462                         if(s != "")
1463                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1464                         msg_entity = e;
1465                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1466                 }
1467         }
1468 }
1469
1470 /*
1471 go to the next level for deathmatch
1472 only called if a time or frag limit has expired
1473 */
1474 void NextLevel()
1475 {
1476         gameover = TRUE;
1477
1478         intermission_running = 1;
1479
1480 // enforce a wait time before allowing changelevel
1481         if(player_count > 0)
1482                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1483         else
1484                 intermission_exittime = -1;
1485
1486         /*
1487         WriteByte (MSG_ALL, SVC_CDTRACK);
1488         WriteByte (MSG_ALL, 3);
1489         WriteByte (MSG_ALL, 3);
1490         // done in FixIntermission
1491         */
1492
1493         //pos = FindIntermission ();
1494
1495         VoteReset();
1496
1497         DumpStats(TRUE);
1498
1499         // send statistics
1500         PlayerStats_GameReport(TRUE);
1501         WeaponStats_Shutdown();
1502
1503         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1504
1505         if(autocvar_sv_eventlog)
1506                 GameLogEcho(":gameover");
1507
1508         GameLogClose();
1509
1510         FOR_EACH_PLAYER(other) {
1511                 FixIntermissionClient(other);
1512                 if(other.winning)
1513                         bprint(other.netname, " ^7wins.\n");
1514         }
1515
1516         if(autocvar_g_campaign)
1517                 CampaignPreIntermission();
1518
1519         MUTATOR_CALLHOOK(MatchEnd);
1520
1521         localcmd("\nsv_hook_gameend\n");
1522 }
1523
1524 /*
1525 ============
1526 CheckRules_Player
1527
1528 Exit deathmatch games upon conditions
1529 ============
1530 */
1531 void CheckRules_Player()
1532 {
1533         if (gameover)   // someone else quit the game already
1534                 return;
1535
1536         if(self.deadflag == DEAD_NO)
1537                 self.play_time += frametime;
1538
1539         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1540         //   (div0: and that in CheckRules_World please)
1541 }
1542
1543 float checkrules_equality;
1544 float checkrules_suddendeathwarning;
1545 float checkrules_suddendeathend;
1546 float checkrules_overtimesadded; //how many overtimes have been already added
1547
1548 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1549 const float WINNING_YES = 1; // winner found
1550 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1551 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1552
1553 float InitiateSuddenDeath()
1554 {
1555         // Check first whether normal overtimes could be added before initiating suddendeath mode
1556         // - for this timelimit_overtime needs to be >0 of course
1557         // - also check the winning condition calculated in the previous frame and only add normal overtime
1558         //   again, if at the point at which timelimit would be extended again, still no winner was found
1559         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1560         {
1561                 return 1; // need to call InitiateOvertime later
1562         }
1563         else
1564         {
1565                 if(!checkrules_suddendeathend)
1566                 {
1567                         if(autocvar_g_campaign)
1568                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1569                         else
1570                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1571                         if(g_race && !g_race_qualifying)
1572                                 race_StartCompleting();
1573                 }
1574                 return 0;
1575         }
1576 }
1577
1578 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1579 {
1580         ++checkrules_overtimesadded;
1581         //add one more overtime by simply extending the timelimit
1582         float tl;
1583         tl = autocvar_timelimit;
1584         tl += autocvar_timelimit_overtime;
1585         cvar_set("timelimit", ftos(tl));
1586
1587         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1588 }
1589
1590 float GetWinningCode(float fraglimitreached, float equality)
1591 {
1592         if(autocvar_g_campaign == 1)
1593                 if(fraglimitreached)
1594                         return WINNING_YES;
1595                 else
1596                         return WINNING_NO;
1597
1598         else
1599                 if(equality)
1600                         if(fraglimitreached)
1601                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1602                         else
1603                                 return WINNING_NEVER;
1604                 else
1605                         if(fraglimitreached)
1606                                 return WINNING_YES;
1607                         else
1608                                 return WINNING_NO;
1609 }
1610
1611 // set the .winning flag for exactly those players with a given field value
1612 void SetWinners(.float field, float value)
1613 {
1614         entity head;
1615         FOR_EACH_PLAYER(head)
1616                 head.winning = (head.field == value);
1617 }
1618
1619 // set the .winning flag for those players with a given field value
1620 void AddWinners(.float field, float value)
1621 {
1622         entity head;
1623         FOR_EACH_PLAYER(head)
1624                 if(head.field == value)
1625                         head.winning = 1;
1626 }
1627
1628 // clear the .winning flags
1629 void ClearWinners(void)
1630 {
1631         entity head;
1632         FOR_EACH_PLAYER(head)
1633                 head.winning = 0;
1634 }
1635
1636 // Onslaught winning condition:
1637 // game terminates if only one team has a working generator (or none)
1638 float WinningCondition_Onslaught()
1639 {
1640         entity head;
1641         float t1, t2, t3, t4;
1642
1643         WinningConditionHelper(); // set worldstatus
1644
1645         if(warmup_stage)
1646                 return WINNING_NO;
1647
1648         // first check if the game has ended
1649         t1 = t2 = t3 = t4 = 0;
1650         head = find(world, classname, "onslaught_generator");
1651         while (head)
1652         {
1653                 if (head.health > 0)
1654                 {
1655                         if (head.team == NUM_TEAM_1) t1 = 1;
1656                         if (head.team == NUM_TEAM_2) t2 = 1;
1657                         if (head.team == NUM_TEAM_3) t3 = 1;
1658                         if (head.team == NUM_TEAM_4) t4 = 1;
1659                 }
1660                 head = find(head, classname, "onslaught_generator");
1661         }
1662         if (t1 + t2 + t3 + t4 < 2)
1663         {
1664                 // game over, only one team remains (or none)
1665                 ClearWinners();
1666                 if (t1) SetWinners(team, NUM_TEAM_1);
1667                 if (t2) SetWinners(team, NUM_TEAM_2);
1668                 if (t3) SetWinners(team, NUM_TEAM_3);
1669                 if (t4) SetWinners(team, NUM_TEAM_4);
1670                 dprint("Have a winner, ending game.\n");
1671                 return WINNING_YES;
1672         }
1673
1674         // Two or more teams remain
1675         return WINNING_NO;
1676 }
1677
1678 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1679 // they win. Otherwise the defending team wins once the timelimit passes.
1680 void assault_new_round();
1681 float WinningCondition_Assault()
1682 {
1683         float status;
1684
1685         WinningConditionHelper(); // set worldstatus
1686
1687         status = WINNING_NO;
1688         // as the timelimit has not yet passed just assume the defending team will win
1689         if(assault_attacker_team == NUM_TEAM_1)
1690         {
1691                 SetWinners(team, NUM_TEAM_2);
1692         }
1693         else
1694         {
1695                 SetWinners(team, NUM_TEAM_1);
1696         }
1697
1698         entity ent;
1699         ent = find(world, classname, "target_assault_roundend");
1700         if(ent)
1701         {
1702                 if(ent.winning) // round end has been triggered by attacking team
1703                 {
1704                         bprint("ASSAULT: round completed...\n");
1705                         SetWinners(team, assault_attacker_team);
1706
1707                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1708
1709                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1710                         {
1711                                 status = WINNING_YES;
1712                         }
1713                         else
1714                         {
1715                                 entity oldself;
1716                                 oldself = self;
1717                                 self = ent;
1718                                 assault_new_round();
1719                                 self = oldself;
1720                         }
1721                 }
1722         }
1723
1724         return status;
1725 }
1726
1727 // LMS winning condition: game terminates if and only if there's at most one
1728 // one player who's living lives. Top two scores being equal cancels the time
1729 // limit.
1730 float WinningCondition_LMS()
1731 {
1732         entity head, head2;
1733         float have_player;
1734         float have_players;
1735         float l;
1736
1737         have_player = FALSE;
1738         have_players = FALSE;
1739         l = LMS_NewPlayerLives();
1740
1741         head = find(world, classname, "player");
1742         if(head)
1743                 have_player = TRUE;
1744         head2 = find(head, classname, "player");
1745         if(head2)
1746                 have_players = TRUE;
1747
1748         if(have_player)
1749         {
1750                 // we have at least one player
1751                 if(have_players)
1752                 {
1753                         // two or more active players - continue with the game
1754                 }
1755                 else
1756                 {
1757                         // exactly one player?
1758
1759                         ClearWinners();
1760                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1761
1762                         if(l)
1763                         {
1764                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1765                                 return WINNING_NO;
1766                         }
1767                         else
1768                         {
1769                                 // a winner!
1770                                 // and assign him his first place
1771                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1772                                 return WINNING_YES;
1773                         }
1774                 }
1775         }
1776         else
1777         {
1778                 // nobody is playing at all...
1779                 if(l)
1780                 {
1781                         // wait for players...
1782                 }
1783                 else
1784                 {
1785                         // SNAFU (maybe a draw game?)
1786                         ClearWinners();
1787                         dprint("No players, ending game.\n");
1788                         return WINNING_YES;
1789                 }
1790         }
1791
1792         // When we get here, we have at least two players who are actually LIVING,
1793         // now check if the top two players have equal score.
1794         WinningConditionHelper();
1795
1796         ClearWinners();
1797         if(WinningConditionHelper_winner)
1798                 WinningConditionHelper_winner.winning = TRUE;
1799         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1800                 return WINNING_NEVER;
1801
1802         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1803         return WINNING_NO;
1804 }
1805
1806 void ShuffleMaplist()
1807 {
1808         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1809 }
1810
1811 float leaderfrags;
1812 float WinningCondition_Scores(float limit, float leadlimit)
1813 {
1814         float limitreached;
1815
1816         // TODO make everything use THIS winning condition (except LMS)
1817         WinningConditionHelper();
1818
1819         if(teamplay)
1820         {
1821                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1822                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1823                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1824                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1825         }
1826
1827         ClearWinners();
1828         if(WinningConditionHelper_winner)
1829                 WinningConditionHelper_winner.winning = 1;
1830         if(WinningConditionHelper_winnerteam >= 0)
1831                 SetWinners(team, WinningConditionHelper_winnerteam);
1832
1833         if(WinningConditionHelper_lowerisbetter)
1834         {
1835                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1836                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1837                 limit = -limit;
1838         }
1839
1840         if(WinningConditionHelper_zeroisworst)
1841                 leadlimit = 0; // not supported in this mode
1842
1843         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1844         // these modes always score in increments of 1, thus this makes sense
1845         {
1846                 if(leaderfrags != WinningConditionHelper_topscore)
1847                 {
1848                         leaderfrags = WinningConditionHelper_topscore;
1849
1850                         if (limit)
1851                         if (leaderfrags == limit - 1)
1852                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1853                         else if (leaderfrags == limit - 2)
1854                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1855                         else if (leaderfrags == limit - 3)
1856                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1857                 }
1858         }
1859
1860         limitreached = FALSE;
1861         if(limit)
1862                 if(WinningConditionHelper_topscore >= limit)
1863                         limitreached = TRUE;
1864         if(leadlimit)
1865         {
1866                 float leadlimitreached;
1867                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1868                 if(autocvar_leadlimit_and_fraglimit)
1869                         limitreached = (limitreached && leadlimitreached);
1870                 else
1871                         limitreached = (limitreached || leadlimitreached);
1872         }
1873
1874         if(limit)
1875                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1876
1877         return GetWinningCode(
1878                 WinningConditionHelper_topscore && limitreached,
1879                 WinningConditionHelper_equality
1880         );
1881 }
1882
1883 float WinningCondition_Race(float fraglimit)
1884 {
1885         float wc;
1886         entity p;
1887         float n, c;
1888
1889         n = 0;
1890         c = 0;
1891         FOR_EACH_PLAYER(p)
1892         {
1893                 ++n;
1894                 if(p.race_completed)
1895                         ++c;
1896         }
1897         if(n && (n == c))
1898                 return WINNING_YES;
1899         wc = WinningCondition_Scores(fraglimit, 0);
1900
1901         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1902         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1903         // do NOT support equality when the laps are all raced!
1904                 return WINNING_STARTSUDDENDEATHOVERTIME;
1905         else
1906                 return WINNING_NEVER;
1907 }
1908
1909 float WinningCondition_QualifyingThenRace(float limit)
1910 {
1911         float wc;
1912         wc = WinningCondition_Scores(limit, 0);
1913
1914         // NEVER initiate overtime
1915         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1916         {
1917                 return WINNING_YES;
1918         }
1919
1920         return wc;
1921 }
1922
1923 float WinningCondition_RanOutOfSpawns()
1924 {
1925         entity head;
1926
1927         if(have_team_spawns <= 0)
1928                 return WINNING_NO;
1929
1930         if(autocvar_g_spawn_useallspawns <= 0)
1931                 return WINNING_NO;
1932
1933         if(!some_spawn_has_been_used)
1934                 return WINNING_NO;
1935
1936         team1_score = team2_score = team3_score = team4_score = 0;
1937
1938         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1939         {
1940                 if(head.team == NUM_TEAM_1)
1941                         team1_score = 1;
1942                 else if(head.team == NUM_TEAM_2)
1943                         team2_score = 1;
1944                 else if(head.team == NUM_TEAM_3)
1945                         team3_score = 1;
1946                 else if(head.team == NUM_TEAM_4)
1947                         team4_score = 1;
1948         }
1949
1950         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1951         {
1952                 if(head.team == NUM_TEAM_1)
1953                         team1_score = 1;
1954                 else if(head.team == NUM_TEAM_2)
1955                         team2_score = 1;
1956                 else if(head.team == NUM_TEAM_3)
1957                         team3_score = 1;
1958                 else if(head.team == NUM_TEAM_4)
1959                         team4_score = 1;
1960         }
1961
1962         ClearWinners();
1963         if(team1_score + team2_score + team3_score + team4_score == 0)
1964         {
1965                 checkrules_equality = TRUE;
1966                 return WINNING_YES;
1967         }
1968         else if(team1_score + team2_score + team3_score + team4_score == 1)
1969         {
1970                 float t, i;
1971                 if(team1_score)
1972                         t = NUM_TEAM_1;
1973                 else if(team2_score)
1974                         t = NUM_TEAM_2;
1975                 else if(team3_score)
1976                         t = NUM_TEAM_3;
1977                 else // if(team4_score)
1978                         t = NUM_TEAM_4;
1979                 CheckAllowedTeams(world);
1980                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1981                 {
1982                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1983                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1984                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1985                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1986                 }
1987
1988                 AddWinners(team, t);
1989                 return WINNING_YES;
1990         }
1991         else
1992                 return WINNING_NO;
1993 }
1994
1995 /*
1996 ============
1997 CheckRules_World
1998
1999 Exit deathmatch games upon conditions
2000 ============
2001 */
2002 void ReadyRestart();
2003 void CheckRules_World()
2004 {
2005         float timelimit;
2006         float fraglimit;
2007         float leadlimit;
2008
2009         VoteThink();
2010         MapVote_Think();
2011
2012         SetDefaultAlpha();
2013
2014         if (gameover)   // someone else quit the game already
2015         {
2016                 if(player_count == 0) // Nobody there? Then let's go to the next map
2017                         MapVote_Start();
2018                         // this will actually check the player count in the next frame
2019                         // again, but this shouldn't hurt
2020                 return;
2021         }
2022
2023         timelimit = autocvar_timelimit * 60;
2024         fraglimit = autocvar_fraglimit;
2025         leadlimit = autocvar_leadlimit;
2026
2027         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2028         {
2029                 if(timelimit > 0)
2030                         timelimit = 0; // timelimit is not made for warmup
2031                 if(fraglimit > 0)
2032                         fraglimit = 0; // no fraglimit for now
2033                 leadlimit = 0; // no leadlimit for now
2034         }
2035
2036         if(timelimit > 0)
2037         {
2038                 timelimit += game_starttime;
2039         }
2040         else if (timelimit < 0)
2041         {
2042                 // endmatch
2043                 NextLevel();
2044                 return;
2045         }
2046
2047         if(g_onslaught)
2048                 timelimit = 0; // ONS has its own overtime rule
2049
2050         float wantovertime;
2051         wantovertime = 0;
2052
2053         if(timelimit > game_starttime)
2054                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2055         else
2056                 game_completion_ratio = 0;
2057
2058         if(checkrules_suddendeathend)
2059         {
2060                 if(!checkrules_suddendeathwarning)
2061                 {
2062                         checkrules_suddendeathwarning = TRUE;
2063                         if(g_race && !g_race_qualifying)
2064                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2065                         else
2066                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2067                 }
2068         }
2069         else
2070         {
2071                 if (timelimit && time >= timelimit)
2072                 {
2073                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2074                         {
2075                                 float totalplayers;
2076                                 float playerswithlaps;
2077                                 float readyplayers;
2078                                 entity head;
2079                                 totalplayers = playerswithlaps = readyplayers = 0;
2080                                 FOR_EACH_PLAYER(head)
2081                                 {
2082                                         ++totalplayers;
2083                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2084                                                 ++playerswithlaps;
2085                                         if(head.ready)
2086                                                 ++readyplayers;
2087                                 }
2088
2089                                 // at least 2 of the players have completed a lap: start the RACE
2090                                 // otherwise, the players should end the qualifying on their own
2091                                 if(readyplayers || playerswithlaps >= 2)
2092                                 {
2093                                         checkrules_suddendeathend = 0;
2094                                         ReadyRestart(); // go to race
2095                                         return;
2096                                 }
2097                                 else
2098                                         wantovertime |= InitiateSuddenDeath();
2099                         }
2100                         else
2101                                 wantovertime |= InitiateSuddenDeath();
2102                 }
2103         }
2104
2105         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2106         {
2107                 NextLevel();
2108                 return;
2109         }
2110
2111         float checkrules_status;
2112         checkrules_status = WinningCondition_RanOutOfSpawns();
2113         if(checkrules_status == WINNING_YES)
2114         {
2115                 bprint("Hey! Someone ran out of spawns!\n");
2116         }
2117         else if(g_race && !g_race_qualifying && timelimit >= 0)
2118         {
2119                 checkrules_status = WinningCondition_Race(fraglimit);
2120                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2121         }
2122         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2123         {
2124                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2125                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2126         }
2127         else if(g_assault)
2128         {
2129                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2130         }
2131         else if(g_lms)
2132         {
2133                 checkrules_status = WinningCondition_LMS();
2134         }
2135         else if (g_onslaught)
2136         {
2137                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2138         }
2139         else
2140         {
2141                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2142                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2143         }
2144
2145         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2146         {
2147                 checkrules_status = WINNING_NEVER;
2148                 checkrules_overtimesadded = -1;
2149                 wantovertime |= InitiateSuddenDeath();
2150         }
2151
2152         if(checkrules_status == WINNING_NEVER)
2153                 // equality cases! Nobody wins if the overtime ends in a draw.
2154                 ClearWinners();
2155
2156         if(wantovertime)
2157         {
2158                 if(checkrules_status == WINNING_NEVER)
2159                         InitiateOvertime();
2160                 else
2161                         checkrules_status = WINNING_YES;
2162         }
2163
2164         if(checkrules_suddendeathend)
2165                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2166                         checkrules_status = WINNING_YES;
2167
2168         if(checkrules_status == WINNING_YES)
2169         {
2170                 //print("WINNING\n");
2171                 NextLevel();
2172         }
2173 }
2174
2175 string GotoMap(string m)
2176 {
2177         m = GameTypeVote_MapInfo_FixName(m);
2178         if (!m)
2179                 return "The map you suggested is not available on this server.";
2180         if (!autocvar_sv_vote_gametype)
2181         if(!MapInfo_CheckMap(m))
2182                 return "The map you suggested does not support the current game mode.";
2183         cvar_set("nextmap", m);
2184         cvar_set("timelimit", "-1");
2185         if(mapvote_initialized || alreadychangedlevel)
2186         {
2187                 if(DoNextMapOverride(0))
2188                         return "Map switch initiated.";
2189                 else
2190                         return "Hm... no. For some reason I like THIS map more.";
2191         }
2192         else
2193                 return "Map switch will happen after scoreboard.";
2194 }
2195
2196
2197 void EndFrame()
2198 {
2199         anticheat_endframe();
2200
2201         float altime;
2202         FOR_EACH_REALCLIENT(self)
2203         {
2204                 self.damage_dealt_total = 0;
2205
2206                 if(IS_SPEC(self))
2207                 {
2208                         if(self.enemy.typehitsound)
2209                                 self.typehit_time = time;
2210                         else if(self.enemy.damage_dealt)
2211                                 self.damage_dealt_total = ceil(self.enemy.damage_dealt);
2212                 }
2213                 else
2214                 {
2215                         if(self.typehitsound)
2216                                 self.typehit_time = time;
2217                         else if(self.damage_dealt)
2218                                 self.damage_dealt_total = ceil(self.damage_dealt);
2219                 }
2220         }
2221         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2222         // add 1 frametime because after this, engine SV_Physics
2223         // increases time by a frametime and then networks the frame
2224         // add another frametime because client shows everything with
2225         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2226         // needed!
2227         FOR_EACH_CLIENT(self)
2228         {
2229                 self.typehitsound = FALSE;
2230                 self.damage_dealt = 0;
2231                 antilag_record(self, altime);
2232         }
2233         FOR_EACH_MONSTER(self)
2234                 antilag_record(self, altime);
2235 }
2236
2237
2238 /*
2239  * RedirectionThink:
2240  * returns TRUE if redirecting
2241  */
2242 float redirection_timeout;
2243 float redirection_nextthink;
2244 float RedirectionThink()
2245 {
2246         float clients_found;
2247
2248         if(redirection_target == "")
2249                 return FALSE;
2250
2251         if(!redirection_timeout)
2252         {
2253                 cvar_set("sv_public", "-2");
2254                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2255                 if(redirection_target == "self")
2256                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2257                 else
2258                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2259         }
2260
2261         if(time < redirection_nextthink)
2262                 return TRUE;
2263
2264         redirection_nextthink = time + 1;
2265
2266         clients_found = 0;
2267         FOR_EACH_REALCLIENT(self)
2268         {
2269                 // TODO add timer
2270                 print("Redirecting: sending connect command to ", self.netname, "\n");
2271                 if(redirection_target == "self")
2272                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2273                 else
2274                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2275                 ++clients_found;
2276         }
2277
2278         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2279
2280         if(time > redirection_timeout || clients_found == 0)
2281                 localcmd("\nwait; wait; wait; quit\n");
2282
2283         return TRUE;
2284 }
2285
2286 void TargetMusic_RestoreGame();
2287 void RestoreGame()
2288 {
2289         // Loaded from a save game
2290         // some things then break, so let's work around them...
2291
2292         // Progs DB (capture records)
2293         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2294
2295         // Mapinfo
2296         MapInfo_Shutdown();
2297         MapInfo_Enumerate();
2298         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2299         WeaponStats_Init();
2300
2301         TargetMusic_RestoreGame();
2302 }
2303
2304 void Shutdown()
2305 {
2306         gameover = 2;
2307
2308         if(world_initialized > 0)
2309         {
2310                 world_initialized = 0;
2311                 print("Saving persistent data...\n");
2312                 Ban_SaveBans();
2313
2314                 // playerstats with unfinished match
2315                 PlayerStats_GameReport(FALSE);
2316
2317                 if(!cheatcount_total)
2318                 {
2319                         if(autocvar_sv_db_saveasdump)
2320                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2321                         else
2322                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2323                 }
2324                 if(autocvar_developer)
2325                 {
2326                         if(autocvar_sv_db_saveasdump)
2327                                 db_dump(TemporaryDB, "server-temp.db");
2328                         else
2329                                 db_save(TemporaryDB, "server-temp.db");
2330                 }
2331                 CheatShutdown(); // must be after cheatcount check
2332                 db_close(ServerProgsDB);
2333                 db_close(TemporaryDB);
2334                 print("done!\n");
2335                 // tell the bot system the game is ending now
2336                 bot_endgame();
2337
2338                 WeaponStats_Shutdown();
2339                 MapInfo_Shutdown();
2340         }
2341         else if(world_initialized == 0)
2342         {
2343                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2344         }
2345 }