qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 void GotoFirstMap()
  99 {
 100         float n;
 101         if(autocvar__sv_init)
 102         {
 103                 // cvar_set("_sv_init", "0");
 104                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 105                 // to this "init" map on a dedicated server will cause no permanent
 106                 // harm
 107                 if(autocvar_g_maplist_shuffle)
 108                         ShuffleMaplist();
 109                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 110                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 111
 112                 MapInfo_Enumerate();
 113                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 114
 115                 if(!DoNextMapOverride(1))
 116                         GotoNextMap(1);
 117
 118                 return;
 119         }
 120
 121         if(time < 5)
 122         {
 123                 self.nextthink = time;
 124         }
 125         else
 126         {
 127                 self.nextthink = time + 1;
 128                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 129         }
 130 }
 131
 132 void cvar_changes_init()
 133 {
 134         float h;
 135         string k, v, d;
 136         float n, i, adding, pureadding;
 137
 138         if(cvar_changes)
 139                 strunzone(cvar_changes);
 140         cvar_changes = string_null;
 141         if(cvar_purechanges)
 142                 strunzone(cvar_purechanges);
 143         cvar_purechanges = string_null;
 144         cvar_purechanges_count = 0;
 145
 146         h = buf_create();
 147         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 148         n = buf_getsize(h);
 149
 150         adding = TRUE;
 151         pureadding = TRUE;
 152
 153         for(i = 0; i < n; ++i)
 154         {
 155                 k = bufstr_get(h, i);
 156
 157 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 158 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 159 #define BADCVAR(p) if(k == p) continue
 160
 161                 // general excludes and namespaces for server admin used cvars
 162                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 163
 164                 // internal
 165                 BADPREFIX("csqc_");
 166                 BADPREFIX("cvar_check_");
 167                 BADCVAR("gamecfg");
 168                 BADCVAR("g_configversion");
 169                 BADCVAR("g_maplist_index");
 170                 BADCVAR("halflifebsp");
 171                 BADPREFIX("sv_world");
 172
 173                 // client
 174                 BADPREFIX("chase_");
 175                 BADPREFIX("cl_");
 176                 BADPREFIX("con_");
 177                 BADPREFIX("scoreboard_");
 178                 BADPREFIX("g_campaign");
 179                 BADPREFIX("g_waypointsprite_");
 180                 BADPREFIX("gl_");
 181                 BADPREFIX("joy");
 182                 BADPREFIX("hud_");
 183                 BADPREFIX("m_");
 184                 BADPREFIX("menu_");
 185                 BADPREFIX("net_slist_");
 186                 BADPREFIX("r_");
 187                 BADPREFIX("sbar_");
 188                 BADPREFIX("scr_");
 189                 BADPREFIX("snd_");
 190                 BADPREFIX("show");
 191                 BADPREFIX("sensitivity");
 192                 BADPREFIX("userbind");
 193                 BADPREFIX("v_");
 194                 BADPREFIX("vid_");
 195                 BADPREFIX("crosshair");
 196                 BADCVAR("mod_q3bsp_lightmapmergepower");
 197                 BADCVAR("mod_q3bsp_nolightmaps");
 198                 BADCVAR("fov");
 199                 BADCVAR("mastervolume");
 200                 BADCVAR("volume");
 201                 BADCVAR("bgmvolume");
 202
 203                 // private
 204                 BADCVAR("developer");
 205                 BADCVAR("log_dest_udp");
 206                 BADCVAR("log_file");
 207                 BADCVAR("net_address");
 208                 BADCVAR("net_address_ipv6");
 209                 BADCVAR("port");
 210                 BADCVAR("savedgamecfg");
 211                 BADCVAR("serverconfig");
 212                 BADCVAR("sv_autoscreenshot");
 213                 BADCVAR("sv_heartbeatperiod");
 214                 BADCVAR("sv_vote_master_password");
 215                 BADCVAR("sys_colortranslation");
 216                 BADCVAR("sys_specialcharactertranslation");
 217                 BADCVAR("timeformat");
 218                 BADCVAR("timestamps");
 219                 BADPREFIX("developer_");
 220                 BADPREFIX("g_ban_");
 221                 BADPREFIX("g_banned_list");
 222                 BADPREFIX("g_chat_flood_");
 223                 BADPREFIX("g_ghost_items");
 224                 BADPREFIX("g_playerstats_");
 225                 BADPREFIX("g_respawn_ghosts");
 226                 BADPREFIX("g_voice_flood_");
 227                 BADPREFIX("rcon_");
 228                 BADPREFIX("sv_allowdownloads");
 229                 BADPREFIX("sv_autodemo");
 230                 BADPREFIX("sv_curl_");
 231                 BADPREFIX("sv_eventlog");
 232                 BADPREFIX("sv_logscores_");
 233                 BADPREFIX("sv_master");
 234                 BADPREFIX("sv_weaponstats_");
 235                 BADPREFIX("sv_waypointsprite_");
 236                 BADCVAR("rescan_pending");
 237
 238                 // these can contain player IDs, so better hide
 239                 BADPREFIX("g_forced_team_");
 240
 241                 // mapinfo
 242                 BADCVAR("fraglimit");
 243                 BADCVAR("g_arena");
 244                 BADCVAR("g_assault");
 245                 BADCVAR("g_ca");
 246                 BADCVAR("g_ctf");
 247                 BADCVAR("g_cts");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_domination_default_teams");
 251                 BADCVAR("g_freezetag");
 252                 BADCVAR("g_keepaway");
 253                 BADCVAR("g_keyhunt");
 254                 BADCVAR("g_keyhunt_teams");
 255                 BADCVAR("g_keyhunt_teams");
 256                 BADCVAR("g_lms");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("g_onslaught");
 259                 BADCVAR("g_race");
 260                 BADCVAR("g_race_qualifying_timelimit");
 261                 BADCVAR("g_runematch");
 262                 BADCVAR("g_tdm");
 263                 BADCVAR("g_tdm_teams");
 264                 BADCVAR("leadlimit");
 265                 BADCVAR("nextmap");
 266                 BADCVAR("teamplay");
 267                 BADCVAR("timelimit");
 268
 269                 // long
 270                 BADCVAR("hostname");
 271                 BADCVAR("g_maplist");
 272                 BADCVAR("g_maplist_mostrecent");
 273                 BADCVAR("sv_motd");
 274
 275                 v = cvar_string(k);
 276                 d = cvar_defstring(k);
 277                 if(v == d)
 278                         continue;
 279
 280                 if(adding)
 281                 {
 282                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 283                         if(strlen(cvar_changes) > 16384)
 284                         {
 285                                 cvar_changes = "// too many settings have been changed to show them here\n";
 286                                 adding = 0;
 287                         }
 288                 }
 289
 290                 // now check if the changes are actually gameplay relevant
 291
 292                 // does nothing visible
 293                 BADCVAR("captureleadlimit_override");
 294                 BADCVAR("g_arena_point_leadlimit");
 295                 BADCVAR("g_balance_kill_delay");
 296                 BADCVAR("g_ca_point_leadlimit");
 297                 BADCVAR("g_ctf_captimerecord_always");
 298                 BADCVAR("g_ctf_flag_capture_effects");
 299                 BADCVAR("g_ctf_flag_glowtrails");
 300                 BADCVAR("g_ctf_flag_pickup_effects");
 301                 BADCVAR("g_domination_point_leadlimit");
 302                 BADCVAR("g_forced_respawn");
 303                 BADCVAR("g_keyhunt_point_leadlimit");
 304                 BADPREFIX("g_mod_");
 305                 BADCVAR("g_nexball_goalleadlimit");
 306                 BADCVAR("g_runematch_point_leadlimit");
 307                 BADCVAR("leadlimit_and_fraglimit");
 308                 BADCVAR("leadlimit_override");
 309                 BADCVAR("pausable");
 310                 BADCVAR("sv_allow_fullbright");
 311                 BADCVAR("sv_checkforpacketsduringsleep");
 312                 BADCVAR("sv_fraginfo");
 313                 BADCVAR("sv_timeout");
 314                 BADPREFIX("sv_timeout_");
 315                 BADCVAR("welcome_message_time");
 316                 BADPREFIX("crypto_");
 317                 BADPREFIX("g_chat_");
 318                 BADPREFIX("g_ctf_captimerecord_");
 319                 BADPREFIX("g_maplist_votable_");
 320                 BADPREFIX("net_");
 321                 BADPREFIX("prvm_");
 322                 BADPREFIX("skill_");
 323                 BADPREFIX("sv_cullentities_");
 324                 BADPREFIX("sv_fraginfo_");
 325                 BADPREFIX("sv_maxidle_");
 326                 BADPREFIX("sv_vote_");
 327                 BADPREFIX("timelimit_");
 328                 BADCVAR("gameversion");
 329                 BADPREFIX("gameversion_");
 330                 BADCVAR("sv_namechangetimer");
 331 #ifndef NO_LEGACY_NETWORKING
 332                 BADCVAR("sv_use_csqc_players"); // transition
 333 #endif
 334
 335                 // allowed changes to server admins (please sync this to server.cfg)
 336                 // vi commands:
 337                 //   :/"impure"/,$d
 338                 //   :g!,^\/\/[^ /],d
 339                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 340                 //   :%!sort
 341                 // yes, this does contain some redundant stuff, don't really care
 342                 BADCVAR("bot_config_file");
 343                 BADCVAR("bot_number");
 344                 BADCVAR("bot_prefix");
 345                 BADCVAR("bot_suffix");
 346                 BADCVAR("capturelimit_override");
 347                 BADCVAR("fraglimit_override");
 348                 BADCVAR("gametype");
 349                 BADCVAR("g_antilag");
 350                 BADCVAR("g_balance_teams");
 351                 BADCVAR("g_balance_teams_force");
 352                 BADCVAR("g_ban_sync_trusted_servers");
 353                 BADCVAR("g_ban_sync_uri");
 354                 BADCVAR("g_ctf_ignore_frags");
 355                 BADCVAR("g_domination_point_limit");
 356                 BADCVAR("g_friendlyfire");
 357                 BADCVAR("g_fullbrightitems");
 358                 BADCVAR("g_fullbrightplayers");
 359                 BADCVAR("g_keyhunt_point_limit");
 360                 BADCVAR("g_keyhunt_teams_override");
 361                 BADCVAR("g_lms_lives_override");
 362                 BADCVAR("g_maplist");
 363                 BADCVAR("g_maplist_check_waypoints");
 364                 BADCVAR("g_maplist_mostrecent_count");
 365                 BADCVAR("g_maplist_shuffle");
 366                 BADCVAR("g_maplist_votable");
 367                 BADCVAR("g_maplist_votable_abstain");
 368                 BADCVAR("g_maplist_votable_nodetail");
 369                 BADCVAR("g_maplist_votable_suggestions");
 370                 BADCVAR("g_maxplayers");
 371                 BADCVAR("g_mirrordamage");
 372                 BADCVAR("g_nexball_goallimit");
 373                 BADCVAR("g_powerups");
 374                 BADCVAR("g_runematch_point_limit");
 375                 BADCVAR("g_start_delay");
 376                 BADCVAR("g_warmup");
 377                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 378                 BADCVAR("hostname");
 379                 BADCVAR("log_file");
 380                 BADCVAR("maxplayers");
 381                 BADCVAR("minplayers");
 382                 BADCVAR("net_address");
 383                 BADCVAR("port");
 384                 BADCVAR("rcon_password");
 385                 BADCVAR("rcon_restricted_commands");
 386                 BADCVAR("rcon_restricted_password");
 387                 BADCVAR("skill");
 388                 BADCVAR("sv_adminnick");
 389                 BADCVAR("sv_autoscreenshot");
 390                 BADCVAR("sv_autotaunt");
 391                 BADCVAR("sv_curl_defaulturl");
 392                 BADCVAR("sv_defaultcharacter");
 393                 BADCVAR("sv_defaultplayercolors");
 394                 BADCVAR("sv_defaultplayermodel");
 395                 BADCVAR("sv_defaultplayerskin");
 396                 BADCVAR("sv_maxidle");
 397                 BADCVAR("sv_maxrate");
 398                 BADCVAR("sv_motd");
 399                 BADCVAR("sv_public");
 400                 BADCVAR("sv_ready_restart");
 401                 BADCVAR("sv_status_privacy");
 402                 BADCVAR("sv_taunt");
 403                 BADCVAR("sv_vote_call");
 404                 BADCVAR("sv_vote_commands");
 405                 BADCVAR("sv_vote_majority_factor");
 406                 BADCVAR("sv_vote_master");
 407                 BADCVAR("sv_vote_master_commands");
 408                 BADCVAR("sv_vote_master_password");
 409                 BADCVAR("sv_vote_simple_majority_factor");
 410                 BADCVAR("sys_ticrate");
 411                 BADCVAR("teamplay_mode");
 412                 BADCVAR("timelimit_override");
 413                 BADCVAR("g_spawnshieldtime");
 414                 BADPREFIX("g_warmup_");
 415                 BADPREFIX("sv_ready_restart_");
 416
 417                 // mutators that announce themselves properly to the server browser
 418                 BADCVAR("g_minstagib");
 419                 BADCVAR("g_new_toys");
 420                 BADCVAR("g_nix");
 421
 422                 if(autocvar_g_minstagib)
 423                 {
 424                         BADCVAR("g_grappling_hook");
 425                         BADCVAR("g_jetpack");
 426                 }
 427 #undef BADPREFIX
 428 #undef BADCVAR
 429
 430                 if(pureadding)
 431                 {
 432                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 433                         if(strlen(cvar_purechanges) > 16384)
 434                         {
 435                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 436                                 pureadding = 0;
 437                         }
 438                 }
 439                 ++cvar_purechanges_count;
 440                 // WARNING: this variable is used for the server list
 441                 // NEVER dare to skip this code!
 442                 // Hacks to intentionally appearing as "pure server" even though you DO have
 443                 // modified settings may be punished by removal from the server list.
 444                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 445                 // though.
 446         }
 447         buf_del(h);
 448         if(cvar_changes == "")
 449                 cvar_changes = "// this server runs at default server settings\n";
 450         else
 451                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 452         cvar_changes = strzone(cvar_changes);
 453         if(cvar_purechanges == "")
 454                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 455         else
 456                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 457         cvar_purechanges = strzone(cvar_purechanges);
 458 }
 459
 460 void detect_maptype()
 461 {
 462 #if 0
 463         vector o, v;
 464         float i;
 465
 466         for(;;)
 467         {
 468                 o = world.mins;
 469                 o_x += random() * (world.maxs_x - world.mins_x);
 470                 o_y += random() * (world.maxs_y - world.mins_y);
 471                 o_z += random() * (world.maxs_z - world.mins_z);
 472
 473                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 474                 if(trace_fraction == 1)
 475                         continue;
 476
 477                 v = trace_endpos;
 478
 479                 for(i = 0; i < 64; i += 4)
 480                 {
 481                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 482         if(trace_fraction == 1)
 483                 continue;
 484                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 485                 }
 486
 487                 break;
 488         }
 489 #endif
 490 }
 491
 492 entity randomseed;
 493 float RandomSeed_Send(entity to, float sf)
 494 {
 495         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 496         WriteShort(MSG_ENTITY, self.cnt);
 497         return TRUE;
 498 }
 499 void RandomSeed_Think()
 500 {
 501         self.cnt = bound(0, floor(random() * 65536), 65535);
 502         self.nextthink = time + 5;
 503
 504         self.SendFlags |= 1;
 505 }
 506 void RandomSeed_Spawn()
 507 {
 508         randomseed = spawn();
 509         randomseed.think = RandomSeed_Think;
 510         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 511
 512         entity oldself;
 513         oldself = self;
 514         self = randomseed;
 515         self.think(); // sets random seed and nextthink
 516         self = oldself;
 517 }
 518
 519 void spawnfunc___init_dedicated_server(void)
 520 {
 521         // handler for _init/_init map (only for dedicated server initialization)
 522
 523         world_initialized = -1; // don't complain
 524         cvar = cvar_normal;
 525         cvar_string = cvar_string_normal;
 526         cvar_set = cvar_set_normal;
 527
 528         remove = remove_unsafely;
 529
 530         entity e;
 531         e = spawn();
 532         e.think = GotoFirstMap;
 533         e.nextthink = time; // this is usually 1 at this point
 534
 535         e = spawn();
 536         e.classname = "info_player_deathmatch"; // safeguard against player joining
 537
 538         self.classname = "worldspawn"; // safeguard against various stuff ;)
 539
 540         // needs to be done so early because of the constants they create
 541         RegisterWeapons();
 542         RegisterGametypes();
 543
 544         MapInfo_Enumerate();
 545         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 546 }
 547
 548 void Map_MarkAsRecent(string m);
 549 float world_already_spawned;
 550 void RegisterWeapons();
 551 void Nagger_Init();
 552 void ClientInit_Spawn();
 553 void WeaponStats_Init();
 554 void WeaponStats_Shutdown();
 555 void spawnfunc_worldspawn (void)
 556 {
 557         float fd, l, i, j, n;
 558         string s, col;
 559
 560         cvar = cvar_normal;
 561         cvar_string = cvar_string_normal;
 562         cvar_set = cvar_set_normal;
 563
 564         if(world_already_spawned)
 565                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 566         world_already_spawned = TRUE;
 567
 568         remove = remove_safely; // during spawning, watch what you remove!
 569
 570         check_unacceptable_compiler_bugs();
 571
 572         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 573
 574         compressShortVector_init();
 575
 576         allowed_to_spawn = TRUE;
 577
 578         entity head;
 579         head = nextent(world);
 580         maxclients = 0;
 581         while(head)
 582         {
 583                 ++maxclients;
 584                 head = nextent(head);
 585         }
 586
 587         // needs to be done so early because of the constants they create
 588         RegisterWeapons();
 589         RegisterGametypes();
 590
 591         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 592
 593         TemporaryDB = db_create();
 594
 595         // 0 normal
 596         lightstyle(0, "m");
 597
 598         // 1 FLICKER (first variety)
 599         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 600
 601         // 2 SLOW STRONG PULSE
 602         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 603
 604         // 3 CANDLE (first variety)
 605         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 606
 607         // 4 FAST STROBE
 608         lightstyle(4, "mamamamamama");
 609
 610         // 5 GENTLE PULSE 1
 611         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 612
 613         // 6 FLICKER (second variety)
 614         lightstyle(6, "nmonqnmomnmomomno");
 615
 616         // 7 CANDLE (second variety)
 617         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 618
 619         // 8 CANDLE (third variety)
 620         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 621
 622         // 9 SLOW STROBE (fourth variety)
 623         lightstyle(9, "aaaaaaaazzzzzzzz");
 624
 625         // 10 FLUORESCENT FLICKER
 626         lightstyle(10, "mmamammmmammamamaaamammma");
 627
 628         // 11 SLOW PULSE NOT FADE TO BLACK
 629         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 630
 631         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 632
 633         // 63 testing
 634         lightstyle(63, "a");
 635
 636         if(autocvar_g_campaign)
 637                 CampaignPreInit();
 638
 639         Map_MarkAsRecent(mapname);
 640
 641         precache_model ("null"); // we need this one before InitGameplayMode
 642         InitGameplayMode();
 643         readlevelcvars();
 644         GrappleHookInit();
 645         ElectroInit();
 646         LaserInit();
 647
 648         player_count = 0;
 649         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 650         if(bot_waypoints_for_items == 1)
 651                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 652                         bot_waypoints_for_items = 0;
 653
 654         precache();
 655
 656         WaypointSprite_Init();
 657
 658         //if (g_domination)
 659         //      dom_init();
 660
 661         GameLogInit(); // prepare everything
 662         // NOTE for matchid:
 663         // changing the logic generating it is okay. But:
 664         // it HAS to stay <= 64 chars
 665         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 666         if(autocvar_sv_eventlog)
 667         {
 668                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 669                 matchid = strzone(s);
 670
 671                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 672                 s = ":gameinfo:mutators:LIST";
 673
 674                 ret_string = s;
 675                 MUTATOR_CALLHOOK(BuildMutatorsString);
 676                 s = ret_string;
 677
 678                 // simple, probably not good in the mutator system
 679                 if(autocvar_g_grappling_hook)
 680                         s = strcat(s, ":grappling_hook");
 681
 682                 // initialiation stuff, not good in the mutator system
 683                 if(!autocvar_g_use_ammunition)
 684                         s = strcat(s, ":no_use_ammunition");
 685
 686                 // initialiation stuff, not good in the mutator system
 687                 if(autocvar_g_pickup_items == 0)
 688                         s = strcat(s, ":no_pickup_items");
 689                 if(autocvar_g_pickup_items > 0)
 690                         s = strcat(s, ":pickup_items");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(autocvar_g_weaponarena != "0")
 694                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 695
 696                 // TODO to mutator system
 697                 if(autocvar_g_norecoil)
 698                         s = strcat(s, ":norecoil");
 699
 700                 // TODO to mutator system
 701                 if(autocvar_g_midair)
 702                         s = strcat(s, ":midair");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_minstagib)
 706                         s = strcat(s, ":minstagib");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WEPSET_ADDSTAT();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 776         Nagger_Init();
 777
 778         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 779         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 780         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 781         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 782         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 793         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         if(g_ca || g_freezetag)
 798         {
 799                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 800                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 801                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 802                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 803         }
 804         if(g_freezetag)
 805         {
 806                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 807                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 808         }
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         lsmaps_reply = "^7Maps available: ";
 826         lsnewmaps_reply = "^7Maps without a record set: ";
 827         for(i = 0, j = 0; i < MapInfo_count; ++i)
 828         {
 829                 if(MapInfo_Get_ByID(i))
 830                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 831                         {
 832                                 if(mod(i, 2))
 833                                         col = "^2";
 834                                 else
 835                                         col = "^3";
 836
 837                                 ++j;
 838
 839                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 840
 841                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 844                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 845                         }
 846         }
 847
 848         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 849         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 850
 851         maplist_reply = "^7Maps in list: ";
 852         n = tokenize_console(autocvar_g_maplist);
 853         for(i = 0, j = 0; i < n; ++i)
 854         {
 855                 if(MapInfo_CheckMap(argv(i)))
 856                 {
 857                         if(mod(j, 2))
 858                                 col = "^2";
 859                         else
 860                                 col = "^3";
 861                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 862                         ++j;
 863                 }
 864         }
 865         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 866         MapInfo_ClearTemps();
 867
 868         for(i = 0; i < 10; ++i)
 869         {
 870                 records_reply[i] = strzone(getrecords(i));
 871         }
 872
 873         ladder_reply = strzone(getladder());
 874
 875         rankings_reply = strzone(getrankings());
 876
 877         // begin other init
 878         ClientInit_Spawn();
 879         RandomSeed_Spawn();
 880         PingPLReport_Spawn();
 881
 882         CheatInit();
 883
 884         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 885
 886         // fill sv_curl_serverpackages from .serverpackage files
 887         if(autocvar_sv_curl_serverpackages_auto)
 888         {
 889                 s = "";
 890                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 891                 for(i = 0; i < n; ++i)
 892                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 893                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 894                                 s = strcat(s, " ", argv(i));
 895                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 896                 if(fd >= 0)
 897                 {
 898                         j = search_getsize(fd);
 899                         for(i = 0; i < j; ++i)
 900                                 s = strcat(s, " ", search_getfilename(fd, i));
 901                         search_end(fd);
 902                 }
 903                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 904                 if(fd >= 0)
 905                 {
 906                         j = search_getsize(fd);
 907                         for(i = 0; i < j; ++i)
 908                                 s = strcat(s, " ", search_getfilename(fd, i));
 909                         search_end(fd);
 910                 }
 911                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 912         }
 913
 914         PlayerStats_Init();
 915
 916         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 917         modname = "Xonotic";
 918         // physics/balance/config changes that count as mod
 919         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 920                 modname = cvar_string("g_mod_physics");
 921         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 922                 modname = cvar_string("g_mod_balance");
 923         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 924                 modname = cvar_string("g_mod_config");
 925         // weird mutators that deserve to count as mod
 926         if(autocvar_g_minstagib)
 927                 modname = "MinstaGib";
 928         // extra mutators that deserve to count as mod
 929         MUTATOR_CALLHOOK(SetModname);
 930         // weird game types that deserve to count as mod
 931         if(g_cts)
 932                 modname = "CTS";
 933         // save it for later
 934         modname = strzone(modname);
 935
 936         WinningConditionHelper(); // set worldstatus
 937
 938         world_initialized = 1;
 939 }
 940
 941 void spawnfunc_light (void)
 942 {
 943         //makestatic (self); // Who the f___ did that?
 944         remove(self);
 945 }
 946
 947 string GetGametype()
 948 {
 949         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 950 }
 951
 952 string getmapname_stored;
 953 string GetMapname()
 954 {
 955         return mapname;
 956 }
 957
 958 float Map_Count, Map_Current;
 959 string Map_Current_Name;
 960
 961 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 962 float GetMaplistPosition()
 963 {
 964         float pos, idx;
 965         string map;
 966
 967         map = GetMapname();
 968         idx = autocvar_g_maplist_index;
 969
 970         if(idx >= 0)
 971                 if(idx < Map_Count)
 972                         if(map == argv(idx))
 973                                 return idx;
 974
 975         for(pos = 0; pos < Map_Count; ++pos)
 976                 if(map == argv(pos))
 977                         return pos;
 978
 979         // resume normal maplist rotation if current map is not in g_maplist
 980         return idx;
 981 }
 982
 983 float MapHasRightSize(string map)
 984 {
 985         float fh;
 986         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 987         if(autocvar_g_maplist_check_waypoints)
 988         {
 989                 dprint("checkwp "); dprint(map);
 990                 if(!fexists(strcat("maps/", map, ".waypoints")))
 991                 {
 992                         dprint(": no waypoints\n");
 993                         return FALSE;
 994                 }
 995                 dprint(": has waypoints\n");
 996         }
 997
 998         // open map size restriction file
 999         dprint("opensize "); dprint(map);
1000         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1001         if(fh >= 0)
1002         {
1003                 float mapmin, mapmax;
1004                 dprint(": ok, ");
1005                 mapmin = stof(fgets(fh));
1006                 mapmax = stof(fgets(fh));
1007                 fclose(fh);
1008                 if(player_count < mapmin)
1009                 {
1010                         dprint("not enough\n");
1011                         return FALSE;
1012                 }
1013                 if(player_count > mapmax)
1014                 {
1015                         dprint("too many\n");
1016                         return FALSE;
1017                 }
1018                 dprint("right size\n");
1019                 return TRUE;
1020         }
1021         dprint(": not found\n");
1022         return TRUE;
1023 }
1024
1025 string Map_Filename(float position)
1026 {
1027         return strcat("maps/", argv(position), ".bsp");
1028 }
1029
1030 string strwords(string s, float w)
1031 {
1032         float endpos;
1033         for(endpos = 0; w && endpos >= 0; --w)
1034                 endpos = strstrofs(s, " ", endpos + 1);
1035         if(endpos < 0)
1036                 return s;
1037         else
1038                 return substring(s, 0, endpos);
1039 }
1040
1041 float strhasword(string s, string w)
1042 {
1043         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1044 }
1045
1046 void Map_MarkAsRecent(string m)
1047 {
1048         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1049 }
1050
1051 float Map_IsRecent(string m)
1052 {
1053         return strhasword(autocvar_g_maplist_mostrecent, m);
1054 }
1055
1056 float Map_Check(float position, float pass)
1057 {
1058         string filename;
1059         string map_next;
1060         map_next = argv(position);
1061         if(pass <= 1)
1062         {
1063                 if(Map_IsRecent(map_next))
1064                         return 0;
1065         }
1066         filename = Map_Filename(position);
1067         if(MapInfo_CheckMap(map_next))
1068         {
1069                 if(pass == 2)
1070                         return 1;
1071                 if(MapHasRightSize(map_next))
1072                         return 1;
1073                 return 0;
1074         }
1075         else
1076                 dprint( "Couldn't select '", filename, "'..\n" );
1077
1078         return 0;
1079 }
1080
1081 void Map_Goto_SetStr(string nextmapname)
1082 {
1083         if(getmapname_stored != "")
1084                 strunzone(getmapname_stored);
1085         if(nextmapname == "")
1086                 getmapname_stored = "";
1087         else
1088                 getmapname_stored = strzone(nextmapname);
1089 }
1090
1091 void Map_Goto_SetFloat(float position)
1092 {
1093         cvar_set("g_maplist_index", ftos(position));
1094         Map_Goto_SetStr(argv(position));
1095 }
1096
1097 void Map_Goto(float reinit)
1098 {
1099         MapInfo_LoadMap(getmapname_stored, reinit);
1100 }
1101
1102 // return codes of map selectors:
1103 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1104 //   -2 = permanent failure
1105 float() MaplistMethod_Iterate = // usual method
1106 {
1107         float pass, i;
1108
1109         for(pass = 1; pass <= 2; ++pass)
1110         {
1111                 for(i = 1; i < Map_Count; ++i)
1112                 {
1113                         float mapindex;
1114                         mapindex = mod(i + Map_Current, Map_Count);
1115                         if(Map_Check(mapindex, pass))
1116                                 return mapindex;
1117                 }
1118         }
1119         return -1;
1120 }
1121
1122 float() MaplistMethod_Repeat = // fallback method
1123 {
1124         if(Map_Check(Map_Current, 2))
1125                 return Map_Current;
1126         return -2;
1127 }
1128
1129 float() MaplistMethod_Random = // random map selection
1130 {
1131         float i, imax;
1132
1133         imax = 42;
1134
1135         for(i = 0; i <= imax; ++i)
1136         {
1137                 float mapindex;
1138                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1139                 if(Map_Check(mapindex, 1))
1140                         return mapindex;
1141         }
1142         return -1;
1143 }
1144
1145 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1146 // the exponent sets a bias on the map selection:
1147 // the higher the exponent, the less likely "shortly repeated" same maps are
1148 {
1149         float i, j, imax, insertpos;
1150
1151         imax = 42;
1152
1153         for(i = 0; i <= imax; ++i)
1154         {
1155                 string newlist;
1156
1157                 // now reinsert this at another position
1158                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1159                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1160                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1161                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1162
1163                 // insert the current map there
1164                 newlist = "";
1165                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1166                         newlist = strcat(newlist, " ", argv(j));
1167                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1168                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1169                         newlist = strcat(newlist, " ", argv(j));
1170                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1171                 cvar_set("g_maplist", newlist);
1172                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1173
1174                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1175                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1176                 if(Map_Check(Map_Current, 1))
1177                         return Map_Current;
1178         }
1179         return -1;
1180 }
1181
1182 void Maplist_Init()
1183 {
1184         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1185         if(Map_Count == 0)
1186         {
1187                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1188                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1189                 if(autocvar_g_maplist_shuffle)
1190                         ShuffleMaplist();
1191                 localcmd("\nmenu_cmd sync\n");
1192                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193         }
1194         if(Map_Count == 0)
1195                 error("empty maplist, cannot select a new map");
1196         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1197
1198         if(Map_Current_Name)
1199                 strunzone(Map_Current_Name);
1200         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1201         // this may or may not be correct, but who cares, in the worst case a map
1202         // isn't chosen in the first pass that should have been
1203 }
1204
1205 string GetNextMap()
1206 {
1207         float nextMap;
1208
1209         Maplist_Init();
1210         nextMap = -1;
1211
1212         if(nextMap == -1)
1213                 if(autocvar_g_maplist_shuffle > 0)
1214                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1215
1216         if(nextMap == -1)
1217                 if(autocvar_g_maplist_selectrandom)
1218                         nextMap = MaplistMethod_Random();
1219
1220         if(nextMap == -1)
1221                 nextMap = MaplistMethod_Iterate();
1222
1223         if(nextMap == -1)
1224                 nextMap = MaplistMethod_Repeat();
1225
1226         if(nextMap >= 0)
1227         {
1228                 Map_Goto_SetFloat(nextMap);
1229                 return getmapname_stored;
1230         }
1231
1232         return "";
1233 }
1234
1235 float DoNextMapOverride(float reinit)
1236 {
1237         if(autocvar_g_campaign)
1238         {
1239                 CampaignPostIntermission();
1240                 alreadychangedlevel = TRUE;
1241                 return TRUE;
1242         }
1243         if(autocvar_quit_when_empty)
1244         {
1245                 if(player_count <= currentbots)
1246                 {
1247                         localcmd("quit\n");
1248                         alreadychangedlevel = TRUE;
1249                         return TRUE;
1250                 }
1251         }
1252         if(autocvar_quit_and_redirect != "")
1253         {
1254                 redirection_target = strzone(autocvar_quit_and_redirect);
1255                 alreadychangedlevel = TRUE;
1256                 return TRUE;
1257         }
1258         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1259         {
1260                 localcmd("restart\n");
1261                 alreadychangedlevel = TRUE;
1262                 return TRUE;
1263         }
1264         if(autocvar_nextmap != "")
1265                 if(MapInfo_CheckMap(autocvar_nextmap))
1266                 {
1267                         Map_Goto_SetStr(autocvar_nextmap);
1268                         Map_Goto(reinit);
1269                         alreadychangedlevel = TRUE;
1270                         return TRUE;
1271                 }
1272         if(!reinit && autocvar_lastlevel)
1273         {
1274                 cvar_settemp_restore();
1275                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1276                 alreadychangedlevel = TRUE;
1277                 return TRUE;
1278         }
1279         return FALSE;
1280 }
1281
1282 void GotoNextMap(float reinit)
1283 {
1284         //string nextmap;
1285         //float n, nummaps;
1286         //string s;
1287         if (alreadychangedlevel)
1288                 return;
1289         alreadychangedlevel = TRUE;
1290
1291         {
1292                 string nextMap;
1293                 float allowReset;
1294
1295                 for(allowReset = 1; allowReset >= 0; --allowReset)
1296                 {
1297                         nextMap = GetNextMap();
1298                         if(nextMap != "")
1299                                 break;
1300
1301                         if(allowReset)
1302                         {
1303                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1304                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1305                                 if(autocvar_g_maplist_shuffle)
1306                                         ShuffleMaplist();
1307                                 localcmd("\nmenu_cmd sync\n");
1308                         }
1309                         else
1310                         {
1311                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1312                         }
1313                 }
1314                 Map_Goto(reinit);
1315         }
1316 }
1317
1318
1319 /*
1320 ============
1321 IntermissionThink
1322
1323 When the player presses attack or jump, change to the next level
1324 ============
1325 */
1326 .float autoscreenshot;
1327 void() MapVote_Start;
1328 void() MapVote_Think;
1329 float mapvote_initialized;
1330 void IntermissionThink()
1331 {
1332         FixIntermissionClient(self);
1333
1334         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1335         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1336
1337         if( (server_screenshot || client_screenshot)
1338                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1339         {
1340                 self.autoscreenshot = -1;
1341                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1342                 return;
1343         }
1344
1345         if (time < intermission_exittime)
1346                 return;
1347
1348         if(!mapvote_initialized)
1349                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1350                         return;
1351
1352         MapVote_Start();
1353 }
1354
1355 /*
1356 ============
1357 FindIntermission
1358
1359 Returns the entity to view from
1360 ============
1361 */
1362 /*
1363 entity FindIntermission()
1364 {
1365         local   entity spot;
1366         local   float cyc;
1367
1368 // look for info_intermission first
1369         spot = find (world, classname, "info_intermission");
1370         if (spot)
1371         {       // pick a random one
1372                 cyc = random() * 4;
1373                 while (cyc > 1)
1374                 {
1375                         spot = find (spot, classname, "info_intermission");
1376                         if (!spot)
1377                                 spot = find (spot, classname, "info_intermission");
1378                         cyc = cyc - 1;
1379                 }
1380                 return spot;
1381         }
1382
1383 // then look for the start position
1384         spot = find (world, classname, "info_player_start");
1385         if (spot)
1386                 return spot;
1387
1388 // testinfo_player_start is only found in regioned levels
1389         spot = find (world, classname, "testplayerstart");
1390         if (spot)
1391                 return spot;
1392
1393 // then look for the start position
1394         spot = find (world, classname, "info_player_deathmatch");
1395         if (spot)
1396                 return spot;
1397
1398         //objerror ("FindIntermission: no spot");
1399         return world;
1400 }
1401 */
1402
1403 /*
1404 ===============================================================================
1405
1406 RULES
1407
1408 ===============================================================================
1409 */
1410
1411 void DumpStats(float final)
1412 {
1413         float file;
1414         string s;
1415         float to_console;
1416         float to_eventlog;
1417         float to_file;
1418         float i;
1419
1420         to_console = autocvar_sv_logscores_console;
1421         to_eventlog = autocvar_sv_eventlog;
1422         to_file = autocvar_sv_logscores_file;
1423
1424         if(!final)
1425         {
1426                 to_console = TRUE; // always print printstats replies
1427                 to_eventlog = FALSE; // but never print them to the event log
1428         }
1429
1430         if(to_eventlog)
1431                 if(autocvar_sv_eventlog_console)
1432                         to_console = FALSE; // otherwise we get the output twice
1433
1434         if(final)
1435                 s = ":scores:";
1436         else
1437                 s = ":status:";
1438         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1439
1440         if(to_console)
1441                 print(s, "\n");
1442         if(to_eventlog)
1443                 GameLogEcho(s);
1444
1445         file = -1;
1446         if(to_file)
1447         {
1448                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1449                 if(file == -1)
1450                         to_file = FALSE;
1451                 else
1452                         fputs(file, strcat(s, "\n"));
1453         }
1454
1455         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1456         if(to_console)
1457                 print(s, "\n");
1458         if(to_eventlog)
1459                 GameLogEcho(s);
1460         if(to_file)
1461                 fputs(file, strcat(s, "\n"));
1462
1463         FOR_EACH_CLIENT(other)
1464         {
1465                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1466                 {
1467                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1468                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1469                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1470                                 s = strcat(s, ftos(other.team), ":");
1471                         else
1472                                 s = strcat(s, "spectator:");
1473
1474                         if(to_console)
1475                                 print(s, other.netname, "\n");
1476                         if(to_eventlog)
1477                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1478                         if(to_file)
1479                                 fputs(file, strcat(s, other.netname, "\n"));
1480                 }
1481         }
1482
1483         if(teamplay)
1484         {
1485                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1486                 if(to_console)
1487                         print(s, "\n");
1488                 if(to_eventlog)
1489                         GameLogEcho(s);
1490                 if(to_file)
1491                         fputs(file, strcat(s, "\n"));
1492
1493                 for(i = 1; i < 16; ++i)
1494                 {
1495                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1496                         s = strcat(s, ":", ftos(i));
1497                         if(to_console)
1498                                 print(s, "\n");
1499                         if(to_eventlog)
1500                                 GameLogEcho(s);
1501                         if(to_file)
1502                                 fputs(file, strcat(s, "\n"));
1503                 }
1504         }
1505
1506         if(to_console)
1507                 print(":end\n");
1508         if(to_eventlog)
1509                 GameLogEcho(":end");
1510         if(to_file)
1511         {
1512                 fputs(file, ":end\n");
1513                 fclose(file);
1514         }
1515 }
1516
1517 void FixIntermissionClient(entity e)
1518 {
1519         string s;
1520         if(!e.autoscreenshot) // initial call
1521         {
1522                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1523                 e.health = -2342;
1524                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1525                 e.solid = SOLID_NOT;
1526                 e.movetype = MOVETYPE_NONE;
1527                 e.takedamage = DAMAGE_NO;
1528                 if(e.weaponentity)
1529                 {
1530                         e.weaponentity.effects = EF_NODRAW;
1531                         if (e.weaponentity.weaponentity)
1532                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1533                 }
1534                 if(clienttype(e) == CLIENTTYPE_REAL)
1535                 {
1536                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1537                         s = autocvar_sv_intermission_cdtrack;
1538                         if(s != "")
1539                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1540                         msg_entity = e;
1541                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1542                 }
1543         }
1544 }
1545
1546 void minstagib_stop_countdown(entity e);
1547 /*
1548 go to the next level for deathmatch
1549 only called if a time or frag limit has expired
1550 */
1551 void NextLevel()
1552 {
1553         gameover = TRUE;
1554
1555         intermission_running = 1;
1556
1557 // enforce a wait time before allowing changelevel
1558         if(player_count > 0)
1559                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1560         else
1561                 intermission_exittime = -1;
1562
1563         /*
1564         WriteByte (MSG_ALL, SVC_CDTRACK);
1565         WriteByte (MSG_ALL, 3);
1566         WriteByte (MSG_ALL, 3);
1567         // done in FixIntermission
1568         */
1569
1570         //pos = FindIntermission ();
1571
1572         VoteReset();
1573
1574         DumpStats(TRUE);
1575
1576         // send statistics
1577         entity e;
1578         PlayerStats_EndMatch(1);
1579         FOR_EACH_CLIENT(e)
1580                 PlayerStats_AddGlobalInfo(e);
1581         PlayerStats_Shutdown();
1582         WeaponStats_Shutdown();
1583
1584         if(autocvar_sv_eventlog)
1585                 GameLogEcho(":gameover");
1586
1587         GameLogClose();
1588
1589         FOR_EACH_PLAYER(other) {
1590                 minstagib_stop_countdown(other);
1591                 FixIntermissionClient(other);
1592                 if(other.winning)
1593                         bprint(other.netname, " ^7wins.\n");
1594         }
1595
1596         if(autocvar_g_campaign)
1597                 CampaignPreIntermission();
1598
1599         localcmd("\nsv_hook_gameend\n");
1600 }
1601
1602 /*
1603 ============
1604 CheckRules_Player
1605
1606 Exit deathmatch games upon conditions
1607 ============
1608 */
1609 void CheckRules_Player()
1610 {
1611         if (gameover)   // someone else quit the game already
1612                 return;
1613
1614         if(self.deadflag == DEAD_NO)
1615                 self.play_time += frametime;
1616
1617         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1618         //   (div0: and that in CheckRules_World please)
1619 }
1620
1621 float checkrules_equality;
1622 float checkrules_suddendeathwarning;
1623 float checkrules_suddendeathend;
1624 float checkrules_overtimesadded; //how many overtimes have been already added
1625
1626 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1627 float WINNING_YES = 1; // winner found
1628 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1629 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1630
1631 float InitiateSuddenDeath()
1632 {
1633         // Check first whether normal overtimes could be added before initiating suddendeath mode
1634         // - for this timelimit_overtime needs to be >0 of course
1635         // - also check the winning condition calculated in the previous frame and only add normal overtime
1636         //   again, if at the point at which timelimit would be extended again, still no winner was found
1637         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1638         {
1639                 return 1; // need to call InitiateOvertime later
1640         }
1641         else
1642         {
1643                 if(!checkrules_suddendeathend)
1644                 {
1645                         if(autocvar_g_campaign)
1646                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1647                         else
1648                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1649                         if(g_race && !g_race_qualifying)
1650                                 race_StartCompleting();
1651                 }
1652                 return 0;
1653         }
1654 }
1655
1656 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1657 {
1658         ++checkrules_overtimesadded;
1659         //add one more overtime by simply extending the timelimit
1660         float tl;
1661         tl = autocvar_timelimit;
1662         tl += autocvar_timelimit_overtime;
1663         cvar_set("timelimit", ftos(tl));
1664         string minutesPlural;
1665         if (autocvar_timelimit_overtime == 1)
1666                 minutesPlural = " ^3minute";
1667         else
1668                 minutesPlural = " ^3minutes";
1669
1670         bcenterprint(
1671                 strcat(
1672                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1673                         ftos(autocvar_timelimit_overtime),
1674                         minutesPlural,
1675                         " to the game!"
1676                 )
1677         );
1678 }
1679
1680 float GetWinningCode(float fraglimitreached, float equality)
1681 {
1682         if(autocvar_g_campaign == 1)
1683                 if(fraglimitreached)
1684                         return WINNING_YES;
1685                 else
1686                         return WINNING_NO;
1687
1688         else
1689                 if(equality)
1690                         if(fraglimitreached)
1691                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1692                         else
1693                                 return WINNING_NEVER;
1694                 else
1695                         if(fraglimitreached)
1696                                 return WINNING_YES;
1697                         else
1698                                 return WINNING_NO;
1699 }
1700
1701 // set the .winning flag for exactly those players with a given field value
1702 void SetWinners(.float field, float value)
1703 {
1704         entity head;
1705         FOR_EACH_PLAYER(head)
1706                 head.winning = (head.field == value);
1707 }
1708
1709 // set the .winning flag for those players with a given field value
1710 void AddWinners(.float field, float value)
1711 {
1712         entity head;
1713         FOR_EACH_PLAYER(head)
1714                 if(head.field == value)
1715                         head.winning = 1;
1716 }
1717
1718 // clear the .winning flags
1719 void ClearWinners(void)
1720 {
1721         entity head;
1722         FOR_EACH_PLAYER(head)
1723                 head.winning = 0;
1724 }
1725
1726 // Onslaught winning condition:
1727 // game terminates if only one team has a working generator (or none)
1728 float WinningCondition_Onslaught()
1729 {
1730         entity head;
1731         float t1, t2, t3, t4;
1732
1733         WinningConditionHelper(); // set worldstatus
1734
1735         if(inWarmupStage)
1736                 return WINNING_NO;
1737
1738         // first check if the game has ended
1739         t1 = t2 = t3 = t4 = 0;
1740         head = find(world, classname, "onslaught_generator");
1741         while (head)
1742         {
1743                 if (head.health > 0)
1744                 {
1745                         if (head.team == COLOR_TEAM1) t1 = 1;
1746                         if (head.team == COLOR_TEAM2) t2 = 1;
1747                         if (head.team == COLOR_TEAM3) t3 = 1;
1748                         if (head.team == COLOR_TEAM4) t4 = 1;
1749                 }
1750                 head = find(head, classname, "onslaught_generator");
1751         }
1752         if (t1 + t2 + t3 + t4 < 2)
1753         {
1754                 // game over, only one team remains (or none)
1755                 ClearWinners();
1756                 if (t1) SetWinners(team, COLOR_TEAM1);
1757                 if (t2) SetWinners(team, COLOR_TEAM2);
1758                 if (t3) SetWinners(team, COLOR_TEAM3);
1759                 if (t4) SetWinners(team, COLOR_TEAM4);
1760                 dprint("Have a winner, ending game.\n");
1761                 return WINNING_YES;
1762         }
1763
1764         // Two or more teams remain
1765         return WINNING_NO;
1766 }
1767
1768 float LMS_NewPlayerLives()
1769 {
1770         float fl;
1771         fl = autocvar_fraglimit;
1772         if(fl == 0)
1773                 fl = 999;
1774
1775         // first player has left the game for dying too much? Nobody else can get in.
1776         if(lms_lowest_lives < 1)
1777                 return 0;
1778
1779         if(!autocvar_g_lms_join_anytime)
1780                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1781                         return 0;
1782
1783         return bound(1, lms_lowest_lives, fl);
1784 }
1785
1786 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1787 // they win. Otherwise the defending team wins once the timelimit passes.
1788 void assault_new_round();
1789 float WinningCondition_Assault()
1790 {
1791         float status;
1792
1793         WinningConditionHelper(); // set worldstatus
1794
1795         status = WINNING_NO;
1796         // as the timelimit has not yet passed just assume the defending team will win
1797         if(assault_attacker_team == COLOR_TEAM1)
1798         {
1799                 SetWinners(team, COLOR_TEAM2);
1800         }
1801         else
1802         {
1803                 SetWinners(team, COLOR_TEAM1);
1804         }
1805
1806         entity ent;
1807         ent = find(world, classname, "target_assault_roundend");
1808         if(ent)
1809         {
1810                 if(ent.winning) // round end has been triggered by attacking team
1811                 {
1812                         bprint("ASSAULT: round completed...\n");
1813                         SetWinners(team, assault_attacker_team);
1814
1815                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1816
1817                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1818                         {
1819                                 status = WINNING_YES;
1820                         }
1821                         else
1822                         {
1823                                 entity oldself;
1824                                 oldself = self;
1825                                 self = ent;
1826                                 assault_new_round();
1827                                 self = oldself;
1828                         }
1829                 }
1830         }
1831
1832         return status;
1833 }
1834
1835 // LMS winning condition: game terminates if and only if there's at most one
1836 // one player who's living lives. Top two scores being equal cancels the time
1837 // limit.
1838 float WinningCondition_LMS()
1839 {
1840         entity head, head2;
1841         float have_player;
1842         float have_players;
1843         float l;
1844
1845         have_player = FALSE;
1846         have_players = FALSE;
1847         l = LMS_NewPlayerLives();
1848
1849         head = find(world, classname, "player");
1850         if(head)
1851                 have_player = TRUE;
1852         head2 = find(head, classname, "player");
1853         if(head2)
1854                 have_players = TRUE;
1855
1856         if(have_player)
1857         {
1858                 // we have at least one player
1859                 if(have_players)
1860                 {
1861                         // two or more active players - continue with the game
1862                 }
1863                 else
1864                 {
1865                         // exactly one player?
1866
1867                         ClearWinners();
1868                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1869
1870                         if(l)
1871                         {
1872                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1873                                 return WINNING_NO;
1874                         }
1875                         else
1876                         {
1877                                 // a winner!
1878                                 // and assign him his first place
1879                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1880                                 return WINNING_YES;
1881                         }
1882                 }
1883         }
1884         else
1885         {
1886                 // nobody is playing at all...
1887                 if(l)
1888                 {
1889                         // wait for players...
1890                 }
1891                 else
1892                 {
1893                         // SNAFU (maybe a draw game?)
1894                         ClearWinners();
1895                         dprint("No players, ending game.\n");
1896                         return WINNING_YES;
1897                 }
1898         }
1899
1900         // When we get here, we have at least two players who are actually LIVING,
1901         // now check if the top two players have equal score.
1902         WinningConditionHelper();
1903
1904         ClearWinners();
1905         if(WinningConditionHelper_winner)
1906                 WinningConditionHelper_winner.winning = TRUE;
1907         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1908                 return WINNING_NEVER;
1909
1910         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1911         return WINNING_NO;
1912 }
1913
1914 void ShuffleMaplist()
1915 {
1916         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1917 }
1918
1919 float leaderfrags;
1920 float WinningCondition_Scores(float limit, float leadlimit)
1921 {
1922         float limitreached;
1923
1924         // TODO make everything use THIS winning condition (except LMS)
1925         WinningConditionHelper();
1926
1927         if(teamplay)
1928         {
1929                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1930                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1931                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1932                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1933         }
1934
1935         ClearWinners();
1936         if(WinningConditionHelper_winner)
1937                 WinningConditionHelper_winner.winning = 1;
1938         if(WinningConditionHelper_winnerteam >= 0)
1939                 SetWinners(team, WinningConditionHelper_winnerteam);
1940
1941         if(WinningConditionHelper_lowerisbetter)
1942         {
1943                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1944                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1945                 limit = -limit;
1946         }
1947
1948         if(WinningConditionHelper_zeroisworst)
1949                 leadlimit = 0; // not supported in this mode
1950
1951         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1952         // these modes always score in increments of 1, thus this makes sense
1953         {
1954                 if(leaderfrags != WinningConditionHelper_topscore)
1955                 {
1956                         leaderfrags = WinningConditionHelper_topscore;
1957
1958                         if (limit)
1959                         if (leaderfrags == limit - 1)
1960                                 Announce("1fragleft");
1961                         else if (leaderfrags == limit - 2)
1962                                 Announce("2fragsleft");
1963                         else if (leaderfrags == limit - 3)
1964                                 Announce("3fragsleft");
1965                 }
1966         }
1967
1968         limitreached = FALSE;
1969         if(limit)
1970                 if(WinningConditionHelper_topscore >= limit)
1971                         limitreached = TRUE;
1972         if(leadlimit)
1973         {
1974                 float leadlimitreached;
1975                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1976                 if(autocvar_leadlimit_and_fraglimit)
1977                         limitreached = (limitreached && leadlimitreached);
1978                 else
1979                         limitreached = (limitreached || leadlimitreached);
1980         }
1981
1982         game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / max(1, limit), 1));
1983
1984         return GetWinningCode(
1985                 WinningConditionHelper_topscore && limitreached,
1986                 WinningConditionHelper_equality
1987         );
1988 }
1989
1990 float WinningCondition_Race(float fraglimit)
1991 {
1992         float wc;
1993         entity p;
1994         float n, c;
1995
1996         n = 0;
1997         c = 0;
1998         FOR_EACH_PLAYER(p)
1999         {
2000                 ++n;
2001                 if(p.race_completed)
2002                         ++c;
2003         }
2004         if(n && (n == c))
2005                 return WINNING_YES;
2006         wc = WinningCondition_Scores(fraglimit, 0);
2007
2008         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2009         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2010         // do NOT support equality when the laps are all raced!
2011                 return WINNING_STARTSUDDENDEATHOVERTIME;
2012         else
2013                 return WINNING_NEVER;
2014         return wc;
2015 }
2016
2017 float WinningCondition_QualifyingThenRace(float limit)
2018 {
2019         float wc;
2020         wc = WinningCondition_Scores(limit, 0);
2021
2022         // NEVER initiate overtime
2023         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2024         {
2025                 return WINNING_YES;
2026         }
2027
2028         return wc;
2029 }
2030
2031 float WinningCondition_RanOutOfSpawns()
2032 {
2033         entity head;
2034
2035         if(have_team_spawns <= 0)
2036                 return WINNING_NO;
2037
2038         if(autocvar_g_spawn_useallspawns <= 0)
2039                 return WINNING_NO;
2040
2041         if(!some_spawn_has_been_used)
2042                 return WINNING_NO;
2043
2044         team1_score = team2_score = team3_score = team4_score = 0;
2045
2046         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2047         {
2048                 if(head.team == COLOR_TEAM1)
2049                         team1_score = 1;
2050                 else if(head.team == COLOR_TEAM2)
2051                         team2_score = 1;
2052                 else if(head.team == COLOR_TEAM3)
2053                         team3_score = 1;
2054                 else if(head.team == COLOR_TEAM4)
2055                         team4_score = 1;
2056         }
2057
2058         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2059         {
2060                 if(head.team == COLOR_TEAM1)
2061                         team1_score = 1;
2062                 else if(head.team == COLOR_TEAM2)
2063                         team2_score = 1;
2064                 else if(head.team == COLOR_TEAM3)
2065                         team3_score = 1;
2066                 else if(head.team == COLOR_TEAM4)
2067                         team4_score = 1;
2068         }
2069
2070         ClearWinners();
2071         if(team1_score + team2_score + team3_score + team4_score == 0)
2072         {
2073                 checkrules_equality = TRUE;
2074                 return WINNING_YES;
2075         }
2076         else if(team1_score + team2_score + team3_score + team4_score == 1)
2077         {
2078                 float t, i;
2079                 if(team1_score)
2080                         t = COLOR_TEAM1;
2081                 else if(team2_score)
2082                         t = COLOR_TEAM2;
2083                 else if(team3_score)
2084                         t = COLOR_TEAM3;
2085                 else // if(team4_score)
2086                         t = COLOR_TEAM4;
2087                 CheckAllowedTeams(world);
2088                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2089                 {
2090                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2091                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2092                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2093                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2094                 }
2095
2096                 AddWinners(team, t);
2097                 return WINNING_YES;
2098         }
2099         else
2100                 return WINNING_NO;
2101 }
2102
2103 /*
2104 ============
2105 CheckRules_World
2106
2107 Exit deathmatch games upon conditions
2108 ============
2109 */
2110 void ReadyRestart();
2111 void CheckRules_World()
2112 {
2113         float timelimit;
2114         float fraglimit;
2115         float leadlimit;
2116
2117         VoteThink();
2118         MapVote_Think();
2119
2120         SetDefaultAlpha();
2121
2122         /*
2123         MapVote_Think should now do that part
2124         if (intermission_running)
2125                 if (time >= intermission_exittime + 60)
2126                 {
2127                         if(!DoNextMapOverride())
2128                                 GotoNextMap();
2129                         return;
2130                 }
2131         */
2132
2133         if (gameover)   // someone else quit the game already
2134         {
2135                 if(player_count == 0) // Nobody there? Then let's go to the next map
2136                         MapVote_Start();
2137                         // this will actually check the player count in the next frame
2138                         // again, but this shouldn't hurt
2139                 return;
2140         }
2141
2142         timelimit = autocvar_timelimit * 60;
2143         fraglimit = autocvar_fraglimit;
2144         leadlimit = autocvar_leadlimit;
2145
2146         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2147         {
2148                 if(timelimit > 0)
2149                         timelimit = 0; // timelimit is not made for warmup
2150                 if(fraglimit > 0)
2151                         fraglimit = 0; // no fraglimit for now
2152                 leadlimit = 0; // no leadlimit for now
2153         }
2154
2155         if(timelimit > 0)
2156         {
2157                 timelimit += game_starttime;
2158         }
2159         else if (timelimit < 0)
2160         {
2161                 // endmatch
2162                 NextLevel();
2163                 return;
2164         }
2165
2166         if(g_onslaught)
2167                 timelimit = 0; // ONS has its own overtime rule
2168
2169         float wantovertime;
2170         wantovertime = 0;
2171
2172         if(timelimit > game_starttime)
2173                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2174         else
2175                 game_completion_ratio = 0;
2176
2177         if(checkrules_suddendeathend)
2178         {
2179                 if(!checkrules_suddendeathwarning)
2180                 {
2181                         checkrules_suddendeathwarning = TRUE;
2182                         if(g_race && !g_race_qualifying)
2183                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2184                         else
2185                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2186                 }
2187         }
2188         else
2189         {
2190                 if (timelimit && time >= timelimit)
2191                 {
2192                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2193                         {
2194                                 float totalplayers;
2195                                 float playerswithlaps;
2196                                 float readyplayers;
2197                                 entity head;
2198                                 totalplayers = playerswithlaps = readyplayers = 0;
2199                                 FOR_EACH_PLAYER(head)
2200                                 {
2201                                         ++totalplayers;
2202                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2203                                                 ++playerswithlaps;
2204                                         if(head.ready)
2205                                                 ++readyplayers;
2206                                 }
2207
2208                                 // at least 2 of the players have completed a lap: start the RACE
2209                                 // otherwise, the players should end the qualifying on their own
2210                                 if(readyplayers || playerswithlaps >= 2)
2211                                 {
2212                                         checkrules_suddendeathend = 0;
2213                                         ReadyRestart(); // go to race
2214                                         return;
2215                                 }
2216                                 else
2217                                         wantovertime |= InitiateSuddenDeath();
2218                         }
2219                         else
2220                                 wantovertime |= InitiateSuddenDeath();
2221                 }
2222         }
2223
2224         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2225         {
2226                 NextLevel();
2227                 return;
2228         }
2229
2230         float checkrules_status;
2231         checkrules_status = WinningCondition_RanOutOfSpawns();
2232         if(checkrules_status == WINNING_YES)
2233         {
2234                 bprint("Hey! Someone ran out of spawns!\n");
2235         }
2236         else if(g_race && !g_race_qualifying && timelimit >= 0)
2237         {
2238                 checkrules_status = WinningCondition_Race(fraglimit);
2239                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2240         }
2241         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2242         {
2243                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2244                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2245         }
2246         else if(g_assault)
2247         {
2248                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2249         }
2250         else if(g_lms)
2251         {
2252                 checkrules_status = WinningCondition_LMS();
2253         }
2254         else if (g_onslaught)
2255         {
2256                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2257         }
2258         else
2259         {
2260                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2261                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2262         }
2263
2264         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2265         {
2266                 checkrules_status = WINNING_NEVER;
2267                 checkrules_overtimesadded = -1;
2268                 wantovertime |= InitiateSuddenDeath();
2269         }
2270
2271         if(checkrules_status == WINNING_NEVER)
2272                 // equality cases! Nobody wins if the overtime ends in a draw.
2273                 ClearWinners();
2274
2275         if(wantovertime)
2276         {
2277                 if(checkrules_status == WINNING_NEVER)
2278                         InitiateOvertime();
2279                 else
2280                         checkrules_status = WINNING_YES;
2281         }
2282
2283         if(checkrules_suddendeathend)
2284                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2285                         checkrules_status = WINNING_YES;
2286
2287         if(checkrules_status == WINNING_YES)
2288         {
2289                 //print("WINNING\n");
2290                 NextLevel();
2291         }
2292 }
2293
2294 float mapvote_nextthink;
2295 float mapvote_initialized;
2296 float mapvote_keeptwotime;
2297 float mapvote_timeout;
2298 string mapvote_message;
2299 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2300 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2301 float mapvote_screenshot_dirs_count;
2302
2303 float mapvote_count;
2304 float mapvote_count_real;
2305 string mapvote_maps[MAPVOTE_COUNT];
2306 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2307 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2308 float mapvote_maps_suggested[MAPVOTE_COUNT];
2309 string mapvote_suggestions[MAPVOTE_COUNT];
2310 float mapvote_suggestion_ptr;
2311 float mapvote_voters;
2312 float mapvote_selections[MAPVOTE_COUNT];
2313 float mapvote_run;
2314 float mapvote_detail;
2315 float mapvote_abstain;
2316 .float mapvote;
2317
2318 void MapVote_ClearAllVotes()
2319 {
2320         FOR_EACH_CLIENT(other)
2321                 other.mapvote = 0;
2322 }
2323
2324 string MapVote_Suggest(string m)
2325 {
2326         float i;
2327         if(m == "")
2328                 return "That's not how to use this command.";
2329         if(!autocvar_g_maplist_votable_suggestions)
2330                 return "Suggestions are not accepted on this server.";
2331         if(mapvote_initialized)
2332                 return "Can't suggest - voting is already in progress!";
2333         m = MapInfo_FixName(m);
2334         if(!m)
2335                 return "The map you suggested is not available on this server.";
2336         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2337                 if(Map_IsRecent(m))
2338                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2339
2340         if(!MapInfo_CheckMap(m))
2341                 return "The map you suggested does not support the current game mode.";
2342         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2343                 if(mapvote_suggestions[i] == m)
2344                         return "This map was already suggested.";
2345         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2346         {
2347                 i = floor(random() * mapvote_suggestion_ptr);
2348         }
2349         else
2350         {
2351                 i = mapvote_suggestion_ptr;
2352                 mapvote_suggestion_ptr += 1;
2353         }
2354         if(mapvote_suggestions[i] != "")
2355                 strunzone(mapvote_suggestions[i]);
2356         mapvote_suggestions[i] = strzone(m);
2357         if(autocvar_sv_eventlog)
2358                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2359         return strcat("Suggestion of ", m, " accepted.");
2360 }
2361
2362 void MapVote_AddVotable(string nextMap, float isSuggestion)
2363 {
2364         float j, i, o;
2365         string pakfile, mapfile;
2366
2367         if(nextMap == "")
2368                 return;
2369         for(j = 0; j < mapvote_count; ++j)
2370                 if(mapvote_maps[j] == nextMap)
2371                         return;
2372         // suggestions might be no longer valid/allowed after gametype switch!
2373         if(isSuggestion)
2374                 if(!MapInfo_CheckMap(nextMap))
2375                         return;
2376         mapvote_maps[mapvote_count] = strzone(nextMap);
2377         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2378
2379         pakfile = string_null;
2380         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2381         {
2382                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2383                 pakfile = whichpack(strcat(mapfile, ".tga"));
2384                 if(pakfile == "")
2385                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2386                 if(pakfile == "")
2387                         pakfile = whichpack(strcat(mapfile, ".png"));
2388                 if(pakfile != "")
2389                         break;
2390         }
2391         if(i >= mapvote_screenshot_dirs_count)
2392                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2393         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2394                 pakfile = substring(pakfile, o, -1);
2395
2396         mapvote_maps_screenshot_dir[mapvote_count] = i;
2397         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2398
2399         mapvote_count += 1;
2400 }
2401
2402 void MapVote_Spawn();
2403 void MapVote_Init()
2404 {
2405         float i;
2406         float nmax, smax;
2407
2408         MapVote_ClearAllVotes();
2409
2410         mapvote_count = 0;
2411         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2412         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2413
2414         if(mapvote_abstain)
2415                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2416         else
2417                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2418         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2419
2420         // we need this for AddVotable, as that cycles through the screenshot dirs
2421         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2422         if(mapvote_screenshot_dirs_count == 0)
2423                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2424         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2425         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2426                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2427
2428         if(mapvote_suggestion_ptr)
2429                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2430                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2431
2432         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2433                 MapVote_AddVotable(GetNextMap(), FALSE);
2434
2435         if(mapvote_count == 0)
2436         {
2437                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2438                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2439                 if(autocvar_g_maplist_shuffle)
2440                         ShuffleMaplist();
2441                 localcmd("\nmenu_cmd sync\n");
2442                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2443                         MapVote_AddVotable(GetNextMap(), FALSE);
2444         }
2445
2446         mapvote_count_real = mapvote_count;
2447         if(mapvote_abstain)
2448                 MapVote_AddVotable("don't care", 0);
2449
2450         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2451
2452         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2453         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2454         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2455                 mapvote_keeptwotime = 0;
2456         mapvote_message = "Choose a map and press its key!";
2457
2458         MapVote_Spawn();
2459 }
2460
2461 void MapVote_SendPicture(float id)
2462 {
2463         msg_entity = self;
2464         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2465         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2466         WriteByte(MSG_ONE, id);
2467         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2468 }
2469
2470 float MapVote_GetMapMask()
2471 {
2472         float mask, i, power;
2473         mask = 0;
2474         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2475                 if(mapvote_maps[i] != "")
2476                         mask |= power;
2477         return mask;
2478 }
2479
2480 entity mapvote_ent;
2481 float MapVote_SendEntity(entity to, float sf)
2482 {
2483         float i;
2484
2485         if(sf & 1)
2486                 sf &~= 2; // if we send 1, we don't need to also send 2
2487
2488         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2489         WriteByte(MSG_ENTITY, sf);
2490
2491         if(sf & 1)
2492         {
2493                 // flag 1 == initialization
2494                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2495                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2496                 WriteString(MSG_ENTITY, "");
2497                 WriteByte(MSG_ENTITY, mapvote_count);
2498                 WriteByte(MSG_ENTITY, mapvote_abstain);
2499                 WriteByte(MSG_ENTITY, mapvote_detail);
2500                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2501                 if(mapvote_count <= 8)
2502                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2503                 else
2504                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2505                 for(i = 0; i < mapvote_count; ++i)
2506                         if(mapvote_maps[i] != "")
2507                         {
2508                                 if(mapvote_abstain && i == mapvote_count - 1)
2509                                 {
2510                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2511                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2512                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2513                                 }
2514                                 else
2515                                 {
2516                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2517                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2518                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2519                                 }
2520                         }
2521         }
2522
2523         if(sf & 2)
2524         {
2525                 // flag 2 == update of mask
2526                 if(mapvote_count <= 8)
2527                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2528                 else
2529                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2530         }
2531
2532         if(sf & 4)
2533         {
2534                 if(mapvote_detail)
2535                         for(i = 0; i < mapvote_count; ++i)
2536                                 if(mapvote_maps[i] != "")
2537                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2538
2539                 WriteByte(MSG_ENTITY, to.mapvote);
2540         }
2541
2542         return TRUE;
2543 }
2544
2545 void MapVote_Spawn()
2546 {
2547         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2548 }
2549
2550 void MapVote_TouchMask()
2551 {
2552         mapvote_ent.SendFlags |= 2;
2553 }
2554
2555 void MapVote_TouchVotes(entity voter)
2556 {
2557         mapvote_ent.SendFlags |= 4;
2558 }
2559
2560 float MapVote_Finished(float mappos)
2561 {
2562         string result;
2563         float i;
2564         float didntvote;
2565
2566         if(autocvar_sv_eventlog)
2567         {
2568                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2569                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2570                 didntvote = mapvote_voters;
2571                 for(i = 0; i < mapvote_count; ++i)
2572                         if(mapvote_maps[i] != "")
2573                         {
2574                                 didntvote -= mapvote_selections[i];
2575                                 if(i != mappos)
2576                                 {
2577                                         result = strcat(result, ":", mapvote_maps[i]);
2578                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2579                                 }
2580                         }
2581                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2582
2583                 GameLogEcho(result);
2584                 if(mapvote_maps_suggested[mappos])
2585                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2586         }
2587
2588         FOR_EACH_REALCLIENT(other)
2589                 FixClientCvars(other);
2590
2591         Map_Goto_SetStr(mapvote_maps[mappos]);
2592         Map_Goto(0);
2593         alreadychangedlevel = TRUE;
2594         return TRUE;
2595 }
2596 void MapVote_CheckRules_1()
2597 {
2598         float i;
2599
2600         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2601         {
2602                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2603                 mapvote_selections[i] = 0;
2604         }
2605
2606         mapvote_voters = 0;
2607         FOR_EACH_REALCLIENT(other)
2608         {
2609                 ++mapvote_voters;
2610                 if(other.mapvote)
2611                 {
2612                         i = other.mapvote - 1;
2613                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2614                         mapvote_selections[i] = mapvote_selections[i] + 1;
2615                 }
2616         }
2617 }
2618
2619 float MapVote_CheckRules_2()
2620 {
2621         float i;
2622         float firstPlace, secondPlace;
2623         float firstPlaceVotes, secondPlaceVotes;
2624         float mapvote_voters_real;
2625         string result;
2626
2627         if(mapvote_count_real == 1)
2628                 return MapVote_Finished(0);
2629
2630         mapvote_voters_real = mapvote_voters;
2631         if(mapvote_abstain)
2632                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2633
2634         RandomSelection_Init();
2635         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2636                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2637         firstPlace = RandomSelection_chosen_float;
2638         firstPlaceVotes = RandomSelection_best_priority;
2639         //dprint("First place: ", ftos(firstPlace), "\n");
2640         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2641
2642         RandomSelection_Init();
2643         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2644                 if(i != firstPlace)
2645                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2646         secondPlace = RandomSelection_chosen_float;
2647         secondPlaceVotes = RandomSelection_best_priority;
2648         //dprint("Second place: ", ftos(secondPlace), "\n");
2649         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2650
2651         if(firstPlace == -1)
2652                 error("No first place in map vote... WTF?");
2653
2654         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2655                 return MapVote_Finished(firstPlace);
2656
2657         if(mapvote_keeptwotime)
2658                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2659                 {
2660                         float didntvote;
2661                         MapVote_TouchMask();
2662                         mapvote_message = "Now decide between the TOP TWO!";
2663                         mapvote_keeptwotime = 0;
2664                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2665                         result = strcat(result, ":", ftos(firstPlaceVotes));
2666                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2667                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2668                         didntvote = mapvote_voters;
2669                         for(i = 0; i < mapvote_count; ++i)
2670                                 if(mapvote_maps[i] != "")
2671                                 {
2672                                         didntvote -= mapvote_selections[i];
2673                                         if(i != firstPlace)
2674                                                 if(i != secondPlace)
2675                                                 {
2676                                                         result = strcat(result, ":", mapvote_maps[i]);
2677                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2678                                                         if(i < mapvote_count_real)
2679                                                         {
2680                                                                 strunzone(mapvote_maps[i]);
2681                                                                 mapvote_maps[i] = "";
2682                                                                 strunzone(mapvote_maps_pakfile[i]);
2683                                                                 mapvote_maps_pakfile[i] = "";
2684                                                         }
2685                                                 }
2686                                 }
2687                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2688                         if(autocvar_sv_eventlog)
2689                                 GameLogEcho(result);
2690                 }
2691
2692         return FALSE;
2693 }
2694 void MapVote_Tick()
2695 {
2696         float keeptwo;
2697         float totalvotes;
2698
2699         keeptwo = mapvote_keeptwotime;
2700         MapVote_CheckRules_1(); // count
2701         if(MapVote_CheckRules_2()) // decide
2702                 return;
2703
2704         totalvotes = 0;
2705         FOR_EACH_REALCLIENT(other)
2706         {
2707                 // hide scoreboard again
2708                 if(other.health != 2342)
2709                 {
2710                         other.health = 2342;
2711                         other.impulse = 0;
2712                         if(clienttype(other) == CLIENTTYPE_REAL)
2713                         {
2714                                 msg_entity = other;
2715                                 WriteByte(MSG_ONE, SVC_FINALE);
2716                                 WriteString(MSG_ONE, "");
2717                         }
2718                 }
2719
2720                 // clear possibly invalid votes
2721                 if(mapvote_maps[other.mapvote - 1] == "")
2722                         other.mapvote = 0;
2723                 // use impulses as new vote
2724                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2725                         if(mapvote_maps[other.impulse - 1] != "")
2726                         {
2727                                 other.mapvote = other.impulse;
2728                                 MapVote_TouchVotes(other);
2729                         }
2730                 other.impulse = 0;
2731
2732                 if(other.mapvote)
2733                         ++totalvotes;
2734         }
2735
2736         MapVote_CheckRules_1(); // just count
2737 }
2738 void MapVote_Start()
2739 {
2740         if(mapvote_run)
2741                 return;
2742
2743         // wait for stats to be sent first
2744         if(!playerstats_waitforme)
2745                 return;
2746
2747         MapInfo_Enumerate();
2748         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2749                 mapvote_run = TRUE;
2750 }
2751 void MapVote_Think()
2752 {
2753         if(!mapvote_run)
2754                 return;
2755
2756         if(alreadychangedlevel)
2757                 return;
2758
2759         if(time < mapvote_nextthink)
2760                 return;
2761         //dprint("tick\n");
2762
2763         mapvote_nextthink = time + 0.5;
2764
2765         if(!mapvote_initialized)
2766         {
2767                 if(autocvar_rescan_pending == 1)
2768                 {
2769                         cvar_set("rescan_pending", "2");
2770                         localcmd("fs_rescan\nrescan_pending 3\n");
2771                         return;
2772                 }
2773                 else if(autocvar_rescan_pending == 2)
2774                 {
2775                         return;
2776                 }
2777                 else if(autocvar_rescan_pending == 3)
2778                 {
2779                         // now build missing mapinfo files
2780                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2781                                 return;
2782
2783                         // we're done, start the timer
2784                         cvar_set("rescan_pending", "0");
2785                 }
2786
2787                 mapvote_initialized = TRUE;
2788                 if(DoNextMapOverride(0))
2789                         return;
2790                 if(!autocvar_g_maplist_votable || player_count <= 0)
2791                 {
2792                         GotoNextMap(0);
2793                         return;
2794                 }
2795                 MapVote_Init();
2796         }
2797
2798         MapVote_Tick();
2799 }
2800
2801 string GotoMap(string m)
2802 {
2803         if(!MapInfo_CheckMap(m))
2804                 return "The map you chose is not available on this server.";
2805         cvar_set("nextmap", m);
2806         cvar_set("timelimit", "-1");
2807         if(mapvote_initialized || alreadychangedlevel)
2808         {
2809                 if(DoNextMapOverride(0))
2810                         return "Map switch initiated.";
2811                 else
2812                         return "Hm... no. For some reason I like THIS map more.";
2813         }
2814         else
2815                 return "Map switch will happen after scoreboard.";
2816 }
2817
2818
2819 void EndFrame()
2820 {
2821         float altime;
2822         FOR_EACH_REALCLIENT(self)
2823         {
2824                 if(self.classname == "spectator")
2825                 {
2826                         if(self.enemy.typehitsound)
2827                                 self.typehit_time = time;
2828                         else if(self.enemy.hitsound)
2829                                 self.hit_time = time;
2830                 }
2831                 else
2832                 {
2833                         if(self.typehitsound)
2834                                 self.typehit_time = time;
2835                         else if(self.hitsound)
2836                                 self.hit_time = time;
2837                 }
2838         }
2839         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2840         // add 1 frametime because after this, engine SV_Physics
2841         // increases time by a frametime and then networks the frame
2842         // add another frametime because client shows everything with
2843         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2844         // needed!
2845         FOR_EACH_CLIENT(self)
2846         {
2847                 self.hitsound = FALSE;
2848                 self.typehitsound = FALSE;
2849                 antilag_record(self, altime);
2850         }
2851 }
2852
2853
2854 /*
2855  * RedirectionThink:
2856  * returns TRUE if redirecting
2857  */
2858 float redirection_timeout;
2859 float redirection_nextthink;
2860 float RedirectionThink()
2861 {
2862         float clients_found;
2863
2864         if(redirection_target == "")
2865                 return FALSE;
2866
2867         if(!redirection_timeout)
2868         {
2869                 cvar_set("sv_public", "-2");
2870                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2871                 if(redirection_target == "self")
2872                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2873                 else
2874                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2875         }
2876
2877         if(time < redirection_nextthink)
2878                 return TRUE;
2879
2880         redirection_nextthink = time + 1;
2881
2882         clients_found = 0;
2883         FOR_EACH_REALCLIENT(self)
2884         {
2885                 // TODO add timer
2886                 print("Redirecting: sending connect command to ", self.netname, "\n");
2887                 if(redirection_target == "self")
2888                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2889                 else
2890                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2891                 ++clients_found;
2892         }
2893
2894         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2895
2896         if(time > redirection_timeout || clients_found == 0)
2897                 localcmd("\nwait; wait; wait; quit\n");
2898
2899         return TRUE;
2900 }
2901
2902 void TargetMusic_RestoreGame();
2903 void RestoreGame()
2904 {
2905         // Loaded from a save game
2906         // some things then break, so let's work around them...
2907
2908         // Progs DB (capture records)
2909         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2910
2911         // Mapinfo
2912         MapInfo_Shutdown();
2913         MapInfo_Enumerate();
2914         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2915         WeaponStats_Init();
2916
2917         TargetMusic_RestoreGame();
2918 }
2919
2920 void Shutdown()
2921 {
2922         entity e;
2923
2924         gameover = 2;
2925
2926         if(world_initialized > 0)
2927         {
2928                 world_initialized = 0;
2929                 print("Saving persistent data...\n");
2930                 Ban_SaveBans();
2931
2932                 PlayerStats_EndMatch(0);
2933                 FOR_EACH_CLIENT(e)
2934                         PlayerStats_AddGlobalInfo(e);
2935                 PlayerStats_Shutdown();
2936
2937                 if(!cheatcount_total)
2938                 {
2939                         if(autocvar_sv_db_saveasdump)
2940                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2941                         else
2942                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2943                 }
2944                 if(autocvar_developer)
2945                 {
2946                         if(autocvar_sv_db_saveasdump)
2947                                 db_dump(TemporaryDB, "server-temp.db");
2948                         else
2949                                 db_save(TemporaryDB, "server-temp.db");
2950                 }
2951                 CheatShutdown(); // must be after cheatcount check
2952                 db_close(ServerProgsDB);
2953                 db_close(TemporaryDB);
2954                 print("done!\n");
2955                 // tell the bot system the game is ending now
2956                 bot_endgame();
2957
2958                 WeaponStats_Shutdown();
2959                 MapInfo_Shutdown();
2960         }
2961         else if(world_initialized == 0)
2962         {
2963                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2964         }
2965 }