qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170         hud_configure_prev = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         db_save(ClientProgsDB, "client.db");
 190         db_close(ClientProgsDB);
 191
 192         cvar_clientsettemp_restore();
 193
 194         if(camera_active)
 195                 cvar_set("chase_active",ftos(chase_active_backup));
 196
 197         if not(isdemo())
 198         {
 199                 if not(calledhooks & HOOK_START)
 200                         localcmd("\n_cl_hook_gamestart nop\n");
 201                 if not(calledhooks & HOOK_END)
 202                         localcmd("\ncl_hook_gameend\n");
 203         }
 204 }
 205
 206 .float has_team;
 207 float SetTeam(entity o, float Team)
 208 {
 209         entity tm;
 210         if(teamplay)
 211         {
 212                 switch(Team)
 213                 {
 214                         case -1:
 215                         case COLOR_TEAM1:
 216                         case COLOR_TEAM2:
 217                         case COLOR_TEAM3:
 218                         case COLOR_TEAM4:
 219                                 break;
 220                         default:
 221                                 if(GetTeam(Team, false) == NULL)
 222                                 {
 223                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 224                                         Team = COLOR_SPECTATOR;
 225                                 }
 226                                 break;
 227                 }
 228         }
 229         else
 230         {
 231                 switch(Team)
 232                 {
 233                         case -1:
 234                         case 0:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == NULL)
 238                                 {
 239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 240                                         Team = COLOR_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         if(Team == -1) // leave
 246         {
 247                 if(o.has_team)
 248                 {
 249                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 250                         tm = GetTeam(o.team, false);
 251                         tm.team_size -= 1;
 252                         o.has_team = 0;
 253                         return TRUE;
 254                 }
 255         }
 256         else
 257         {
 258                 if not(o.has_team)
 259                 {
 260                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         o.has_team = 1;
 265                         return TRUE;
 266                 }
 267                 else if(Team != o.team)
 268                 {
 269                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 270                         tm = GetTeam(o.team, false);
 271                         tm.team_size -= 1;
 272                         o.team = Team;
 273                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         return TRUE;
 277                 }
 278         }
 279         return FALSE;
 280 }
 281
 282 void Playerchecker_Think()
 283 {
 284         float i;
 285         entity e;
 286         for(i = 0; i < maxclients; ++i)
 287         {
 288                 e = playerslots[i];
 289                 if(GetPlayerName(i) == "")
 290                 {
 291                         if(e.sort_prev)
 292                         {
 293                                 //print("playerchecker: KILL KILL KILL\n");
 294                                 // player disconnected
 295                                 SetTeam(e, -1);
 296                                 RemovePlayer(e);
 297                                 e.sort_prev = world;
 298                                 //e.gotscores = 0;
 299                         }
 300                 }
 301                 else
 302                 {
 303                         if not(e.sort_prev)
 304                         {
 305                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 328         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 329
 330         entity playerchecker;
 331         playerchecker = spawn();
 332         playerchecker.think = Playerchecker_Think;
 333         playerchecker.nextthink = time + 0.2;
 334
 335         Porto_Init();
 336         TrueAim_Init();
 337
 338         postinit = true;
 339 }
 340
 341 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 342 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 343 float button_zoom;
 344 void Cmd_HUD_SetFields(float);
 345 void Cmd_HUD_Help(float);
 346 float CSQC_ConsoleCommand(string strMessage)
 347 {
 348         float argc;
 349         // Tokenize String
 350         //argc = tokenize(strMessage);
 351         argc = tokenize_console(strMessage);
 352
 353         // Acquire Command
 354         local string strCmd;
 355         strCmd = argv(0);
 356
 357         if(strCmd == "hud_configure") { // config hud
 358                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 359                 return true;
 360         } else if(strCmd == "hud_save") { // save hud config
 361                 if(argv(1) == "" || argv(2)) {
 362                         print("Usage:\n");
 363                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 364                 }
 365                 else
 366                         HUD_Panel_ExportCfg(argv(1));
 367                 return true;
 368         } else if(strCmd == "+button4") { // zoom
 369                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 370                 if(ignore_plus_zoom)
 371                 {
 372                         --ignore_plus_zoom;
 373                         return false;
 374                 }
 375                 button_zoom = 1;
 376                 return true;
 377         } else if(strCmd == "-button4") { // zoom
 378                 if(ignore_minus_zoom)
 379                 {
 380                         --ignore_minus_zoom;
 381                         return false;
 382                 }
 383                 button_zoom = 0;
 384                 return true;
 385         } else if(strCmd == "+button3") { // secondary
 386                 button_attack2 = 1;
 387                 return false;
 388         } else if(strCmd == "-button3") { // secondary
 389                 button_attack2 = 0;
 390                 return false;
 391         } else if(strCmd == "+showscores") {
 392                 scoreboard_showscores = true;
 393                 return true;
 394         } else if(strCmd == "-showscores") {
 395                 scoreboard_showscores = false;
 396                 return true;
 397         } else if(strCmd == "+showaccuracy") {
 398                 scoreboard_showaccuracy = true;
 399                 return true;
 400         } else if(strCmd == "-showaccuracy") {
 401                 scoreboard_showaccuracy = false;
 402                 return true;
 403         }
 404
 405         if(camera_active)
 406         if(strCmd == "+forward" || strCmd == "-back") {
 407                 ++camera_direction_x;
 408                 return true;
 409         } else if(strCmd == "-forward" || strCmd == "+back") {
 410                 --camera_direction_x;
 411                 return true;
 412         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 413                 --camera_direction_y;
 414                 return true;
 415         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 416                 ++camera_direction_y;
 417                 return true;
 418         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 419                 ++camera_direction_z;
 420                 return true;
 421         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 422                 --camera_direction_z;
 423                 return true;
 424         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 425                 ++camera_roll;
 426                 return true;
 427         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 428                 --camera_roll;
 429                 return true;
 430         }
 431
 432         return false;
 433 }
 434
 435 .vector view_ofs;
 436 entity debug_shotorg;
 437 void ShotOrg_Draw()
 438 {
 439         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 440         self.angles = view_angles;
 441         self.angles_x = -self.angles_x;
 442         if not(self.cnt)
 443                 self.drawmask = MASK_NORMAL;
 444         else
 445                 self.drawmask = 0;
 446 }
 447 void ShotOrg_Draw2D()
 448 {
 449         vector coord2d_topleft, coord2d_topright, coord2d;
 450         string s;
 451         vector fs;
 452
 453         s = vtos(self.view_ofs);
 454         s = substring(s, 1, strlen(s) - 2);
 455         if(tokenize_console(s) == 3)
 456                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 457
 458         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 459         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 460
 461         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 462
 463         coord2d = coord2d_topleft;
 464         if(fs_x < 8)
 465         {
 466                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 467                 fs = '8 8 0';
 468         }
 469         coord2d_y -= fs_y;
 470         coord2d_z = 0;
 471         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 472 }
 473
 474 void ShotOrg_Spawn()
 475 {
 476         debug_shotorg = spawn();
 477         debug_shotorg.draw = ShotOrg_Draw;
 478         debug_shotorg.draw2d = ShotOrg_Draw2D;
 479         debug_shotorg.renderflags = RF_VIEWMODEL;
 480         debug_shotorg.effects = EF_FULLBRIGHT;
 481         precache_model("models/shotorg_adjuster.md3");
 482         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 483         debug_shotorg.scale = 2;
 484         debug_shotorg.view_ofs = '25 8 -8';
 485 }
 486
 487 void DrawDebugModel()
 488 {
 489         if(time - floor(time) > 0.5)
 490         {
 491                 PolyDrawModel(self);
 492                 self.drawmask = 0;
 493         }
 494         else
 495         {
 496                 self.renderflags = 0;
 497                 self.drawmask = MASK_NORMAL;
 498         }
 499 }
 500
 501 void GameCommand(string msg)
 502 {
 503         string s;
 504         float argc;
 505         entity e;
 506         argc = tokenize_console(msg);
 507
 508         if(argv(0) == "help" || argc == 0)
 509         {
 510                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 511                 print("  settemp cvar value\n");
 512                 print("  scoreboard_columns_set ...\n");
 513                 print("  scoreboard_columns_help\n");
 514                 GameCommand_Generic("help");
 515                 return;
 516         }
 517
 518         if(GameCommand_Generic(msg))
 519                 return;
 520
 521         string cmd;
 522         cmd = argv(0);
 523         if(cmd == "mv_download") {
 524                 Cmd_MapVote_MapDownload(argc);
 525         }
 526         else if(cmd == "settemp") {
 527                 cvar_clientsettemp(argv(1), argv(2));
 528         }
 529         else if(cmd == "scoreboard_columns_set") {
 530                 Cmd_HUD_SetFields(argc);
 531         }
 532         else if(cmd == "scoreboard_columns_help") {
 533                 Cmd_HUD_Help(argc);
 534         }
 535 #ifdef BLURTEST
 536         else if(cmd == "blurtest") {
 537                 blurtest_time0 = time;
 538                 blurtest_time1 = time + stof(argv(1));
 539                 blurtest_radius = stof(argv(2));
 540                 blurtest_power = stof(argv(3));
 541         }
 542 #endif
 543         else if(cmd == "shotorg_move") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_movez") {
 551                 if(!debug_shotorg)
 552                         ShotOrg_Spawn();
 553                 else
 554                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 556         }
 557         else if(cmd == "shotorg_set") {
 558                 if(!debug_shotorg)
 559                         ShotOrg_Spawn();
 560                 else
 561                         debug_shotorg.view_ofs = stov(argv(1));
 562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 563         }
 564         else if(cmd == "shotorg_setz") {
 565                 if(!debug_shotorg)
 566                         ShotOrg_Spawn();
 567                 else
 568                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 569                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 570         }
 571         else if(cmd == "shotorg_toggle_hide") {
 572                 if(debug_shotorg)
 573                 {
 574                         debug_shotorg.cnt = !debug_shotorg.cnt;
 575                 }
 576         }
 577         else if(cmd == "shotorg_end") {
 578                 if(debug_shotorg)
 579                 {
 580                         print(vtos(debug_shotorg.view_ofs), "\n");
 581                         remove(debug_shotorg);
 582                         debug_shotorg = world;
 583                 }
 584                 localcmd("sv_cmd debug_shotorg\n");
 585         }
 586         else if(cmd == "sendcvar") {
 587                 // W_FixWeaponOrder will trash argv, so save what we need.
 588                 string thiscvar;
 589                 thiscvar = strzone(argv(1));
 590                 s = cvar_string(thiscvar);
 591                 if(thiscvar == "cl_weaponpriority")
 592                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 593                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 595                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 596                 strunzone(thiscvar);
 597         }
 598         else if(cmd == "spawn") {
 599                 s = argv(1);
 600                 e = spawn();
 601                 precache_model(s);
 602                 setmodel(e, s);
 603                 setorigin(e, view_origin);
 604                 e.angles = view_angles;
 605                 e.draw = DrawDebugModel;
 606                 e.classname = "debugmodel";
 607         }
 608         else
 609         {
 610                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 611         }
 612
 613         return;
 614 }
 615
 616 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 617 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 618 // All keys are in ascii.
 619 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 620 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 621 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 622 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 623 {
 624         local float bSkipKey;
 625         bSkipKey = false;
 626
 627         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 628                 return true;
 629
 630         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 631                 return true;
 632
 633         if(menu_visible)
 634                 if(menu_action(bInputType, nPrimary, nSecondary))
 635                         return TRUE;
 636
 637         if(autocvar_cl_allow_uid2name == -1 && gametype == GAME_CTS || gametype == GAME_RACE && panel_fg_alpha) // don't lock keys before we actually see what's going on
 638         {
 639                 string vyes_keys;
 640                 float keys;
 641                 vyes_keys = findkeysforcommand("vyes");
 642                 keys = tokenize(vyes_keys);
 643
 644                 float i;
 645                 for (i = 0; i < keys; ++i)
 646                 {
 647                         if(nPrimary == stof(argv(i)))
 648                         {
 649                                 cvar_set("cl_allow_uid2name", "1");
 650                                 return true;
 651                         }
 652                 }
 653
 654                 string vno_keys;
 655                 vno_keys = findkeysforcommand("vno");
 656                 keys = tokenize(vno_keys);
 657
 658                 float i;
 659                 for (i = 0; i < keys; ++i)
 660                 {
 661                         if(nPrimary == stof(argv(i)))
 662                         {
 663                                 cvar_set("cl_allow_uid2name", "0");
 664                                 return true;
 665                         }
 666                 }
 667         }
 668
 669         return bSkipKey;
 670 }
 671
 672 // END REQUIRED CSQC FUNCTIONS
 673 // --------------------------------------------------------------------------
 674
 675 // --------------------------------------------------------------------------
 676 // BEGIN OPTIONAL CSQC FUNCTIONS
 677 void Ent_ReadEntCS()
 678 {
 679         InterpolateOrigin_Undo();
 680
 681         self.classname = "entcs_receiver";
 682         self.sv_entnum = ReadByte() - 1;
 683         self.origin_x = ReadShort();
 684         self.origin_y = ReadShort();
 685         self.origin_z = ReadShort();
 686         self.angles_y = ReadByte() * 360.0 / 256;
 687         self.origin_z = self.angles_x = self.angles_z = 0;
 688
 689         InterpolateOrigin_Note();
 690 }
 691
 692 void Ent_Remove();
 693
 694 void Ent_RemovePlayerScore()
 695 {
 696         float i;
 697
 698         if(self.owner)
 699         {
 700                 SetTeam(self.owner, -1);
 701                 self.owner.gotscores = 0;
 702                 for(i = 0; i < MAX_SCORE; ++i)
 703                         self.owner.(scores[i]) = 0; // clear all scores
 704         }
 705 }
 706
 707 void Ent_ReadPlayerScore()
 708 {
 709         float i, n;
 710         float isNew;
 711         entity o;
 712
 713         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 714         // (no I've never heard of M-x replace-string, sed, or anything like that)
 715         isNew = !self.owner; // workaround for DP bug
 716         n = ReadByte()-1;
 717
 718 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 719         if(!isNew && n != self.sv_entnum)
 720         {
 721                 print("A CSQC entity changed its owner!\n");
 722                 isNew = true;
 723                 Ent_Remove();
 724                 self.enttype = ENT_CLIENT_SCORES;
 725         }
 726 #endif
 727
 728         self.sv_entnum = n;
 729
 730         if not(playerslots[self.sv_entnum])
 731                 playerslots[self.sv_entnum] = spawn();
 732         o = self.owner = playerslots[self.sv_entnum];
 733         o.sv_entnum = self.sv_entnum;
 734         o.gotscores = 1;
 735
 736         //if not(o.sort_prev)
 737         //      RegisterPlayer(o);
 738         //playerchecker will do this for us later, if it has not already done so
 739
 740         float sf, lf;
 741 #if MAX_SCORE <= 8
 742         sf = ReadByte();
 743         lf = ReadByte();
 744 #else
 745         sf = ReadShort();
 746         lf = ReadShort();
 747 #endif
 748         float p;
 749         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 750                 if(sf & p)
 751                 {
 752                         if(lf & p)
 753                                 o.(scores[i]) = ReadInt24_t();
 754                         else
 755                                 o.(scores[i]) = ReadChar();
 756                 }
 757
 758         if(o.sort_prev)
 759                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 760
 761         self.entremove = Ent_RemovePlayerScore;
 762 }
 763
 764 void Ent_ReadTeamScore()
 765 {
 766         float i;
 767         entity o;
 768
 769         self.team = ReadByte();
 770         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 771
 772         float sf, lf;
 773 #if MAX_TEAMSCORE <= 8
 774         sf = ReadByte();
 775         lf = ReadByte();
 776 #else
 777         sf = ReadShort();
 778         lf = ReadShort();
 779 #endif
 780         float p;
 781         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 782                 if(sf & p)
 783                 {
 784                         if(lf & p)
 785                                 o.(teamscores[i]) = ReadInt24_t();
 786                         else
 787                                 o.(teamscores[i]) = ReadChar();
 788                 }
 789
 790         HUD_UpdateTeamPos(o);
 791 }
 792
 793 void Net_Reset()
 794 {
 795 }
 796
 797 void Ent_ClientData()
 798 {
 799         float f;
 800         float newspectatee_status;
 801
 802         f = ReadByte();
 803
 804         scoreboard_showscores_force = (f & 1);
 805
 806         if(f & 2)
 807         {
 808                 newspectatee_status = ReadByte();
 809                 if(newspectatee_status == player_localentnum)
 810                         newspectatee_status = -1; // observing
 811         }
 812         else
 813                 newspectatee_status = 0;
 814
 815         spectatorbutton_zoom = (f & 4);
 816
 817         if(f & 8)
 818         {
 819                 angles_held_status = 1;
 820                 angles_held_x = ReadAngle();
 821                 angles_held_y = ReadAngle();
 822                 angles_held_z = 0;
 823         }
 824         else
 825                 angles_held_status = 0;
 826
 827         if(newspectatee_status != spectatee_status)
 828         {
 829                 float i;
 830                 // clear the weapon accuracy stats
 831                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 832                         weapon_hits[i] = 0;
 833                         weapon_fired[i] = 0;
 834                 }
 835
 836                 // clear race stuff
 837                 race_laptime = 0;
 838                 race_checkpointtime = 0;
 839         }
 840         spectatee_status = newspectatee_status;
 841 }
 842
 843 void Ent_Nagger()
 844 {
 845         float nags, i, j, b, f;
 846
 847         nags = ReadByte();
 848
 849         if(nags & 128)
 850         {
 851                 if(vote_called_vote)
 852                         strunzone(vote_called_vote);
 853                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 854         }
 855
 856         if(nags & 1)
 857         {
 858                 for(j = 0; j < maxclients; ++j)
 859                         if(playerslots[j])
 860                                 playerslots[j].ready = 1;
 861                 for(i = 1; i <= maxclients; i += 8)
 862                 {
 863                         f = ReadByte();
 864                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 865                                 if not(f & b)
 866                                         if(playerslots[j])
 867                                                 playerslots[j].ready = 0;
 868                 }
 869         }
 870
 871         ready_waiting = (nags & 1);
 872         ready_waiting_for_me = (nags & 2);
 873         vote_waiting = (nags & 4);
 874         vote_waiting_for_me = (nags & 8);
 875         warmup_stage = (nags & 16);
 876 }
 877
 878 void Ent_RandomSeed()
 879 {
 880         float s;
 881         prandom_debug();
 882         s = ReadShort();
 883         psrandom(s);
 884 }
 885
 886 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 887 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 888 void Ent_RadarLink();
 889 void Ent_Init();
 890 void Ent_ScoresInfo();
 891 void(float bIsNewEntity) CSQC_Ent_Update =
 892 {
 893         float t;
 894         float savetime;
 895         t = ReadByte();
 896
 897         // set up the "time" global for received entities to be correct for interpolation purposes
 898         savetime = time;
 899         if(servertime)
 900         {
 901                 time = servertime;
 902         }
 903         else
 904         {
 905                 serverprevtime = time;
 906                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 907                 time = serverprevtime + serverdeltatime;
 908         }
 909
 910 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 911         if(self.enttype)
 912                 if(t != self.enttype)
 913                 {
 914                         print("A CSQC entity changed its type!\n");
 915                         Ent_Remove();
 916                         bIsNewEntity = 1;
 917                 }
 918 #endif
 919         self.enttype = t;
 920         switch(t)
 921         {
 922                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 923                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 924                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 925                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 926                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 927                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 928                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 929                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 930                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 931                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 932                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 933                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 934                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 935                 case ENT_CLIENT_INIT: Ent_Init(); break;
 936                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 937                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 938                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 939                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 940                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 941                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 942                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 943                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 944                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 945                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 946                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 947                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 948                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 949                 default:
 950                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 951                         break;
 952         }
 953
 954         time = savetime;
 955 };
 956 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 957 // used when an entity changes its type. For an entity that someone interacts
 958 // with others, make sure it can no longer do so.
 959 void Ent_Remove()
 960 {
 961         if(self.entremove)
 962                 self.entremove();
 963
 964         self.enttype = 0;
 965         self.classname = "";
 966         self.draw = menu_sub_null;
 967         self.entremove = menu_sub_null;
 968         // TODO possibly set more stuff to defaults
 969 }
 970 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 971 void CSQC_Ent_Remove()
 972 {
 973         if(self.enttype)
 974                 Ent_Remove();
 975         remove(self);
 976 }
 977
 978 void Gamemode_Init()
 979 {
 980         if(gametype == GAME_ONSLAUGHT) {
 981                 print(strcat("Using ", minimapname, " as minimap.\n"));
 982                 precache_pic("gfx/ons-cp-neutral.tga");
 983                 precache_pic("gfx/ons-cp-red.tga");
 984                 precache_pic("gfx/ons-cp-blue.tga");
 985                 precache_pic("gfx/ons-frame.tga");
 986                 precache_pic("gfx/ons-frame-team.tga");
 987         }
 988
 989         if not(isdemo())
 990         {
 991                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 992                 calledhooks |= HOOK_START;
 993         }
 994 }
 995 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 996 void CSQC_Parse_StuffCmd(string strMessage)
 997 {
 998         localcmd(strMessage);
 999 }
1000 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1001 void CSQC_Parse_Print(string strMessage)
1002 {
1003         print(ColorTranslateRGB(strMessage));
1004 }
1005
1006 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1007 void CSQC_Parse_CenterPrint(string strMessage)
1008 {
1009         centerprint(strMessage);
1010 }
1011
1012 string notranslate_fogcmd1 = "\nfog ";
1013 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1014 void Fog_Force()
1015 {
1016         // TODO somehow thwart prvm_globalset client ...
1017
1018         if(forcefog != "")
1019                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1020 }
1021
1022 void Gamemode_Init();
1023 void Ent_ScoresInfo()
1024 {
1025         float i;
1026         self.classname = "ent_client_scores_info";
1027         gametype = ReadByte();
1028         for(i = 0; i < MAX_SCORE; ++i)
1029         {
1030                 scores_label[i] = strzone(ReadString());
1031                 scores_flags[i] = ReadByte();
1032         }
1033         for(i = 0; i < MAX_TEAMSCORE; ++i)
1034         {
1035                 teamscores_label[i] = strzone(ReadString());
1036                 teamscores_flags[i] = ReadByte();
1037         }
1038         HUD_InitScores();
1039         Gamemode_Init();
1040 }
1041
1042 void Ent_Init()
1043 {
1044         self.classname = "ent_client_init";
1045
1046         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1047
1048         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1049         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1050         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1051         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1052         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1053         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1054         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1055         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1056         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1057         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1058         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1059         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1060
1061         if(forcefog)
1062                 strunzone(forcefog);
1063         forcefog = strzone(ReadString());
1064
1065         armorblockpercent = ReadByte() / 255.0;
1066
1067         g_weaponswitchdelay = ReadByte() / 255.0;
1068
1069         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1070         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1071
1072         nex_scope = !ReadByte();
1073         campingrifle_scope = !ReadByte();
1074
1075         if(!postinit)
1076                 PostInit();
1077 }
1078
1079 void Net_ReadRace()
1080 {
1081         float b;
1082
1083         b = ReadByte();
1084
1085         switch(b)
1086         {
1087                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1088                         race_checkpoint = ReadByte();
1089                         race_time = ReadInt24_t();
1090                         race_previousbesttime = ReadInt24_t();
1091                         if(race_previousbestname)
1092                                 strunzone(race_previousbestname);
1093                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1094
1095                         race_checkpointtime = time;
1096
1097                         if(race_checkpoint == 0 || race_checkpoint == 254)
1098                         {
1099                                 race_penaltyaccumulator = 0;
1100                                 race_laptime = time; // valid
1101                         }
1102
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_CLEAR:
1106                         race_laptime = 0;
1107                         race_checkpointtime = 0;
1108                         break;
1109
1110                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1111                         race_laptime = ReadCoord();
1112                         race_checkpointtime = -99999;
1113                         // fall through
1114                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1115                         race_nextcheckpoint = ReadByte();
1116
1117                         race_nextbesttime = ReadInt24_t();
1118                         if(race_nextbestname)
1119                                 strunzone(race_nextbestname);
1120                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1121                         break;
1122
1123                 case RACE_NET_CHECKPOINT_HIT_RACE:
1124                         race_mycheckpoint = ReadByte();
1125                         race_mycheckpointtime = time;
1126                         race_mycheckpointdelta = ReadInt24_t();
1127                         race_mycheckpointlapsdelta = ReadByte();
1128                         if(race_mycheckpointlapsdelta >= 128)
1129                                 race_mycheckpointlapsdelta -= 256;
1130                         if(race_mycheckpointenemy)
1131                                 strunzone(race_mycheckpointenemy);
1132                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1133                         break;
1134
1135                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1136                         race_othercheckpoint = ReadByte();
1137                         race_othercheckpointtime = time;
1138                         race_othercheckpointdelta = ReadInt24_t();
1139                         race_othercheckpointlapsdelta = ReadByte();
1140                         if(race_othercheckpointlapsdelta >= 128)
1141                                 race_othercheckpointlapsdelta -= 256;
1142                         if(race_othercheckpointenemy)
1143                                 strunzone(race_othercheckpointenemy);
1144                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1145                         break;
1146
1147                 case RACE_NET_PENALTY_RACE:
1148                         race_penaltyeventtime = time;
1149                         race_penaltytime = ReadShort();
1150                         //race_penaltyaccumulator += race_penaltytime;
1151                         if(race_penaltyreason)
1152                                 strunzone(race_penaltyreason);
1153                         race_penaltyreason = strzone(ReadString());
1154                         break;
1155
1156                 case RACE_NET_PENALTY_QUALIFYING:
1157                         race_penaltyeventtime = time;
1158                         race_penaltytime = ReadShort();
1159                         race_penaltyaccumulator += race_penaltytime;
1160                         if(race_penaltyreason)
1161                                 strunzone(race_penaltyreason);
1162                         race_penaltyreason = strzone(ReadString());
1163                         break;
1164
1165                 case RACE_NET_SERVER_RECORD:
1166                         race_server_record = ReadInt24_t();
1167                         break;
1168                 case RACE_NET_SPEED_AWARD:
1169                         race_speedaward = ReadInt24_t();
1170                         if(race_speedaward_holder)
1171                                 strunzone(race_speedaward_holder);
1172                         race_speedaward_holder = strzone(ReadString());
1173                         break;
1174                 case RACE_NET_SPEED_AWARD_BEST:
1175                         race_speedaward_alltimebest = ReadInt24_t();
1176                         if(race_speedaward_alltimebest_holder)
1177                                 strunzone(race_speedaward_alltimebest_holder);
1178                         race_speedaward_alltimebest_holder = strzone(ReadString());
1179                         break;
1180                 case RACE_NET_SERVER_RANKINGS:
1181                         float pos, prevpos, del;
1182                         pos = ReadShort();
1183                         prevpos = ReadShort();
1184                         del = ReadShort();
1185
1186                         // move other rankings out of the way
1187                         float i;
1188                         if (prevpos) {
1189                                 for (i=prevpos-1;i>pos-1;--i) {
1190                                         grecordtime[i] = grecordtime[i-1];
1191                                         if(grecordholder[i])
1192                                                 strunzone(grecordholder[i]);
1193                                         grecordholder[i] = strzone(grecordholder[i-1]);
1194                                 }
1195                         } else if (del) { // a record has been deleted by the admin
1196                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1197                                         if (i == RANKINGS_CNT-1) { // clear out last record
1198                                                 grecordtime[i] = 0;
1199                                                 if (grecordholder[i])
1200                                                         strunzone(grecordholder[i]);
1201                                                 grecordholder[i] = string_null;
1202                                         }
1203                                         else {
1204                                                 grecordtime[i] = grecordtime[i+1];
1205                                                 if (grecordholder[i])
1206                                                         strunzone(grecordholder[i]);
1207                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1208                                         }
1209                                 }
1210                         } else { // player has no ranked record yet
1211                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1212                                         grecordtime[i] = grecordtime[i-1];
1213                                         if(grecordholder[i])
1214                                                 strunzone(grecordholder[i]);
1215                                         grecordholder[i] = strzone(grecordholder[i-1]);
1216                                 }
1217                         }
1218
1219                         // store new ranking
1220                         if(grecordholder[pos-1] != "")
1221                                 strunzone(grecordholder[pos-1]);
1222                         grecordholder[pos-1] = strzone(ReadString());
1223                         grecordtime[pos-1] = ReadInt24_t();
1224                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1225                                 race_myrank = pos;
1226                         break;
1227                 case RACE_NET_SERVER_STATUS:
1228                         race_status = ReadShort();
1229                         if(race_status_name)
1230                                 strunzone(race_status_name);
1231                         race_status_name = strzone(ReadString());
1232         }
1233 }
1234
1235 void Net_ReadSpawn()
1236 {
1237         zoomin_effect = 1;
1238         current_viewzoom = 0.6;
1239 }
1240
1241 void Net_TeamNagger()
1242 {
1243         teamnagger = 1;
1244 }
1245
1246 void Net_ReadPingPLReport()
1247 {
1248         float e, pi, pl, ml;
1249         e = ReadByte();
1250         pi = ReadShort();
1251         pl = ReadByte();
1252         ml = ReadByte();
1253         if not(playerslots[e])
1254                 return;
1255         playerslots[e].ping = pi;
1256         playerslots[e].ping_packetloss = pl / 255.0;
1257         playerslots[e].ping_movementloss = ml / 255.0;
1258 }
1259
1260 void Net_VoteDialog(float highlight) {
1261         if(highlight) {
1262                 vote_highlighted = ReadByte();
1263                 return;
1264         }
1265
1266         vote_yescount = ReadByte();
1267         vote_nocount = ReadByte();
1268         vote_needed = ReadByte();
1269         vote_active = 1;
1270 }
1271
1272 void Net_VoteDialogReset() {
1273         vote_active = 0;
1274 }
1275
1276 void Net_Notify() {
1277         float type;
1278         type = ReadByte();
1279
1280         if(type == CSQC_KILLNOTIFY)
1281         {
1282                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1283         }
1284         else if(type == CSQC_CENTERPRINT)
1285         {
1286                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1287         }
1288 }
1289
1290 void Net_WeaponComplain() {
1291         complain_weapon = ReadByte();
1292
1293         if(complain_weapon_name)
1294                 strunzone(complain_weapon_name);
1295         complain_weapon_name = strzone(ReadString());
1296
1297         complain_weapon_type = ReadByte();
1298
1299         complain_weapon_time = time;
1300         weapontime = time; // ping the weapon panel
1301 }
1302
1303 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1304 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1305 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1306 float CSQC_Parse_TempEntity()
1307 {
1308         local float bHandled;
1309                 bHandled  = true;
1310         // Acquire TE ID
1311         local float nTEID;
1312                 nTEID = ReadByte();
1313
1314                 // NOTE: Could just do return instead of break...
1315         switch(nTEID)
1316         {
1317                 case TE_CSQC_TARGET_MUSIC:
1318                         Net_TargetMusic();
1319                         bHandled = true;
1320                         break;
1321                 case TE_CSQC_PICTURE:
1322                         Net_MapVote_Picture();
1323                         bHandled = true;
1324                         break;
1325                 case TE_CSQC_RACE:
1326                         Net_ReadRace();
1327                         bHandled = true;
1328                         break;
1329                 case TE_CSQC_SPAWN:
1330                         Net_ReadSpawn();
1331                         bHandled = true;
1332                         break;
1333                 case TE_CSQC_ZCURVEPARTICLES:
1334                         Net_ReadZCurveParticles();
1335                         bHandled = true;
1336                         break;
1337                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1338                         Net_ReadNexgunBeamParticle();
1339                         bHandled = true;
1340                         break;
1341                 case TE_CSQC_TEAMNAGGER:
1342                         Net_TeamNagger();
1343                         bHandled = true;
1344                         break;
1345                 case TE_CSQC_VOTE:
1346                         Net_VoteDialog(ReadByte());
1347                         bHandled = true;
1348                         break;
1349                 case TE_CSQC_VOTERESET:
1350                         Net_VoteDialogReset();
1351                         bHandled = true;
1352                         break;
1353                 case TE_CSQC_LIGHTNINGARC:
1354                         Net_ReadLightningarc();
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_PINGPLREPORT:
1358                         Net_ReadPingPLReport();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_ANNOUNCE:
1362                         announce_snd = strzone(ReadString());
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_NOTIFY:
1366                         Net_Notify();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_WEAPONCOMPLAIN:
1370                         Net_WeaponComplain();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_CR_MAXBULLETS:
1374                         cr_maxbullets = ReadByte();
1375                         bHandled = true;
1376                         break;
1377                 default:
1378                         // No special logic for this temporary entity; return 0 so the engine can handle it
1379                         bHandled = false;
1380                         break;
1381         }
1382
1383         return bHandled;
1384 }
1385
1386 string getcommandkey(string text, string command)
1387 {
1388         string keys;
1389         float n, j, k, l;
1390
1391         if (!hud_showbinds)
1392                 return text;
1393
1394         keys = db_get(binddb, command);
1395         if (!keys)
1396         {
1397                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1398                 for(j = 0; j < n; ++j)
1399                 {
1400                         k = stof(argv(j));
1401                         if(k != -1)
1402                         {
1403                                 if ("" == keys)
1404                                         keys = keynumtostring(k);
1405                                 else
1406                                         keys = strcat(keys, ", ", keynumtostring(k));
1407
1408                                 ++l;
1409                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1410                         }
1411
1412                 }
1413                 db_put(binddb, command, keys);
1414         }
1415
1416         if ("" == keys) {
1417                 if (hud_showbinds > 1)
1418                         return strcat(text, " (not bound)");
1419                 else
1420                         return text;
1421         }
1422         else if (hud_showbinds > 1)
1423                 return strcat(text, " (", keys, ")");
1424         else
1425                 return keys;
1426 }