qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 void WaypointSprite_Load();
  46 void CSQC_Init(void)
  47 {
  48         prvm_language = cvar_string("prvm_language");
  49
  50 #ifdef USE_FTE
  51 #pragma target ID
  52         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  53         if(!__engine_check)
  54         {
  55                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  56                 localcmd("\ndisconnect\n");
  57                 return;
  58         }
  59 #pragma target FTE
  60 #endif
  61
  62         check_unacceptable_compiler_bugs();
  63
  64 #ifdef WATERMARK
  65         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  66 #endif
  67
  68         float i;
  69
  70 #ifdef COMPAT_XON050_ENGINE
  71         // old engine lacks implementation of player_localnum
  72         player_localnum = player_localentnum - 1;
  73 #endif
  74
  75         binddb = db_create();
  76         tempdb = db_create();
  77         ClientProgsDB = db_load("client.db");
  78         compressShortVector_init();
  79
  80         drawfont = FONT_USER+1;
  81         menu_visible = FALSE;
  82         menu_show = menu_show_error;
  83         menu_action = menu_sub_null;
  84
  85         for(i = 0; i < 255; ++i)
  86                 if(getplayerkeyvalue(i, "viewentity") == "")
  87                         break;
  88         maxclients = i;
  89
  90         registercommand("hud_configure");
  91         registercommand("hud_save");
  92         //registercommand("menu_action");
  93
  94         registercommand("+showscores");registercommand("-showscores");
  95         registercommand("+showaccuracy");registercommand("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercommand("+forward");registercommand("-forward");
 102                 registercommand("+back");registercommand("-back");
 103                 registercommand("+moveup");registercommand("-moveup");
 104                 registercommand("+movedown");registercommand("-movedown");
 105                 registercommand("+moveright");registercommand("-moveright");
 106                 registercommand("+moveleft");registercommand("-moveleft");
 107                 registercommand("+roll_right");registercommand("-roll_right");
 108                 registercommand("+roll_left");registercommand("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default");
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_model("null");
 136         precache_sound("misc/hit.wav");
 137         precache_sound("misc/typehit.wav");
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         Vehicles_Precache();
 144         turrets_precache();
 145   Announcer_Precache();
 146         Tuba_Precache();
 147
 148         if(autocvar_cl_reticle)
 149         {
 150                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 151                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 152         }
 153
 154         get_mi_min_max_texcoords(1); // try the CLEVER way first
 155         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 156         shortmapname = mi_shortname;
 157
 158         if(precache_pic(minimapname) == "")
 159         {
 160                 // but maybe we have a non-clever minimap
 161                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 162                 if(precache_pic(minimapname) == "")
 163                         minimapname = ""; // FAIL
 164                 else
 165                         get_mi_min_max_texcoords(0); // load new texcoords
 166         }
 167
 168         mi_center = (mi_min + mi_max) * 0.5;
 169         mi_scale = mi_max - mi_min;
 170         minimapname = strzone(minimapname);
 171
 172         WarpZone_Init();
 173
 174         hud_configure_prev = -1;
 175         tab_panel = -1;
 176 }
 177
 178 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 179 void CSQC_Shutdown(void)
 180 {
 181 #ifdef USE_FTE
 182 #pragma TARGET id
 183         if(!__engine_check)
 184                 return 0;
 185 #pragma TARGET fte
 186 #endif
 187
 188         WarpZone_Shutdown();
 189
 190         remove(teams);
 191         remove(players);
 192         db_close(binddb);
 193         db_close(tempdb);
 194         if(autocvar_cl_db_saveasdump)
 195                 db_dump(ClientProgsDB, "client.db");
 196         else
 197                 db_save(ClientProgsDB, "client.db");
 198         db_close(ClientProgsDB);
 199
 200         cvar_clientsettemp_restore();
 201
 202         if(camera_active)
 203                 cvar_set("chase_active",ftos(chase_active_backup));
 204
 205         // unset the event chasecam's chase_active
 206         if(autocvar_chase_active < 0)
 207                 cvar_set("chase_active", "0");
 208
 209         if not(isdemo())
 210         {
 211                 if not(calledhooks & HOOK_START)
 212                         localcmd("\n_cl_hook_gamestart nop\n");
 213                 if not(calledhooks & HOOK_END)
 214                         localcmd("\ncl_hook_gameend\n");
 215         }
 216 }
 217
 218 .float has_team;
 219 float SetTeam(entity o, float Team)
 220 {
 221         entity tm;
 222         if(teamplay)
 223         {
 224                 switch(Team)
 225                 {
 226                         case -1:
 227                         case COLOR_TEAM1:
 228                         case COLOR_TEAM2:
 229                         case COLOR_TEAM3:
 230                         case COLOR_TEAM4:
 231                                 break;
 232                         default:
 233                                 if(GetTeam(Team, false) == world)
 234                                 {
 235                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 236                                         Team = COLOR_SPECTATOR;
 237                                 }
 238                                 break;
 239                 }
 240         }
 241         else
 242         {
 243                 switch(Team)
 244                 {
 245                         case -1:
 246                         case 0:
 247                                 break;
 248                         default:
 249                                 if(GetTeam(Team, false) == world)
 250                                 {
 251                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 252                                         Team = COLOR_SPECTATOR;
 253                                 }
 254                                 break;
 255                 }
 256         }
 257         if(Team == -1) // leave
 258         {
 259                 if(o.has_team)
 260                 {
 261                         tm = GetTeam(o.team, false);
 262                         tm.team_size -= 1;
 263                         o.has_team = 0;
 264                         return TRUE;
 265                 }
 266         }
 267         else
 268         {
 269                 if not(o.has_team)
 270                 {
 271                         o.team = Team;
 272                         tm = GetTeam(Team, true);
 273                         tm.team_size += 1;
 274                         o.has_team = 1;
 275                         return TRUE;
 276                 }
 277                 else if(Team != o.team)
 278                 {
 279                         tm = GetTeam(o.team, false);
 280                         tm.team_size -= 1;
 281                         o.team = Team;
 282                         tm = GetTeam(Team, true);
 283                         tm.team_size += 1;
 284                         return TRUE;
 285                 }
 286         }
 287         return FALSE;
 288 }
 289
 290 void Playerchecker_Think()
 291 {
 292         float i;
 293         entity e;
 294         for(i = 0; i < maxclients; ++i)
 295         {
 296                 e = playerslots[i];
 297                 if(GetPlayerName(i) == "")
 298                 {
 299                         if(e.sort_prev)
 300                         {
 301                                 // player disconnected
 302                                 SetTeam(e, -1);
 303                                 RemovePlayer(e);
 304                                 e.sort_prev = world;
 305                                 //e.gotscores = 0;
 306                         }
 307                 }
 308                 else
 309                 {
 310                         if not(e.sort_prev)
 311                         {
 312                                 // player connected
 313                                 if not(e)
 314                                         playerslots[i] = e = spawn();
 315                                 e.sv_entnum = i;
 316                                 e.ping = 0;
 317                                 e.ping_packetloss = 0;
 318                                 e.ping_movementloss = 0;
 319                                 //e.gotscores = 0; // we might already have the scores...
 320                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 321                                 RegisterPlayer(e);
 322                                 HUD_UpdatePlayerPos(e);
 323                         }
 324                 }
 325         }
 326         self.nextthink = time + 0.2;
 327 }
 328
 329 void Porto_Init();
 330 void TrueAim_Init();
 331 void PostInit(void)
 332 {
 333         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 334
 335         entity playerchecker;
 336         playerchecker = spawn();
 337         playerchecker.think = Playerchecker_Think;
 338         playerchecker.nextthink = time + 0.2;
 339
 340         Porto_Init();
 341         TrueAim_Init();
 342
 343         postinit = true;
 344 }
 345
 346 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercommand" function
 347 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 348 float button_zoom;
 349 void Cmd_HUD_SetFields(float);
 350 void Cmd_HUD_Help(float);
 351 float CSQC_ConsoleCommand(string strMessage)
 352 {
 353         float argc;
 354         // Tokenize String
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+showscores") {
 373                 scoreboard_showscores = true;
 374                 return true;
 375         } else if(strCmd == "-showscores") {
 376                 scoreboard_showscores = false;
 377                 return true;
 378         } else if(strCmd == "+showaccuracy") {
 379                 scoreboard_showaccuracy = true;
 380                 return true;
 381         } else if(strCmd == "-showaccuracy") {
 382                 scoreboard_showaccuracy = false;
 383                 return true;
 384         }
 385
 386         if(camera_active)
 387         if(strCmd == "+forward" || strCmd == "-back") {
 388                 ++camera_direction_x;
 389                 return true;
 390         } else if(strCmd == "-forward" || strCmd == "+back") {
 391                 --camera_direction_x;
 392                 return true;
 393         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 394                 --camera_direction_y;
 395                 return true;
 396         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 397                 ++camera_direction_y;
 398                 return true;
 399         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 400                 ++camera_direction_z;
 401                 return true;
 402         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 403                 --camera_direction_z;
 404                 return true;
 405         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 406                 ++camera_roll;
 407                 return true;
 408         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 409                 --camera_roll;
 410                 return true;
 411         }
 412
 413         return false;
 414 }
 415
 416 .vector view_ofs;
 417 entity debug_shotorg;
 418 void ShotOrg_Draw()
 419 {
 420         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 421         self.angles = view_angles;
 422         self.angles_x = -self.angles_x;
 423         if not(self.cnt)
 424                 self.drawmask = MASK_NORMAL;
 425         else
 426                 self.drawmask = 0;
 427 }
 428 void ShotOrg_Draw2D()
 429 {
 430         vector coord2d_topleft, coord2d_topright, coord2d;
 431         string s;
 432         vector fs;
 433
 434         s = vtos(self.view_ofs);
 435         s = substring(s, 1, strlen(s) - 2);
 436         if(tokenize_console(s) == 3)
 437                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 438
 439         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 440         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 441
 442         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 443
 444         coord2d = coord2d_topleft;
 445         if(fs_x < 8)
 446         {
 447                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 448                 fs = '8 8 0';
 449         }
 450         coord2d_y -= fs_y;
 451         coord2d_z = 0;
 452         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 453 }
 454
 455 void ShotOrg_Spawn()
 456 {
 457         debug_shotorg = spawn();
 458         debug_shotorg.draw = ShotOrg_Draw;
 459         debug_shotorg.draw2d = ShotOrg_Draw2D;
 460         debug_shotorg.renderflags = RF_VIEWMODEL;
 461         debug_shotorg.effects = EF_FULLBRIGHT;
 462         precache_model("models/shotorg_adjuster.md3");
 463         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 464         debug_shotorg.scale = 2;
 465         debug_shotorg.view_ofs = '25 8 -8';
 466 }
 467
 468 void DrawDebugModel()
 469 {
 470         if(time - floor(time) > 0.5)
 471         {
 472                 PolyDrawModel(self);
 473                 self.drawmask = 0;
 474         }
 475         else
 476         {
 477                 self.renderflags = 0;
 478                 self.drawmask = MASK_NORMAL;
 479         }
 480 }
 481
 482 void GameCommand(string msg)
 483 {
 484         string s;
 485         float argc;
 486         entity e;
 487         argc = tokenize_console(msg);
 488
 489         if(argv(0) == "help" || argc == 0)
 490         {
 491                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 492                 print(_("  settemp cvar value\n"));
 493                 print(_("  scoreboard_columns_set ...\n"));
 494                 print(_("  scoreboard_columns_help\n"));
 495                 GameCommand_Generic("help");
 496                 return;
 497         }
 498
 499         if(GameCommand_Generic(msg))
 500                 return;
 501
 502         string cmd;
 503         cmd = argv(0);
 504         if(cmd == "mv_download") {
 505                 Cmd_MapVote_MapDownload(argc);
 506         }
 507         else if(cmd == "hud_panel_radar_maximized")
 508         {
 509                 if(argc == 1)
 510                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 511                 else
 512                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 513         }
 514         else if(cmd == "settemp") {
 515                 cvar_clientsettemp(argv(1), argv(2));
 516         }
 517         else if(cmd == "scoreboard_columns_set") {
 518                 Cmd_HUD_SetFields(argc);
 519         }
 520         else if(cmd == "scoreboard_columns_help") {
 521                 Cmd_HUD_Help(argc);
 522         }
 523 #ifdef BLURTEST
 524         else if(cmd == "blurtest") {
 525                 blurtest_time0 = time;
 526                 blurtest_time1 = time + stof(argv(1));
 527                 blurtest_radius = stof(argv(2));
 528                 blurtest_power = stof(argv(3));
 529         }
 530 #endif
 531         else if(cmd == "shotorg_move") {
 532                 if(!debug_shotorg)
 533                         ShotOrg_Spawn();
 534                 else
 535                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 536                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 537         }
 538         else if(cmd == "shotorg_movez") {
 539                 if(!debug_shotorg)
 540                         ShotOrg_Spawn();
 541                 else
 542                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 543                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 544         }
 545         else if(cmd == "shotorg_set") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = stov(argv(1));
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_setz") {
 553                 if(!debug_shotorg)
 554                         ShotOrg_Spawn();
 555                 else
 556                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 557                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 558         }
 559         else if(cmd == "shotorg_toggle_hide") {
 560                 if(debug_shotorg)
 561                 {
 562                         debug_shotorg.cnt = !debug_shotorg.cnt;
 563                 }
 564         }
 565         else if(cmd == "shotorg_end") {
 566                 if(debug_shotorg)
 567                 {
 568                         print(vtos(debug_shotorg.view_ofs), "\n");
 569                         remove(debug_shotorg);
 570                         debug_shotorg = world;
 571                 }
 572                 localcmd("sv_cmd debug_shotorg\n");
 573         }
 574         else if(cmd == "sendcvar") {
 575                 // W_FixWeaponOrder will trash argv, so save what we need.
 576                 string thiscvar;
 577                 thiscvar = strzone(argv(1));
 578                 s = cvar_string(thiscvar);
 579                 if(thiscvar == "cl_weaponpriority")
 580                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 581                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 582                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 583                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 584                 strunzone(thiscvar);
 585         }
 586         else if(cmd == "spawn") {
 587                 s = argv(1);
 588                 e = spawn();
 589                 precache_model(s);
 590                 setmodel(e, s);
 591                 setorigin(e, view_origin);
 592                 e.angles = view_angles;
 593                 e.draw = DrawDebugModel;
 594                 e.classname = "debugmodel";
 595         }
 596     else if(cmd == "vyes")
 597     {
 598         if(uid2name_dialog)
 599         {
 600             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 601             vote_prev = 0;
 602             localcmd("setreport cl_allow_uid2name 1\n");
 603             vote_change = -9999;
 604                         uid2name_dialog = 0;
 605         }
 606         else
 607         {
 608             localcmd("cmd vote yes\n");
 609         }
 610     }
 611     else if(cmd == "vno")
 612     {
 613         if(uid2name_dialog)
 614         {
 615             vote_active = 0;
 616             vote_prev = 0;
 617             localcmd("setreport cl_allow_uid2name 0\n");
 618             vote_change = -9999;
 619                         uid2name_dialog = 0;
 620         }
 621         else
 622         {
 623             localcmd("cmd vote no\n");
 624         }
 625     }
 626
 627         else
 628         {
 629                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 630         }
 631
 632         return;
 633 }
 634
 635 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 636 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 637 // All keys are in ascii.
 638 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 639 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 640 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 641 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 642 {
 643         float bSkipKey;
 644         bSkipKey = false;
 645
 646         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 647                 return true;
 648
 649         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 650                 return true;
 651
 652         if(menu_visible)
 653                 if(menu_action(bInputType, nPrimary, nSecondary))
 654                         return TRUE;
 655
 656         return bSkipKey;
 657 }
 658
 659 // END REQUIRED CSQC FUNCTIONS
 660 // --------------------------------------------------------------------------
 661
 662 // --------------------------------------------------------------------------
 663 // BEGIN OPTIONAL CSQC FUNCTIONS
 664 void Ent_RemoveEntCS()
 665 {
 666         entcs_receiver[self.sv_entnum] = world;
 667 }
 668 void Ent_ReadEntCS()
 669 {
 670         float sf;
 671         InterpolateOrigin_Undo();
 672
 673         self.classname = "entcs_receiver";
 674         sf = ReadByte();
 675
 676         if(sf & 1)
 677                 self.sv_entnum = ReadByte();
 678         if(sf & 2)
 679         {
 680                 self.origin_x = ReadShort();
 681                 self.origin_y = ReadShort();
 682                 self.origin_z = ReadShort();
 683         }
 684         if(sf & 4)
 685         {
 686                 self.angles_y = ReadByte() * 360.0 / 256;
 687                 self.angles_x = self.angles_z = 0;
 688         }
 689         if(sf & 8)
 690                 self.healthvalue = ReadByte() * 10;
 691         if(sf & 16)
 692                 self.armorvalue = ReadByte() * 10;
 693
 694         entcs_receiver[self.sv_entnum] = self;
 695         self.entremove = Ent_RemoveEntCS;
 696
 697         InterpolateOrigin_Note();
 698 }
 699
 700 void Ent_Remove();
 701
 702 void Ent_RemovePlayerScore()
 703 {
 704         float i;
 705
 706         if(self.owner)
 707         {
 708                 SetTeam(self.owner, -1);
 709                 self.owner.gotscores = 0;
 710                 for(i = 0; i < MAX_SCORE; ++i)
 711                         self.owner.(scores[i]) = 0; // clear all scores
 712         }
 713 }
 714
 715 void Ent_ReadPlayerScore()
 716 {
 717         float i, n;
 718         float isNew;
 719         entity o;
 720
 721         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 722         // (no I've never heard of M-x replace-string, sed, or anything like that)
 723         isNew = !self.owner; // workaround for DP bug
 724         n = ReadByte()-1;
 725
 726 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 727         if(!isNew && n != self.sv_entnum)
 728         {
 729                 //print(_("A CSQC entity changed its owner!\n"));
 730                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 731                 isNew = true;
 732                 Ent_Remove();
 733                 self.enttype = ENT_CLIENT_SCORES;
 734         }
 735 #endif
 736
 737         self.sv_entnum = n;
 738
 739         if not(playerslots[self.sv_entnum])
 740                 playerslots[self.sv_entnum] = spawn();
 741         o = self.owner = playerslots[self.sv_entnum];
 742         o.sv_entnum = self.sv_entnum;
 743         o.gotscores = 1;
 744
 745         //if not(o.sort_prev)
 746         //      RegisterPlayer(o);
 747         //playerchecker will do this for us later, if it has not already done so
 748
 749         float sf, lf;
 750 #if MAX_SCORE <= 8
 751         sf = ReadByte();
 752         lf = ReadByte();
 753 #else
 754         sf = ReadShort();
 755         lf = ReadShort();
 756 #endif
 757         float p;
 758         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 759                 if(sf & p)
 760                 {
 761                         if(lf & p)
 762                                 o.(scores[i]) = ReadInt24_t();
 763                         else
 764                                 o.(scores[i]) = ReadChar();
 765                 }
 766
 767         if(o.sort_prev)
 768                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 769
 770         self.entremove = Ent_RemovePlayerScore;
 771 }
 772
 773 void Ent_ReadTeamScore()
 774 {
 775         float i;
 776         entity o;
 777
 778         self.team = ReadByte();
 779         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 780
 781         float sf, lf;
 782 #if MAX_TEAMSCORE <= 8
 783         sf = ReadByte();
 784         lf = ReadByte();
 785 #else
 786         sf = ReadShort();
 787         lf = ReadShort();
 788 #endif
 789         float p;
 790         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 791                 if(sf & p)
 792                 {
 793                         if(lf & p)
 794                                 o.(teamscores[i]) = ReadInt24_t();
 795                         else
 796                                 o.(teamscores[i]) = ReadChar();
 797                 }
 798
 799         HUD_UpdateTeamPos(o);
 800 }
 801
 802 void Ent_ClientData()
 803 {
 804         float f;
 805         float newspectatee_status;
 806
 807         f = ReadByte();
 808
 809         scoreboard_showscores_force = (f & 1);
 810
 811         if(f & 2)
 812         {
 813                 newspectatee_status = ReadByte();
 814                 if(newspectatee_status == player_localnum + 1)
 815                         newspectatee_status = -1; // observing
 816         }
 817         else
 818                 newspectatee_status = 0;
 819
 820         spectatorbutton_zoom = (f & 4);
 821
 822         if(f & 8)
 823         {
 824                 angles_held_status = 1;
 825                 angles_held_x = ReadAngle();
 826                 angles_held_y = ReadAngle();
 827                 angles_held_z = 0;
 828         }
 829         else
 830                 angles_held_status = 0;
 831
 832         if(newspectatee_status != spectatee_status)
 833         {
 834                 // clear race stuff
 835                 race_laptime = 0;
 836                 race_checkpointtime = 0;
 837         }
 838         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 839         {
 840                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 841                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 842                 )
 843                         prev_p_health = -1;
 844                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 845                         prev_health = -1;
 846         }
 847         spectatee_status = newspectatee_status;
 848
 849         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 850 }
 851
 852 void Ent_Nagger()
 853 {
 854         float nags, i, j, b, f;
 855
 856         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 857
 858         if(!(nags & 4))
 859         {
 860                 if(vote_called_vote)
 861                         strunzone(vote_called_vote);
 862                 vote_called_vote = string_null;
 863                 vote_active = 0;
 864         }
 865         else
 866         {
 867                 vote_active = 1;
 868         }
 869
 870         if(nags & 64)
 871         {
 872                 vote_yescount = ReadByte();
 873                 vote_nocount = ReadByte();
 874                 vote_needed = ReadByte();
 875                 vote_highlighted = ReadChar();
 876         }
 877
 878         if(nags & 128)
 879         {
 880                 if(vote_called_vote)
 881                         strunzone(vote_called_vote);
 882                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 883         }
 884
 885         if(nags & 1)
 886         {
 887                 for(j = 0; j < maxclients; ++j)
 888                         if(playerslots[j])
 889                                 playerslots[j].ready = 1;
 890                 for(i = 1; i <= maxclients; i += 8)
 891                 {
 892                         f = ReadByte();
 893                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 894                                 if not(f & b)
 895                                         if(playerslots[j])
 896                                                 playerslots[j].ready = 0;
 897                 }
 898         }
 899
 900         ready_waiting = (nags & 1);
 901         ready_waiting_for_me = (nags & 2);
 902         vote_waiting = (nags & 4);
 903         vote_waiting_for_me = (nags & 8);
 904         warmup_stage = (nags & 16);
 905 }
 906
 907 void Ent_RandomSeed()
 908 {
 909         float s;
 910         prandom_debug();
 911         s = ReadShort();
 912         psrandom(s);
 913 }
 914
 915 void Ent_ReadAccuracy(void)
 916 {
 917         float sf, f, w, b;
 918         sf = ReadInt24_t();
 919         if(sf == 0)
 920         {
 921                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 922                         weapon_accuracy[w] = -1;
 923                 return;
 924         }
 925
 926         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 927         {
 928                 if(sf & f)
 929                 {
 930                         b = ReadByte();
 931                         if(b == 0)
 932                                 weapon_accuracy[w] = -1;
 933                         else if(b == 255)
 934                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 935                         else
 936                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 937                 }
 938         }
 939 }
 940
 941 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 942 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 943 void Ent_RadarLink();
 944 void Ent_Init();
 945 void Ent_ScoresInfo();
 946 void CSQC_Ent_Update(float bIsNewEntity)
 947 {
 948         float t;
 949         float savetime;
 950         t = ReadByte();
 951
 952         // set up the "time" global for received entities to be correct for interpolation purposes
 953         savetime = time;
 954         if(servertime)
 955         {
 956                 time = servertime;
 957         }
 958         else
 959         {
 960                 serverprevtime = time;
 961                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 962                 time = serverprevtime + serverdeltatime;
 963         }
 964
 965 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 966         if(self.enttype)
 967         {
 968                 if(t != self.enttype || bIsNewEntity)
 969                 {
 970                         //print(_("A CSQC entity changed its type!\n"));
 971                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 972                         Ent_Remove();
 973                         bIsNewEntity = 1;
 974                 }
 975         }
 976         else
 977         {
 978                 if(!bIsNewEntity)
 979                 {
 980                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 981                         bIsNewEntity = 1;
 982                 }
 983         }
 984 #endif
 985         self.enttype = t;
 986         switch(t)
 987         {
 988                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 989                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 990                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 991                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 992                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 993                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 994                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 995                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 996                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 997                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 998                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 999                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
1000                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
1001                 case ENT_CLIENT_INIT: Ent_Init(); break;
1002                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
1003                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
1004                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
1005                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
1006                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1007                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1008                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1009                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1010                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1011                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1012                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1013                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1014                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1015                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1016                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1017                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1018                 case ENT_CLIENT_TURRET: ent_turret(); break;
1019                 default:
1020                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1021                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1022                         break;
1023         }
1024
1025         time = savetime;
1026 }
1027 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1028 // used when an entity changes its type. For an entity that someone interacts
1029 // with others, make sure it can no longer do so.
1030 void Ent_Remove()
1031 {
1032         if(self.entremove)
1033                 self.entremove();
1034
1035         self.enttype = 0;
1036         self.classname = "";
1037         self.draw = menu_sub_null;
1038         self.entremove = menu_sub_null;
1039         // TODO possibly set more stuff to defaults
1040 }
1041 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1042 void CSQC_Ent_Remove()
1043 {
1044         if(self.enttype)
1045                 Ent_Remove();
1046         remove(self);
1047 }
1048
1049 void Gamemode_Init()
1050 {
1051         if not(isdemo())
1052         {
1053                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1054                 calledhooks |= HOOK_START;
1055         }
1056 }
1057 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1058 void CSQC_Parse_StuffCmd(string strMessage)
1059 {
1060         localcmd(strMessage);
1061 }
1062 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1063 void CSQC_Parse_Print(string strMessage)
1064 {
1065         print(ColorTranslateRGB(strMessage));
1066 }
1067
1068 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
1069 void CSQC_Parse_CenterPrint(string strMessage)
1070 {
1071         centerprint_hud(strMessage);
1072 }
1073
1074 string notranslate_fogcmd1 = "\nfog ";
1075 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1076 void Fog_Force()
1077 {
1078         // TODO somehow thwart prvm_globalset client ...
1079
1080         if(forcefog != "")
1081                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1082 }
1083
1084 void Gamemode_Init();
1085 void Ent_ScoresInfo()
1086 {
1087         float i;
1088         self.classname = "ent_client_scores_info";
1089         gametype = ReadByte();
1090         for(i = 0; i < MAX_SCORE; ++i)
1091         {
1092                 scores_label[i] = strzone(ReadString());
1093                 scores_flags[i] = ReadByte();
1094         }
1095         for(i = 0; i < MAX_TEAMSCORE; ++i)
1096         {
1097                 teamscores_label[i] = strzone(ReadString());
1098                 teamscores_flags[i] = ReadByte();
1099         }
1100         HUD_InitScores();
1101         Gamemode_Init();
1102 }
1103
1104 void Ent_Init()
1105 {
1106         self.classname = "ent_client_init";
1107
1108         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1109
1110         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1111         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1112         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1113         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1114         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1115         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1116         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1117         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1118         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122
1123         if(forcefog)
1124                 strunzone(forcefog);
1125         forcefog = strzone(ReadString());
1126
1127         armorblockpercent = ReadByte() / 255.0;
1128
1129         g_weaponswitchdelay = ReadByte() / 255.0;
1130
1131         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1132         g_balance_grenadelauncher_bouncestop = ReadCoord();
1133         g_balance_electro_secondary_bouncefactor = ReadCoord();
1134         g_balance_electro_secondary_bouncestop = ReadCoord();
1135
1136         nex_scope = !ReadByte();
1137         rifle_scope = !ReadByte();
1138
1139         serverflags = ReadByte();
1140
1141         minelayer_maxmines = ReadByte();
1142
1143         hagar_maxrockets = ReadByte();
1144
1145         g_trueaim_minrange = ReadCoord();
1146
1147         if(!postinit)
1148                 PostInit();
1149 }
1150
1151 void Net_ReadRace()
1152 {
1153         float b;
1154
1155         b = ReadByte();
1156
1157         switch(b)
1158         {
1159                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1160                         race_checkpoint = ReadByte();
1161                         race_time = ReadInt24_t();
1162                         race_previousbesttime = ReadInt24_t();
1163                         if(race_previousbestname)
1164                                 strunzone(race_previousbestname);
1165                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1166
1167                         race_checkpointtime = time;
1168
1169                         if(race_checkpoint == 0 || race_checkpoint == 254)
1170                         {
1171                                 race_penaltyaccumulator = 0;
1172                                 race_laptime = time; // valid
1173                         }
1174
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_CLEAR:
1178                         race_laptime = 0;
1179                         race_checkpointtime = 0;
1180                         break;
1181
1182                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1183                         race_laptime = ReadCoord();
1184                         race_checkpointtime = -99999;
1185                         // fall through
1186                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1187                         race_nextcheckpoint = ReadByte();
1188
1189                         race_nextbesttime = ReadInt24_t();
1190                         if(race_nextbestname)
1191                                 strunzone(race_nextbestname);
1192                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1193                         break;
1194
1195                 case RACE_NET_CHECKPOINT_HIT_RACE:
1196                         race_mycheckpoint = ReadByte();
1197                         race_mycheckpointtime = time;
1198                         race_mycheckpointdelta = ReadInt24_t();
1199                         race_mycheckpointlapsdelta = ReadByte();
1200                         if(race_mycheckpointlapsdelta >= 128)
1201                                 race_mycheckpointlapsdelta -= 256;
1202                         if(race_mycheckpointenemy)
1203                                 strunzone(race_mycheckpointenemy);
1204                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1205                         break;
1206
1207                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1208                         race_othercheckpoint = ReadByte();
1209                         race_othercheckpointtime = time;
1210                         race_othercheckpointdelta = ReadInt24_t();
1211                         race_othercheckpointlapsdelta = ReadByte();
1212                         if(race_othercheckpointlapsdelta >= 128)
1213                                 race_othercheckpointlapsdelta -= 256;
1214                         if(race_othercheckpointenemy)
1215                                 strunzone(race_othercheckpointenemy);
1216                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1217                         break;
1218
1219                 case RACE_NET_PENALTY_RACE:
1220                         race_penaltyeventtime = time;
1221                         race_penaltytime = ReadShort();
1222                         //race_penaltyaccumulator += race_penaltytime;
1223                         if(race_penaltyreason)
1224                                 strunzone(race_penaltyreason);
1225                         race_penaltyreason = strzone(ReadString());
1226                         break;
1227
1228                 case RACE_NET_PENALTY_QUALIFYING:
1229                         race_penaltyeventtime = time;
1230                         race_penaltytime = ReadShort();
1231                         race_penaltyaccumulator += race_penaltytime;
1232                         if(race_penaltyreason)
1233                                 strunzone(race_penaltyreason);
1234                         race_penaltyreason = strzone(ReadString());
1235                         break;
1236
1237                 case RACE_NET_SERVER_RECORD:
1238                         race_server_record = ReadInt24_t();
1239                         break;
1240                 case RACE_NET_SPEED_AWARD:
1241                         race_speedaward = ReadInt24_t();
1242                         if(race_speedaward_holder)
1243                                 strunzone(race_speedaward_holder);
1244                         race_speedaward_holder = strzone(ReadString());
1245                         break;
1246                 case RACE_NET_SPEED_AWARD_BEST:
1247                         race_speedaward_alltimebest = ReadInt24_t();
1248                         if(race_speedaward_alltimebest_holder)
1249                                 strunzone(race_speedaward_alltimebest_holder);
1250                         race_speedaward_alltimebest_holder = strzone(ReadString());
1251                         break;
1252                 case RACE_NET_SERVER_RANKINGS:
1253                         float pos, prevpos, del;
1254                         pos = ReadShort();
1255                         prevpos = ReadShort();
1256                         del = ReadShort();
1257
1258                         // move other rankings out of the way
1259                         float i;
1260                         if (prevpos) {
1261                                 for (i=prevpos-1;i>pos-1;--i) {
1262                                         grecordtime[i] = grecordtime[i-1];
1263                                         if(grecordholder[i])
1264                                                 strunzone(grecordholder[i]);
1265                                         grecordholder[i] = strzone(grecordholder[i-1]);
1266                                 }
1267                         } else if (del) { // a record has been deleted by the admin
1268                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1269                                         if (i == RANKINGS_CNT-1) { // clear out last record
1270                                                 grecordtime[i] = 0;
1271                                                 if (grecordholder[i])
1272                                                         strunzone(grecordholder[i]);
1273                                                 grecordholder[i] = string_null;
1274                                         }
1275                                         else {
1276                                                 grecordtime[i] = grecordtime[i+1];
1277                                                 if (grecordholder[i])
1278                                                         strunzone(grecordholder[i]);
1279                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1280                                         }
1281                                 }
1282                         } else { // player has no ranked record yet
1283                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1284                                         grecordtime[i] = grecordtime[i-1];
1285                                         if(grecordholder[i])
1286                                                 strunzone(grecordholder[i]);
1287                                         grecordholder[i] = strzone(grecordholder[i-1]);
1288                                 }
1289                         }
1290
1291                         // store new ranking
1292                         if(grecordholder[pos-1] != "")
1293                                 strunzone(grecordholder[pos-1]);
1294                         grecordholder[pos-1] = strzone(ReadString());
1295                         grecordtime[pos-1] = ReadInt24_t();
1296                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1297                                 race_myrank = pos;
1298                         break;
1299                 case RACE_NET_SERVER_STATUS:
1300                         race_status = ReadShort();
1301                         if(race_status_name)
1302                                 strunzone(race_status_name);
1303                         race_status_name = strzone(ReadString());
1304         }
1305 }
1306
1307 void Net_ReadSpawn()
1308 {
1309         zoomin_effect = 1;
1310         current_viewzoom = 0.6;
1311 }
1312
1313 void Net_TeamNagger()
1314 {
1315         teamnagger = 1;
1316 }
1317
1318 void Net_ReadPingPLReport()
1319 {
1320         float e, pi, pl, ml;
1321         e = ReadByte();
1322         pi = ReadShort();
1323         pl = ReadByte();
1324         ml = ReadByte();
1325         if not(playerslots[e])
1326                 return;
1327         playerslots[e].ping = pi;
1328         playerslots[e].ping_packetloss = pl / 255.0;
1329         playerslots[e].ping_movementloss = ml / 255.0;
1330 }
1331
1332 void Net_WeaponComplain() {
1333         complain_weapon = ReadByte();
1334
1335         if(complain_weapon_name)
1336                 strunzone(complain_weapon_name);
1337         complain_weapon_name = strzone(ReadString());
1338
1339         complain_weapon_type = ReadByte();
1340
1341         complain_weapon_time = time;
1342         weapontime = time; // ping the weapon panel
1343 }
1344
1345 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1346 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1347 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1348 float CSQC_Parse_TempEntity()
1349 {
1350         float bHandled;
1351                 bHandled  = true;
1352         // Acquire TE ID
1353         float nTEID;
1354                 nTEID = ReadByte();
1355
1356                 // NOTE: Could just do return instead of break...
1357         switch(nTEID)
1358         {
1359                 case TE_CSQC_TARGET_MUSIC:
1360                         Net_TargetMusic();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_PICTURE:
1364                         Net_MapVote_Picture();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_RACE:
1368                         Net_ReadRace();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_SPAWN:
1372                         Net_ReadSpawn();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_ZCURVEPARTICLES:
1376                         Net_ReadZCurveParticles();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1380                         Net_ReadNexgunBeamParticle();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_TEAMNAGGER:
1384                         Net_TeamNagger();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_LIGHTNINGARC:
1388                         Net_ReadLightningarc();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_PINGPLREPORT:
1392                         Net_ReadPingPLReport();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_ANNOUNCE:
1396                         Announcer_Play(ReadString());
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_KILLNOTIFY:
1400                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_KILLCENTERPRINT:
1404                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_CENTERPRINT_GENERIC:
1408                         float id;
1409                         string s;
1410                         id = ReadByte();
1411                         s = ReadString();
1412                         if (id != 0 && s != "")
1413                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1414                         else
1415                                 centerprint_generic(id, s, 0, 0);
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_WEAPONCOMPLAIN:
1419                         Net_WeaponComplain();
1420                         bHandled = true;
1421                         break;
1422                 case TE_CSQC_VEHICLESETUP:
1423                         Net_VehicleSetup();
1424                         bHandled = true;
1425                         break;
1426                 default:
1427                         // No special logic for this temporary entity; return 0 so the engine can handle it
1428                         bHandled = false;
1429                         break;
1430         }
1431
1432         return bHandled;
1433 }
1434
1435 string getcommandkey(string text, string command)
1436 {
1437         string keys;
1438         float n, j, k, l;
1439
1440         if (!autocvar_hud_showbinds)
1441                 return text;
1442
1443         keys = db_get(binddb, command);
1444         if (!keys)
1445         {
1446                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1447                 for(j = 0; j < n; ++j)
1448                 {
1449                         k = stof(argv(j));
1450                         if(k != -1)
1451                         {
1452                                 if ("" == keys)
1453                                         keys = keynumtostring(k);
1454                                 else
1455                                         keys = strcat(keys, ", ", keynumtostring(k));
1456
1457                                 ++l;
1458                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1459                         }
1460
1461                 }
1462                 db_put(binddb, command, keys);
1463         }
1464
1465         if ("" == keys) {
1466                 if (autocvar_hud_showbinds > 1)
1467                         return sprintf(_("%s (not bound)"), text);
1468                 else
1469                         return text;
1470         }
1471         else if (autocvar_hud_showbinds > 1)
1472                 return sprintf(_("%s (%s)"), text, keys);
1473         else
1474                 return keys;
1475 }