qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431                 BADCVAR("g_grappling_hook");
 432                 BADCVAR("g_jetpack");
 433
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s, col;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         entity head;
 585         head = nextent(world);
 586         maxclients = 0;
 587         while(head)
 588         {
 589                 ++maxclients;
 590                 head = nextent(head);
 591         }
 592
 593         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 594
 595         // needs to be done so early because of the constants they create
 596         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WEPSET_ADDSTAT();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // g_movementspeed hack
 800         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 801         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 802         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 803         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 804
 805         // secrets
 806         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 807         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 808
 809         // misc
 810         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 811
 812         next_pingtime = time + 5;
 813
 814         detect_maptype();
 815
 816         // set up information replies for clients and server to use
 817         lsmaps_reply = "^7Maps available: ";
 818         lsnewmaps_reply = "^7Maps without a record set: ";
 819         for(i = 0, j = 0; i < MapInfo_count; ++i)
 820         {
 821                 if(MapInfo_Get_ByID(i))
 822                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 823                         {
 824                                 if(mod(i, 2))
 825                                         col = "^2";
 826                                 else
 827                                         col = "^3";
 828
 829                                 ++j;
 830
 831                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 832
 833                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 834                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 835                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 836                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 837                         }
 838         }
 839
 840         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 841         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 842
 843         maplist_reply = "^7Maps in list: ";
 844         n = tokenize_console(autocvar_g_maplist);
 845         for(i = 0, j = 0; i < n; ++i)
 846         {
 847                 if(MapInfo_CheckMap(argv(i)))
 848                 {
 849                         if(mod(j, 2))
 850                                 col = "^2";
 851                         else
 852                                 col = "^3";
 853                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 854                         ++j;
 855                 }
 856         }
 857         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 858         MapInfo_ClearTemps();
 859
 860         for(i = 0; i < 10; ++i)
 861         {
 862                 s = getrecords(i);
 863                 if (s)
 864                         records_reply[i] = strzone(s);
 865         }
 866
 867         ladder_reply = strzone(getladder());
 868
 869         rankings_reply = strzone(getrankings());
 870
 871         // begin other init
 872         ClientInit_Spawn();
 873         RandomSeed_Spawn();
 874         PingPLReport_Spawn();
 875
 876         CheatInit();
 877
 878         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 879
 880         // fill sv_curl_serverpackages from .serverpackage files
 881         if(autocvar_sv_curl_serverpackages_auto)
 882         {
 883                 s = "";
 884                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 885                 for(i = 0; i < n; ++i)
 886                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 887                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 888                                 s = strcat(s, " ", argv(i));
 889                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 890                 if(fd >= 0)
 891                 {
 892                         j = search_getsize(fd);
 893                         for(i = 0; i < j; ++i)
 894                                 s = strcat(s, " ", search_getfilename(fd, i));
 895                         search_end(fd);
 896                 }
 897                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 898                 if(fd >= 0)
 899                 {
 900                         j = search_getsize(fd);
 901                         for(i = 0; i < j; ++i)
 902                                 s = strcat(s, " ", search_getfilename(fd, i));
 903                         search_end(fd);
 904                 }
 905                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 906         }
 907
 908         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 909         modname = "Xonotic";
 910         // physics/balance/config changes that count as mod
 911         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 912                 modname = cvar_string("g_mod_physics");
 913         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 914                 modname = cvar_string("g_mod_balance");
 915         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 916                 modname = cvar_string("g_mod_config");
 917         // extra mutators that deserve to count as mod
 918         MUTATOR_CALLHOOK(SetModname);
 919
 920         // save it for later
 921         modname = strzone(modname);
 922
 923         WinningConditionHelper(); // set worldstatus
 924
 925         world_initialized = 1;
 926 }
 927
 928 void spawnfunc_light (void)
 929 {
 930         //makestatic (self); // Who the f___ did that?
 931         remove(self);
 932 }
 933
 934 string GetGametype()
 935 {
 936         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 937 }
 938
 939 string getmapname_stored;
 940 string GetMapname()
 941 {
 942         return mapname;
 943 }
 944
 945 float Map_Count, Map_Current;
 946 string Map_Current_Name;
 947
 948 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 949 float GetMaplistPosition()
 950 {
 951         float pos, idx;
 952         string map;
 953
 954         map = GetMapname();
 955         idx = autocvar_g_maplist_index;
 956
 957         if(idx >= 0)
 958                 if(idx < Map_Count)
 959                         if(map == argv(idx))
 960                                 return idx;
 961
 962         for(pos = 0; pos < Map_Count; ++pos)
 963                 if(map == argv(pos))
 964                         return pos;
 965
 966         // resume normal maplist rotation if current map is not in g_maplist
 967         return idx;
 968 }
 969
 970 float MapHasRightSize(string map)
 971 {
 972         float fh;
 973         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 974         if(autocvar_g_maplist_check_waypoints)
 975         {
 976                 dprint("checkwp "); dprint(map);
 977                 if(!fexists(strcat("maps/", map, ".waypoints")))
 978                 {
 979                         dprint(": no waypoints\n");
 980                         return FALSE;
 981                 }
 982                 dprint(": has waypoints\n");
 983         }
 984
 985         // open map size restriction file
 986         dprint("opensize "); dprint(map);
 987         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 988         if(fh >= 0)
 989         {
 990                 float mapmin, mapmax;
 991                 dprint(": ok, ");
 992                 mapmin = stof(fgets(fh));
 993                 mapmax = stof(fgets(fh));
 994                 fclose(fh);
 995                 if(player_count < mapmin)
 996                 {
 997                         dprint("not enough\n");
 998                         return FALSE;
 999                 }
1000                 if(player_count > mapmax)
1001                 {
1002                         dprint("too many\n");
1003                         return FALSE;
1004                 }
1005                 dprint("right size\n");
1006                 return TRUE;
1007         }
1008         dprint(": not found\n");
1009         return TRUE;
1010 }
1011
1012 string Map_Filename(float position)
1013 {
1014         return strcat("maps/", argv(position), ".bsp");
1015 }
1016
1017 string strwords(string s, float w)
1018 {
1019         float endpos;
1020         for(endpos = 0; w && endpos >= 0; --w)
1021                 endpos = strstrofs(s, " ", endpos + 1);
1022         if(endpos < 0)
1023                 return s;
1024         else
1025                 return substring(s, 0, endpos);
1026 }
1027
1028 float strhasword(string s, string w)
1029 {
1030         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1031 }
1032
1033 void Map_MarkAsRecent(string m)
1034 {
1035         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1036 }
1037
1038 float Map_IsRecent(string m)
1039 {
1040         return strhasword(autocvar_g_maplist_mostrecent, m);
1041 }
1042
1043 float Map_Check(float position, float pass)
1044 {
1045         string filename;
1046         string map_next;
1047         map_next = argv(position);
1048         if(pass <= 1)
1049         {
1050                 if(Map_IsRecent(map_next))
1051                         return 0;
1052         }
1053         filename = Map_Filename(position);
1054         if(MapInfo_CheckMap(map_next))
1055         {
1056                 if(pass == 2)
1057                         return 1;
1058                 if(MapHasRightSize(map_next))
1059                         return 1;
1060                 return 0;
1061         }
1062         else
1063                 dprint( "Couldn't select '", filename, "'..\n" );
1064
1065         return 0;
1066 }
1067
1068 void Map_Goto_SetStr(string nextmapname)
1069 {
1070         if(getmapname_stored != "")
1071                 strunzone(getmapname_stored);
1072         if(nextmapname == "")
1073                 getmapname_stored = "";
1074         else
1075                 getmapname_stored = strzone(nextmapname);
1076 }
1077
1078 void Map_Goto_SetFloat(float position)
1079 {
1080         cvar_set("g_maplist_index", ftos(position));
1081         Map_Goto_SetStr(argv(position));
1082 }
1083
1084 void Map_Goto(float reinit)
1085 {
1086         MapInfo_LoadMap(getmapname_stored, reinit);
1087 }
1088
1089 // return codes of map selectors:
1090 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1091 //   -2 = permanent failure
1092 float() MaplistMethod_Iterate = // usual method
1093 {
1094         float pass, i;
1095
1096         dprint("Trying MaplistMethod_Iterate\n");
1097
1098         for(pass = 1; pass <= 2; ++pass)
1099         {
1100                 for(i = 1; i < Map_Count; ++i)
1101                 {
1102                         float mapindex;
1103                         mapindex = mod(i + Map_Current, Map_Count);
1104                         if(Map_Check(mapindex, pass))
1105                                 return mapindex;
1106                 }
1107         }
1108         return -1;
1109 }
1110
1111 float() MaplistMethod_Repeat = // fallback method
1112 {
1113         dprint("Trying MaplistMethod_Repeat\n");
1114
1115         if(Map_Check(Map_Current, 2))
1116                 return Map_Current;
1117         return -2;
1118 }
1119
1120 float() MaplistMethod_Random = // random map selection
1121 {
1122         float i, imax;
1123
1124         dprint("Trying MaplistMethod_Random\n");
1125
1126         imax = 42;
1127
1128         for(i = 0; i <= imax; ++i)
1129         {
1130                 float mapindex;
1131                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1132                 if(Map_Check(mapindex, 1))
1133                         return mapindex;
1134         }
1135         return -1;
1136 }
1137
1138 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1139 // the exponent sets a bias on the map selection:
1140 // the higher the exponent, the less likely "shortly repeated" same maps are
1141 {
1142         float i, j, imax, insertpos;
1143
1144         dprint("Trying MaplistMethod_Shuffle\n");
1145
1146         imax = 42;
1147
1148         for(i = 0; i <= imax; ++i)
1149         {
1150                 string newlist;
1151
1152                 // now reinsert this at another position
1153                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1154                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1155                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1156                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1157
1158                 // insert the current map there
1159                 newlist = "";
1160                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1161                         newlist = strcat(newlist, " ", argv(j));
1162                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1163                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1164                         newlist = strcat(newlist, " ", argv(j));
1165                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1166                 cvar_set("g_maplist", newlist);
1167                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168
1169                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1170                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1171                 if(Map_Check(Map_Current, 1))
1172                         return Map_Current;
1173         }
1174         return -1;
1175 }
1176
1177 void Maplist_Init()
1178 {
1179         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180         float i;
1181         for (i = 0; i < Map_Count; ++i)
1182                 if (Map_Check(i, 2))
1183                         break;
1184         if (i == Map_Count)
1185         {
1186                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1187                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1188                 if(autocvar_g_maplist_shuffle)
1189                         ShuffleMaplist();
1190                 localcmd("\nmenu_cmd sync\n");
1191                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         }
1193         if(Map_Count == 0)
1194                 error("empty maplist, cannot select a new map");
1195         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1196
1197         if(Map_Current_Name)
1198                 strunzone(Map_Current_Name);
1199         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1200         // this may or may not be correct, but who cares, in the worst case a map
1201         // isn't chosen in the first pass that should have been
1202 }
1203
1204 string GetNextMap()
1205 {
1206         float nextMap;
1207
1208         Maplist_Init();
1209         nextMap = -1;
1210
1211         if(nextMap == -1)
1212                 if(autocvar_g_maplist_shuffle > 0)
1213                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1214
1215         if(nextMap == -1)
1216                 if(autocvar_g_maplist_selectrandom)
1217                         nextMap = MaplistMethod_Random();
1218
1219         if(nextMap == -1)
1220                 nextMap = MaplistMethod_Iterate();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Repeat();
1224
1225         if(nextMap >= 0)
1226         {
1227                 Map_Goto_SetFloat(nextMap);
1228                 return getmapname_stored;
1229         }
1230
1231         return "";
1232 }
1233
1234 float DoNextMapOverride(float reinit)
1235 {
1236         if(autocvar_g_campaign)
1237         {
1238                 CampaignPostIntermission();
1239                 alreadychangedlevel = TRUE;
1240                 return TRUE;
1241         }
1242         if(autocvar_quit_when_empty)
1243         {
1244                 if(player_count <= currentbots)
1245                 {
1246                         localcmd("quit\n");
1247                         alreadychangedlevel = TRUE;
1248                         return TRUE;
1249                 }
1250         }
1251         if(autocvar_quit_and_redirect != "")
1252         {
1253                 redirection_target = strzone(autocvar_quit_and_redirect);
1254                 alreadychangedlevel = TRUE;
1255                 return TRUE;
1256         }
1257         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1258         {
1259                 localcmd("restart\n");
1260                 alreadychangedlevel = TRUE;
1261                 return TRUE;
1262         }
1263         if(autocvar_nextmap != "")
1264                 if(MapInfo_CheckMap(autocvar_nextmap))
1265                 {
1266                         Map_Goto_SetStr(autocvar_nextmap);
1267                         Map_Goto(reinit);
1268                         alreadychangedlevel = TRUE;
1269                         return TRUE;
1270                 }
1271         if(!reinit && autocvar_lastlevel)
1272         {
1273                 cvar_settemp_restore();
1274                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1275                 alreadychangedlevel = TRUE;
1276                 return TRUE;
1277         }
1278         return FALSE;
1279 }
1280
1281 void GotoNextMap(float reinit)
1282 {
1283         //string nextmap;
1284         //float n, nummaps;
1285         //string s;
1286         if (alreadychangedlevel)
1287                 return;
1288         alreadychangedlevel = TRUE;
1289
1290         string nextMap;
1291
1292         nextMap = GetNextMap();
1293         if(nextMap == "")
1294                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1295 }
1296
1297
1298 /*
1299 ============
1300 IntermissionThink
1301
1302 When the player presses attack or jump, change to the next level
1303 ============
1304 */
1305 .float autoscreenshot;
1306 void() MapVote_Start;
1307 void() MapVote_Think;
1308 float mapvote_initialized;
1309 void IntermissionThink()
1310 {
1311         FixIntermissionClient(self);
1312
1313         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1314         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1315
1316         if( (server_screenshot || client_screenshot)
1317                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1318         {
1319                 self.autoscreenshot = -1;
1320                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1321                 return;
1322         }
1323
1324         if (time < intermission_exittime)
1325                 return;
1326
1327         if(!mapvote_initialized)
1328                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1329                         return;
1330
1331         MapVote_Start();
1332 }
1333
1334 /*
1335 ============
1336 FindIntermission
1337
1338 Returns the entity to view from
1339 ============
1340 */
1341 /*
1342 entity FindIntermission()
1343 {
1344         local   entity spot;
1345         local   float cyc;
1346
1347 // look for info_intermission first
1348         spot = find (world, classname, "info_intermission");
1349         if (spot)
1350         {       // pick a random one
1351                 cyc = random() * 4;
1352                 while (cyc > 1)
1353                 {
1354                         spot = find (spot, classname, "info_intermission");
1355                         if (!spot)
1356                                 spot = find (spot, classname, "info_intermission");
1357                         cyc = cyc - 1;
1358                 }
1359                 return spot;
1360         }
1361
1362 // then look for the start position
1363         spot = find (world, classname, "info_player_start");
1364         if (spot)
1365                 return spot;
1366
1367 // testinfo_player_start is only found in regioned levels
1368         spot = find (world, classname, "testplayerstart");
1369         if (spot)
1370                 return spot;
1371
1372 // then look for the start position
1373         spot = find (world, classname, "info_player_deathmatch");
1374         if (spot)
1375                 return spot;
1376
1377         //objerror ("FindIntermission: no spot");
1378         return world;
1379 }
1380 */
1381
1382 /*
1383 ===============================================================================
1384
1385 RULES
1386
1387 ===============================================================================
1388 */
1389
1390 void DumpStats(float final)
1391 {
1392         float file;
1393         string s;
1394         float to_console;
1395         float to_eventlog;
1396         float to_file;
1397         float i;
1398
1399         to_console = autocvar_sv_logscores_console;
1400         to_eventlog = autocvar_sv_eventlog;
1401         to_file = autocvar_sv_logscores_file;
1402
1403         if(!final)
1404         {
1405                 to_console = TRUE; // always print printstats replies
1406                 to_eventlog = FALSE; // but never print them to the event log
1407         }
1408
1409         if(to_eventlog)
1410                 if(autocvar_sv_eventlog_console)
1411                         to_console = FALSE; // otherwise we get the output twice
1412
1413         if(final)
1414                 s = ":scores:";
1415         else
1416                 s = ":status:";
1417         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1418
1419         if(to_console)
1420                 print(s, "\n");
1421         if(to_eventlog)
1422                 GameLogEcho(s);
1423
1424         file = -1;
1425         if(to_file)
1426         {
1427                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1428                 if(file == -1)
1429                         to_file = FALSE;
1430                 else
1431                         fputs(file, strcat(s, "\n"));
1432         }
1433
1434         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1435         if(to_console)
1436                 print(s, "\n");
1437         if(to_eventlog)
1438                 GameLogEcho(s);
1439         if(to_file)
1440                 fputs(file, strcat(s, "\n"));
1441
1442         FOR_EACH_CLIENT(other)
1443         {
1444                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1445                 {
1446                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1447                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1448                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1449                                 s = strcat(s, ftos(other.team), ":");
1450                         else
1451                                 s = strcat(s, "spectator:");
1452
1453                         if(to_console)
1454                                 print(s, other.netname, "\n");
1455                         if(to_eventlog)
1456                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1457                         if(to_file)
1458                                 fputs(file, strcat(s, other.netname, "\n"));
1459                 }
1460         }
1461
1462         if(teamplay)
1463         {
1464                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1465                 if(to_console)
1466                         print(s, "\n");
1467                 if(to_eventlog)
1468                         GameLogEcho(s);
1469                 if(to_file)
1470                         fputs(file, strcat(s, "\n"));
1471
1472                 for(i = 1; i < 16; ++i)
1473                 {
1474                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1475                         s = strcat(s, ":", ftos(i));
1476                         if(to_console)
1477                                 print(s, "\n");
1478                         if(to_eventlog)
1479                                 GameLogEcho(s);
1480                         if(to_file)
1481                                 fputs(file, strcat(s, "\n"));
1482                 }
1483         }
1484
1485         if(to_console)
1486                 print(":end\n");
1487         if(to_eventlog)
1488                 GameLogEcho(":end");
1489         if(to_file)
1490         {
1491                 fputs(file, ":end\n");
1492                 fclose(file);
1493         }
1494 }
1495
1496 void FixIntermissionClient(entity e)
1497 {
1498         string s;
1499         if(!e.autoscreenshot) // initial call
1500         {
1501                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1502                 e.health = -2342;
1503                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1504                 e.solid = SOLID_NOT;
1505                 e.movetype = MOVETYPE_NONE;
1506                 e.takedamage = DAMAGE_NO;
1507                 if(e.weaponentity)
1508                 {
1509                         e.weaponentity.effects = EF_NODRAW;
1510                         if (e.weaponentity.weaponentity)
1511                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1512                 }
1513                 if(IS_REAL_CLIENT(e))
1514                 {
1515                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1516                         s = autocvar_sv_intermission_cdtrack;
1517                         if(s != "")
1518                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1519                         msg_entity = e;
1520                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1521                 }
1522         }
1523 }
1524
1525 /*
1526 go to the next level for deathmatch
1527 only called if a time or frag limit has expired
1528 */
1529 void NextLevel()
1530 {
1531         gameover = TRUE;
1532
1533         intermission_running = 1;
1534
1535 // enforce a wait time before allowing changelevel
1536         if(player_count > 0)
1537                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1538         else
1539                 intermission_exittime = -1;
1540
1541         /*
1542         WriteByte (MSG_ALL, SVC_CDTRACK);
1543         WriteByte (MSG_ALL, 3);
1544         WriteByte (MSG_ALL, 3);
1545         // done in FixIntermission
1546         */
1547
1548         //pos = FindIntermission ();
1549
1550         VoteReset();
1551
1552         DumpStats(TRUE);
1553
1554         // send statistics
1555         entity e;
1556         PlayerStats_EndMatch(1);
1557         FOR_EACH_CLIENT(e)
1558                 PlayerStats_AddGlobalInfo(e);
1559         PlayerStats_Shutdown();
1560         WeaponStats_Shutdown();
1561
1562         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1563
1564         if(autocvar_sv_eventlog)
1565                 GameLogEcho(":gameover");
1566
1567         GameLogClose();
1568
1569         FOR_EACH_PLAYER(other) {
1570                 FixIntermissionClient(other);
1571                 if(other.winning)
1572                         bprint(other.netname, " ^7wins.\n");
1573         }
1574
1575         if(autocvar_g_campaign)
1576                 CampaignPreIntermission();
1577
1578         MUTATOR_CALLHOOK(MatchEnd);
1579
1580         localcmd("\nsv_hook_gameend\n");
1581 }
1582
1583 /*
1584 ============
1585 CheckRules_Player
1586
1587 Exit deathmatch games upon conditions
1588 ============
1589 */
1590 void CheckRules_Player()
1591 {
1592         if (gameover)   // someone else quit the game already
1593                 return;
1594
1595         if(self.deadflag == DEAD_NO)
1596                 self.play_time += frametime;
1597
1598         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1599         //   (div0: and that in CheckRules_World please)
1600 }
1601
1602 float checkrules_equality;
1603 float checkrules_suddendeathwarning;
1604 float checkrules_suddendeathend;
1605 float checkrules_overtimesadded; //how many overtimes have been already added
1606
1607 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1608 float WINNING_YES = 1; // winner found
1609 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1610 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1611
1612 float InitiateSuddenDeath()
1613 {
1614         // Check first whether normal overtimes could be added before initiating suddendeath mode
1615         // - for this timelimit_overtime needs to be >0 of course
1616         // - also check the winning condition calculated in the previous frame and only add normal overtime
1617         //   again, if at the point at which timelimit would be extended again, still no winner was found
1618         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1619         {
1620                 return 1; // need to call InitiateOvertime later
1621         }
1622         else
1623         {
1624                 if(!checkrules_suddendeathend)
1625                 {
1626                         if(autocvar_g_campaign)
1627                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1628                         else
1629                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1630                         if(g_race && !g_race_qualifying)
1631                                 race_StartCompleting();
1632                 }
1633                 return 0;
1634         }
1635 }
1636
1637 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1638 {
1639         ++checkrules_overtimesadded;
1640         //add one more overtime by simply extending the timelimit
1641         float tl;
1642         tl = autocvar_timelimit;
1643         tl += autocvar_timelimit_overtime;
1644         cvar_set("timelimit", ftos(tl));
1645
1646         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1647 }
1648
1649 float GetWinningCode(float fraglimitreached, float equality)
1650 {
1651         if(autocvar_g_campaign == 1)
1652                 if(fraglimitreached)
1653                         return WINNING_YES;
1654                 else
1655                         return WINNING_NO;
1656
1657         else
1658                 if(equality)
1659                         if(fraglimitreached)
1660                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1661                         else
1662                                 return WINNING_NEVER;
1663                 else
1664                         if(fraglimitreached)
1665                                 return WINNING_YES;
1666                         else
1667                                 return WINNING_NO;
1668 }
1669
1670 // set the .winning flag for exactly those players with a given field value
1671 void SetWinners(.float field, float value)
1672 {
1673         entity head;
1674         FOR_EACH_PLAYER(head)
1675                 head.winning = (head.field == value);
1676 }
1677
1678 // set the .winning flag for those players with a given field value
1679 void AddWinners(.float field, float value)
1680 {
1681         entity head;
1682         FOR_EACH_PLAYER(head)
1683                 if(head.field == value)
1684                         head.winning = 1;
1685 }
1686
1687 // clear the .winning flags
1688 void ClearWinners(void)
1689 {
1690         entity head;
1691         FOR_EACH_PLAYER(head)
1692                 head.winning = 0;
1693 }
1694
1695 // Onslaught winning condition:
1696 // game terminates if only one team has a working generator (or none)
1697 float WinningCondition_Onslaught()
1698 {
1699         entity head;
1700         float t1, t2, t3, t4;
1701
1702         WinningConditionHelper(); // set worldstatus
1703
1704         if(inWarmupStage)
1705                 return WINNING_NO;
1706
1707         // first check if the game has ended
1708         t1 = t2 = t3 = t4 = 0;
1709         head = find(world, classname, "onslaught_generator");
1710         while (head)
1711         {
1712                 if (head.health > 0)
1713                 {
1714                         if (head.team == NUM_TEAM_1) t1 = 1;
1715                         if (head.team == NUM_TEAM_2) t2 = 1;
1716                         if (head.team == NUM_TEAM_3) t3 = 1;
1717                         if (head.team == NUM_TEAM_4) t4 = 1;
1718                 }
1719                 head = find(head, classname, "onslaught_generator");
1720         }
1721         if (t1 + t2 + t3 + t4 < 2)
1722         {
1723                 // game over, only one team remains (or none)
1724                 ClearWinners();
1725                 if (t1) SetWinners(team, NUM_TEAM_1);
1726                 if (t2) SetWinners(team, NUM_TEAM_2);
1727                 if (t3) SetWinners(team, NUM_TEAM_3);
1728                 if (t4) SetWinners(team, NUM_TEAM_4);
1729                 dprint("Have a winner, ending game.\n");
1730                 return WINNING_YES;
1731         }
1732
1733         // Two or more teams remain
1734         return WINNING_NO;
1735 }
1736
1737 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1738 // they win. Otherwise the defending team wins once the timelimit passes.
1739 void assault_new_round();
1740 float WinningCondition_Assault()
1741 {
1742         float status;
1743
1744         WinningConditionHelper(); // set worldstatus
1745
1746         status = WINNING_NO;
1747         // as the timelimit has not yet passed just assume the defending team will win
1748         if(assault_attacker_team == NUM_TEAM_1)
1749         {
1750                 SetWinners(team, NUM_TEAM_2);
1751         }
1752         else
1753         {
1754                 SetWinners(team, NUM_TEAM_1);
1755         }
1756
1757         entity ent;
1758         ent = find(world, classname, "target_assault_roundend");
1759         if(ent)
1760         {
1761                 if(ent.winning) // round end has been triggered by attacking team
1762                 {
1763                         bprint("ASSAULT: round completed...\n");
1764                         SetWinners(team, assault_attacker_team);
1765
1766                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1767
1768                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1769                         {
1770                                 status = WINNING_YES;
1771                         }
1772                         else
1773                         {
1774                                 entity oldself;
1775                                 oldself = self;
1776                                 self = ent;
1777                                 assault_new_round();
1778                                 self = oldself;
1779                         }
1780                 }
1781         }
1782
1783         return status;
1784 }
1785
1786 // LMS winning condition: game terminates if and only if there's at most one
1787 // one player who's living lives. Top two scores being equal cancels the time
1788 // limit.
1789 float WinningCondition_LMS()
1790 {
1791         entity head, head2;
1792         float have_player;
1793         float have_players;
1794         float l;
1795
1796         have_player = FALSE;
1797         have_players = FALSE;
1798         l = LMS_NewPlayerLives();
1799
1800         head = find(world, classname, "player");
1801         if(head)
1802                 have_player = TRUE;
1803         head2 = find(head, classname, "player");
1804         if(head2)
1805                 have_players = TRUE;
1806
1807         if(have_player)
1808         {
1809                 // we have at least one player
1810                 if(have_players)
1811                 {
1812                         // two or more active players - continue with the game
1813                 }
1814                 else
1815                 {
1816                         // exactly one player?
1817
1818                         ClearWinners();
1819                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1820
1821                         if(l)
1822                         {
1823                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1824                                 return WINNING_NO;
1825                         }
1826                         else
1827                         {
1828                                 // a winner!
1829                                 // and assign him his first place
1830                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1831                                 return WINNING_YES;
1832                         }
1833                 }
1834         }
1835         else
1836         {
1837                 // nobody is playing at all...
1838                 if(l)
1839                 {
1840                         // wait for players...
1841                 }
1842                 else
1843                 {
1844                         // SNAFU (maybe a draw game?)
1845                         ClearWinners();
1846                         dprint("No players, ending game.\n");
1847                         return WINNING_YES;
1848                 }
1849         }
1850
1851         // When we get here, we have at least two players who are actually LIVING,
1852         // now check if the top two players have equal score.
1853         WinningConditionHelper();
1854
1855         ClearWinners();
1856         if(WinningConditionHelper_winner)
1857                 WinningConditionHelper_winner.winning = TRUE;
1858         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1859                 return WINNING_NEVER;
1860
1861         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1862         return WINNING_NO;
1863 }
1864
1865 void ShuffleMaplist()
1866 {
1867         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1868 }
1869
1870 float leaderfrags;
1871 float WinningCondition_Scores(float limit, float leadlimit)
1872 {
1873         float limitreached;
1874
1875         // TODO make everything use THIS winning condition (except LMS)
1876         WinningConditionHelper();
1877
1878         if(teamplay)
1879         {
1880                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1881                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1882                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1883                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1884         }
1885
1886         ClearWinners();
1887         if(WinningConditionHelper_winner)
1888                 WinningConditionHelper_winner.winning = 1;
1889         if(WinningConditionHelper_winnerteam >= 0)
1890                 SetWinners(team, WinningConditionHelper_winnerteam);
1891
1892         if(WinningConditionHelper_lowerisbetter)
1893         {
1894                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1895                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1896                 limit = -limit;
1897         }
1898
1899         if(WinningConditionHelper_zeroisworst)
1900                 leadlimit = 0; // not supported in this mode
1901
1902         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1903         // these modes always score in increments of 1, thus this makes sense
1904         {
1905                 if(leaderfrags != WinningConditionHelper_topscore)
1906                 {
1907                         leaderfrags = WinningConditionHelper_topscore;
1908
1909                         if (limit)
1910                         if (leaderfrags == limit - 1)
1911                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1912                         else if (leaderfrags == limit - 2)
1913                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1914                         else if (leaderfrags == limit - 3)
1915                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1916                 }
1917         }
1918
1919         limitreached = FALSE;
1920         if(limit)
1921                 if(WinningConditionHelper_topscore >= limit)
1922                         limitreached = TRUE;
1923         if(leadlimit)
1924         {
1925                 float leadlimitreached;
1926                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1927                 if(autocvar_leadlimit_and_fraglimit)
1928                         limitreached = (limitreached && leadlimitreached);
1929                 else
1930                         limitreached = (limitreached || leadlimitreached);
1931         }
1932
1933         if(limit)
1934                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1935
1936         return GetWinningCode(
1937                 WinningConditionHelper_topscore && limitreached,
1938                 WinningConditionHelper_equality
1939         );
1940 }
1941
1942 float WinningCondition_Race(float fraglimit)
1943 {
1944         float wc;
1945         entity p;
1946         float n, c;
1947
1948         n = 0;
1949         c = 0;
1950         FOR_EACH_PLAYER(p)
1951         {
1952                 ++n;
1953                 if(p.race_completed)
1954                         ++c;
1955         }
1956         if(n && (n == c))
1957                 return WINNING_YES;
1958         wc = WinningCondition_Scores(fraglimit, 0);
1959
1960         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1961         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1962         // do NOT support equality when the laps are all raced!
1963                 return WINNING_STARTSUDDENDEATHOVERTIME;
1964         else
1965                 return WINNING_NEVER;
1966 }
1967
1968 float WinningCondition_QualifyingThenRace(float limit)
1969 {
1970         float wc;
1971         wc = WinningCondition_Scores(limit, 0);
1972
1973         // NEVER initiate overtime
1974         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1975         {
1976                 return WINNING_YES;
1977         }
1978
1979         return wc;
1980 }
1981
1982 float WinningCondition_RanOutOfSpawns()
1983 {
1984         entity head;
1985
1986         if(have_team_spawns <= 0)
1987                 return WINNING_NO;
1988
1989         if(autocvar_g_spawn_useallspawns <= 0)
1990                 return WINNING_NO;
1991
1992         if(!some_spawn_has_been_used)
1993                 return WINNING_NO;
1994
1995         team1_score = team2_score = team3_score = team4_score = 0;
1996
1997         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1998         {
1999                 if(head.team == NUM_TEAM_1)
2000                         team1_score = 1;
2001                 else if(head.team == NUM_TEAM_2)
2002                         team2_score = 1;
2003                 else if(head.team == NUM_TEAM_3)
2004                         team3_score = 1;
2005                 else if(head.team == NUM_TEAM_4)
2006                         team4_score = 1;
2007         }
2008
2009         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2010         {
2011                 if(head.team == NUM_TEAM_1)
2012                         team1_score = 1;
2013                 else if(head.team == NUM_TEAM_2)
2014                         team2_score = 1;
2015                 else if(head.team == NUM_TEAM_3)
2016                         team3_score = 1;
2017                 else if(head.team == NUM_TEAM_4)
2018                         team4_score = 1;
2019         }
2020
2021         ClearWinners();
2022         if(team1_score + team2_score + team3_score + team4_score == 0)
2023         {
2024                 checkrules_equality = TRUE;
2025                 return WINNING_YES;
2026         }
2027         else if(team1_score + team2_score + team3_score + team4_score == 1)
2028         {
2029                 float t, i;
2030                 if(team1_score)
2031                         t = NUM_TEAM_1;
2032                 else if(team2_score)
2033                         t = NUM_TEAM_2;
2034                 else if(team3_score)
2035                         t = NUM_TEAM_3;
2036                 else // if(team4_score)
2037                         t = NUM_TEAM_4;
2038                 CheckAllowedTeams(world);
2039                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2040                 {
2041                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2042                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2043                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2044                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2045                 }
2046
2047                 AddWinners(team, t);
2048                 return WINNING_YES;
2049         }
2050         else
2051                 return WINNING_NO;
2052 }
2053
2054 /*
2055 ============
2056 CheckRules_World
2057
2058 Exit deathmatch games upon conditions
2059 ============
2060 */
2061 void ReadyRestart();
2062 void CheckRules_World()
2063 {
2064         float timelimit;
2065         float fraglimit;
2066         float leadlimit;
2067
2068         VoteThink();
2069         MapVote_Think();
2070
2071         SetDefaultAlpha();
2072
2073         /*
2074         MapVote_Think should now do that part
2075         if (intermission_running)
2076                 if (time >= intermission_exittime + 60)
2077                 {
2078                         if(!DoNextMapOverride())
2079                                 GotoNextMap();
2080                         return;
2081                 }
2082         */
2083
2084         if (gameover)   // someone else quit the game already
2085         {
2086                 if(player_count == 0) // Nobody there? Then let's go to the next map
2087                         MapVote_Start();
2088                         // this will actually check the player count in the next frame
2089                         // again, but this shouldn't hurt
2090                 return;
2091         }
2092
2093         timelimit = autocvar_timelimit * 60;
2094         fraglimit = autocvar_fraglimit;
2095         leadlimit = autocvar_leadlimit;
2096
2097         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2098         {
2099                 if(timelimit > 0)
2100                         timelimit = 0; // timelimit is not made for warmup
2101                 if(fraglimit > 0)
2102                         fraglimit = 0; // no fraglimit for now
2103                 leadlimit = 0; // no leadlimit for now
2104         }
2105
2106         if(timelimit > 0)
2107         {
2108                 timelimit += game_starttime;
2109         }
2110         else if (timelimit < 0)
2111         {
2112                 // endmatch
2113                 NextLevel();
2114                 return;
2115         }
2116
2117         if(g_onslaught)
2118                 timelimit = 0; // ONS has its own overtime rule
2119
2120         float wantovertime;
2121         wantovertime = 0;
2122
2123         if(timelimit > game_starttime)
2124                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2125         else
2126                 game_completion_ratio = 0;
2127
2128         if(checkrules_suddendeathend)
2129         {
2130                 if(!checkrules_suddendeathwarning)
2131                 {
2132                         checkrules_suddendeathwarning = TRUE;
2133                         if(g_race && !g_race_qualifying)
2134                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2135                         else
2136                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2137                 }
2138         }
2139         else
2140         {
2141                 if (timelimit && time >= timelimit)
2142                 {
2143                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2144                         {
2145                                 float totalplayers;
2146                                 float playerswithlaps;
2147                                 float readyplayers;
2148                                 entity head;
2149                                 totalplayers = playerswithlaps = readyplayers = 0;
2150                                 FOR_EACH_PLAYER(head)
2151                                 {
2152                                         ++totalplayers;
2153                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2154                                                 ++playerswithlaps;
2155                                         if(head.ready)
2156                                                 ++readyplayers;
2157                                 }
2158
2159                                 // at least 2 of the players have completed a lap: start the RACE
2160                                 // otherwise, the players should end the qualifying on their own
2161                                 if(readyplayers || playerswithlaps >= 2)
2162                                 {
2163                                         checkrules_suddendeathend = 0;
2164                                         ReadyRestart(); // go to race
2165                                         return;
2166                                 }
2167                                 else
2168                                         wantovertime |= InitiateSuddenDeath();
2169                         }
2170                         else
2171                                 wantovertime |= InitiateSuddenDeath();
2172                 }
2173         }
2174
2175         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2176         {
2177                 NextLevel();
2178                 return;
2179         }
2180
2181         float checkrules_status;
2182         checkrules_status = WinningCondition_RanOutOfSpawns();
2183         if(checkrules_status == WINNING_YES)
2184         {
2185                 bprint("Hey! Someone ran out of spawns!\n");
2186         }
2187         else if(g_race && !g_race_qualifying && timelimit >= 0)
2188         {
2189                 checkrules_status = WinningCondition_Race(fraglimit);
2190                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2191         }
2192         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2193         {
2194                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2195                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2196         }
2197         else if(g_assault)
2198         {
2199                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2200         }
2201         else if(g_lms)
2202         {
2203                 checkrules_status = WinningCondition_LMS();
2204         }
2205         else if (g_onslaught)
2206         {
2207                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2208         }
2209         else
2210         {
2211                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2212                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2213         }
2214
2215         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2216         {
2217                 checkrules_status = WINNING_NEVER;
2218                 checkrules_overtimesadded = -1;
2219                 wantovertime |= InitiateSuddenDeath();
2220         }
2221
2222         if(checkrules_status == WINNING_NEVER)
2223                 // equality cases! Nobody wins if the overtime ends in a draw.
2224                 ClearWinners();
2225
2226         if(wantovertime)
2227         {
2228                 if(checkrules_status == WINNING_NEVER)
2229                         InitiateOvertime();
2230                 else
2231                         checkrules_status = WINNING_YES;
2232         }
2233
2234         if(checkrules_suddendeathend)
2235                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2236                         checkrules_status = WINNING_YES;
2237
2238         if(checkrules_status == WINNING_YES)
2239         {
2240                 //print("WINNING\n");
2241                 NextLevel();
2242         }
2243 }
2244
2245 float mapvote_nextthink;
2246 float mapvote_initialized;
2247 float mapvote_keeptwotime;
2248 float mapvote_timeout;
2249 string mapvote_message;
2250 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2251 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2252 float mapvote_screenshot_dirs_count;
2253
2254 float mapvote_count;
2255 float mapvote_count_real;
2256 string mapvote_maps[MAPVOTE_COUNT];
2257 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2258 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2259 float mapvote_maps_suggested[MAPVOTE_COUNT];
2260 string mapvote_suggestions[MAPVOTE_COUNT];
2261 float mapvote_suggestion_ptr;
2262 float mapvote_voters;
2263 float mapvote_selections[MAPVOTE_COUNT];
2264 float mapvote_run;
2265 float mapvote_detail;
2266 float mapvote_abstain;
2267 .float mapvote;
2268
2269 void MapVote_ClearAllVotes()
2270 {
2271         FOR_EACH_CLIENT(other)
2272                 other.mapvote = 0;
2273 }
2274
2275 string MapVote_Suggest(string m)
2276 {
2277         float i;
2278         if(m == "")
2279                 return "That's not how to use this command.";
2280         if(!autocvar_g_maplist_votable_suggestions)
2281                 return "Suggestions are not accepted on this server.";
2282         if(mapvote_initialized)
2283                 return "Can't suggest - voting is already in progress!";
2284         m = MapInfo_FixName(m);
2285         if not(m)
2286                 return "The map you suggested is not available on this server.";
2287         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2288                 if(Map_IsRecent(m))
2289                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2290
2291         if(!MapInfo_CheckMap(m))
2292                 return "The map you suggested does not support the current game mode.";
2293         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2294                 if(mapvote_suggestions[i] == m)
2295                         return "This map was already suggested.";
2296         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2297         {
2298                 i = floor(random() * mapvote_suggestion_ptr);
2299         }
2300         else
2301         {
2302                 i = mapvote_suggestion_ptr;
2303                 mapvote_suggestion_ptr += 1;
2304         }
2305         if(mapvote_suggestions[i] != "")
2306                 strunzone(mapvote_suggestions[i]);
2307         mapvote_suggestions[i] = strzone(m);
2308         if(autocvar_sv_eventlog)
2309                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2310         return strcat("Suggestion of ", m, " accepted.");
2311 }
2312
2313 void MapVote_AddVotable(string nextMap, float isSuggestion)
2314 {
2315         float j, i, o;
2316         string pakfile, mapfile;
2317
2318         if(nextMap == "")
2319                 return;
2320         for(j = 0; j < mapvote_count; ++j)
2321                 if(mapvote_maps[j] == nextMap)
2322                         return;
2323         // suggestions might be no longer valid/allowed after gametype switch!
2324         if(isSuggestion)
2325                 if(!MapInfo_CheckMap(nextMap))
2326                         return;
2327         mapvote_maps[mapvote_count] = strzone(nextMap);
2328         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2329
2330         pakfile = string_null;
2331         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2332         {
2333                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2334                 pakfile = whichpack(strcat(mapfile, ".tga"));
2335                 if(pakfile == "")
2336                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2337                 if(pakfile == "")
2338                         pakfile = whichpack(strcat(mapfile, ".png"));
2339                 if(pakfile != "")
2340                         break;
2341         }
2342         if(i >= mapvote_screenshot_dirs_count)
2343                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2344         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2345                 pakfile = substring(pakfile, o, -1);
2346
2347         mapvote_maps_screenshot_dir[mapvote_count] = i;
2348         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2349
2350         mapvote_count += 1;
2351 }
2352
2353 void MapVote_Spawn();
2354 void MapVote_Init()
2355 {
2356         float i;
2357         float nmax, smax;
2358
2359         MapVote_ClearAllVotes();
2360
2361         mapvote_count = 0;
2362         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2363         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2364
2365         if(mapvote_abstain)
2366                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2367         else
2368                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2369         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2370
2371         // we need this for AddVotable, as that cycles through the screenshot dirs
2372         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2373         if(mapvote_screenshot_dirs_count == 0)
2374                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2375         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2376         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2377                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2378
2379         if(mapvote_suggestion_ptr)
2380                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2381                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2382
2383         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2384                 MapVote_AddVotable(GetNextMap(), FALSE);
2385
2386         if(mapvote_count == 0)
2387         {
2388                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2389                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2390                 if(autocvar_g_maplist_shuffle)
2391                         ShuffleMaplist();
2392                 localcmd("\nmenu_cmd sync\n");
2393                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2394                         MapVote_AddVotable(GetNextMap(), FALSE);
2395         }
2396
2397         mapvote_count_real = mapvote_count;
2398         if(mapvote_abstain)
2399                 MapVote_AddVotable("don't care", 0);
2400
2401         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2402
2403         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2404         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2405         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2406                 mapvote_keeptwotime = 0;
2407         mapvote_message = "Choose a map and press its key!";
2408
2409         MapVote_Spawn();
2410 }
2411
2412 void MapVote_SendPicture(float id)
2413 {
2414         msg_entity = self;
2415         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2416         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2417         WriteByte(MSG_ONE, id);
2418         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2419 }
2420
2421 float MapVote_GetMapMask()
2422 {
2423         float mask, i, power;
2424         mask = 0;
2425         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2426                 if(mapvote_maps[i] != "")
2427                         mask |= power;
2428         return mask;
2429 }
2430
2431 entity mapvote_ent;
2432 float MapVote_SendEntity(entity to, float sf)
2433 {
2434         float i;
2435
2436         if(sf & 1)
2437                 sf &~= 2; // if we send 1, we don't need to also send 2
2438
2439         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2440         WriteByte(MSG_ENTITY, sf);
2441
2442         if(sf & 1)
2443         {
2444                 // flag 1 == initialization
2445                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2446                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2447                 WriteString(MSG_ENTITY, "");
2448                 WriteByte(MSG_ENTITY, mapvote_count);
2449                 WriteByte(MSG_ENTITY, mapvote_abstain);
2450                 WriteByte(MSG_ENTITY, mapvote_detail);
2451                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2452                 if(mapvote_count <= 8)
2453                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2454                 else
2455                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2456                 for(i = 0; i < mapvote_count; ++i)
2457                         if(mapvote_maps[i] != "")
2458                         {
2459                                 if(mapvote_abstain && i == mapvote_count - 1)
2460                                 {
2461                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2462                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2463                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2464                                 }
2465                                 else
2466                                 {
2467                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2468                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2469                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2470                                 }
2471                         }
2472         }
2473
2474         if(sf & 2)
2475         {
2476                 // flag 2 == update of mask
2477                 if(mapvote_count <= 8)
2478                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2479                 else
2480                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2481         }
2482
2483         if(sf & 4)
2484         {
2485                 if(mapvote_detail)
2486                         for(i = 0; i < mapvote_count; ++i)
2487                                 if(mapvote_maps[i] != "")
2488                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2489
2490                 WriteByte(MSG_ENTITY, to.mapvote);
2491         }
2492
2493         return TRUE;
2494 }
2495
2496 void MapVote_Spawn()
2497 {
2498         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2499 }
2500
2501 void MapVote_TouchMask()
2502 {
2503         mapvote_ent.SendFlags |= 2;
2504 }
2505
2506 void MapVote_TouchVotes(entity voter)
2507 {
2508         mapvote_ent.SendFlags |= 4;
2509 }
2510
2511 float MapVote_Finished(float mappos)
2512 {
2513         string result;
2514         float i;
2515         float didntvote;
2516
2517         if(autocvar_sv_eventlog)
2518         {
2519                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2520                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2521                 didntvote = mapvote_voters;
2522                 for(i = 0; i < mapvote_count; ++i)
2523                         if(mapvote_maps[i] != "")
2524                         {
2525                                 didntvote -= mapvote_selections[i];
2526                                 if(i != mappos)
2527                                 {
2528                                         result = strcat(result, ":", mapvote_maps[i]);
2529                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2530                                 }
2531                         }
2532                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2533
2534                 GameLogEcho(result);
2535                 if(mapvote_maps_suggested[mappos])
2536                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2537         }
2538
2539         FOR_EACH_REALCLIENT(other)
2540                 FixClientCvars(other);
2541
2542         Map_Goto_SetStr(mapvote_maps[mappos]);
2543         Map_Goto(0);
2544         alreadychangedlevel = TRUE;
2545         return TRUE;
2546 }
2547 void MapVote_CheckRules_1()
2548 {
2549         float i;
2550
2551         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2552         {
2553                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2554                 mapvote_selections[i] = 0;
2555         }
2556
2557         mapvote_voters = 0;
2558         FOR_EACH_REALCLIENT(other)
2559         {
2560                 ++mapvote_voters;
2561                 if(other.mapvote)
2562                 {
2563                         i = other.mapvote - 1;
2564                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2565                         mapvote_selections[i] = mapvote_selections[i] + 1;
2566                 }
2567         }
2568 }
2569
2570 float MapVote_CheckRules_2()
2571 {
2572         float i;
2573         float firstPlace, secondPlace;
2574         float firstPlaceVotes, secondPlaceVotes;
2575         float mapvote_voters_real;
2576         string result;
2577
2578         if(mapvote_count_real == 1)
2579                 return MapVote_Finished(0);
2580
2581         mapvote_voters_real = mapvote_voters;
2582         if(mapvote_abstain)
2583                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2584
2585         RandomSelection_Init();
2586         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2587                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2588         firstPlace = RandomSelection_chosen_float;
2589         firstPlaceVotes = RandomSelection_best_priority;
2590         //dprint("First place: ", ftos(firstPlace), "\n");
2591         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2592
2593         RandomSelection_Init();
2594         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2595                 if(i != firstPlace)
2596                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2597         secondPlace = RandomSelection_chosen_float;
2598         secondPlaceVotes = RandomSelection_best_priority;
2599         //dprint("Second place: ", ftos(secondPlace), "\n");
2600         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2601
2602         if(firstPlace == -1)
2603                 error("No first place in map vote... WTF?");
2604
2605         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2606                 return MapVote_Finished(firstPlace);
2607
2608         if(mapvote_keeptwotime)
2609                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2610                 {
2611                         float didntvote;
2612                         MapVote_TouchMask();
2613                         mapvote_message = "Now decide between the TOP TWO!";
2614                         mapvote_keeptwotime = 0;
2615                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2616                         result = strcat(result, ":", ftos(firstPlaceVotes));
2617                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2618                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2619                         didntvote = mapvote_voters;
2620                         for(i = 0; i < mapvote_count; ++i)
2621                                 if(mapvote_maps[i] != "")
2622                                 {
2623                                         didntvote -= mapvote_selections[i];
2624                                         if(i != firstPlace)
2625                                                 if(i != secondPlace)
2626                                                 {
2627                                                         result = strcat(result, ":", mapvote_maps[i]);
2628                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2629                                                         if(i < mapvote_count_real)
2630                                                         {
2631                                                                 strunzone(mapvote_maps[i]);
2632                                                                 mapvote_maps[i] = "";
2633                                                                 strunzone(mapvote_maps_pakfile[i]);
2634                                                                 mapvote_maps_pakfile[i] = "";
2635                                                         }
2636                                                 }
2637                                 }
2638                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2639                         if(autocvar_sv_eventlog)
2640                                 GameLogEcho(result);
2641                 }
2642
2643         return FALSE;
2644 }
2645 void MapVote_Tick()
2646 {
2647         float keeptwo;
2648         float totalvotes;
2649
2650         keeptwo = mapvote_keeptwotime;
2651         MapVote_CheckRules_1(); // count
2652         if(MapVote_CheckRules_2()) // decide
2653                 return;
2654
2655         totalvotes = 0;
2656         FOR_EACH_REALCLIENT(other)
2657         {
2658                 // hide scoreboard again
2659                 if(other.health != 2342)
2660                 {
2661                         other.health = 2342;
2662                         other.impulse = 0;
2663                         if(IS_REAL_CLIENT(other))
2664                         {
2665                                 msg_entity = other;
2666                                 WriteByte(MSG_ONE, SVC_FINALE);
2667                                 WriteString(MSG_ONE, "");
2668                         }
2669                 }
2670
2671                 // clear possibly invalid votes
2672                 if(mapvote_maps[other.mapvote - 1] == "")
2673                         other.mapvote = 0;
2674                 // use impulses as new vote
2675                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2676                         if(mapvote_maps[other.impulse - 1] != "")
2677                         {
2678                                 other.mapvote = other.impulse;
2679                                 MapVote_TouchVotes(other);
2680                         }
2681                 other.impulse = 0;
2682
2683                 if(other.mapvote)
2684                         ++totalvotes;
2685         }
2686
2687         MapVote_CheckRules_1(); // just count
2688 }
2689 void MapVote_Start()
2690 {
2691         if(mapvote_run)
2692                 return;
2693
2694         // wait for stats to be sent first
2695         if(!playerstats_waitforme)
2696                 return;
2697
2698         MapInfo_Enumerate();
2699         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2700                 mapvote_run = TRUE;
2701 }
2702 void MapVote_Think()
2703 {
2704         if(!mapvote_run)
2705                 return;
2706
2707         if(alreadychangedlevel)
2708                 return;
2709
2710         if(time < mapvote_nextthink)
2711                 return;
2712         //dprint("tick\n");
2713
2714         mapvote_nextthink = time + 0.5;
2715
2716         if(!mapvote_initialized)
2717         {
2718                 if(autocvar_rescan_pending == 1)
2719                 {
2720                         cvar_set("rescan_pending", "2");
2721                         localcmd("fs_rescan\nrescan_pending 3\n");
2722                         return;
2723                 }
2724                 else if(autocvar_rescan_pending == 2)
2725                 {
2726                         return;
2727                 }
2728                 else if(autocvar_rescan_pending == 3)
2729                 {
2730                         // now build missing mapinfo files
2731                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2732                                 return;
2733
2734                         // we're done, start the timer
2735                         cvar_set("rescan_pending", "0");
2736                 }
2737
2738                 mapvote_initialized = TRUE;
2739                 if(DoNextMapOverride(0))
2740                         return;
2741                 if(!autocvar_g_maplist_votable || player_count <= 0)
2742                 {
2743                         GotoNextMap(0);
2744                         return;
2745                 }
2746                 MapVote_Init();
2747         }
2748
2749         MapVote_Tick();
2750 }
2751
2752 string GotoMap(string m)
2753 {
2754         if(!MapInfo_CheckMap(m))
2755                 return "The map you chose is not available on this server.";
2756         cvar_set("nextmap", m);
2757         cvar_set("timelimit", "-1");
2758         if(mapvote_initialized || alreadychangedlevel)
2759         {
2760                 if(DoNextMapOverride(0))
2761                         return "Map switch initiated.";
2762                 else
2763                         return "Hm... no. For some reason I like THIS map more.";
2764         }
2765         else
2766                 return "Map switch will happen after scoreboard.";
2767 }
2768
2769
2770 void EndFrame()
2771 {
2772         float altime;
2773         FOR_EACH_REALCLIENT(self)
2774         {
2775                 if(IS_SPEC(self))
2776                 {
2777                         if(self.enemy.typehitsound)
2778                                 self.typehit_time = time;
2779                         else if(self.enemy.hitsound)
2780                                 self.hit_time = time;
2781                 }
2782                 else
2783                 {
2784                         if(self.typehitsound)
2785                                 self.typehit_time = time;
2786                         else if(self.hitsound)
2787                                 self.hit_time = time;
2788                 }
2789         }
2790         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2791         // add 1 frametime because after this, engine SV_Physics
2792         // increases time by a frametime and then networks the frame
2793         // add another frametime because client shows everything with
2794         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2795         // needed!
2796         FOR_EACH_CLIENT(self)
2797         {
2798                 self.hitsound = FALSE;
2799                 self.typehitsound = FALSE;
2800                 antilag_record(self, altime);
2801         }
2802 }
2803
2804
2805 /*
2806  * RedirectionThink:
2807  * returns TRUE if redirecting
2808  */
2809 float redirection_timeout;
2810 float redirection_nextthink;
2811 float RedirectionThink()
2812 {
2813         float clients_found;
2814
2815         if(redirection_target == "")
2816                 return FALSE;
2817
2818         if(!redirection_timeout)
2819         {
2820                 cvar_set("sv_public", "-2");
2821                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2822                 if(redirection_target == "self")
2823                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2824                 else
2825                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2826         }
2827
2828         if(time < redirection_nextthink)
2829                 return TRUE;
2830
2831         redirection_nextthink = time + 1;
2832
2833         clients_found = 0;
2834         FOR_EACH_REALCLIENT(self)
2835         {
2836                 // TODO add timer
2837                 print("Redirecting: sending connect command to ", self.netname, "\n");
2838                 if(redirection_target == "self")
2839                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2840                 else
2841                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2842                 ++clients_found;
2843         }
2844
2845         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2846
2847         if(time > redirection_timeout || clients_found == 0)
2848                 localcmd("\nwait; wait; wait; quit\n");
2849
2850         return TRUE;
2851 }
2852
2853 void TargetMusic_RestoreGame();
2854 void RestoreGame()
2855 {
2856         // Loaded from a save game
2857         // some things then break, so let's work around them...
2858
2859         // Progs DB (capture records)
2860         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2861
2862         // Mapinfo
2863         MapInfo_Shutdown();
2864         MapInfo_Enumerate();
2865         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2866         WeaponStats_Init();
2867
2868         TargetMusic_RestoreGame();
2869 }
2870
2871 void Shutdown()
2872 {
2873         entity e;
2874
2875         gameover = 2;
2876
2877         if(world_initialized > 0)
2878         {
2879                 world_initialized = 0;
2880                 print("Saving persistent data...\n");
2881                 Ban_SaveBans();
2882
2883                 PlayerStats_EndMatch(0);
2884                 FOR_EACH_CLIENT(e)
2885                         PlayerStats_AddGlobalInfo(e);
2886                 PlayerStats_Shutdown();
2887
2888                 if(!cheatcount_total)
2889                 {
2890                         if(autocvar_sv_db_saveasdump)
2891                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2892                         else
2893                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2894                 }
2895                 if(autocvar_developer)
2896                 {
2897                         if(autocvar_sv_db_saveasdump)
2898                                 db_dump(TemporaryDB, "server-temp.db");
2899                         else
2900                                 db_save(TemporaryDB, "server-temp.db");
2901                 }
2902                 CheatShutdown(); // must be after cheatcount check
2903                 db_close(ServerProgsDB);
2904                 db_close(TemporaryDB);
2905                 print("done!\n");
2906                 // tell the bot system the game is ending now
2907                 bot_endgame();
2908
2909                 WeaponStats_Shutdown();
2910                 MapInfo_Shutdown();
2911         }
2912         else if(world_initialized == 0)
2913         {
2914                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2915         }
2916 }